new remote code

[scpubgit/Tak.git] / lib / Tak / ConnectorService.pm

package Tak::ConnectorService;

use IPC::Open2;
use IO::All;
use Tak::Router;
use Tak::Client;
use Tak::ConnectionService;
use Moo;

with 'Tak::Role::Service';

has connections => (is => 'ro', default => sub { Tak::Router->new });

sub handle_create {
  my ($self) = @_;
  my $kid_pid = IPC::Open2::open2(my $kid_out, my $kid_in, $^X, '-')
    or die "Couldn't open2 child: $!";
  io($kid_in)->print(io('maint/mk-fat |')->all, "__END__\n");
  my $connection = Tak::ConnectionService->new(
    read_fh => $kid_out, write_fh => $kid_in,
    listening_service => Tak::Router->new
  );
  my $client = Tak::Client->new(service => $connection);
  # actually, we should register with a monotonic id and
  # stash the pid elsewhere. but meh for now.
  my $pid = $client->do(meta => 'pid');
  $self->connections->register('|'.$pid, $connection);
  return ('proxy', '|'.$pid);
}

sub start_proxy_request {
  my ($self, $req, @payload) = @_;;
  $self->connections->start_request($req, @payload);
}

sub receive_proxy {
  my ($self, @payload) = @_;
  $self->connections->receive(@payload);
}

1;