t/14roundtrippin.t

   1 use warnings;
   2 use strict;
   3
   4 use Test::More;
   5 use Test::Exception;
   6
   7 use SQL::Abstract::Test import => [qw(is_same_sql dumper)];
   8 use SQL::Abstract::Tree;
   9
  10 my $sqlat = SQL::Abstract::Tree->new;
  11
  12 my @sql = (
  13   "INSERT INTO artist DEFAULT VALUES",
  14   "INSERT INTO artist VALUES ()",
  15   "SELECT a, b, c FROM foo WHERE foo.a = 1 and foo.b LIKE 'station'",
  16   "SELECT COUNT( * ) FROM foo",
  17   "SELECT COUNT( * ), SUM( blah ) FROM foo",
  18   "SELECT * FROM (SELECT * FROM foobar) WHERE foo.a = 1 and foo.b LIKE 'station'",
  19   "SELECT * FROM lolz WHERE ( foo.a = 1 ) and foo.b LIKE 'station'",
  20   "SELECT [screen].[id], [screen].[name], [screen].[section_id], [screen].[xtype] FROM [users_roles] [me] JOIN [roles] [role] ON [role].[id] = [me].[role_id] JOIN [roles_permissions] [role_permissions] ON [role_permissions].[role_id] = [role].[id] JOIN [permissions] [permission] ON [permission].[id] = [role_permissions].[permission_id] JOIN [permissionscreens] [permission_screens] ON [permission_screens].[permission_id] = [permission].[id] JOIN [screens] [screen] ON [screen].[id] = [permission_screens].[screen_id] WHERE ( [me].[user_id] = ? ) GROUP BY [screen].[id], [screen].[name], [screen].[section_id], [screen].[xtype]",
  21   "SELECT * FROM foo WHERE NOT EXISTS (SELECT bar FROM baz)",
  22   "SELECT * FROM (SELECT SUM (CASE WHEN me.artist = 'foo' THEN 1 ELSE 0 END AS artist_sum) FROM foobar) WHERE foo.a = 1 and foo.b LIKE 'station'",
  23   "SELECT COUNT( * ) FROM foo me JOIN bar rel_bar ON rel_bar.id_bar = me.fk_bar WHERE NOT EXISTS (SELECT inner_baz.id_baz FROM baz inner_baz WHERE ( ( inner_baz.fk_a != ? AND ( fk_bar = me.fk_bar AND name = me.name ) ) ) )",
  24   "SELECT foo AS bar FROM baz ORDER BY x + ? DESC, oomph, y - ? DESC, unf, baz.g / ? ASC, buzz * 0 DESC, foo DESC, ickk ASC",
  25   "SELECT inner_forum_roles.forum_id FROM forum_roles AS inner_forum_roles LEFT JOIN user_roles AS inner_user_roles USING(user_role_type_id) WHERE inner_user_roles.user_id = users__row.user_id",
  26   "SELECT * FROM foo WHERE foo.a @@ to_tsquery('word')",
  27   "SELECT * FROM foo ORDER BY name + ?, [me].[id]",
  28   "SELECT foo AS bar FROM baz ORDER BY x + ? DESC, baz.g",
  29   # deliberate batshit insanity
  30   "SELECT foo FROM bar WHERE > 12",
  31 );
  32
  33 # FIXME FIXME FIXME
  34 # The formatter/unparser accumulated a ton of technical debt,
  35 # and I don't have time to fix it all :( Some of the problems:
  36 # - format() does an implicit parenthesis unroll for prettyness
  37 #   which makes it hard to do exact comparisons
  38 # - there is no space preservation framework (also makes comparisons
  39 #   problematic)
  40 # - there is no operator case preservation framework either
  41 #
  42 # So what we do instead is resort to some monkey patching and
  43 # lowercasing and stuff to get something we can compare to the
  44 # original SQL string
  45 # Ugly but somewhat effective
  46
  47 for my $orig (@sql) {
  48   my $plain_formatted = $sqlat->format($orig);
  49   is_same_sql( $plain_formatted, $orig, 'Formatted string is_same_sql()-matched' );
  50
  51   my $ast = $sqlat->parse($orig);
  52   my $reassembled = do {
  53     no warnings 'redefine';
  54     local *SQL::Abstract::Tree::_parenthesis_unroll = sub {};
  55     $sqlat->unparse($ast);
  56   };
  57
  58   # deal with whitespace around parenthesis readjustment
  59   $_ =~ s/ \s* ( [ \(\) ] ) \s* /$1/gx
  60     for ($orig, $reassembled);
  61
  62   is (
  63     lc($reassembled),
  64     lc($orig),
  65     sprintf( 'roundtrip works (%s...)', substr $orig, 0, 20 )
  66   ) or do {
  67     my ($ast1, $ast2) = map { dumper( $sqlat->parse($_) ) } ( $orig, $reassembled );
  68
  69     note "ast1: $ast1";
  70     note "ast2: $ast2";
  71   };
  72 }
  73
  74 # this is invalid SQL, we are just checking that the parser
  75 # does not inadvertently make it right
  76 my $sql = 'SELECT * FROM foo WHERE x IN ( ( 1 ) )';
  77 is(
  78   $sqlat->unparse($sqlat->parse($sql)),
  79   $sql,
  80   'Multi-parens around IN survive',
  81 );
  82
  83 lives_ok { $sqlat->unparse( $sqlat->parse( <<'EOS' ) ) } 'Able to parse/unparse grossly malformed sql';
  84 SELECT
  85   (
  86     SELECT *, *  FROM EXISTS bar JOIN ON a = b
  87     NOT WHERE c !!= d
  88   ),
  89   NOT x,
  90   (
  91     SELECT * FROM bar WHERE NOT NOT EXISTS (SELECT 1)
  92   ),
  93 WHERE NOT NOT 1 AND OR foo IN (1,2,,,3,,,),
  94 GROUP BY bar
  95
  96 EOS
  97
  98 done_testing;