lib/SQL/Abstract/Tree.pm

   1 package SQL::Abstract::Tree;
   2
   3 use strict;
   4 use warnings;
   5 no warnings 'qw';
   6 use Carp;
   7
   8 use Hash::Merge qw//;
   9
  10 use base 'Class::Accessor::Grouped';
  11
  12 __PACKAGE__->mk_group_accessors( simple => qw(
  13    newline indent_string indent_amount colormap indentmap fill_in_placeholders
  14    placeholder_surround
  15 ));
  16
  17 my $merger = Hash::Merge->new;
  18
  19 $merger->specify_behavior({
  20    SCALAR => {
  21       SCALAR => sub { $_[1] },
  22       ARRAY  => sub { [ $_[0], @{$_[1]} ] },
  23       HASH   => sub { $_[1] },
  24    },
  25    ARRAY => {
  26       SCALAR => sub { $_[1] },
  27       ARRAY  => sub { $_[1] },
  28       HASH   => sub { $_[1] },
  29    },
  30    HASH => {
  31       SCALAR => sub { $_[1] },
  32       ARRAY  => sub { [ values %{$_[0]}, @{$_[1]} ] },
  33       HASH   => sub { Hash::Merge::_merge_hashes( $_[0], $_[1] ) },
  34    },
  35 }, 'SQLA::Tree Behavior' );
  36
  37 my $op_look_ahead = '(?: (?= [\s\)\(\;] ) | \z)';
  38 my $op_look_behind = '(?: (?<= [\,\s\)\(] ) | \A )';
  39
  40 my $quote_left = qr/[\`\'\"\[]/;
  41 my $quote_right = qr/[\`\'\"\]]/;
  42
  43 my $placeholder_re = qr/(?: \? | \$\d+ )/x;
  44
  45 # These SQL keywords always signal end of the current expression (except inside
  46 # of a parenthesized subexpression).
  47 # Format: A list of strings that will be compiled to extended syntax ie.
  48 # /.../x) regexes, without capturing parentheses. They will be automatically
  49 # anchored to op boundaries (excluding quotes) to match the whole token.
  50 my @expression_start_keywords = (
  51   'SELECT',
  52   'UPDATE',
  53   'SET',
  54   'INSERT \s+ INTO',
  55   'DELETE \s+ FROM',
  56   'FROM',
  57   '(?:
  58     (?:
  59         (?: (?: LEFT | RIGHT | FULL ) \s+ )?
  60         (?: (?: CROSS | INNER | OUTER ) \s+ )?
  61     )?
  62     JOIN
  63   )',
  64   'ON',
  65   'WHERE',
  66   '(?: DEFAULT \s+ )? VALUES',
  67   'GROUP \s+ BY',
  68   'HAVING',
  69   'ORDER \s+ BY',
  70   'SKIP',
  71   'FIRST',
  72   'LIMIT',
  73   'OFFSET',
  74   'FOR',
  75   'UNION',
  76   'INTERSECT',
  77   'EXCEPT',
  78   'BEGIN \s+ WORK',
  79   'COMMIT',
  80   'ROLLBACK \s+ TO \s+ SAVEPOINT',
  81   'ROLLBACK',
  82   'SAVEPOINT',
  83   'RELEASE \s+ SAVEPOINT',
  84   'RETURNING',
  85   'ROW_NUMBER \s* \( \s* \) \s+ OVER',
  86 );
  87
  88 my $expr_start_re = join ("\n\t|\n", @expression_start_keywords );
  89 $expr_start_re = qr/ $op_look_behind (?i: $expr_start_re ) $op_look_ahead /x;
  90
  91 # These are binary operator keywords always a single LHS and RHS
  92 # * AND/OR are handled separately as they are N-ary
  93 # * so is NOT as being unary
  94 # * BETWEEN without paranthesis around the ANDed arguments (which
  95 #   makes it a non-binary op) is detected and accomodated in
  96 #   _recurse_parse()
  97 # * AS is not really an operator but is handled here as it's also LHS/RHS
  98
  99 # this will be included in the $binary_op_re, the distinction is interesting during
 100 # testing as one is tighter than the other, plus alphanum cmp ops have different
 101 # look ahead/behind (e.g. "x"="y" )
 102 my @alphanum_cmp_op_keywords = (qw/< > != <> = <= >= /);
 103 my $alphanum_cmp_op_re = join ("\n\t|\n", map
 104   { "(?: (?<= [\\w\\s] | $quote_right ) | \\A )"  . quotemeta ($_) . "(?: (?= [\\w\\s] | $quote_left ) | \\z )" }
 105   @alphanum_cmp_op_keywords
 106 );
 107 $alphanum_cmp_op_re = qr/$alphanum_cmp_op_re/x;
 108
 109 my $binary_op_re = '(?: NOT \s+)? (?:' . join ('|', qw/IN BETWEEN R?LIKE/) . ')';
 110 $binary_op_re = join "\n\t|\n",
 111   "$op_look_behind (?i: $binary_op_re | AS ) $op_look_ahead",
 112   $alphanum_cmp_op_re,
 113   $op_look_behind . 'IS (?:\s+ NOT)?' . "(?= \\s+ NULL \\b | $op_look_ahead )",
 114 ;
 115 $binary_op_re = qr/$binary_op_re/x;
 116
 117 my $unary_op_re = '(?: NOT \s+ EXISTS | NOT )';
 118 $unary_op_re = join "\n\t|\n",
 119   "$op_look_behind (?i: $unary_op_re ) $op_look_ahead",
 120 ;
 121 $unary_op_re = qr/$unary_op_re/x;
 122
 123 my $asc_desc_re = qr/$op_look_behind (?i: ASC | DESC ) $op_look_ahead /x;
 124 my $and_or_re = qr/$op_look_behind (?i: AND | OR ) $op_look_ahead /x;
 125
 126 my $tokenizer_re = join("\n\t|\n",
 127   $expr_start_re,
 128   $binary_op_re,
 129   $unary_op_re,
 130   $asc_desc_re,
 131   $and_or_re,
 132   $op_look_behind . ' \* ' . $op_look_ahead,
 133   (map { quotemeta $_ } qw/, ( )/),
 134   $placeholder_re,
 135 );
 136
 137 # this one *is* capturing for the split below
 138 # splits on whitespace if all else fails
 139 # has to happen before the composiign qr's are anchored (below)
 140 $tokenizer_re = qr/ \s* ( $tokenizer_re ) \s* | \s+ /x;
 141
 142 # Parser states for _recurse_parse()
 143 use constant PARSE_TOP_LEVEL => 0;
 144 use constant PARSE_IN_EXPR => 1;
 145 use constant PARSE_IN_PARENS => 2;
 146 use constant PARSE_IN_FUNC => 3;
 147 use constant PARSE_RHS => 4;
 148 use constant PARSE_LIST_ELT => 5;
 149
 150 my $expr_term_re = qr/$expr_start_re | \)/x;
 151 my $rhs_term_re = qr/ $expr_term_re | $binary_op_re | $unary_op_re | $asc_desc_re | $and_or_re | \, /x;
 152 my $all_std_keywords_re = qr/ $rhs_term_re | \( | $placeholder_re /x;
 153
 154 # anchor everything - even though keywords are separated by the tokenizer, leakage may occur
 155 for (
 156   $quote_left,
 157   $quote_right,
 158   $placeholder_re,
 159   $expr_start_re,
 160   $alphanum_cmp_op_re,
 161   $binary_op_re,
 162   $unary_op_re,
 163   $asc_desc_re,
 164   $and_or_re,
 165   $expr_term_re,
 166   $rhs_term_re,
 167   $all_std_keywords_re,
 168 ) {
 169   $_ = qr/ \A $_ \z /x;
 170 }
 171
 172
 173
 174 my %indents = (
 175    select        => 0,
 176    update        => 0,
 177    'insert into' => 0,
 178    'delete from' => 0,
 179    from          => 1,
 180    where         => 0,
 181    join          => 1,
 182    'left join'   => 1,
 183    on            => 2,
 184    having        => 0,
 185    'group by'    => 0,
 186    'order by'    => 0,
 187    set           => 1,
 188    into          => 1,
 189    values        => 1,
 190    limit         => 1,
 191    offset        => 1,
 192    skip          => 1,
 193    first         => 1,
 194 );
 195
 196 my %profiles = (
 197    console => {
 198       fill_in_placeholders => 1,
 199       placeholder_surround => ['?/', ''],
 200       indent_string => ' ',
 201       indent_amount => 2,
 202       newline       => "\n",
 203       colormap      => {},
 204       indentmap     => \%indents,
 205
 206       eval { require Term::ANSIColor }
 207         ? do {
 208           my $c = \&Term::ANSIColor::color;
 209
 210           my $red     = [$c->('red')    , $c->('reset')];
 211           my $cyan    = [$c->('cyan')   , $c->('reset')];
 212           my $green   = [$c->('green')  , $c->('reset')];
 213           my $yellow  = [$c->('yellow') , $c->('reset')];
 214           my $blue    = [$c->('blue')   , $c->('reset')];
 215           my $magenta = [$c->('magenta'), $c->('reset')];
 216           my $b_o_w   = [$c->('black on_white'), $c->('reset')];
 217           (
 218             placeholder_surround => [$c->('black on_magenta'), $c->('reset')],
 219             colormap => {
 220               'begin work'            => $b_o_w,
 221               commit                  => $b_o_w,
 222               rollback                => $b_o_w,
 223               savepoint               => $b_o_w,
 224               'rollback to savepoint' => $b_o_w,
 225               'release savepoint'     => $b_o_w,
 226
 227               select                  => $red,
 228               'insert into'           => $red,
 229               update                  => $red,
 230               'delete from'           => $red,
 231
 232               set                     => $cyan,
 233               from                    => $cyan,
 234
 235               where                   => $green,
 236               values                  => $yellow,
 237
 238               join                    => $magenta,
 239               'left join'             => $magenta,
 240               on                      => $blue,
 241
 242               'group by'              => $yellow,
 243               having                  => $yellow,
 244               'order by'              => $yellow,
 245
 246               skip                    => $green,
 247               first                   => $green,
 248               limit                   => $green,
 249               offset                  => $green,
 250             }
 251           );
 252         } : (),
 253    },
 254    console_monochrome => {
 255       fill_in_placeholders => 1,
 256       placeholder_surround => ['?/', ''],
 257       indent_string => ' ',
 258       indent_amount => 2,
 259       newline       => "\n",
 260       colormap      => {},
 261       indentmap     => \%indents,
 262    },
 263    html => {
 264       fill_in_placeholders => 1,
 265       placeholder_surround => ['<span class="placeholder">', '</span>'],
 266       indent_string => '&nbsp;',
 267       indent_amount => 2,
 268       newline       => "<br />\n",
 269       colormap      => {
 270          select        => ['<span class="select">'  , '</span>'],
 271          'insert into' => ['<span class="insert-into">'  , '</span>'],
 272          update        => ['<span class="select">'  , '</span>'],
 273          'delete from' => ['<span class="delete-from">'  , '</span>'],
 274
 275          set           => ['<span class="set">', '</span>'],
 276          from          => ['<span class="from">'    , '</span>'],
 277
 278          where         => ['<span class="where">'   , '</span>'],
 279          values        => ['<span class="values">', '</span>'],
 280
 281          join          => ['<span class="join">'    , '</span>'],
 282          'left join'   => ['<span class="left-join">','</span>'],
 283          on            => ['<span class="on">'      , '</span>'],
 284
 285          'group by'    => ['<span class="group-by">', '</span>'],
 286          having        => ['<span class="having">',   '</span>'],
 287          'order by'    => ['<span class="order-by">', '</span>'],
 288
 289          skip          => ['<span class="skip">',   '</span>'],
 290          first         => ['<span class="first">',  '</span>'],
 291          limit         => ['<span class="limit">',  '</span>'],
 292          offset        => ['<span class="offset">', '</span>'],
 293
 294          'begin work'  => ['<span class="begin-work">', '</span>'],
 295          commit        => ['<span class="commit">', '</span>'],
 296          rollback      => ['<span class="rollback">', '</span>'],
 297          savepoint     => ['<span class="savepoint">', '</span>'],
 298          'rollback to savepoint' => ['<span class="rollback-to-savepoint">', '</span>'],
 299          'release savepoint'     => ['<span class="release-savepoint">', '</span>'],
 300       },
 301       indentmap     => \%indents,
 302    },
 303    none => {
 304       colormap      => {},
 305       indentmap     => {},
 306    },
 307 );
 308
 309 sub new {
 310    my $class = shift;
 311    my $args  = shift || {};
 312
 313    my $profile = delete $args->{profile} || 'none';
 314
 315    die "No such profile '$profile'!" unless exists $profiles{$profile};
 316
 317    my $data = $merger->merge( $profiles{$profile}, $args );
 318
 319    bless $data, $class
 320 }
 321
 322 sub parse {
 323   my ($self, $s) = @_;
 324
 325   # tokenize string, and remove all optional whitespace
 326   my $tokens = [];
 327   foreach my $token (split $tokenizer_re, $s) {
 328     push @$tokens, $token if (
 329       defined $token
 330         and
 331       length $token
 332         and
 333       $token =~ /\S/
 334     );
 335   }
 336
 337   return [ $self->_recurse_parse($tokens, PARSE_TOP_LEVEL) ];
 338 }
 339
 340 sub _recurse_parse {
 341   my ($self, $tokens, $state) = @_;
 342
 343   my @left;
 344   while (1) { # left-associative parsing
 345
 346     if ( ! @$tokens
 347           or
 348         ($state == PARSE_IN_PARENS && $tokens->[0] eq ')')
 349           or
 350         ($state == PARSE_IN_EXPR && $tokens->[0] =~ $expr_term_re )
 351           or
 352         ($state == PARSE_RHS && $tokens->[0] =~ $rhs_term_re )
 353           or
 354         ($state == PARSE_LIST_ELT && ( $tokens->[0] eq ',' or $tokens->[0] =~ $expr_term_re ) )
 355     ) {
 356       return @left;
 357     }
 358
 359     my $token = shift @$tokens;
 360
 361     # nested expression in ()
 362     if ($token eq '(' ) {
 363       my @right = $self->_recurse_parse($tokens, PARSE_IN_PARENS);
 364       $token = shift @$tokens   or croak "missing closing ')' around block " . $self->unparse(\@right);
 365       $token eq ')'             or croak "unexpected token '$token' terminating block " . $self->unparse(\@right);
 366
 367       push @left, [ '-PAREN' => \@right ];
 368     }
 369
 370     # AND/OR
 371     elsif ($token =~ $and_or_re) {
 372       my $op = uc $token;
 373
 374       my @right = $self->_recurse_parse($tokens, PARSE_IN_EXPR);
 375
 376       # Merge chunks if "logic" matches
 377       @left = [ $op => [ @left, (@right and $op eq $right[0][0])
 378         ? @{ $right[0][1] }
 379         : @right
 380       ] ];
 381     }
 382
 383     # LIST (,)
 384     elsif ($token eq ',') {
 385
 386       my @right = $self->_recurse_parse($tokens, PARSE_LIST_ELT);
 387
 388       # deal with malformed lists ( foo, bar, , baz )
 389       @right = [] unless @right;
 390
 391       @right = [ -MISC => [ @right ] ] if @right > 1;
 392
 393       if (!@left) {
 394         @left = [ -LIST => [ [], @right ] ];
 395       }
 396       elsif ($left[0][0] eq '-LIST') {
 397         push @{$left[0][1]}, (@{$right[0]} and  $right[0][0] eq '-LIST')
 398           ? @{$right[0][1]}
 399           : @right
 400         ;
 401       }
 402       else {
 403         @left = [ -LIST => [ @left, @right ] ];
 404       }
 405     }
 406
 407     # binary operator keywords
 408     elsif ($token =~ $binary_op_re) {
 409       my $op = uc $token;
 410
 411       my @right = $self->_recurse_parse($tokens, PARSE_RHS);
 412
 413       # A between with a simple LITERAL for a 1st RHS argument needs a
 414       # rerun of the search to (hopefully) find the proper AND construct
 415       if ($op eq 'BETWEEN' and $right[0] eq '-LITERAL') {
 416         unshift @$tokens, $right[1][0];
 417         @right = $self->_recurse_parse($tokens, PARSE_IN_EXPR);
 418       }
 419
 420       @left = [$op => [ @left, @right ]];
 421     }
 422
 423     # unary op keywords
 424     elsif ( $token =~ $unary_op_re ) {
 425       my $op = uc $token;
 426       my @right = $self->_recurse_parse ($tokens, PARSE_RHS);
 427
 428       push @left, [ $op => \@right ];
 429     }
 430
 431     # expression terminator keywords
 432     elsif ( $token =~ $expr_start_re ) {
 433       my $op = uc $token;
 434       my @right = $self->_recurse_parse($tokens, PARSE_IN_EXPR);
 435
 436       push @left, [ $op => \@right ];
 437     }
 438
 439     # a '?'
 440     elsif ( $token =~ $placeholder_re) {
 441       push @left, [ -PLACEHOLDER => [ $token ] ];
 442     }
 443
 444     # check if the current token is an unknown op-start
 445     elsif (@$tokens and ($tokens->[0] eq '(' or $tokens->[0] =~ $placeholder_re ) ) {
 446       push @left, [ $token => [ $self->_recurse_parse($tokens, PARSE_RHS) ] ];
 447     }
 448
 449     # we're now in "unknown token" land - start eating tokens until
 450     # we see something familiar, OR in the case of RHS (binop) stop
 451     # after the first token
 452     # Also stop processing when we could end up with an unknown func
 453     else {
 454       my @lits = [ -LITERAL => [$token] ];
 455
 456       unless ( $state == PARSE_RHS ) {
 457         while (
 458           @$tokens
 459             and
 460           $tokens->[0] !~ $all_std_keywords_re
 461             and
 462           ! ( @$tokens > 1 and $tokens->[1] eq '(' )
 463         ) {
 464           push @lits, [ -LITERAL => [ shift @$tokens ] ];
 465          }
 466       }
 467
 468       if (@left == 1) {
 469         unshift @lits, pop @left;
 470        }
 471
 472       @lits = [ -MISC => [ @lits ] ] if @lits > 1;
 473
 474       push @left, @lits;
 475     }
 476
 477     if (@$tokens) {
 478
 479       # deal with post-fix operators (asc/desc)
 480       if ($tokens->[0] =~ $asc_desc_re) {
 481         return @left if $state == PARSE_RHS;
 482         @left = [ ('-' . uc (shift @$tokens)) => [ @left ] ];
 483       }
 484
 485       return @left if $state == PARSE_RHS and $left[-1][0] eq '-LITERAL';
 486     }
 487   }
 488 }
 489
 490 sub format_keyword {
 491   my ($self, $keyword) = @_;
 492
 493   if (my $around = $self->colormap->{lc $keyword}) {
 494      $keyword = "$around->[0]$keyword$around->[1]";
 495   }
 496
 497   return $keyword
 498 }
 499
 500 my %starters = (
 501    select        => 1,
 502    update        => 1,
 503    'insert into' => 1,
 504    'delete from' => 1,
 505 );
 506
 507 sub pad_keyword {
 508    my ($self, $keyword, $depth) = @_;
 509
 510    my $before = '';
 511    if (defined $self->indentmap->{lc $keyword}) {
 512       $before = $self->newline . $self->indent($depth + $self->indentmap->{lc $keyword});
 513    }
 514    $before = '' if $depth == 0 and defined $starters{lc $keyword};
 515    return [$before, ''];
 516 }
 517
 518 sub indent { ($_[0]->indent_string||'') x ( ( $_[0]->indent_amount || 0 ) * $_[1] ) }
 519
 520 sub _is_key {
 521    my ($self, $tree) = @_;
 522    $tree = $tree->[0] while ref $tree;
 523
 524    defined $tree && defined $self->indentmap->{lc $tree};
 525 }
 526
 527 sub fill_in_placeholder {
 528    my ($self, $bindargs) = @_;
 529
 530    if ($self->fill_in_placeholders) {
 531       my $val = shift @{$bindargs} || '';
 532       my $quoted = $val =~ s/^(['"])(.*)\1$/$2/;
 533       my ($left, $right) = @{$self->placeholder_surround};
 534       $val =~ s/\\/\\\\/g;
 535       $val =~ s/'/\\'/g;
 536       $val = qq('$val') if $quoted;
 537       return qq($left$val$right)
 538    }
 539    return '?'
 540 }
 541
 542 # FIXME - terrible name for a user facing API
 543 sub unparse {
 544   my ($self, $tree, $bindargs) = @_;
 545   $self->_unparse($tree, [@{$bindargs||[]}], 0);
 546 }
 547
 548 sub _unparse {
 549   my ($self, $tree, $bindargs, $depth) = @_;
 550
 551   if (not $tree or not @$tree) {
 552     return '';
 553   }
 554
 555   # FIXME - needs a config switch to disable
 556   $self->_parenthesis_unroll($tree);
 557
 558   my ($op, $args) = @{$tree}[0,1];
 559
 560   if (! defined $op or (! ref $op and ! defined $args) ) {
 561     require Data::Dumper;
 562     Carp::confess( sprintf ( "Internal error - malformed branch at depth $depth:\n%s",
 563       Data::Dumper::Dumper($tree)
 564     ) );
 565   }
 566
 567   if (ref $op) {
 568     return join (' ', map $self->_unparse($_, $bindargs, $depth), @$tree);
 569   }
 570   elsif ($op eq '-LITERAL') { # literal has different sig
 571     return $args->[0];
 572   }
 573   elsif ($op eq '-PLACEHOLDER') {
 574     return $self->fill_in_placeholder($bindargs);
 575   }
 576   elsif ($op eq '-PAREN') {
 577     return sprintf ('( %s )',
 578       join (' ', map { $self->_unparse($_, $bindargs, $depth + 2) } @{$args} )
 579         .
 580       ($self->_is_key($args)
 581         ? ( $self->newline||'' ) . $self->indent($depth + 1)
 582         : ''
 583       )
 584     );
 585   }
 586   elsif ($op eq 'AND' or $op eq 'OR' or $op =~ $binary_op_re ) {
 587     return join (" $op ", map $self->_unparse($_, $bindargs, $depth), @{$args});
 588   }
 589   elsif ($op eq '-LIST' ) {
 590     return join (', ', map $self->_unparse($_, $bindargs, $depth), @{$args});
 591   }
 592   elsif ($op eq '-MISC' ) {
 593     return join (' ', map $self->_unparse($_, $bindargs, $depth), @{$args});
 594   }
 595   elsif ($op =~ qr/^-(ASC|DESC)$/ ) {
 596     my $dir = $1;
 597     return join (' ', (map $self->_unparse($_, $bindargs, $depth), @{$args}), $dir);
 598   }
 599   else {
 600     my ($l, $r) = @{$self->pad_keyword($op, $depth)};
 601
 602     my $rhs = $self->_unparse($args, $bindargs, $depth);
 603
 604     return sprintf "$l%s$r", join(
 605       ( ref $args eq 'ARRAY' and @{$args} == 1 and $args->[0][0] eq '-PAREN' )
 606         ? ''    # mysql--
 607         : ' '
 608       ,
 609       $self->format_keyword($op),
 610       (length $rhs ? $rhs : () ),
 611     );
 612   }
 613 }
 614
 615 # All of these keywords allow their parameters to be specified with or without parenthesis without changing the semantics
 616 my @unrollable_ops = (
 617   'ON',
 618   'WHERE',
 619   'GROUP \s+ BY',
 620   'HAVING',
 621   'ORDER \s+ BY',
 622   'I?LIKE',
 623 );
 624 my $unrollable_ops_re = join ' | ', @unrollable_ops;
 625 $unrollable_ops_re = qr/$unrollable_ops_re/xi;
 626
 627 sub _parenthesis_unroll {
 628   my $self = shift;
 629   my $ast = shift;
 630
 631   return unless (ref $ast and ref $ast->[1]);
 632
 633   my $changes;
 634   do {
 635     my @children;
 636     $changes = 0;
 637
 638     for my $child (@{$ast->[1]}) {
 639
 640       # the current node in this loop is *always* a PAREN
 641       if (! ref $child or ! @$child or $child->[0] ne '-PAREN') {
 642         push @children, $child;
 643         next;
 644       }
 645
 646       # unroll nested parenthesis
 647       while ( @{$child->[1]} == 1 and $child->[1][0][0] eq '-PAREN') {
 648         $child = $child->[1][0];
 649         $changes++;
 650       }
 651
 652       # if the parent operator explcitly allows it nuke the parenthesis
 653       if ( $ast->[0] =~ $unrollable_ops_re ) {
 654         push @children, @{$child->[1]};
 655         $changes++;
 656       }
 657
 658       # if the parenthesis are wrapped around an AND/OR matching the parent AND/OR - open the parenthesis up and merge the list
 659       elsif (
 660         @{$child->[1]} == 1
 661             and
 662         ( $ast->[0] eq 'AND' or $ast->[0] eq 'OR')
 663             and
 664         $child->[1][0][0] eq $ast->[0]
 665       ) {
 666         push @children, @{$child->[1][0][1]};
 667         $changes++;
 668       }
 669
 670       # only *ONE* LITERAL or placeholder element
 671       # as an AND/OR/NOT argument
 672       elsif (
 673         @{$child->[1]} == 1 && (
 674           $child->[1][0][0] eq '-LITERAL'
 675             or
 676           $child->[1][0][0] eq '-PLACEHOLDER'
 677         ) && (
 678           $ast->[0] eq 'AND' or $ast->[0] eq 'OR' or $ast->[0] eq 'NOT'
 679         )
 680       ) {
 681         push @children, @{$child->[1]};
 682         $changes++;
 683       }
 684
 685       # an AND/OR expression with only one binop in the parenthesis
 686       # with exactly two grandchildren
 687       # the only time when we can *not* unroll this is when both
 688       # the parent and the child are mathops (in which case we'll
 689       # break precedence) or when the child is BETWEEN (special
 690       # case)
 691       elsif (
 692         @{$child->[1]} == 1
 693           and
 694         ($ast->[0] eq 'AND' or $ast->[0] eq 'OR')
 695           and
 696         $child->[1][0][0] =~ $binary_op_re
 697           and
 698         $child->[1][0][0] ne 'BETWEEN'
 699           and
 700         @{$child->[1][0][1]} == 2
 701           and
 702         ! (
 703           $child->[1][0][0] =~ $alphanum_cmp_op_re
 704             and
 705           $ast->[0] =~ $alphanum_cmp_op_re
 706         )
 707       ) {
 708         push @children, @{$child->[1]};
 709         $changes++;
 710       }
 711
 712       # a function binds tighter than a mathop - see if our ancestor is a
 713       # mathop, and our content is:
 714       # a single non-mathop child with a single PAREN grandchild which
 715       # would indicate mathop ( nonmathop ( ... ) )
 716       # or a single non-mathop with a single LITERAL ( nonmathop foo )
 717       # or a single non-mathop with a single PLACEHOLDER ( nonmathop ? )
 718       elsif (
 719         @{$child->[1]} == 1
 720           and
 721         @{$child->[1][0][1]} == 1
 722           and
 723         $ast->[0] =~ $alphanum_cmp_op_re
 724           and
 725         $child->[1][0][0] !~ $alphanum_cmp_op_re
 726           and
 727         (
 728           $child->[1][0][1][0][0] eq '-PAREN'
 729             or
 730           $child->[1][0][1][0][0] eq '-LITERAL'
 731             or
 732           $child->[1][0][1][0][0] eq '-PLACEHOLDER'
 733         )
 734       ) {
 735         push @children, @{$child->[1]};
 736         $changes++;
 737       }
 738
 739       # a construct of ... ( somefunc ( ... ) ) ... can safely lose the outer parens
 740       # except for the case of ( NOT ( ... ) ) which has already been handled earlier
 741       elsif (
 742         @{$child->[1]} == 1
 743           and
 744         @{$child->[1][0][1]} == 1
 745           and
 746         $child->[1][0][0] ne 'NOT'
 747           and
 748         ref $child->[1][0][1][0] eq 'ARRAY'
 749           and
 750         $child->[1][0][1][0][0] eq '-PAREN'
 751       ) {
 752         push @children, @{$child->[1]};
 753         $changes++;
 754       }
 755
 756
 757       # otherwise no more mucking for this pass
 758       else {
 759         push @children, $child;
 760       }
 761     }
 762
 763     $ast->[1] = \@children;
 764
 765   } while ($changes);
 766 }
 767
 768 sub _strip_asc_from_order_by {
 769   my ($self, $ast) = @_;
 770
 771   return $ast if (
 772     ref $ast ne 'ARRAY'
 773       or
 774     $ast->[0] ne 'ORDER BY'
 775   );
 776
 777
 778   my $to_replace;
 779
 780   if (@{$ast->[1]} == 1 and $ast->[1][0][0] eq '-ASC') {
 781     $to_replace = [ $ast->[1][0] ];
 782   }
 783   elsif (@{$ast->[1]} == 1 and $ast->[1][0][0] eq '-LIST') {
 784     $to_replace = [ grep { $_->[0] eq '-ASC' } @{$ast->[1][0][1]} ];
 785   }
 786
 787   @$_ = @{$_->[1][0]} for @$to_replace;
 788
 789   $ast;
 790 }
 791
 792 sub format { my $self = shift; $self->unparse($self->parse($_[0]), $_[1]) }
 793
 794 1;
 795
 796 =pod
 797
 798 =head1 NAME
 799
 800 SQL::Abstract::Tree - Represent SQL as an AST
 801
 802 =head1 SYNOPSIS
 803
 804  my $sqla_tree = SQL::Abstract::Tree->new({ profile => 'console' });
 805
 806  print $sqla_tree->format('SELECT * FROM foo WHERE foo.a > 2');
 807
 808  # SELECT *
 809  #   FROM foo
 810  #   WHERE foo.a > 2
 811
 812 =head1 METHODS
 813
 814 =head2 new
 815
 816  my $sqla_tree = SQL::Abstract::Tree->new({ profile => 'console' });
 817
 818  $args = {
 819    profile => 'console',      # predefined profile to use (default: 'none')
 820    fill_in_placeholders => 1, # true for placeholder population
 821    placeholder_surround =>    # The strings that will be wrapped around
 822               [GREEN, RESET], # populated placeholders if the above is set
 823    indent_string => ' ',      # the string used when indenting
 824    indent_amount => 2,        # how many of above string to use for a single
 825                               # indent level
 826    newline       => "\n",     # string for newline
 827    colormap      => {
 828      select => [RED, RESET], # a pair of strings defining what to surround
 829                              # the keyword with for colorization
 830      # ...
 831    },
 832    indentmap     => {
 833      select        => 0,     # A zero means that the keyword will start on
 834                              # a new line
 835      from          => 1,     # Any other positive integer means that after
 836      on            => 2,     # said newline it will get that many indents
 837      # ...
 838    },
 839  }
 840
 841 Returns a new SQL::Abstract::Tree object.  All arguments are optional.
 842
 843 =head3 profiles
 844
 845 There are four predefined profiles, C<none>, C<console>, C<console_monochrome>,
 846 and C<html>.  Typically a user will probably just use C<console> or
 847 C<console_monochrome>, but if something about a profile bothers you, merely
 848 use the profile and override the parts that you don't like.
 849
 850 =head2 format
 851
 852  $sqlat->format('SELECT * FROM bar WHERE x = ?', [1])
 853
 854 Takes C<$sql> and C<\@bindargs>.
 855
 856 Returns a formatting string based on the string passed in
 857
 858 =head2 parse
 859
 860  $sqlat->parse('SELECT * FROM bar WHERE x = ?')
 861
 862 Returns a "tree" representing passed in SQL.  Please do not depend on the
 863 structure of the returned tree.  It may be stable at some point, but not yet.
 864
 865 =head2 unparse
 866
 867  $sqlat->unparse($tree_structure, \@bindargs)
 868
 869 Transform "tree" into SQL, applying various transforms on the way.
 870
 871 =head2 format_keyword
 872
 873  $sqlat->format_keyword('SELECT')
 874
 875 Currently this just takes a keyword and puts the C<colormap> stuff around it.
 876 Later on it may do more and allow for coderef based transforms.
 877
 878 =head2 pad_keyword
 879
 880  my ($before, $after) = @{$sqlat->pad_keyword('SELECT')};
 881
 882 Returns whitespace to be inserted around a keyword.
 883
 884 =head2 fill_in_placeholder
 885
 886  my $value = $sqlat->fill_in_placeholder(\@bindargs)
 887
 888 Removes last arg from passed arrayref and returns it, surrounded with
 889 the values in placeholder_surround, and then surrounded with single quotes.
 890
 891 =head2 indent
 892
 893 Returns as many indent strings as indent amounts times the first argument.
 894
 895 =head1 ACCESSORS
 896
 897 =head2 colormap
 898
 899 See L</new>
 900
 901 =head2 fill_in_placeholders
 902
 903 See L</new>
 904
 905 =head2 indent_amount
 906
 907 See L</new>
 908
 909 =head2 indent_string
 910
 911 See L</new>
 912
 913 =head2 indentmap
 914
 915 See L</new>
 916
 917 =head2 newline
 918
 919 See L</new>
 920
 921 =head2 placeholder_surround
 922
 923 See L</new>
 924