lib/SQL/Abstract/Tree.pm

   1 package SQL::Abstract::Tree;
   2
   3 use strict;
   4 use warnings;
   5 no warnings 'qw';
   6 use Carp;
   7
   8 use Hash::Merge qw//;
   9
  10 use base 'Class::Accessor::Grouped';
  11
  12 __PACKAGE__->mk_group_accessors( simple => qw(
  13    newline indent_string indent_amount colormap indentmap fill_in_placeholders
  14    placeholder_surround
  15 ));
  16
  17 my $merger = Hash::Merge->new;
  18
  19 $merger->specify_behavior({
  20    SCALAR => {
  21       SCALAR => sub { $_[1] },
  22       ARRAY  => sub { [ $_[0], @{$_[1]} ] },
  23       HASH   => sub { $_[1] },
  24    },
  25    ARRAY => {
  26       SCALAR => sub { $_[1] },
  27       ARRAY  => sub { $_[1] },
  28       HASH   => sub { $_[1] },
  29    },
  30    HASH => {
  31       SCALAR => sub { $_[1] },
  32       ARRAY  => sub { [ values %{$_[0]}, @{$_[1]} ] },
  33       HASH   => sub { Hash::Merge::_merge_hashes( $_[0], $_[1] ) },
  34    },
  35 }, 'SQLA::Tree Behavior' );
  36
  37 my $op_look_ahead = '(?: (?= [\s\)\(\;] ) | \z)';
  38 my $op_look_behind = '(?: (?<= [\,\s\)\(] ) | \A )';
  39
  40 my $quote_left = qr/[\`\'\"\[]/;
  41 my $quote_right = qr/[\`\'\"\]]/;
  42
  43 my $placeholder_re = qr/(?: \? | \$\d+ )/x;
  44
  45 # These SQL keywords always signal end of the current expression (except inside
  46 # of a parenthesized subexpression).
  47 # Format: A list of strings that will be compiled to extended syntax ie.
  48 # /.../x) regexes, without capturing parentheses. They will be automatically
  49 # anchored to op boundaries (excluding quotes) to match the whole token.
  50 my @expression_start_keywords = (
  51   'SELECT',
  52   'UPDATE',
  53   'SET',
  54   'INSERT \s+ INTO',
  55   'DELETE \s+ FROM',
  56   'FROM',
  57   '(?:
  58     (?:
  59         (?: (?: LEFT | RIGHT | FULL ) \s+ )?
  60         (?: (?: CROSS | INNER | OUTER ) \s+ )?
  61     )?
  62     JOIN
  63   )',
  64   'ON',
  65   'WHERE',
  66   '(?: DEFAULT \s+ )? VALUES',
  67   'GROUP \s+ BY',
  68   'HAVING',
  69   'ORDER \s+ BY',
  70   'SKIP',
  71   'FIRST',
  72   'LIMIT',
  73   'OFFSET',
  74   'FOR',
  75   'UNION',
  76   'INTERSECT',
  77   'EXCEPT',
  78   'BEGIN \s+ WORK',
  79   'COMMIT',
  80   'ROLLBACK \s+ TO \s+ SAVEPOINT',
  81   'ROLLBACK',
  82   'SAVEPOINT',
  83   'RELEASE \s+ SAVEPOINT',
  84   'RETURNING',
  85   'ROW_NUMBER \s* \( \s* \) \s+ OVER',
  86 );
  87
  88 my $expr_start_re = join ("\n\t|\n", @expression_start_keywords );
  89 $expr_start_re = qr/ $op_look_behind (?i: $expr_start_re ) $op_look_ahead /x;
  90
  91 # These are binary operator keywords always a single LHS and RHS
  92 # * AND/OR are handled separately as they are N-ary
  93 # * so is NOT as being unary
  94 # * BETWEEN without paranthesis around the ANDed arguments (which
  95 #   makes it a non-binary op) is detected and accomodated in
  96 #   _recurse_parse()
  97 # * AS is not really an operator but is handled here as it's also LHS/RHS
  98
  99 # this will be included in the $binary_op_re, the distinction is interesting during
 100 # testing as one is tighter than the other, plus mathops have different look
 101 # ahead/behind (e.g. "x"="y" )
 102 my @math_op_keywords = (qw/ - + < > != <> = <= >= /);
 103 my $math_op_re = join ("\n\t|\n", map
 104   { "(?: (?<= [\\w\\s] | $quote_right ) | \\A )"  . quotemeta ($_) . "(?: (?= [\\w\\s] | $quote_left ) | \\z )" }
 105   @math_op_keywords
 106 );
 107 $math_op_re = qr/$math_op_re/x;
 108
 109 my $binary_op_re = '(?: NOT \s+)? (?:' . join ('|', qw/IN BETWEEN R?LIKE/) . ')';
 110 $binary_op_re = join "\n\t|\n",
 111   "$op_look_behind (?i: $binary_op_re | AS ) $op_look_ahead",
 112   $math_op_re,
 113   $op_look_behind . 'IS (?:\s+ NOT)?' . "(?= \\s+ NULL \\b | $op_look_ahead )",
 114 ;
 115 $binary_op_re = qr/$binary_op_re/x;
 116
 117 my $unary_op_re = '(?: NOT \s+ EXISTS | NOT )';
 118 $unary_op_re = join "\n\t|\n",
 119   "$op_look_behind (?i: $unary_op_re ) $op_look_ahead",
 120 ;
 121 $unary_op_re = qr/$unary_op_re/x;
 122
 123 my $asc_desc_re = qr/$op_look_behind (?i: ASC | DESC ) $op_look_ahead /x;
 124 my $and_or_re = qr/$op_look_behind (?i: AND | OR ) $op_look_ahead /x;
 125
 126 my $tokenizer_re = join("\n\t|\n",
 127   $expr_start_re,
 128   $binary_op_re,
 129   $unary_op_re,
 130   $asc_desc_re,
 131   $and_or_re,
 132   "$op_look_behind \\* $op_look_ahead",
 133   (map { quotemeta $_ } qw/, ( )/),
 134   $placeholder_re,
 135 );
 136
 137 # this one *is* capturing for the split below
 138 # splits on whitespace if all else fails
 139 # has to happen before the composiign qr's are anchored (below)
 140 $tokenizer_re = qr/ \s* ( $tokenizer_re ) \s* | \s+ /x;
 141
 142 # Parser states for _recurse_parse()
 143 use constant PARSE_TOP_LEVEL => 0;
 144 use constant PARSE_IN_EXPR => 1;
 145 use constant PARSE_IN_PARENS => 2;
 146 use constant PARSE_IN_FUNC => 3;
 147 use constant PARSE_RHS => 4;
 148 use constant PARSE_LIST_ELT => 5;
 149
 150 my $expr_term_re = qr/$expr_start_re | \)/x;
 151 my $rhs_term_re = qr/ $expr_term_re | $binary_op_re | $unary_op_re | $asc_desc_re | $and_or_re | \, /x;
 152 my $common_single_args_re = qr/ \* | $placeholder_re /x;
 153 my $all_std_keywords_re = qr/ $rhs_term_re | \( | $common_single_args_re /x;
 154
 155 # anchor everything - even though keywords are separated by the tokenizer, leakage may occur
 156 for (
 157   $quote_left,
 158   $quote_right,
 159   $placeholder_re,
 160   $expr_start_re,
 161   $math_op_re,
 162   $binary_op_re,
 163   $unary_op_re,
 164   $asc_desc_re,
 165   $and_or_re,
 166   $expr_term_re,
 167   $rhs_term_re,
 168   $common_single_args_re,
 169   $all_std_keywords_re,
 170 ) {
 171   $_ = qr/ \A $_ \z /x;
 172 }
 173
 174
 175
 176 my %indents = (
 177    select        => 0,
 178    update        => 0,
 179    'insert into' => 0,
 180    'delete from' => 0,
 181    from          => 1,
 182    where         => 0,
 183    join          => 1,
 184    'left join'   => 1,
 185    on            => 2,
 186    having        => 0,
 187    'group by'    => 0,
 188    'order by'    => 0,
 189    set           => 1,
 190    into          => 1,
 191    values        => 1,
 192    limit         => 1,
 193    offset        => 1,
 194    skip          => 1,
 195    first         => 1,
 196 );
 197
 198 my %profiles = (
 199    console => {
 200       fill_in_placeholders => 1,
 201       placeholder_surround => ['?/', ''],
 202       indent_string => ' ',
 203       indent_amount => 2,
 204       newline       => "\n",
 205       colormap      => {},
 206       indentmap     => \%indents,
 207
 208       eval { require Term::ANSIColor }
 209         ? do {
 210           my $c = \&Term::ANSIColor::color;
 211
 212           my $red     = [$c->('red')    , $c->('reset')];
 213           my $cyan    = [$c->('cyan')   , $c->('reset')];
 214           my $green   = [$c->('green')  , $c->('reset')];
 215           my $yellow  = [$c->('yellow') , $c->('reset')];
 216           my $blue    = [$c->('blue')   , $c->('reset')];
 217           my $magenta = [$c->('magenta'), $c->('reset')];
 218           my $b_o_w   = [$c->('black on_white'), $c->('reset')];
 219           (
 220             placeholder_surround => [$c->('black on_magenta'), $c->('reset')],
 221             colormap => {
 222               'begin work'            => $b_o_w,
 223               commit                  => $b_o_w,
 224               rollback                => $b_o_w,
 225               savepoint               => $b_o_w,
 226               'rollback to savepoint' => $b_o_w,
 227               'release savepoint'     => $b_o_w,
 228
 229               select                  => $red,
 230               'insert into'           => $red,
 231               update                  => $red,
 232               'delete from'           => $red,
 233
 234               set                     => $cyan,
 235               from                    => $cyan,
 236
 237               where                   => $green,
 238               values                  => $yellow,
 239
 240               join                    => $magenta,
 241               'left join'             => $magenta,
 242               on                      => $blue,
 243
 244               'group by'              => $yellow,
 245               having                  => $yellow,
 246               'order by'              => $yellow,
 247
 248               skip                    => $green,
 249               first                   => $green,
 250               limit                   => $green,
 251               offset                  => $green,
 252             }
 253           );
 254         } : (),
 255    },
 256    console_monochrome => {
 257       fill_in_placeholders => 1,
 258       placeholder_surround => ['?/', ''],
 259       indent_string => ' ',
 260       indent_amount => 2,
 261       newline       => "\n",
 262       colormap      => {},
 263       indentmap     => \%indents,
 264    },
 265    html => {
 266       fill_in_placeholders => 1,
 267       placeholder_surround => ['<span class="placeholder">', '</span>'],
 268       indent_string => '&nbsp;',
 269       indent_amount => 2,
 270       newline       => "<br />\n",
 271       colormap      => {
 272          select        => ['<span class="select">'  , '</span>'],
 273          'insert into' => ['<span class="insert-into">'  , '</span>'],
 274          update        => ['<span class="select">'  , '</span>'],
 275          'delete from' => ['<span class="delete-from">'  , '</span>'],
 276
 277          set           => ['<span class="set">', '</span>'],
 278          from          => ['<span class="from">'    , '</span>'],
 279
 280          where         => ['<span class="where">'   , '</span>'],
 281          values        => ['<span class="values">', '</span>'],
 282
 283          join          => ['<span class="join">'    , '</span>'],
 284          'left join'   => ['<span class="left-join">','</span>'],
 285          on            => ['<span class="on">'      , '</span>'],
 286
 287          'group by'    => ['<span class="group-by">', '</span>'],
 288          having        => ['<span class="having">',   '</span>'],
 289          'order by'    => ['<span class="order-by">', '</span>'],
 290
 291          skip          => ['<span class="skip">',   '</span>'],
 292          first         => ['<span class="first">',  '</span>'],
 293          limit         => ['<span class="limit">',  '</span>'],
 294          offset        => ['<span class="offset">', '</span>'],
 295
 296          'begin work'  => ['<span class="begin-work">', '</span>'],
 297          commit        => ['<span class="commit">', '</span>'],
 298          rollback      => ['<span class="rollback">', '</span>'],
 299          savepoint     => ['<span class="savepoint">', '</span>'],
 300          'rollback to savepoint' => ['<span class="rollback-to-savepoint">', '</span>'],
 301          'release savepoint'     => ['<span class="release-savepoint">', '</span>'],
 302       },
 303       indentmap     => \%indents,
 304    },
 305    none => {
 306       colormap      => {},
 307       indentmap     => {},
 308    },
 309 );
 310
 311 sub new {
 312    my $class = shift;
 313    my $args  = shift || {};
 314
 315    my $profile = delete $args->{profile} || 'none';
 316
 317    die "No such profile '$profile'!" unless exists $profiles{$profile};
 318
 319    my $data = $merger->merge( $profiles{$profile}, $args );
 320
 321    bless $data, $class
 322 }
 323
 324 sub parse {
 325   my ($self, $s) = @_;
 326
 327   # tokenize string, and remove all optional whitespace
 328   my $tokens = [];
 329   foreach my $token (split $tokenizer_re, $s) {
 330     push @$tokens, $token if (
 331       defined $token
 332         and
 333       length $token
 334         and
 335       $token =~ /\S/
 336     );
 337   }
 338
 339   return [ $self->_recurse_parse($tokens, PARSE_TOP_LEVEL) ];
 340 }
 341
 342 sub _recurse_parse {
 343   my ($self, $tokens, $state) = @_;
 344
 345   my @left;
 346   while (1) { # left-associative parsing
 347
 348     if ( ! @$tokens
 349           or
 350         ($state == PARSE_IN_PARENS && $tokens->[0] eq ')')
 351           or
 352         ($state == PARSE_IN_EXPR && $tokens->[0] =~ $expr_term_re )
 353           or
 354         ($state == PARSE_RHS && $tokens->[0] =~ $rhs_term_re )
 355           or
 356         ($state == PARSE_LIST_ELT && ( $tokens->[0] eq ',' or $tokens->[0] =~ $expr_term_re ) )
 357     ) {
 358       return @left;
 359     }
 360
 361     my $token = shift @$tokens;
 362
 363     # nested expression in ()
 364     if ($token eq '(' ) {
 365       my @right = $self->_recurse_parse($tokens, PARSE_IN_PARENS);
 366       $token = shift @$tokens   or croak "missing closing ')' around block " . $self->unparse(\@right);
 367       $token eq ')'             or croak "unexpected token '$token' terminating block " . $self->unparse(\@right);
 368
 369       push @left, [ '-PAREN' => \@right ];
 370     }
 371
 372     # AND/OR
 373     elsif ($token =~ $and_or_re) {
 374       my $op = uc $token;
 375
 376       my @right = $self->_recurse_parse($tokens, PARSE_IN_EXPR);
 377
 378       # Merge chunks if "logic" matches
 379       @left = [ $op => [ @left, (@right and $op eq $right[0][0])
 380         ? @{ $right[0][1] }
 381         : @right
 382       ] ];
 383     }
 384
 385     # LIST (,)
 386     elsif ($token eq ',') {
 387
 388       my @right = $self->_recurse_parse($tokens, PARSE_LIST_ELT);
 389
 390       # deal with malformed lists ( foo, bar, , baz )
 391       @right = [] unless @right;
 392
 393       @right = [ -MISC => [ @right ] ] if @right > 1;
 394
 395       if (!@left) {
 396         @left = [ -LIST => [ [], @right ] ];
 397       }
 398       elsif ($left[0][0] eq '-LIST') {
 399         push @{$left[0][1]}, (@{$right[0]} and  $right[0][0] eq '-LIST')
 400           ? @{$right[0][1]}
 401           : @right
 402         ;
 403       }
 404       else {
 405         @left = [ -LIST => [ @left, @right ] ];
 406       }
 407     }
 408
 409     # binary operator keywords
 410     elsif ($token =~ $binary_op_re) {
 411       my $op = uc $token;
 412
 413       my @right = $self->_recurse_parse($tokens, PARSE_RHS);
 414
 415       # A between with a simple LITERAL for a 1st RHS argument needs a
 416       # rerun of the search to (hopefully) find the proper AND construct
 417       if ($op eq 'BETWEEN' and $right[0] eq '-LITERAL') {
 418         unshift @$tokens, $right[1][0];
 419         @right = $self->_recurse_parse($tokens, PARSE_IN_EXPR);
 420       }
 421
 422       @left = [$op => [ @left, @right ]];
 423     }
 424
 425     # unary op keywords
 426     elsif ( $token =~ $unary_op_re ) {
 427       my $op = uc $token;
 428       my @right = $self->_recurse_parse ($tokens, PARSE_RHS);
 429
 430       push @left, [ $op => \@right ];
 431     }
 432
 433     # expression terminator keywords
 434     elsif ( $token =~ $expr_start_re ) {
 435       my $op = uc $token;
 436       my @right = $self->_recurse_parse($tokens, PARSE_IN_EXPR);
 437
 438       push @left, [ $op => \@right ];
 439     }
 440
 441     # a '?'
 442     elsif ( $token =~ $placeholder_re) {
 443       push @left, [ -PLACEHOLDER => [ $token ] ];
 444     }
 445
 446     # check if the current token is an unknown op-start
 447     elsif (@$tokens and ($tokens->[0] eq '(' or $tokens->[0] =~ $common_single_args_re ) ) {
 448       push @left, [ $token => [ $self->_recurse_parse($tokens, PARSE_RHS) ] ];
 449     }
 450
 451     # we're now in "unknown token" land - start eating tokens until
 452     # we see something familiar
 453     else {
 454       my @lits = [ -LITERAL => [$token] ];
 455
 456       while (@$tokens and $tokens->[0] !~ $all_std_keywords_re) {
 457         push @lits, [ -LITERAL => [ shift @$tokens ] ];
 458        }
 459
 460       if (@left == 1) {
 461         unshift @lits, pop @left;
 462        }
 463
 464       @lits = [ -MISC => [ @lits ] ] if @lits > 1;
 465
 466       push @left, @lits;
 467     }
 468
 469     # deal with post-fix operators (only when sql is sane - i.e. we have one element to apply to)
 470     if (@left == 1 and @$tokens) {
 471
 472       # asc/desc
 473       if ($tokens->[0] =~ $asc_desc_re) {
 474         my $op = shift @$tokens;
 475
 476         # if -MISC - this is a literal collection, do not promote asc/desc to an op
 477         if ($left[0][0] eq '-MISC') {
 478           push @{$left[0][1]}, [ -LITERAL => [ $op ] ];
 479         }
 480         else {
 481           @left = [ ('-' . uc ($op)) => [ @left ] ];
 482         }
 483       }
 484     }
 485   }
 486 }
 487
 488 sub format_keyword {
 489   my ($self, $keyword) = @_;
 490
 491   if (my $around = $self->colormap->{lc $keyword}) {
 492      $keyword = "$around->[0]$keyword$around->[1]";
 493   }
 494
 495   return $keyword
 496 }
 497
 498 my %starters = (
 499    select        => 1,
 500    update        => 1,
 501    'insert into' => 1,
 502    'delete from' => 1,
 503 );
 504
 505 sub pad_keyword {
 506    my ($self, $keyword, $depth) = @_;
 507
 508    my $before = '';
 509    if (defined $self->indentmap->{lc $keyword}) {
 510       $before = $self->newline . $self->indent($depth + $self->indentmap->{lc $keyword});
 511    }
 512    $before = '' if $depth == 0 and defined $starters{lc $keyword};
 513    return [$before, ''];
 514 }
 515
 516 sub indent { ($_[0]->indent_string||'') x ( ( $_[0]->indent_amount || 0 ) * $_[1] ) }
 517
 518 sub _is_key {
 519    my ($self, $tree) = @_;
 520    $tree = $tree->[0] while ref $tree;
 521
 522    defined $tree && defined $self->indentmap->{lc $tree};
 523 }
 524
 525 sub fill_in_placeholder {
 526    my ($self, $bindargs) = @_;
 527
 528    if ($self->fill_in_placeholders) {
 529       my $val = shift @{$bindargs} || '';
 530       my $quoted = $val =~ s/^(['"])(.*)\1$/$2/;
 531       my ($left, $right) = @{$self->placeholder_surround};
 532       $val =~ s/\\/\\\\/g;
 533       $val =~ s/'/\\'/g;
 534       $val = qq('$val') if $quoted;
 535       return qq($left$val$right)
 536    }
 537    return '?'
 538 }
 539
 540 # FIXME - terrible name for a user facing API
 541 sub unparse {
 542   my ($self, $tree, $bindargs) = @_;
 543   $self->_unparse($tree, [@{$bindargs||[]}], 0);
 544 }
 545
 546 sub _unparse {
 547   my ($self, $tree, $bindargs, $depth) = @_;
 548
 549   if (not $tree or not @$tree) {
 550     return '';
 551   }
 552
 553   # FIXME - needs a config switch to disable
 554   $self->_parenthesis_unroll($tree);
 555
 556   my ($op, $args) = @{$tree}[0,1];
 557
 558   if (! defined $op or (! ref $op and ! defined $args) ) {
 559     require Data::Dumper;
 560     Carp::confess( sprintf ( "Internal error - malformed branch at depth $depth:\n%s",
 561       Data::Dumper::Dumper($tree)
 562     ) );
 563   }
 564
 565   if (ref $op) {
 566     return join (' ', map $self->_unparse($_, $bindargs, $depth), @$tree);
 567   }
 568   elsif ($op eq '-LITERAL') { # literal has different sig
 569     return $args->[0];
 570   }
 571   elsif ($op eq '-PLACEHOLDER') {
 572     return $self->fill_in_placeholder($bindargs);
 573   }
 574   elsif ($op eq '-PAREN') {
 575     return sprintf ('( %s )',
 576       join (' ', map { $self->_unparse($_, $bindargs, $depth + 2) } @{$args} )
 577         .
 578       ($self->_is_key($args)
 579         ? ( $self->newline||'' ) . $self->indent($depth + 1)
 580         : ''
 581       )
 582     );
 583   }
 584   elsif ($op eq 'AND' or $op eq 'OR' or $op =~ $binary_op_re ) {
 585     return join (" $op ", map $self->_unparse($_, $bindargs, $depth), @{$args});
 586   }
 587   elsif ($op eq '-LIST' ) {
 588     return join (', ', map $self->_unparse($_, $bindargs, $depth), @{$args});
 589   }
 590   elsif ($op eq '-MISC' ) {
 591     return join (' ', map $self->_unparse($_, $bindargs, $depth), @{$args});
 592   }
 593   elsif ($op =~ qr/^-(ASC|DESC)$/ ) {
 594     my $dir = $1;
 595     return join (' ', (map $self->_unparse($_, $bindargs, $depth), @{$args}), $dir);
 596   }
 597   else {
 598     my ($l, $r) = @{$self->pad_keyword($op, $depth)};
 599     return sprintf "$l%s%s%s$r",
 600       $self->format_keyword($op),
 601       ( ref $args eq 'ARRAY' and @{$args} == 1 and $args->[0][0] eq '-PAREN' )
 602         ? ''    # mysql--
 603         : ' '
 604       ,
 605       $self->_unparse($args, $bindargs, $depth),
 606     ;
 607   }
 608 }
 609
 610 # All of these keywords allow their parameters to be specified with or without parenthesis without changing the semantics
 611 my @unrollable_ops = (
 612   'ON',
 613   'WHERE',
 614   'GROUP \s+ BY',
 615   'HAVING',
 616   'ORDER \s+ BY',
 617   'I?LIKE',
 618 );
 619 my $unrollable_ops_re = join ' | ', @unrollable_ops;
 620 $unrollable_ops_re = qr/$unrollable_ops_re/xi;
 621
 622 sub _parenthesis_unroll {
 623   my $self = shift;
 624   my $ast = shift;
 625
 626   return unless (ref $ast and ref $ast->[1]);
 627
 628   my $changes;
 629   do {
 630     my @children;
 631     $changes = 0;
 632
 633     for my $child (@{$ast->[1]}) {
 634
 635       # the current node in this loop is *always* a PAREN
 636       if (! ref $child or ! @$child or $child->[0] ne '-PAREN') {
 637         push @children, $child;
 638         next;
 639       }
 640
 641       # unroll nested parenthesis
 642       while ( @{$child->[1]} == 1 and $child->[1][0][0] eq '-PAREN') {
 643         $child = $child->[1][0];
 644         $changes++;
 645       }
 646
 647       # if the parent operator explcitly allows it nuke the parenthesis
 648       if ( $ast->[0] =~ $unrollable_ops_re ) {
 649         push @children, @{$child->[1]};
 650         $changes++;
 651       }
 652
 653       # if the parenthesis are wrapped around an AND/OR matching the parent AND/OR - open the parenthesis up and merge the list
 654       elsif (
 655         @{$child->[1]} == 1
 656             and
 657         ( $ast->[0] eq 'AND' or $ast->[0] eq 'OR')
 658             and
 659         $child->[1][0][0] eq $ast->[0]
 660       ) {
 661         push @children, @{$child->[1][0][1]};
 662         $changes++;
 663       }
 664
 665       # only *ONE* LITERAL or placeholder element
 666       # as an AND/OR/NOT argument
 667       elsif (
 668         @{$child->[1]} == 1 && (
 669           $child->[1][0][0] eq '-LITERAL'
 670             or
 671           $child->[1][0][0] eq '-PLACEHOLDER'
 672         ) && (
 673           $ast->[0] eq 'AND' or $ast->[0] eq 'OR' or $ast->[0] eq 'NOT'
 674         )
 675       ) {
 676         push @children, @{$child->[1]};
 677         $changes++;
 678       }
 679
 680       # an AND/OR expression with only one binop in the parenthesis
 681       # with exactly two grandchildren
 682       # the only time when we can *not* unroll this is when both
 683       # the parent and the child are mathops (in which case we'll
 684       # break precedence) or when the child is BETWEEN (special
 685       # case)
 686       elsif (
 687         @{$child->[1]} == 1
 688           and
 689         ($ast->[0] eq 'AND' or $ast->[0] eq 'OR')
 690           and
 691         $child->[1][0][0] =~ $binary_op_re
 692           and
 693         $child->[1][0][0] ne 'BETWEEN'
 694           and
 695         @{$child->[1][0][1]} == 2
 696           and
 697         ! (
 698           $child->[1][0][0] =~ $math_op_re
 699             and
 700           $ast->[0] =~ $math_op_re
 701         )
 702       ) {
 703         push @children, @{$child->[1]};
 704         $changes++;
 705       }
 706
 707       # a function binds tighter than a mathop - see if our ancestor is a
 708       # mathop, and our content is:
 709       # a single non-mathop child with a single PAREN grandchild which
 710       # would indicate mathop ( nonmathop ( ... ) )
 711       # or a single non-mathop with a single LITERAL ( nonmathop foo )
 712       # or a single non-mathop with a single PLACEHOLDER ( nonmathop ? )
 713       elsif (
 714         @{$child->[1]} == 1
 715           and
 716         @{$child->[1][0][1]} == 1
 717           and
 718         $ast->[0] =~ $math_op_re
 719           and
 720         $child->[1][0][0] !~ $math_op_re
 721           and
 722         (
 723           $child->[1][0][1][0][0] eq '-PAREN'
 724             or
 725           $child->[1][0][1][0][0] eq '-LITERAL'
 726             or
 727           $child->[1][0][1][0][0] eq '-PLACEHOLDER'
 728         )
 729       ) {
 730         push @children, @{$child->[1]};
 731         $changes++;
 732       }
 733
 734
 735       # otherwise no more mucking for this pass
 736       else {
 737         push @children, $child;
 738       }
 739     }
 740
 741     $ast->[1] = \@children;
 742
 743   } while ($changes);
 744 }
 745
 746 sub format { my $self = shift; $self->unparse($self->parse($_[0]), $_[1]) }
 747
 748 1;
 749
 750 =pod
 751
 752 =head1 NAME
 753
 754 SQL::Abstract::Tree - Represent SQL as an AST
 755
 756 =head1 SYNOPSIS
 757
 758  my $sqla_tree = SQL::Abstract::Tree->new({ profile => 'console' });
 759
 760  print $sqla_tree->format('SELECT * FROM foo WHERE foo.a > 2');
 761
 762  # SELECT *
 763  #   FROM foo
 764  #   WHERE foo.a > 2
 765
 766 =head1 METHODS
 767
 768 =head2 new
 769
 770  my $sqla_tree = SQL::Abstract::Tree->new({ profile => 'console' });
 771
 772  $args = {
 773    profile => 'console',      # predefined profile to use (default: 'none')
 774    fill_in_placeholders => 1, # true for placeholder population
 775    placeholder_surround =>    # The strings that will be wrapped around
 776               [GREEN, RESET], # populated placeholders if the above is set
 777    indent_string => ' ',      # the string used when indenting
 778    indent_amount => 2,        # how many of above string to use for a single
 779                               # indent level
 780    newline       => "\n",     # string for newline
 781    colormap      => {
 782      select => [RED, RESET], # a pair of strings defining what to surround
 783                              # the keyword with for colorization
 784      # ...
 785    },
 786    indentmap     => {
 787      select        => 0,     # A zero means that the keyword will start on
 788                              # a new line
 789      from          => 1,     # Any other positive integer means that after
 790      on            => 2,     # said newline it will get that many indents
 791      # ...
 792    },
 793  }
 794
 795 Returns a new SQL::Abstract::Tree object.  All arguments are optional.
 796
 797 =head3 profiles
 798
 799 There are four predefined profiles, C<none>, C<console>, C<console_monochrome>,
 800 and C<html>.  Typically a user will probably just use C<console> or
 801 C<console_monochrome>, but if something about a profile bothers you, merely
 802 use the profile and override the parts that you don't like.
 803
 804 =head2 format
 805
 806  $sqlat->format('SELECT * FROM bar WHERE x = ?', [1])
 807
 808 Takes C<$sql> and C<\@bindargs>.
 809
 810 Returns a formatting string based on the string passed in
 811
 812 =head2 parse
 813
 814  $sqlat->parse('SELECT * FROM bar WHERE x = ?')
 815
 816 Returns a "tree" representing passed in SQL.  Please do not depend on the
 817 structure of the returned tree.  It may be stable at some point, but not yet.
 818
 819 =head2 unparse
 820
 821  $sqlat->unparse($tree_structure, \@bindargs)
 822
 823 Transform "tree" into SQL, applying various transforms on the way.
 824
 825 =head2 format_keyword
 826
 827  $sqlat->format_keyword('SELECT')
 828
 829 Currently this just takes a keyword and puts the C<colormap> stuff around it.
 830 Later on it may do more and allow for coderef based transforms.
 831
 832 =head2 pad_keyword
 833
 834  my ($before, $after) = @{$sqlat->pad_keyword('SELECT')};
 835
 836 Returns whitespace to be inserted around a keyword.
 837
 838 =head2 fill_in_placeholder
 839
 840  my $value = $sqlat->fill_in_placeholder(\@bindargs)
 841
 842 Removes last arg from passed arrayref and returns it, surrounded with
 843 the values in placeholder_surround, and then surrounded with single quotes.
 844
 845 =head2 indent
 846
 847 Returns as many indent strings as indent amounts times the first argument.
 848
 849 =head1 ACCESSORS
 850
 851 =head2 colormap
 852
 853 See L</new>
 854
 855 =head2 fill_in_placeholders
 856
 857 See L</new>
 858
 859 =head2 indent_amount
 860
 861 See L</new>
 862
 863 =head2 indent_string
 864
 865 See L</new>
 866
 867 =head2 indentmap
 868
 869 See L</new>
 870
 871 =head2 newline
 872
 873 See L</new>
 874
 875 =head2 placeholder_surround
 876
 877 See L</new>
 878