lib/SQL/Abstract/Tree.pm

   1 package SQL::Abstract::Tree;
   2
   3 use strict;
   4 use warnings;
   5 use Carp;
   6
   7
   8 use base 'Class::Accessor::Grouped';
   9
  10 __PACKAGE__->mk_group_accessors( simple => $_ ) for qw(
  11    newline indent_string indent_amount colormap indentmap
  12 );
  13
  14 # Parser states for _recurse_parse()
  15 use constant PARSE_TOP_LEVEL => 0;
  16 use constant PARSE_IN_EXPR => 1;
  17 use constant PARSE_IN_PARENS => 2;
  18 use constant PARSE_RHS => 3;
  19
  20 # These SQL keywords always signal end of the current expression (except inside
  21 # of a parenthesized subexpression).
  22 # Format: A list of strings that will be compiled to extended syntax (ie.
  23 # /.../x) regexes, without capturing parentheses. They will be automatically
  24 # anchored to word boundaries to match the whole token).
  25 my @expression_terminator_sql_keywords = (
  26   'SELECT',
  27   'UPDATE',
  28   'INSERT \s+ INTO',
  29   'DELETE \s+ FROM',
  30   'FROM',
  31   'SET',
  32   '(?:
  33     (?:
  34         (?: \b (?: LEFT | RIGHT | FULL ) \s+ )?
  35         (?: \b (?: CROSS | INNER | OUTER ) \s+ )?
  36     )?
  37     JOIN
  38   )',
  39   'ON',
  40   'WHERE',
  41   'VALUES',
  42   'EXISTS',
  43   'GROUP \s+ BY',
  44   'HAVING',
  45   'ORDER \s+ BY',
  46   'LIMIT',
  47   'OFFSET',
  48   'FOR',
  49   'UNION',
  50   'INTERSECT',
  51   'EXCEPT',
  52   'RETURNING',
  53   'ROW_NUMBER \s* \( \s* \) \s+ OVER',
  54 );
  55
  56 # These are binary operator keywords always a single LHS and RHS
  57 # * AND/OR are handled separately as they are N-ary
  58 # * so is NOT as being unary
  59 # * BETWEEN without paranthesis around the ANDed arguments (which
  60 #   makes it a non-binary op) is detected and accomodated in
  61 #   _recurse_parse()
  62 my $stuff_around_mathops = qr/[\w\s\`\'\"\)]/;
  63 my @binary_op_keywords = (
  64   ( map
  65     {
  66       ' ^ '  . quotemeta ($_) . "(?= \$ | $stuff_around_mathops ) ",
  67       " (?<= $stuff_around_mathops)" . quotemeta ($_) . "(?= \$ | $stuff_around_mathops ) ",
  68     }
  69     (qw/< > != <> = <= >=/)
  70   ),
  71   ( map
  72     { '\b (?: NOT \s+)?' . $_ . '\b' }
  73     (qw/IN BETWEEN LIKE/)
  74   ),
  75 );
  76
  77 my $tokenizer_re_str = join("\n\t|\n",
  78   ( map { '\b' . $_ . '\b' } @expression_terminator_sql_keywords, 'AND', 'OR', 'NOT'),
  79   @binary_op_keywords,
  80 );
  81
  82 my $tokenizer_re = qr/ \s* ( $tokenizer_re_str | \( | \) | \? ) \s* /xi;
  83
  84 sub _binary_op_keywords { @binary_op_keywords }
  85
  86 my %indents = (
  87    select        => 0,
  88    update        => 0,
  89    'insert into' => 0,
  90    'delete from' => 0,
  91    from          => 1,
  92    where         => 1,
  93    join          => 1,
  94    'left join'   => 1,
  95    on            => 2,
  96    'group by'    => 1,
  97    'order by'    => 1,
  98    set           => 1,
  99    into          => 1,
 100    values        => 2,
 101 );
 102
 103 my %profiles = (
 104    console => {
 105       indent_string => ' ',
 106       indent_amount => 2,
 107       newline       => "\n",
 108       colormap      => {},
 109       indentmap     => { %indents },
 110    },
 111    console_monochrome => {
 112       indent_string => ' ',
 113       indent_amount => 2,
 114       newline       => "\n",
 115       colormap      => {},
 116       indentmap     => { %indents },
 117    },
 118    html => {
 119       indent_string => '&nbsp;',
 120       indent_amount => 2,
 121       newline       => "<br />\n",
 122       colormap      => {
 123          select        => ['<span class="select">'  , '</span>'],
 124          'insert into' => ['<span class="insert-into">'  , '</span>'],
 125          update        => ['<span class="select">'  , '</span>'],
 126          'delete from' => ['<span class="delete-from">'  , '</span>'],
 127          where         => ['<span class="where">'   , '</span>'],
 128          from          => ['<span class="from">'    , '</span>'],
 129          join          => ['<span class="join">'    , '</span>'],
 130          on            => ['<span class="on">'      , '</span>'],
 131          'group by'    => ['<span class="group-by">', '</span>'],
 132          'order by'    => ['<span class="order-by">', '</span>'],
 133          set           => ['<span class="set">', '</span>'],
 134          into          => ['<span class="into">', '</span>'],
 135          values        => ['<span class="values">', '</span>'],
 136       },
 137       indentmap     => { %indents },
 138    },
 139    none => {
 140       colormap      => {},
 141       indentmap     => {},
 142    },
 143 );
 144
 145 eval {
 146    require Term::ANSIColor;
 147    $profiles{console}->{colormap} = {
 148       select        => [Term::ANSIColor::color('red'), Term::ANSIColor::color('reset')],
 149       'insert into' => [Term::ANSIColor::color('red'), Term::ANSIColor::color('reset')],
 150       update        => [Term::ANSIColor::color('red'), Term::ANSIColor::color('reset')],
 151       'delete from' => [Term::ANSIColor::color('red'), Term::ANSIColor::color('reset')],
 152
 153       set           => [Term::ANSIColor::color('cyan'), Term::ANSIColor::color('reset')],
 154       from          => [Term::ANSIColor::color('cyan'), Term::ANSIColor::color('reset')],
 155
 156       where         => [Term::ANSIColor::color('green'), Term::ANSIColor::color('reset')],
 157       values        => [Term::ANSIColor::color('yellow'), Term::ANSIColor::color('reset')],
 158
 159       join          => [Term::ANSIColor::color('magenta'), Term::ANSIColor::color('reset')],
 160       'left join'   => [Term::ANSIColor::color('magenta'), Term::ANSIColor::color('reset')],
 161       on            => [Term::ANSIColor::color('blue'), Term::ANSIColor::color('reset')],
 162
 163       'group by'    => [Term::ANSIColor::color('yellow'), Term::ANSIColor::color('reset')],
 164       'order by'    => [Term::ANSIColor::color('yellow'), Term::ANSIColor::color('reset')],
 165    };
 166 };
 167
 168 sub new {
 169    my ($class, $args) = @_;
 170
 171    my $profile = delete $args->{profile} || 'none';
 172    my $data = {%{$profiles{$profile}}, %{$args||{}}};
 173
 174    bless $data, $class
 175 }
 176
 177 sub parse {
 178   my ($self, $s) = @_;
 179
 180   # tokenize string, and remove all optional whitespace
 181   my $tokens = [];
 182   foreach my $token (split $tokenizer_re, $s) {
 183     push @$tokens, $token if (length $token) && ($token =~ /\S/);
 184   }
 185
 186   my $tree = $self->_recurse_parse($tokens, PARSE_TOP_LEVEL);
 187   return $tree;
 188 }
 189
 190 sub _recurse_parse {
 191   my ($self, $tokens, $state) = @_;
 192
 193   my $left;
 194   while (1) { # left-associative parsing
 195
 196     my $lookahead = $tokens->[0];
 197     if ( not defined($lookahead)
 198           or
 199         ($state == PARSE_IN_PARENS && $lookahead eq ')')
 200           or
 201         ($state == PARSE_IN_EXPR && grep { $lookahead =~ /^ $_ $/xi } ('\)', @expression_terminator_sql_keywords ) )
 202           or
 203         ($state == PARSE_RHS && grep { $lookahead =~ /^ $_ $/xi } ('\)', @expression_terminator_sql_keywords, @binary_op_keywords, 'AND', 'OR', 'NOT' ) )
 204     ) {
 205       return $left;
 206     }
 207
 208     my $token = shift @$tokens;
 209
 210     # nested expression in ()
 211     if ($token eq '(' ) {
 212       my $right = $self->_recurse_parse($tokens, PARSE_IN_PARENS);
 213       $token = shift @$tokens   or croak "missing closing ')' around block " . $self->unparse($right);
 214       $token eq ')'             or croak "unexpected token '$token' terminating block " . $self->unparse($right);
 215
 216       $left = $left ? [@$left, [PAREN => [$right] ]]
 217                     : [PAREN  => [$right] ];
 218     }
 219     # AND/OR
 220     elsif ($token =~ /^ (?: OR | AND ) $/xi )  {
 221       my $op = uc $token;
 222       my $right = $self->_recurse_parse($tokens, PARSE_IN_EXPR);
 223
 224       # Merge chunks if logic matches
 225       if (ref $right and $op eq $right->[0]) {
 226         $left = [ (shift @$right ), [$left, map { @$_ } @$right] ];
 227       }
 228       else {
 229        $left = [$op => [$left, $right]];
 230       }
 231     }
 232     # binary operator keywords
 233     elsif (grep { $token =~ /^ $_ $/xi } @binary_op_keywords ) {
 234       my $op = uc $token;
 235       my $right = $self->_recurse_parse($tokens, PARSE_RHS);
 236
 237       # A between with a simple LITERAL for a 1st RHS argument needs a
 238       # rerun of the search to (hopefully) find the proper AND construct
 239       if ($op eq 'BETWEEN' and $right->[0] eq 'LITERAL') {
 240         unshift @$tokens, $right->[1][0];
 241         $right = $self->_recurse_parse($tokens, PARSE_IN_EXPR);
 242       }
 243
 244       $left = [$op => [$left, $right] ];
 245     }
 246     # expression terminator keywords (as they start a new expression)
 247     elsif (grep { $token =~ /^ $_ $/xi } @expression_terminator_sql_keywords ) {
 248       my $op = uc $token;
 249       my $right = $self->_recurse_parse($tokens, PARSE_IN_EXPR);
 250       $left = $left ? [ $left,  [$op => [$right] ]]
 251                     : [ $op => [$right] ];
 252     }
 253     # NOT (last as to allow all other NOT X pieces first)
 254     elsif ( $token =~ /^ not $/ix ) {
 255       my $op = uc $token;
 256       my $right = $self->_recurse_parse ($tokens, PARSE_RHS);
 257       $left = $left ? [ @$left, [$op => [$right] ]]
 258                     : [ $op => [$right] ];
 259
 260     }
 261     # literal (eat everything on the right until RHS termination)
 262     else {
 263       my $right = $self->_recurse_parse ($tokens, PARSE_RHS);
 264       $left = $left ? [ $left, [LITERAL => [join ' ', $token, $self->unparse($right)||()] ] ]
 265                     : [ LITERAL => [join ' ', $token, $self->unparse($right)||()] ];
 266     }
 267   }
 268 }
 269
 270 sub format_keyword {
 271   my ($self, $keyword) = @_;
 272
 273   if (my $around = $self->colormap->{lc $keyword}) {
 274      $keyword = "$around->[0]$keyword$around->[1]";
 275   }
 276
 277   return $keyword
 278 }
 279
 280 sub whitespace {
 281    my ($self, $keyword, $depth) = @_;
 282
 283    my $before = '';
 284    if (defined $self->indentmap->{lc $keyword}) {
 285       $before = $self->newline . $self->indent($depth + $self->indentmap->{lc $keyword});
 286    }
 287    $before = '' if $depth == 0 and lc $keyword eq 'select';
 288    return [$before, ' '];
 289 }
 290
 291 sub indent { ($_[0]->indent_string||'') x ( ( $_[0]->indent_amount || 0 ) * $_[1] ) }
 292
 293 sub _is_select {
 294    my $tree = shift;
 295    $tree = $tree->[0] while ref $tree;
 296
 297    defined $tree && lc $tree eq 'select';
 298 }
 299
 300 sub unparse {
 301   my ($self, $tree, $depth) = @_;
 302
 303   $depth ||= 0;
 304
 305   if (not $tree ) {
 306     return '';
 307   }
 308
 309   my $car = $tree->[0];
 310   my $cdr = $tree->[1];
 311
 312   if (ref $car) {
 313     return join ('', map $self->unparse($_, $depth), @$tree);
 314   }
 315   elsif ($car eq 'LITERAL') {
 316     return $cdr->[0];
 317   }
 318   elsif ($car eq 'PAREN') {
 319     return '(' .
 320       join(' ',
 321         map $self->unparse($_, $depth + 2), @{$cdr}) .
 322     (_is_select($cdr)?( $self->newline||'' ).$self->indent($depth + 1):'') . ') ';
 323   }
 324   elsif ($car eq 'OR' or $car eq 'AND' or (grep { $car =~ /^ $_ $/xi } @binary_op_keywords ) ) {
 325     return join (" $car ", map $self->unparse($_, $depth), @{$cdr});
 326   }
 327   else {
 328     my ($l, $r) = @{$self->whitespace($car, $depth)};
 329     return sprintf "$l%s %s$r", $self->format_keyword($car), $self->unparse($cdr, $depth);
 330   }
 331 }
 332
 333 sub format { my $self = shift; $self->unparse($self->parse(@_)) }
 334
 335 1;
 336
 337 =pod
 338
 339 =head1 SYNOPSIS
 340
 341  my $sqla_tree = SQL::Abstract::Tree->new({ profile => 'console' });
 342
 343  print $sqla_tree->format('SELECT * FROM foo WHERE foo.a > 2');
 344
 345  # SELECT *
 346  #   FROM foo
 347  #   WHERE foo.a > 2
 348
 349 =head1 METHODS
 350
 351 =head2 new
 352
 353  my $sqla_tree = SQL::Abstract::Tree->new({ profile => 'console' });
 354
 355 =head2 format
 356
 357  $sqlat->format('SELECT * FROM bar')
 358
 359 Returns a formatting string based on wthe string passed in