lib/SQL/Abstract/Tree.pm

   1 package SQL::Abstract::Tree;
   2
   3 use strict;
   4 use warnings;
   5 use Carp;
   6
   7
   8 use base 'Class::Accessor::Grouped';
   9
  10 __PACKAGE__->mk_group_accessors( simple => $_ ) for qw(
  11    newline indent_string indent_amount colormap indentmap
  12 );
  13
  14 # Parser states for _recurse_parse()
  15 use constant PARSE_TOP_LEVEL => 0;
  16 use constant PARSE_IN_EXPR => 1;
  17 use constant PARSE_IN_PARENS => 2;
  18 use constant PARSE_RHS => 3;
  19
  20 # These SQL keywords always signal end of the current expression (except inside
  21 # of a parenthesized subexpression).
  22 # Format: A list of strings that will be compiled to extended syntax (ie.
  23 # /.../x) regexes, without capturing parentheses. They will be automatically
  24 # anchored to word boundaries to match the whole token).
  25 my @expression_terminator_sql_keywords = (
  26   'SELECT',
  27   'FROM',
  28   '(?:
  29     (?:
  30         (?: \b (?: LEFT | RIGHT | FULL ) \s+ )?
  31         (?: \b (?: CROSS | INNER | OUTER ) \s+ )?
  32     )?
  33     JOIN
  34   )',
  35   'ON',
  36   'WHERE',
  37   'EXISTS',
  38   'GROUP \s+ BY',
  39   'HAVING',
  40   'ORDER \s+ BY',
  41   'LIMIT',
  42   'OFFSET',
  43   'FOR',
  44   'UNION',
  45   'INTERSECT',
  46   'EXCEPT',
  47   'RETURNING',
  48 );
  49
  50 # These are binary operator keywords always a single LHS and RHS
  51 # * AND/OR are handled separately as they are N-ary
  52 # * so is NOT as being unary
  53 # * BETWEEN without paranthesis around the ANDed arguments (which
  54 #   makes it a non-binary op) is detected and accomodated in
  55 #   _recurse_parse()
  56 my $stuff_around_mathops = qr/[\w\s\`\'\"\)]/;
  57 my @binary_op_keywords = (
  58   ( map
  59     {
  60       ' ^ '  . quotemeta ($_) . "(?= \$ | $stuff_around_mathops ) ",
  61       " (?<= $stuff_around_mathops)" . quotemeta ($_) . "(?= \$ | $stuff_around_mathops ) ",
  62     }
  63     (qw/< > != <> = <= >=/)
  64   ),
  65   ( map
  66     { '\b (?: NOT \s+)?' . $_ . '\b' }
  67     (qw/IN BETWEEN LIKE/)
  68   ),
  69 );
  70
  71 my $tokenizer_re_str = join("\n\t|\n",
  72   ( map { '\b' . $_ . '\b' } @expression_terminator_sql_keywords, 'AND', 'OR', 'NOT'),
  73   @binary_op_keywords,
  74 );
  75
  76 my $tokenizer_re = qr/ \s* ( $tokenizer_re_str | \( | \) | \? ) \s* /xi;
  77
  78 sub _binary_op_keywords { @binary_op_keywords }
  79
  80 my %indents = (
  81    select     => 0,
  82    where      => 1,
  83    from       => 1,
  84    join       => 1,
  85    on         => 2,
  86    'group by' => 1,
  87 );
  88
  89 my %profiles = (
  90    console => {
  91       indent_string => ' ',
  92       indent_amount => 2,
  93       newline       => "\n",
  94       colormap      => {},
  95       indentmap     => { %indents },
  96    },
  97    console_monochrome => {
  98       indent_string => ' ',
  99       indent_amount => 2,
 100       newline       => "\n",
 101       colormap      => {},
 102       indentmap     => { %indents },
 103    },
 104    html => {
 105       indent_string => '&nbsp;',
 106       indent_amount => 2,
 107       newline       => "<br />\n",
 108       colormap      => {
 109          select     => ['<span class="select">'  , '</span>'],
 110          where      => ['<span class="where">'   , '</span>'],
 111          from       => ['<span class="from">'    , '</span>'],
 112          join       => ['<span class="join">'    , '</span>'],
 113          on         => ['<span class="on">'      , '</span>'],
 114          'group by' => ['<span class="group-by">', '</span>'],
 115       },
 116       indentmap     => { %indents },
 117    },
 118    none => {
 119       colormap      => {},
 120       indentmap     => {},
 121    },
 122 );
 123
 124 eval {
 125    require Term::ANSIColor;
 126    $profiles{console}->{colormap} = {
 127       select => [Term::ANSIColor::color('red'), Term::ANSIColor::color('reset')],
 128       where  => [Term::ANSIColor::color('green'), Term::ANSIColor::color('reset')],
 129       from   => [Term::ANSIColor::color('cyan'), Term::ANSIColor::color('reset')],
 130    };
 131 };
 132
 133 sub new {
 134    my ($class, $args) = @_;
 135
 136    my $profile = delete $args->{profile} || 'none';
 137    my $data = {%{$profiles{$profile}}, %{$args||{}}};
 138
 139    bless $data, $class
 140 }
 141
 142 sub parse {
 143   my ($self, $s) = @_;
 144
 145   # tokenize string, and remove all optional whitespace
 146   my $tokens = [];
 147   foreach my $token (split $tokenizer_re, $s) {
 148     push @$tokens, $token if (length $token) && ($token =~ /\S/);
 149   }
 150
 151   my $tree = $self->_recurse_parse($tokens, PARSE_TOP_LEVEL);
 152   return $tree;
 153 }
 154
 155 sub _recurse_parse {
 156   my ($self, $tokens, $state) = @_;
 157
 158   my $left;
 159   while (1) { # left-associative parsing
 160
 161     my $lookahead = $tokens->[0];
 162     if ( not defined($lookahead)
 163           or
 164         ($state == PARSE_IN_PARENS && $lookahead eq ')')
 165           or
 166         ($state == PARSE_IN_EXPR && grep { $lookahead =~ /^ $_ $/xi } ('\)', @expression_terminator_sql_keywords ) )
 167           or
 168         ($state == PARSE_RHS && grep { $lookahead =~ /^ $_ $/xi } ('\)', @expression_terminator_sql_keywords, @binary_op_keywords, 'AND', 'OR', 'NOT' ) )
 169     ) {
 170       return $left;
 171     }
 172
 173     my $token = shift @$tokens;
 174
 175     # nested expression in ()
 176     if ($token eq '(' ) {
 177       my $right = $self->_recurse_parse($tokens, PARSE_IN_PARENS);
 178       $token = shift @$tokens   or croak "missing closing ')' around block " . $self->unparse($right);
 179       $token eq ')'             or croak "unexpected token '$token' terminating block " . $self->unparse($right);
 180
 181       $left = $left ? [@$left, [PAREN => [$right] ]]
 182                     : [PAREN  => [$right] ];
 183     }
 184     # AND/OR
 185     elsif ($token =~ /^ (?: OR | AND ) $/xi )  {
 186       my $op = uc $token;
 187       my $right = $self->_recurse_parse($tokens, PARSE_IN_EXPR);
 188
 189       # Merge chunks if logic matches
 190       if (ref $right and $op eq $right->[0]) {
 191         $left = [ (shift @$right ), [$left, map { @$_ } @$right] ];
 192       }
 193       else {
 194        $left = [$op => [$left, $right]];
 195       }
 196     }
 197     # binary operator keywords
 198     elsif (grep { $token =~ /^ $_ $/xi } @binary_op_keywords ) {
 199       my $op = uc $token;
 200       my $right = $self->_recurse_parse($tokens, PARSE_RHS);
 201
 202       # A between with a simple LITERAL for a 1st RHS argument needs a
 203       # rerun of the search to (hopefully) find the proper AND construct
 204       if ($op eq 'BETWEEN' and $right->[0] eq 'LITERAL') {
 205         unshift @$tokens, $right->[1][0];
 206         $right = $self->_recurse_parse($tokens, PARSE_IN_EXPR);
 207       }
 208
 209       $left = [$op => [$left, $right] ];
 210     }
 211     # expression terminator keywords (as they start a new expression)
 212     elsif (grep { $token =~ /^ $_ $/xi } @expression_terminator_sql_keywords ) {
 213       my $op = uc $token;
 214       my $right = $self->_recurse_parse($tokens, PARSE_IN_EXPR);
 215       $left = $left ? [ $left,  [$op => [$right] ]]
 216                     : [ $op => [$right] ];
 217     }
 218     # NOT (last as to allow all other NOT X pieces first)
 219     elsif ( $token =~ /^ not $/ix ) {
 220       my $op = uc $token;
 221       my $right = $self->_recurse_parse ($tokens, PARSE_RHS);
 222       $left = $left ? [ @$left, [$op => [$right] ]]
 223                     : [ $op => [$right] ];
 224
 225     }
 226     # literal (eat everything on the right until RHS termination)
 227     else {
 228       my $right = $self->_recurse_parse ($tokens, PARSE_RHS);
 229       $left = $left ? [ $left, [LITERAL => [join ' ', $token, $self->unparse($right)||()] ] ]
 230                     : [ LITERAL => [join ' ', $token, $self->unparse($right)||()] ];
 231     }
 232   }
 233 }
 234
 235 sub format_keyword {
 236   my ($self, $keyword) = @_;
 237
 238   if (my $around = $self->colormap->{lc $keyword}) {
 239      $keyword = "$around->[0]$keyword$around->[1]";
 240   }
 241
 242   return $keyword
 243 }
 244
 245 sub whitespace {
 246    my ($self, $keyword, $depth) = @_;
 247
 248    my $before = '';
 249    my $after  = ' ';
 250    if (defined $self->indentmap->{lc $keyword}) {
 251       $before = $self->newline . $self->indent($depth + $self->indentmap->{lc $keyword});
 252    }
 253    $before = '' if $depth == 0 and lc $keyword eq 'select';
 254    return [$before, $after];
 255 }
 256
 257 sub indent { ($_[0]->indent_string||'') x ( ( $_[0]->indent_amount || 0 ) * $_[1] ) }
 258
 259 sub _is_select {
 260    my $tree = shift;
 261    $tree = $tree->[0] while ref $tree;
 262
 263    defined $tree && lc $tree eq 'select';
 264 }
 265
 266 sub unparse {
 267   my ($self, $tree, $depth) = @_;
 268
 269   $depth ||= 0;
 270
 271   if (not $tree ) {
 272     return '';
 273   }
 274
 275   my $car = $tree->[0];
 276   my $cdr = $tree->[1];
 277
 278   if (ref $car) {
 279     return join ('', map $self->unparse($_, $depth), @$tree);
 280   }
 281   elsif ($car eq 'LITERAL') {
 282     return $cdr->[0];
 283   }
 284   elsif ($car eq 'PAREN') {
 285     return '(' .
 286       join(' ',
 287         map $self->unparse($_, $depth + 2), @{$cdr}) .
 288     (_is_select($cdr)?( $self->newline||'' ).$self->indent($depth + 1):'') . ')';
 289   }
 290   elsif ($car eq 'OR' or $car eq 'AND' or (grep { $car =~ /^ $_ $/xi } @binary_op_keywords ) ) {
 291     return join (" $car ", map $self->unparse($_, $depth), @{$cdr});
 292   }
 293   else {
 294     my ($l, $r) = @{$self->whitespace($car, $depth)};
 295     return sprintf "$l%s %s$r", $self->format_keyword($car), $self->unparse($cdr, $depth);
 296   }
 297 }
 298
 299 sub format { my $self = shift; $self->unparse($self->parse(@_)) }
 300
 301 1;
 302
 303 =pod
 304
 305 =head1 SYNOPSIS
 306
 307  my $sqla_tree = SQL::Abstract::Tree->new({ profile => 'console' });
 308
 309  print $sqla_tree->format('SELECT * FROM foo WHERE foo.a > 2');
 310
 311  # SELECT *
 312  #   FROM foo
 313  #   WHERE foo.a > 2
 314