lib/SQL/Abstract/ExtraClauses.pm

   1 package SQL::Abstract::ExtraClauses;
   2
   3 use strict;
   4 use warnings;
   5 use if $] < '5.010', 'MRO::Compat';
   6 use mro 'c3';
   7 use base qw(SQL::Abstract::Clauses);
   8
   9 BEGIN { *puke = \&SQL::Abstract::puke }
  10
  11 sub register_defaults {
  12   my $self = shift;
  13   $self->next::method(@_);
  14   $self->clauses_of(
  15     select => $self->clauses_of('select'), qw(group_by having)
  16   );
  17   $self->clause_expanders(
  18     'select.group_by', sub {
  19       $_[0]->_expand_maybe_list_expr($_[1], -ident)
  20     },
  21     'select.having', 'expand_expr',
  22   );
  23   foreach my $thing (qw(join from_list)) {
  24     $self->expander($thing => "_expand_${thing}")
  25          ->renderer($thing => "_render_${thing}")
  26   }
  27   $self->op_expander(as => '_expand_op_as');
  28   $self->expander(as => '_expand_op_as');
  29   $self->renderer(as => '_render_as');
  30
  31   $self->clauses_of(update => sub {
  32     my ($self, @clauses) = @_;
  33     splice(@clauses, 2, 0, 'from');
  34     @clauses;
  35   });
  36
  37   $self->clauses_of(delete => sub {
  38     my ($self, @clauses) = @_;
  39     splice(@clauses, 1, 0, 'using');
  40     @clauses;
  41   });
  42
  43   $self->clause_expanders(
  44     'update.from' => '_expand_select_clause_from',
  45     'delete.using' => sub {
  46       +(using => $_[0]->_expand_from_list(undef, $_[1]));
  47     },
  48     'insert.rowvalues' => sub {
  49       +(from => $_[0]->expand_expr({ -values => $_[1] }));
  50     },
  51     'insert.select' => sub {
  52       +(from => $_[0]->expand_expr({ -select => $_[1] }));
  53     },
  54   );
  55   return $self;
  56 }
  57
  58 sub _expand_select_clause_from {
  59   my ($self, $from) = @_;
  60   +(from => $self->_expand_from_list(undef, $from));
  61 }
  62
  63 sub _expand_from_list {
  64   my ($self, undef, $args) = @_;
  65   if (ref($args) eq 'HASH') {
  66     return { -from_list => [ $self->expand_expr($args) ] };
  67   }
  68   my @list;
  69   my @args = ref($args) eq 'ARRAY' ? @$args : ($args);
  70   while (my $entry = shift @args) {
  71     if (!ref($entry) and $entry =~ /^-(.*)/) {
  72       if ($1 eq 'as') {
  73         $list[-1] = $self->expand_expr({ -as => [
  74           $list[-1], map +(ref($_) eq 'ARRAY' ? @$_ : $_), shift(@args)
  75         ]});
  76         next;
  77       }
  78       $entry = { $entry => shift @args };
  79     }
  80     my $aqt = $self->expand_expr($entry, -ident);
  81     if ($aqt->{-join} and not $aqt->{-join}{from}) {
  82       $aqt->{-join}{from} = pop @list;
  83     }
  84     push @list, $aqt;
  85   }
  86   return { -from_list => \@list };
  87 }
  88
  89 sub _expand_join {
  90   my ($self, undef, $args) = @_;
  91   my %proto = (
  92     ref($args) eq 'HASH'
  93       ? %$args
  94       : (to => $args->[0], @{$args}[1..$#$args])
  95   );
  96   if (my $as = delete $proto{as}) {
  97     $proto{to} = { -as => [ $proto{to}, ref($as) eq 'ARRAY' ? @$as : $as ] };
  98   }
  99   if (defined($proto{using}) and ref(my $using = $proto{using}) ne 'HASH') {
 100     $proto{using} = { -row => [
 101       map [ $self->expand_expr($_, -ident) ],
 102         ref($using) eq 'ARRAY' ? @$using: $using
 103     ] };
 104   }
 105   my %ret = map +($_ => $self->expand_expr($proto{$_}, -ident)),
 106               sort keys %proto;
 107   return +{ -join => \%ret };
 108 }
 109
 110 sub _render_from_list {
 111   my ($self, $list) = @_;
 112   return $self->_join_parts(', ', map [ $self->render_aqt($_) ], @$list);
 113 }
 114
 115 sub _render_join {
 116   my ($self, $args) = @_;
 117
 118   my @parts = (
 119     [ $self->render_aqt($args->{from}) ],
 120     [ $self->_sqlcase(
 121         ($args->{type}
 122           ? join(' ', split '_', $args->{type}).' '
 123           : ''
 124         )
 125         .'join'
 126       )
 127     ],
 128     [ $self->render_aqt(
 129         map +($_->{-ident} || $_->{-as} ? $_ : { -row => [ $_ ] }), $args->{to}
 130     ) ],
 131     ($args->{on} ? (
 132       [ $self->_sqlcase('on') ],
 133       [ $self->render_aqt($args->{on}) ],
 134     ) : ()),
 135     ($args->{using} ? (
 136       [ $self->_sqlcase('using') ],
 137       [ $self->render_aqt($args->{using}) ],
 138     ) : ()),
 139   );
 140   return $self->_join_parts(' ', @parts);
 141 }
 142
 143 sub _expand_op_as {
 144   my ($self, undef, $vv, $k) = @_;
 145   my @as = map $self->expand_expr($_, -ident),
 146              (defined($k) ? ($k) : ()), ref($vv) eq 'ARRAY' ? @$vv : $vv;
 147   return { -as => \@as };
 148 }
 149
 150 sub _render_as {
 151   my ($self, $args) = @_;
 152   my ($thing, $as, @cols) = @$args;
 153   return $self->_join_parts(
 154     ' ',
 155     [ $self->render_aqt($thing) ],
 156     [ $self->_sqlcase('as') ],
 157     (@cols
 158       ? [ $self->_join_parts('',
 159             [ $self->render_aqt($as) ],
 160             [ '(' ],
 161             [ $self->_join_parts(
 162                 ', ',
 163                 map [ $self->render_aqt($_) ], @cols
 164             ) ],
 165             [ ')' ],
 166         ) ]
 167       : [ $self->render_aqt($as) ]
 168     ),
 169   );
 170 }
 171
 172 1;