lib/SQL/Abstract/ExtraClauses.pm

   1 package SQL::Abstract::ExtraClauses;
   2
   3 use strict;
   4 use warnings;
   5 use if $] < '5.010', 'MRO::Compat';
   6 use mro 'c3';
   7 use base qw(SQL::Abstract::Clauses);
   8
   9 BEGIN { *puke = \&SQL::Abstract::puke }
  10
  11 sub register_defaults {
  12   my $self = shift;
  13   $self->next::method(@_);
  14   $self->clauses_of(
  15     select => $self->clauses_of('select'), qw(group_by having)
  16   );
  17   $self->clause_expanders(
  18     'select.group_by', sub {
  19       $_[0]->_expand_maybe_list_expr($_[1], -ident)
  20     },
  21     'select.having', 'expand_expr',
  22   );
  23   foreach my $thing (qw(join from_list)) {
  24     $self->expander($thing => "_expand_${thing}")
  25          ->renderer($thing => "_render_${thing}")
  26   }
  27   $self->op_expander(as => '_expand_op_as');
  28   $self->expander(as => '_expand_op_as');
  29   $self->renderer(as => '_render_as');
  30
  31   splice(@{$self->{clauses_of}{update}}, 2, 0, 'from');
  32   splice(@{$self->{clauses_of}{delete}}, 1, 0, 'using');
  33   $self->clause_expanders(
  34     'update.from' => '_expand_select_clause_from',
  35     'delete.using' => sub {
  36       +(using => $_[0]->_expand_from_list(undef, $_[1]));
  37     },
  38     'insert.rowvalues' => sub {
  39       +(from => $_[0]->expand_expr({ -values => $_[1] }));
  40     },
  41     'insert.select' => sub {
  42       +(from => $_[0]->expand_expr({ -select => $_[1] }));
  43     },
  44   );
  45   return $self;
  46 }
  47
  48 sub _expand_select_clause_from {
  49   my ($self, $from) = @_;
  50   +(from => $self->_expand_from_list(undef, $from));
  51 }
  52
  53 sub _expand_from_list {
  54   my ($self, undef, $args) = @_;
  55   if (ref($args) eq 'HASH') {
  56     return { -from_list => [ $self->expand_expr($args) ] };
  57   }
  58   my @list;
  59   my @args = ref($args) eq 'ARRAY' ? @$args : ($args);
  60   while (my $entry = shift @args) {
  61     if (!ref($entry) and $entry =~ /^-(.*)/) {
  62       if ($1 eq 'as') {
  63         $list[-1] = $self->expand_expr({ -as => [
  64           $list[-1], map +(ref($_) eq 'ARRAY' ? @$_ : $_), shift(@args)
  65         ]});
  66         next;
  67       }
  68       $entry = { $entry => shift @args };
  69     }
  70     my $aqt = $self->expand_expr($entry, -ident);
  71     if ($aqt->{-join} and not $aqt->{-join}{from}) {
  72       $aqt->{-join}{from} = pop @list;
  73     }
  74     push @list, $aqt;
  75   }
  76   return { -from_list => \@list };
  77 }
  78
  79 sub _expand_join {
  80   my ($self, undef, $args) = @_;
  81   my %proto = (
  82     ref($args) eq 'HASH'
  83       ? %$args
  84       : (to => $args->[0], @{$args}[1..$#$args])
  85   );
  86   if (my $as = delete $proto{as}) {
  87     $proto{to} = { -as => [ $proto{to}, ref($as) eq 'ARRAY' ? @$as : $as ] };
  88   }
  89   if (defined($proto{using}) and ref(my $using = $proto{using}) ne 'HASH') {
  90     $proto{using} = { -row => [
  91       map [ $self->expand_expr($_, -ident) ],
  92         ref($using) eq 'ARRAY' ? @$using: $using
  93     ] };
  94   }
  95   my %ret = map +($_ => $self->expand_expr($proto{$_}, -ident)),
  96               sort keys %proto;
  97   return +{ -join => \%ret };
  98 }
  99
 100 sub _render_from_list {
 101   my ($self, $list) = @_;
 102   return $self->_join_parts(', ', map [ $self->render_aqt($_) ], @$list);
 103 }
 104
 105 sub _render_join {
 106   my ($self, $args) = @_;
 107
 108   my @parts = (
 109     [ $self->render_aqt($args->{from}) ],
 110     [ $self->_sqlcase(
 111         ($args->{type}
 112           ? join(' ', split '_', $args->{type}).' '
 113           : ''
 114         )
 115         .'join'
 116       )
 117     ],
 118     [ $self->render_aqt(
 119         map +($_->{-ident} || $_->{-as} ? $_ : { -row => [ $_ ] }), $args->{to}
 120     ) ],
 121     ($args->{on} ? (
 122       [ $self->_sqlcase('on') ],
 123       [ $self->render_aqt($args->{on}) ],
 124     ) : ()),
 125     ($args->{using} ? (
 126       [ $self->_sqlcase('using') ],
 127       [ $self->render_aqt($args->{using}) ],
 128     ) : ()),
 129   );
 130   return $self->_join_parts(' ', @parts);
 131 }
 132
 133 sub _expand_op_as {
 134   my ($self, undef, $vv, $k) = @_;
 135   my @as = map $self->expand_expr($_, -ident),
 136              (defined($k) ? ($k) : ()), ref($vv) eq 'ARRAY' ? @$vv : $vv;
 137   return { -as => \@as };
 138 }
 139
 140 sub _render_as {
 141   my ($self, $args) = @_;
 142   my ($thing, $as, @cols) = @$args;
 143   return $self->_join_parts(
 144     ' ',
 145     [ $self->render_aqt($thing) ],
 146     [ $self->_sqlcase('as') ],
 147     (@cols
 148       ? [ $self->_join_parts('',
 149             [ $self->render_aqt($as) ],
 150             [ '(' ],
 151             [ $self->_join_parts(
 152                 ', ',
 153                 map [ $self->render_aqt($_) ], @cols
 154             ) ],
 155             [ ')' ],
 156         ) ]
 157       : [ $self->render_aqt($as) ]
 158     ),
 159   );
 160 }
 161
 162 1;