lib/SQL/Abstract/ExtraClauses.pm

   1 package SQL::Abstract::ExtraClauses;
   2
   3 use Moo;
   4
   5 has sqla => (
   6   is => 'ro', init_arg => undef,
   7   handles => [ qw(
   8     expand_expr expand_maybe_list_expr render_aqt
   9     format_keyword join_query_parts
  10   ) ],
  11 );
  12
  13 sub cb {
  14   my ($self, $method, @args) = @_;
  15   return sub {
  16     local $self->{sqla} = shift;
  17     $self->$method(@args, @_)
  18   };
  19 }
  20
  21 sub apply_to {
  22   my ($self, $sqla) = @_;
  23   $self = $self->new unless ref($self);
  24   my @clauses = $sqla->clauses_of('select');
  25   my @before_setop;
  26   CLAUSE: foreach my $idx (0..$#clauses) {
  27     if ($clauses[$idx] eq 'order_by') {
  28       @before_setop = @clauses[0..$idx-1];
  29       splice(@clauses, $idx, 0, qw(setop group_by having));
  30       last CLAUSE;
  31     }
  32   }
  33   die "Huh?" unless @before_setop;
  34   $sqla->clauses_of(select => 'with', @clauses);
  35   $sqla->clause_expanders(
  36     'select.group_by', $self->cb(sub {
  37       $_[0]->expand_maybe_list_expr($_[2], -ident)
  38     }),
  39     'select.having', $self->cb(sub { $_[0]->expand_expr($_[2]) }),
  40   );
  41   foreach my $thing (qw(join from_list)) {
  42     $sqla->expander($thing => $self->cb("_expand_${thing}"))
  43          ->renderer($thing => $self->cb("_render_${thing}"))
  44   }
  45   $sqla->op_expander(as => $self->cb('_expand_op_as'));
  46   $sqla->expander(as => $self->cb('_expand_op_as'));
  47   $sqla->renderer(as => $self->cb('_render_as'));
  48   $sqla->expander(alias => $self->cb('_expand_alias'));
  49   $sqla->renderer(alias => $self->cb('_render_alias'));
  50
  51   $sqla->clauses_of(update => sub {
  52     my ($self, @clauses) = @_;
  53     splice(@clauses, 2, 0, 'from');
  54     @clauses;
  55   });
  56
  57   $sqla->clauses_of(delete => sub {
  58     my ($self, @clauses) = @_;
  59     splice(@clauses, 1, 0, 'using');
  60     @clauses;
  61   });
  62
  63   $sqla->clause_expanders(
  64     'update.from' => $self->cb('_expand_from_list'),
  65     'delete.using' => $self->cb('_expand_from_list'),
  66     'insert.rowvalues' => $self->cb(sub {
  67       +(from => $_[0]->expand_expr({ -values => $_[2] }));
  68     }),
  69     'insert.select' => $self->cb(sub {
  70       +(from => $_[0]->expand_expr({ -select => $_[2] }));
  71     }),
  72   );
  73
  74   # set ops
  75   $sqla->wrap_expander(select => sub {
  76     $self->cb('_expand_select', $_[0], \@before_setop);
  77   });
  78
  79   $sqla->clause_renderer('select.setop' => $self->cb(sub {
  80     my ($self, undef, $setop) = @_;
  81     $self->render_aqt($setop);
  82   }));
  83
  84   foreach my $setop (qw(union intersect except)) {
  85     $sqla->expander($setop => $self->cb('_expand_setop'));
  86     $sqla->renderer($setop => $self->cb('_render_setop'));
  87   }
  88
  89   my $setop_expander = $self->cb('_expand_clause_setop');
  90
  91   $sqla->clause_expanders(
  92     map +($_ => $setop_expander),
  93       map "select.${_}",
  94         map +($_, "${_}_all", "${_}_distinct"),
  95           qw(union intersect except)
  96   );
  97
  98   my $w_exp = $self->cb('_expand_with');
  99   my $w_rdr = $self->cb('_render_with');
 100   $sqla->clause_expander('select.with' => $w_exp);
 101   $sqla->clause_expander('select.with_recursive' => $w_exp);
 102   $sqla->clause_renderer('select.with' => $w_rdr);
 103
 104   foreach my $stmt (qw(insert update delete)) {
 105     $sqla->clauses_of($stmt => 'with', $sqla->clauses_of($stmt));
 106     $sqla->clause_expander("${stmt}.$_" => $w_exp)
 107       for qw(with with_recursive);
 108     $sqla->clause_renderer("${stmt}.with" => $w_rdr);
 109   }
 110
 111   $sqla->expander(cast => $self->cb('_expand_cast'));
 112
 113   $sqla->clause_expanders(
 114     "select.from", $self->cb('_expand_from_list'),
 115     "update.target", $self->cb('_expand_update_clause_target'),
 116     "update.update", $self->cb('_expand_update_clause_target'),
 117   );
 118
 119   return $sqla;
 120 }
 121
 122 sub _expand_select {
 123   my ($self, $orig, $before_setop, @args) = @_;
 124   my $exp = $self->sqla->$orig(@args);
 125   return $exp unless my $setop = (my $sel = $exp->{-select})->{setop};
 126   if (my @keys = grep $sel->{$_}, @$before_setop) {
 127     my %inner; @inner{@keys} = delete @{$sel}{@keys};
 128     unshift @{(values(%$setop))[0]{queries}},
 129       { -select => \%inner };
 130   }
 131   return $exp;
 132 }
 133
 134 sub _expand_from_list {
 135   my ($self, undef, $args) = @_;
 136   if (ref($args) eq 'HASH') {
 137     return $args if $args->{-from_list};
 138     return { -from_list => [ $self->expand_expr($args) ] };
 139   }
 140   my @list;
 141   my @args = ref($args) eq 'ARRAY' ? @$args : ($args);
 142   while (my $entry = shift @args) {
 143     if (!ref($entry) and $entry =~ /^-(.*)/) {
 144       if ($1 eq 'as') {
 145         $list[-1] = $self->expand_expr({ -as => [
 146           $list[-1], map +(ref($_) eq 'ARRAY' ? @$_ : $_), shift(@args)
 147         ]});
 148         next;
 149       }
 150       $entry = { $entry => shift @args };
 151     }
 152     my $aqt = $self->expand_expr($entry, -ident);
 153     if ($aqt->{-join} and not $aqt->{-join}{from}) {
 154       $aqt->{-join}{from} = pop @list;
 155     }
 156     push @list, $aqt;
 157   }
 158   return { -from_list => \@list };
 159 }
 160
 161 sub _expand_join {
 162   my ($self, undef, $args) = @_;
 163   my %proto = (
 164     ref($args) eq 'HASH'
 165       ? %$args
 166       : (to => $args->[0], @{$args}[1..$#$args])
 167   );
 168   if (my $as = delete $proto{as}) {
 169     $proto{to} = $self->expand_expr({ -as => [ $proto{to}, $as ] });
 170   }
 171   if (defined($proto{using}) and ref(my $using = $proto{using}) ne 'HASH') {
 172     $proto{using} = [
 173       map [ $self->expand_expr($_, -ident) ],
 174         ref($using) eq 'ARRAY' ? @$using: $using
 175     ];
 176   }
 177   my %ret = map +($_ => $self->expand_expr($proto{$_}, -ident)),
 178               sort keys %proto;
 179   return +{ -join => \%ret };
 180 }
 181
 182 sub _render_from_list {
 183   my ($self, undef, $list) = @_;
 184   return $self->join_query_parts(', ', @$list);
 185 }
 186
 187 sub _render_join {
 188   my ($self, undef, $args) = @_;
 189
 190   my @parts = (
 191     $args->{from},
 192     $self->format_keyword(join '_', ($args->{type}||()), 'join'),
 193     (map +($_->{-ident} || $_->{-as} ? $_ : ('(', $_, ')')), $args->{to}),
 194     ($args->{on} ? (
 195       $self->format_keyword('on') ,
 196       $args->{on},
 197     ) : ()),
 198     ($args->{using} ? (
 199       $self->format_keyword('using'),
 200       '(', $args->{using}, ')',
 201     ) : ()),
 202   );
 203   return $self->join_query_parts(' ', @parts);
 204 }
 205
 206 sub _expand_op_as {
 207   my ($self, undef, $vv, $k) = @_;
 208   my @vv = (ref($vv) eq 'ARRAY' ? @$vv : $vv);
 209   $k ||= shift @vv;
 210   my $ik = $self->expand_expr($k, -ident);
 211   return +{ -as => [ $ik, $self->expand_expr($vv[0], -alias) ] }
 212     if @vv == 1 and ref($vv[0]) eq 'HASH';
 213
 214   my @as = map $self->expand_expr($_, -ident), @vv;
 215   return { -as => [ $ik, { -alias => \@as } ] };
 216 }
 217
 218 sub _render_as {
 219   my ($self, undef, $args) = @_;
 220   my ($thing, $alias) = @$args;
 221   return $self->join_query_parts(
 222     ' ',
 223     $thing,
 224     $self->format_keyword('as'),
 225     $alias,
 226   );
 227 }
 228
 229 sub _render_alias {
 230   my ($self, undef, $args) = @_;
 231   my ($as, @cols) = @$args;
 232   return (@cols
 233     ? $self->join_query_parts('',
 234          $as,
 235          '(',
 236          $self->join_query_parts(
 237            ', ',
 238            @cols
 239          ),
 240          ')',
 241       )
 242     : $self->render_aqt($as)
 243   );
 244 }
 245
 246 sub _expand_update_clause_target {
 247   my ($self, undef, $target) = @_;
 248   +(target => $self->_expand_from_list(undef, $target));
 249 }
 250
 251 sub _expand_cast {
 252   my ($self, undef, $thing) = @_;
 253   return { -func => [ cast => $thing ] } if ref($thing) eq 'HASH';
 254   my ($cast, $to) = @{$thing};
 255   +{ -func => [ cast => { -as => [
 256     $self->expand_expr($cast),
 257     $self->expand_expr($to, -ident),
 258   ] } ] };
 259 }
 260
 261 sub _expand_alias {
 262   my ($self, undef, $args) = @_;
 263   if (ref($args) eq 'HASH' and my $alias = $args->{-alias}) {
 264     $args = $alias;
 265   }
 266   +{ -alias => [
 267       map $self->expand_expr($_, -ident),
 268       ref($args) eq 'ARRAY' ? @{$args} : $args
 269     ]
 270   }
 271 }
 272
 273 sub _expand_with {
 274   my ($self, $name, $with) = @_;
 275   my (undef, $type) = split '_', $name;
 276   if (ref($with) eq 'HASH') {
 277     return +{
 278       %$with,
 279       queries => [
 280         map +[
 281           $self->expand_expr({ -alias => $_->[0] }, -ident),
 282           $self->expand_expr($_->[1]),
 283         ], @{$with->{queries}}
 284       ]
 285     }
 286   }
 287   my @with = @$with;
 288   my @exp;
 289   while (my ($alias, $query) = splice @with, 0, 2) {
 290     push @exp, [
 291       $self->expand_expr({ -alias => $alias }, -ident),
 292       $self->expand_expr($query)
 293     ];
 294   }
 295   return +(with => { ($type ? (type => $type) : ()), queries => \@exp });
 296 }
 297
 298 sub _render_with {
 299   my ($self, undef, $with) = @_;
 300   my $q_part = $self->join_query_parts(', ',
 301     map {
 302       my ($alias, $query) = @$_;
 303       $self->join_query_parts(' ',
 304           $alias,
 305           $self->format_keyword('as'),
 306           $query,
 307       )
 308     } @{$with->{queries}}
 309   );
 310   return $self->join_query_parts(' ',
 311     $self->format_keyword(join '_', 'with', ($with->{type}||'')),
 312     $q_part,
 313   );
 314 }
 315
 316 sub _expand_setop {
 317   my ($self, $setop, $args) = @_;
 318   +{ "-${setop}" => {
 319        %$args,
 320        queries => [ map $self->expand_expr($_), @{$args->{queries}} ],
 321   } };
 322 }
 323
 324 sub _render_setop {
 325   my ($self, $setop, $args) = @_;
 326   $self->join_query_parts(
 327     ' '.$self->format_keyword(join '_', $setop, ($args->{type}||())).' ',
 328     @{$args->{queries}}
 329   );
 330 }
 331
 332 sub _expand_clause_setop {
 333   my ($self, $setop, $args) = @_;
 334   my ($op, $type) = split '_', $setop;
 335   +(setop => $self->expand_expr({
 336     "-${op}" => {
 337       ($type ? (type => $type) : ()),
 338       queries => (ref($args) eq 'ARRAY' ? $args : [ $args ])
 339     }
 340   }));
 341 }
 342
 343 1;