lib/SQL/Abstract/ExtraClauses.pm

   1 package SQL::Abstract::ExtraClauses;
   2
   3 use strict;
   4 use warnings;
   5 use if $] < '5.010', 'MRO::Compat';
   6 use mro 'c3';
   7 use base qw(SQL::Abstract::Clauses);
   8
   9 BEGIN { *puke = \&SQL::Abstract::puke }
  10
  11 sub register_defaults {
  12   my $self = shift;
  13   $self->next::method(@_);
  14   my @clauses = $self->clauses_of('select');
  15   my @before_setop;
  16   CLAUSE: foreach my $idx (0..$#clauses) {
  17     if ($clauses[$idx] eq 'order_by') {
  18       @before_setop = @clauses[0..$idx-1];
  19       splice(@clauses, $idx, 0, qw(setop group_by having));
  20       last CLAUSE;
  21     }
  22   }
  23   die "Huh?" unless @before_setop;
  24   $self->clauses_of(select => 'with', @clauses);
  25   $self->clause_expanders(
  26     'select.group_by', sub {
  27       $_[0]->_expand_maybe_list_expr($_[1], -ident)
  28     },
  29     'select.having', 'expand_expr',
  30   );
  31   foreach my $thing (qw(join from_list)) {
  32     $self->expander($thing => "_expand_${thing}")
  33          ->renderer($thing => "_render_${thing}")
  34   }
  35   $self->op_expander(as => '_expand_op_as');
  36   $self->expander(as => '_expand_op_as');
  37   $self->renderer(as => '_render_as');
  38
  39   $self->clauses_of(update => sub {
  40     my ($self, @clauses) = @_;
  41     splice(@clauses, 2, 0, 'from');
  42     @clauses;
  43   });
  44
  45   $self->clauses_of(delete => sub {
  46     my ($self, @clauses) = @_;
  47     splice(@clauses, 1, 0, 'using');
  48     @clauses;
  49   });
  50
  51   $self->clause_expanders(
  52     'update.from' => '_expand_select_clause_from',
  53     'delete.using' => sub {
  54       +(using => $_[0]->_expand_from_list(undef, $_[1]));
  55     },
  56     'insert.rowvalues' => sub {
  57       +(from => $_[0]->expand_expr({ -values => $_[1] }));
  58     },
  59     'insert.select' => sub {
  60       +(from => $_[0]->expand_expr({ -select => $_[1] }));
  61     },
  62   );
  63
  64   # set ops
  65   {
  66     my $orig = $self->expander('select');
  67     $self->expander(select => sub {
  68       my $self = shift;
  69       my $exp = $self->$orig(@_);
  70       return $exp unless my $setop = (my $sel = $exp->{-select})->{setop};
  71       if (my @keys = grep $sel->{$_}, @before_setop) {
  72         my %inner; @inner{@keys} = delete @{$sel}{@keys};
  73         unshift @{(values(%$setop))[0]{queries}},
  74           { -select => \%inner };
  75       }
  76       return $exp;
  77     });
  78   }
  79   my $expand_setop = sub {
  80     my ($self, $setop, $args) = @_;
  81     +{ "-${setop}" => {
  82          %$args,
  83          queries => [ map $self->expand_expr($_), @{$args->{queries}} ],
  84     } };
  85   };
  86   $self->expanders(map +($_ => $expand_setop), qw(union intersect except));
  87
  88   $self->clause_renderer('select.setop' => sub {
  89     my ($self, $setop) = @_;
  90     $self->render_aqt($setop);
  91   });
  92
  93   foreach my $setop (qw(union intersect except)) {
  94     $self->renderer($setop => sub {
  95       my ($self, $args) = @_;
  96       $self->join_clauses(
  97         ' '.$self->format_keyword(join '_', $setop, ($args->{type}||())).' ',
  98         map [ $self->render_aqt($_) ], @{$args->{queries}}
  99       );
 100     });
 101
 102     $self->clause_expander("select.${setop}" => sub {
 103       +(setop => $_[0]->expand_expr({
 104                    "-${setop}" => {
 105                      queries => (ref($_[1]) eq 'ARRAY' ? $_[1] : [ $_[1] ]),
 106                    }
 107                  }));
 108     });
 109     $self->clause_expander("select.${setop}_all" => sub {
 110       +(setop => $_[0]->expand_expr({
 111                    "-${setop}" => {
 112                      type => 'all',
 113                      queries => (ref($_[1]) eq 'ARRAY' ? $_[1] : [ $_[1] ]),
 114                    }
 115                  }));
 116     });
 117   }
 118   $self->clause_expander('select.with' => my $with_expander = sub {
 119     my ($self, $with) = @_;
 120     if (ref($with) eq 'HASH') {
 121       return +{
 122         %$with,
 123         queries => [ map $self->expand_expr($_), @{$with->{queries}} ]
 124       }
 125     }
 126     my @with = @$with;
 127     my @exp;
 128     while (my ($name, $query) = splice @with, 0, 2) {
 129       my @n = map $self->expand_expr($_, -ident),
 130                 ref($name) eq 'ARRAY' ? @$name : $name;
 131       push @exp, [
 132         \@n,
 133         $self->expand_expr($query)
 134       ];
 135     }
 136     return +{ queries => \@exp };
 137   });
 138   $self->clause_expander('select.with_recursive' => sub {
 139     my ($self, $with) = @_;
 140     my $exp = $self->$with_expander($with);
 141     return +(with => +{
 142       %$exp,
 143       type => 'recursive'
 144     });
 145   });
 146   $self->clause_renderer('select.with' => sub {
 147     my ($self, $with) = @_;
 148     my $q_part = [ $self->join_clauses(', ',
 149       map {
 150         my ($alias, $query) = @$_;
 151         [ $self->join_clauses(' ',
 152             [ $self->_render_alias($alias) ],
 153             [ $self->format_keyword('as') ],
 154             [ $self->render_aqt($query) ],
 155         ) ]
 156       } @{$with->{queries}}
 157     ) ];
 158     return $self->join_clauses(' ',
 159       [ $self->format_keyword(join '_', 'with', ($with->{type}||'')) ],
 160       $q_part,
 161     );
 162   });
 163
 164   return $self;
 165 }
 166
 167 sub format_keyword { $_[0]->_sqlcase(join ' ', split '_', $_[1]) }
 168
 169 sub _expand_select_clause_from {
 170   my ($self, $from) = @_;
 171   +(from => $self->_expand_from_list(undef, $from));
 172 }
 173
 174 sub _expand_from_list {
 175   my ($self, undef, $args) = @_;
 176   if (ref($args) eq 'HASH') {
 177     return { -from_list => [ $self->expand_expr($args) ] };
 178   }
 179   my @list;
 180   my @args = ref($args) eq 'ARRAY' ? @$args : ($args);
 181   while (my $entry = shift @args) {
 182     if (!ref($entry) and $entry =~ /^-(.*)/) {
 183       if ($1 eq 'as') {
 184         $list[-1] = $self->expand_expr({ -as => [
 185           $list[-1], map +(ref($_) eq 'ARRAY' ? @$_ : $_), shift(@args)
 186         ]});
 187         next;
 188       }
 189       $entry = { $entry => shift @args };
 190     }
 191     my $aqt = $self->expand_expr($entry, -ident);
 192     if ($aqt->{-join} and not $aqt->{-join}{from}) {
 193       $aqt->{-join}{from} = pop @list;
 194     }
 195     push @list, $aqt;
 196   }
 197   return { -from_list => \@list };
 198 }
 199
 200 sub _expand_join {
 201   my ($self, undef, $args) = @_;
 202   my %proto = (
 203     ref($args) eq 'HASH'
 204       ? %$args
 205       : (to => $args->[0], @{$args}[1..$#$args])
 206   );
 207   if (my $as = delete $proto{as}) {
 208     $proto{to} = { -as => [ $proto{to}, ref($as) eq 'ARRAY' ? @$as : $as ] };
 209   }
 210   if (defined($proto{using}) and ref(my $using = $proto{using}) ne 'HASH') {
 211     $proto{using} = { -row => [
 212       map [ $self->expand_expr($_, -ident) ],
 213         ref($using) eq 'ARRAY' ? @$using: $using
 214     ] };
 215   }
 216   my %ret = map +($_ => $self->expand_expr($proto{$_}, -ident)),
 217               sort keys %proto;
 218   return +{ -join => \%ret };
 219 }
 220
 221 sub _render_from_list {
 222   my ($self, $list) = @_;
 223   return $self->join_clauses(', ', map [ $self->render_aqt($_) ], @$list);
 224 }
 225
 226 sub _render_join {
 227   my ($self, $args) = @_;
 228
 229   my @parts = (
 230     [ $self->render_aqt($args->{from}) ],
 231     [ $self->format_keyword(join '_', ($args->{type}||()), 'join') ],
 232     [ $self->render_aqt(
 233         map +($_->{-ident} || $_->{-as} ? $_ : { -row => [ $_ ] }), $args->{to}
 234     ) ],
 235     ($args->{on} ? (
 236       [ $self->format_keyword('on') ],
 237       [ $self->render_aqt($args->{on}) ],
 238     ) : ()),
 239     ($args->{using} ? (
 240       [ $self->format_keyword('using') ],
 241       [ $self->render_aqt($args->{using}) ],
 242     ) : ()),
 243   );
 244   return $self->join_clauses(' ', @parts);
 245 }
 246
 247 sub _expand_op_as {
 248   my ($self, undef, $vv, $k) = @_;
 249   my @as = map $self->expand_expr($_, -ident),
 250              (defined($k) ? ($k) : ()), ref($vv) eq 'ARRAY' ? @$vv : $vv;
 251   return { -as => \@as };
 252 }
 253
 254 sub _render_as {
 255   my ($self, $args) = @_;
 256   my ($thing, @alias) = @$args;
 257   return $self->join_clauses(
 258     ' ',
 259     [ $self->render_aqt($thing) ],
 260     [ $self->format_keyword('as') ],
 261     [ $self->_render_alias(\@alias) ],
 262   );
 263 }
 264
 265 sub _render_alias {
 266   my ($self, $args) = @_;
 267   my ($as, @cols) = @$args;
 268   return (@cols
 269     ? $self->join_clauses('',
 270          [ $self->render_aqt($as) ],
 271          [ '(' ],
 272          [ $self->join_clauses(
 273              ', ',
 274              map [ $self->render_aqt($_) ], @cols
 275          ) ],
 276          [ ')' ],
 277       )
 278     : $self->render_aqt($as)
 279   );
 280 }
 281
 282 sub _expand_update_clause_target {
 283   my ($self, $target) = @_;
 284   +(target => $self->_expand_from_list(undef, $target));
 285 }
 286
 287 1;