lib/SQL/Abstract/ExtraClauses.pm

   1 package SQL::Abstract::ExtraClauses;
   2
   3 use Moo;
   4
   5 has sqla => (
   6   is => 'ro', init_arg => undef,
   7   handles => [ qw(
   8     expand_expr expand_maybe_list_expr render_aqt
   9     format_keyword join_query_parts
  10   ) ],
  11 );
  12
  13 BEGIN { *puke = \&SQL::Abstract::puke }
  14
  15 sub cb {
  16   my ($self, $method) = @_;
  17   return sub { local $self->{sqla} = shift; $self->$method(@_) };
  18 }
  19
  20 sub apply_to {
  21   my ($self, $sqla) = @_;
  22   $self = $self->new unless ref($self);
  23   my @clauses = $sqla->clauses_of('select');
  24   my @before_setop;
  25   CLAUSE: foreach my $idx (0..$#clauses) {
  26     if ($clauses[$idx] eq 'order_by') {
  27       @before_setop = @clauses[0..$idx-1];
  28       splice(@clauses, $idx, 0, qw(setop group_by having));
  29       last CLAUSE;
  30     }
  31   }
  32   die "Huh?" unless @before_setop;
  33   $sqla->clauses_of(select => 'with', @clauses);
  34   $sqla->clause_expanders(
  35     'select.group_by', $self->cb(sub {
  36       $_[0]->expand_maybe_list_expr($_[2], -ident)
  37     }),
  38     'select.having', $self->cb(sub { $_[0]->expand_expr($_[2]) }),
  39   );
  40   foreach my $thing (qw(join from_list)) {
  41     $sqla->expander($thing => $self->cb("_expand_${thing}"))
  42          ->renderer($thing => $self->cb("_render_${thing}"))
  43   }
  44   $sqla->op_expander(as => $self->cb('_expand_op_as'));
  45   $sqla->expander(as => $self->cb('_expand_op_as'));
  46   $sqla->renderer(as => $self->cb('_render_as'));
  47   $sqla->expander(alias => $self->cb('_expand_alias'));
  48   $sqla->renderer(alias => $self->cb('_render_alias'));
  49
  50   $sqla->clauses_of(update => sub {
  51     my ($self, @clauses) = @_;
  52     splice(@clauses, 2, 0, 'from');
  53     @clauses;
  54   });
  55
  56   $sqla->clauses_of(delete => sub {
  57     my ($self, @clauses) = @_;
  58     splice(@clauses, 1, 0, 'using');
  59     @clauses;
  60   });
  61
  62   $sqla->clause_expanders(
  63     'update.from' => $self->cb('_expand_select_clause_from'),
  64     'delete.using' => $self->cb(sub {
  65       +(using => $_[0]->_expand_from_list(undef, $_[2]));
  66     }),
  67     'insert.rowvalues' => $self->cb(sub {
  68       +(from => $_[0]->expand_expr({ -values => $_[2] }));
  69     }),
  70     'insert.select' => $self->cb(sub {
  71       +(from => $_[0]->expand_expr({ -select => $_[2] }));
  72     }),
  73   );
  74
  75   # set ops
  76   $sqla->wrap_expander(select => sub {
  77     my $orig = shift;
  78     $self->cb(sub {
  79       my $self = shift;
  80       my $exp = $self->sqla->$orig(@_);
  81       return $exp unless my $setop = (my $sel = $exp->{-select})->{setop};
  82       if (my @keys = grep $sel->{$_}, @before_setop) {
  83         my %inner; @inner{@keys} = delete @{$sel}{@keys};
  84         unshift @{(values(%$setop))[0]{queries}},
  85           { -select => \%inner };
  86       }
  87       return $exp;
  88     });
  89   });
  90   my $expand_setop = $self->cb(sub {
  91     my ($self, $setop, $args) = @_;
  92     +{ "-${setop}" => {
  93          %$args,
  94          queries => [ map $self->expand_expr($_), @{$args->{queries}} ],
  95     } };
  96   });
  97   $sqla->expanders(map +($_ => $expand_setop), qw(union intersect except));
  98
  99   $sqla->clause_renderer('select.setop' => $self->cb(sub {
 100     my ($self, undef, $setop) = @_;
 101     $self->render_aqt($setop);
 102   }));
 103
 104   $sqla->renderer($_ => $self->cb(sub {
 105     my ($self, $setop, $args) = @_;
 106     $self->join_query_parts(
 107       ' '.$self->format_keyword(join '_', $setop, ($args->{type}||())).' ',
 108       @{$args->{queries}}
 109     );
 110   })) for qw(union intersect except);
 111
 112   my $setop_expander = $self->cb(sub {
 113     my ($self, $setop, $args) = @_;
 114     my ($op, $type) = split '_', $setop;
 115     +(setop => $self->expand_expr({
 116       "-${op}" => {
 117         ($type ? (type => $type) : ()),
 118         queries => (ref($args) eq 'ARRAY' ? $args : [ $args ])
 119       }
 120     }));
 121   });
 122
 123   $sqla->clause_expanders(
 124     map +($_ => $setop_expander),
 125       map "select.${_}",
 126         map +($_, "${_}_all", "${_}_distinct"),
 127           qw(union intersect except)
 128   );
 129
 130   my $w_exp = $self->cb('_expand_with');
 131   my $w_rdr = $self->cb('_render_with');
 132   $sqla->clause_expander('select.with' => $w_exp);
 133   $sqla->clause_expander('select.with_recursive' => $w_exp);
 134   $sqla->clause_renderer('select.with' => $w_rdr);
 135
 136   foreach my $stmt (qw(insert update delete)) {
 137     $sqla->clauses_of($stmt => 'with', $sqla->clauses_of($stmt));
 138     $sqla->clause_expander("${stmt}.$_" => $w_exp)
 139       for qw(with with_recursive);
 140     $sqla->clause_renderer("${stmt}.with" => $w_rdr);
 141   }
 142
 143   $sqla->expander(cast => $self->cb('_expand_cast'));
 144
 145   $sqla->clause_expanders(
 146     "select.from", $self->cb('_expand_select_clause_from'),
 147     "update.target", $self->cb('_expand_update_clause_target'),
 148     "update.update", $self->cb('_expand_update_clause_target'),
 149   );
 150
 151   return $sqla;
 152 }
 153
 154 sub _expand_select_clause_from {
 155   my ($self, undef, $from) = @_;
 156   +(from => $self->_expand_from_list(undef, $from));
 157 }
 158
 159 sub _expand_from_list {
 160   my ($self, undef, $args) = @_;
 161   if (ref($args) eq 'HASH') {
 162     return $args if $args->{-from_list};
 163     return { -from_list => [ $self->expand_expr($args) ] };
 164   }
 165   my @list;
 166   my @args = ref($args) eq 'ARRAY' ? @$args : ($args);
 167   while (my $entry = shift @args) {
 168     if (!ref($entry) and $entry =~ /^-(.*)/) {
 169       if ($1 eq 'as') {
 170         $list[-1] = $self->expand_expr({ -as => [
 171           $list[-1], map +(ref($_) eq 'ARRAY' ? @$_ : $_), shift(@args)
 172         ]});
 173         next;
 174       }
 175       $entry = { $entry => shift @args };
 176     }
 177     my $aqt = $self->expand_expr($entry, -ident);
 178     if ($aqt->{-join} and not $aqt->{-join}{from}) {
 179       $aqt->{-join}{from} = pop @list;
 180     }
 181     push @list, $aqt;
 182   }
 183   return { -from_list => \@list };
 184 }
 185
 186 sub _expand_join {
 187   my ($self, undef, $args) = @_;
 188   my %proto = (
 189     ref($args) eq 'HASH'
 190       ? %$args
 191       : (to => $args->[0], @{$args}[1..$#$args])
 192   );
 193   if (my $as = delete $proto{as}) {
 194     $proto{to} = $self->expand_expr({ -as => [ $proto{to}, $as ] });
 195   }
 196   if (defined($proto{using}) and ref(my $using = $proto{using}) ne 'HASH') {
 197     $proto{using} = [
 198       map [ $self->expand_expr($_, -ident) ],
 199         ref($using) eq 'ARRAY' ? @$using: $using
 200     ];
 201   }
 202   my %ret = map +($_ => $self->expand_expr($proto{$_}, -ident)),
 203               sort keys %proto;
 204   return +{ -join => \%ret };
 205 }
 206
 207 sub _render_from_list {
 208   my ($self, undef, $list) = @_;
 209   return $self->join_query_parts(', ', @$list);
 210 }
 211
 212 sub _render_join {
 213   my ($self, undef, $args) = @_;
 214
 215   my @parts = (
 216     $args->{from},
 217     $self->format_keyword(join '_', ($args->{type}||()), 'join'),
 218     (map +($_->{-ident} || $_->{-as} ? $_ : ('(', $_, ')')), $args->{to}),
 219     ($args->{on} ? (
 220       $self->format_keyword('on') ,
 221       $args->{on},
 222     ) : ()),
 223     ($args->{using} ? (
 224       $self->format_keyword('using'),
 225       '(', $args->{using}, ')',
 226     ) : ()),
 227   );
 228   return $self->join_query_parts(' ', @parts);
 229 }
 230
 231 sub _expand_op_as {
 232   my ($self, undef, $vv, $k) = @_;
 233   my @vv = (ref($vv) eq 'ARRAY' ? @$vv : $vv);
 234   $k ||= shift @vv;
 235   my $ik = $self->expand_expr($k, -ident);
 236   return +{ -as => [ $ik, $self->expand_expr($vv[0], -alias) ] }
 237     if @vv == 1 and ref($vv[0]) eq 'HASH';
 238
 239   my @as = map $self->expand_expr($_, -ident), @vv;
 240   return { -as => [ $ik, { -alias => \@as } ] };
 241 }
 242
 243 sub _render_as {
 244   my ($self, undef, $args) = @_;
 245   my ($thing, $alias) = @$args;
 246   return $self->join_query_parts(
 247     ' ',
 248     $thing,
 249     $self->format_keyword('as'),
 250     $alias,
 251   );
 252 }
 253
 254 sub _render_alias {
 255   my ($self, undef, $args) = @_;
 256   my ($as, @cols) = @$args;
 257   return (@cols
 258     ? $self->join_query_parts('',
 259          $as,
 260          '(',
 261          $self->join_query_parts(
 262            ', ',
 263            @cols
 264          ),
 265          ')',
 266       )
 267     : $self->render_aqt($as)
 268   );
 269 }
 270
 271 sub _expand_update_clause_target {
 272   my ($self, undef, $target) = @_;
 273   +(target => $self->_expand_from_list(undef, $target));
 274 }
 275
 276 sub _expand_cast {
 277   my ($self, undef, $thing) = @_;
 278   return { -func => [ cast => $thing ] } if ref($thing) eq 'HASH';
 279   my ($cast, $to) = @{$thing};
 280   +{ -func => [ cast => { -as => [
 281     $self->expand_expr($cast),
 282     $self->expand_expr($to, -ident),
 283   ] } ] };
 284 }
 285
 286 sub _expand_alias {
 287   my ($self, undef, $args) = @_;
 288   if (ref($args) eq 'HASH' and my $alias = $args->{-alias}) {
 289     $args = $alias;
 290   }
 291   +{ -alias => [
 292       map $self->expand_expr($_, -ident),
 293       ref($args) eq 'ARRAY' ? @{$args} : $args
 294     ]
 295   }
 296 }
 297
 298 sub _expand_with {
 299   my ($self, $name, $with) = @_;
 300   my (undef, $type) = split '_', $name;
 301   if (ref($with) eq 'HASH') {
 302     return +{
 303       %$with,
 304       queries => [
 305         map +[
 306           $self->expand_expr({ -alias => $_->[0] }, -ident),
 307           $self->expand_expr($_->[1]),
 308         ], @{$with->{queries}}
 309       ]
 310     }
 311   }
 312   my @with = @$with;
 313   my @exp;
 314   while (my ($alias, $query) = splice @with, 0, 2) {
 315     push @exp, [
 316       $self->expand_expr({ -alias => $alias }, -ident),
 317       $self->expand_expr($query)
 318     ];
 319   }
 320   return +(with => { ($type ? (type => $type) : ()), queries => \@exp });
 321 }
 322
 323 sub _render_with {
 324   my ($self, undef, $with) = @_;
 325   my $q_part = $self->join_query_parts(', ',
 326     map {
 327       my ($alias, $query) = @$_;
 328       $self->join_query_parts(' ',
 329           $alias,
 330           $self->format_keyword('as'),
 331           $query,
 332       )
 333     } @{$with->{queries}}
 334   );
 335   return $self->join_query_parts(' ',
 336     $self->format_keyword(join '_', 'with', ($with->{type}||'')),
 337     $q_part,
 338   );
 339 }
 340
 341 1;