lib/SQL/Abstract/ExtraClauses.pm

   1 package SQL::Abstract::ExtraClauses;
   2
   3 use strict;
   4 use warnings;
   5 use if $] < '5.010', 'MRO::Compat';
   6 use mro 'c3';
   7 use base qw(SQL::Abstract::Clauses);
   8
   9 BEGIN { *puke = \&SQL::Abstract::puke }
  10
  11 sub register_defaults {
  12   my $self = shift;
  13   $self->next::method(@_);
  14   $self->clauses_of(
  15     select => $self->clauses_of('select'), qw(group_by having)
  16   );
  17   $self->clause_expanders(
  18     'select.group_by', sub {
  19       $_[0]->_expand_maybe_list_expr($_[1], -ident)
  20     },
  21     'select.having', 'expand_expr',
  22   );
  23   foreach my $thing (qw(join from_list)) {
  24     $self->expander($thing => "_expand_${thing}")
  25          ->renderer($thing => "_render_${thing}")
  26   }
  27   $self->op_expander(as => '_expand_op_as');
  28   $self->expander(as => '_expand_op_as');
  29   $self->renderer(as => '_render_as');
  30
  31   $self->clauses_of(update => sub {
  32     my ($self, @clauses) = @_;
  33     splice(@clauses, 2, 0, 'from');
  34     @clauses;
  35   });
  36
  37   $self->clauses_of(delete => sub {
  38     my ($self, @clauses) = @_;
  39     splice(@clauses, 1, 0, 'using');
  40     @clauses;
  41   });
  42
  43   $self->clause_expanders(
  44     'update.from' => '_expand_select_clause_from',
  45     'delete.using' => sub {
  46       +(using => $_[0]->_expand_from_list(undef, $_[1]));
  47     },
  48     'insert.rowvalues' => sub {
  49       +(from => $_[0]->expand_expr({ -values => $_[1] }));
  50     },
  51     'insert.select' => sub {
  52       +(from => $_[0]->expand_expr({ -select => $_[1] }));
  53     },
  54   );
  55
  56   $self->renderer(keyword => sub {
  57     $_[0]->_sqlcase(join ' ', split '_', $_[1]);
  58   });
  59   return $self;
  60 }
  61
  62 sub _expand_select_clause_from {
  63   my ($self, $from) = @_;
  64   +(from => $self->_expand_from_list(undef, $from));
  65 }
  66
  67 sub _expand_from_list {
  68   my ($self, undef, $args) = @_;
  69   if (ref($args) eq 'HASH') {
  70     return { -from_list => [ $self->expand_expr($args) ] };
  71   }
  72   my @list;
  73   my @args = ref($args) eq 'ARRAY' ? @$args : ($args);
  74   while (my $entry = shift @args) {
  75     if (!ref($entry) and $entry =~ /^-(.*)/) {
  76       if ($1 eq 'as') {
  77         $list[-1] = $self->expand_expr({ -as => [
  78           $list[-1], map +(ref($_) eq 'ARRAY' ? @$_ : $_), shift(@args)
  79         ]});
  80         next;
  81       }
  82       $entry = { $entry => shift @args };
  83     }
  84     my $aqt = $self->expand_expr($entry, -ident);
  85     if ($aqt->{-join} and not $aqt->{-join}{from}) {
  86       $aqt->{-join}{from} = pop @list;
  87     }
  88     push @list, $aqt;
  89   }
  90   return { -from_list => \@list };
  91 }
  92
  93 sub _expand_join {
  94   my ($self, undef, $args) = @_;
  95   my %proto = (
  96     ref($args) eq 'HASH'
  97       ? %$args
  98       : (to => $args->[0], @{$args}[1..$#$args])
  99   );
 100   if (my $as = delete $proto{as}) {
 101     $proto{to} = { -as => [ $proto{to}, ref($as) eq 'ARRAY' ? @$as : $as ] };
 102   }
 103   if (defined($proto{using}) and ref(my $using = $proto{using}) ne 'HASH') {
 104     $proto{using} = { -row => [
 105       map [ $self->expand_expr($_, -ident) ],
 106         ref($using) eq 'ARRAY' ? @$using: $using
 107     ] };
 108   }
 109   my %ret = map +($_ => $self->expand_expr($proto{$_}, -ident)),
 110               sort keys %proto;
 111   return +{ -join => \%ret };
 112 }
 113
 114 sub _render_from_list {
 115   my ($self, $list) = @_;
 116   return $self->_join_parts(', ', map [ $self->render_aqt($_) ], @$list);
 117 }
 118
 119 sub _render_join {
 120   my ($self, $args) = @_;
 121
 122   my @parts = (
 123     [ $self->render_aqt($args->{from}) ],
 124     [ $self->render_aqt(
 125         { -keyword => join '_', ($args->{type}||()), 'join' }
 126     ) ],
 127     [ $self->render_aqt(
 128         map +($_->{-ident} || $_->{-as} ? $_ : { -row => [ $_ ] }), $args->{to}
 129     ) ],
 130     ($args->{on} ? (
 131       [ $self->render_aqt({ -keyword => 'on' }) ],
 132       [ $self->render_aqt($args->{on}) ],
 133     ) : ()),
 134     ($args->{using} ? (
 135       [ $self->render_aqt({ -keyword => 'using' }) ],
 136       [ $self->render_aqt($args->{using}) ],
 137     ) : ()),
 138   );
 139   return $self->_join_parts(' ', @parts);
 140 }
 141
 142 sub _expand_op_as {
 143   my ($self, undef, $vv, $k) = @_;
 144   my @as = map $self->expand_expr($_, -ident),
 145              (defined($k) ? ($k) : ()), ref($vv) eq 'ARRAY' ? @$vv : $vv;
 146   return { -as => \@as };
 147 }
 148
 149 sub _render_as {
 150   my ($self, $args) = @_;
 151   my ($thing, $as, @cols) = @$args;
 152   return $self->_join_parts(
 153     ' ',
 154     [ $self->render_aqt($thing) ],
 155     [ $self->render_aqt({ -keyword => 'as' }) ],
 156     (@cols
 157       ? [ $self->_join_parts('',
 158             [ $self->render_aqt($as) ],
 159             [ '(' ],
 160             [ $self->_join_parts(
 161                 ', ',
 162                 map [ $self->render_aqt($_) ], @cols
 163             ) ],
 164             [ ')' ],
 165         ) ]
 166       : [ $self->render_aqt($as) ]
 167     ),
 168   );
 169 }
 170
 171 1;