lib/SQL/Abstract/Clauses.pm

   1 package SQL::Abstract::Clauses;
   2
   3 use strict;
   4 use warnings;
   5 use if $] < '5.010', 'MRO::Compat';
   6 use mro 'c3';
   7 use base 'SQL::Abstract';
   8
   9 BEGIN { *puke = \&SQL::Abstract::puke }
  10
  11 sub new {
  12   shift->next::method(@_)->register_defaults
  13 }
  14
  15 sub register_defaults {
  16   my ($self) = @_;
  17   $self->{clauses_of}{select} = [ qw(select from where order_by) ];
  18   $self->{expand}{select} = sub { shift->_expand_statement(@_) };
  19   $self->{render}{select} = sub { shift->_render_statement(select => @_) };
  20   $self->{expand_clause}{"select.$_"} = "_expand_select_clause_$_"
  21     for @{$self->{clauses_of}{select}};
  22   $self->{clauses_of}{update} = [ qw(update set where returning) ];
  23   $self->{expand}{update} = sub { shift->_expand_statement(@_) };
  24   $self->{render}{update} = sub { shift->_render_statement(update => @_) };
  25   $self->{expand_clause}{"update.$_"} = "_expand_update_clause_$_"
  26     for @{$self->{clauses_of}{update}};
  27   $self->{clauses_of}{delete} = [ qw(delete_from where returning) ];
  28   $self->{expand}{delete} = sub { shift->_expand_statement(@_) };
  29   $self->{render}{delete} = sub { shift->_render_statement(delete => @_) };
  30   $self->{expand_clause}{"delete.$_"} = "_expand_delete_clause_$_"
  31     for @{$self->{clauses_of}{delete}};
  32   $self->{clauses_of}{insert} = [
  33     'insert_into', 'fields', 'values', 'returning'
  34   ];
  35   $self->{expand}{insert} = sub { shift->_expand_statement(@_) };
  36   $self->{render}{insert} = sub { shift->_render_statement(insert => @_) };
  37   $self->{expand_clause}{'insert.insert_into'} = sub {
  38     shift->expand_expr(@_, -ident);
  39   };
  40   $self->{expand_clause}{'insert.values'} = '_expand_insert_clause_values';
  41   $self->{expand_clause}{'insert.returning'} = sub {
  42     shift->_expand_maybe_list_expr(@_, -ident);
  43   };
  44   $self->{render_clause}{'insert.fields'} = sub {
  45     return $_[0]->render_aqt($_[1]);
  46   };
  47   return $self;
  48 }
  49
  50 sub _expand_select_clause_select {
  51   my ($self, $select) = @_;
  52   +(select => $self->_expand_maybe_list_expr($select, -ident));
  53 }
  54
  55 sub _expand_select_clause_from {
  56   my ($self, $from) = @_;
  57   +(from => $self->_expand_maybe_list_expr($from, -ident));
  58 }
  59
  60 sub _expand_select_clause_where {
  61   my ($self, $where) = @_;
  62   +(where => $self->expand_expr($where));
  63 }
  64
  65 sub _expand_select_clause_order_by {
  66   my ($self, $order_by) = @_;
  67   +(order_by => $self->_expand_order_by($order_by));
  68 }
  69
  70 sub _expand_update_clause_update {
  71   my ($self, $target) = @_;
  72   +(update => $self->expand_expr($target, -ident));
  73 }
  74
  75 sub _expand_update_clause_set {
  76   return $_[1] if ref($_[1]) eq 'HASH' and ($_[1]->{-op}||[''])->[0] eq ',';
  77   +(set => shift->_expand_update_set_values(@_));
  78 }
  79
  80 sub _expand_update_clause_where {
  81   +(where => shift->expand_expr(@_));
  82 }
  83
  84 sub _expand_update_clause_returning {
  85   +(returning => shift->_expand_maybe_list_expr(@_, -ident));
  86 }
  87
  88 sub _expand_delete_clause_delete_from {
  89   +(delete_from => shift->_expand_maybe_list_expr(@_, -ident));
  90 }
  91
  92 sub _expand_delete_clause_where { +(where => shift->expand_expr(@_)); }
  93
  94 sub _expand_delete_clause_returning {
  95   +(returning => shift->_expand_maybe_list_expr(@_, -ident));
  96 }
  97
  98 sub _expand_statement {
  99   my ($self, $type, $args) = @_;
 100   my $ec = $self->{expand_clause};
 101   return +{ "-${type}" => +{
 102     map {
 103       my $val = $args->{$_};
 104       if (defined($val) and my $exp = $ec->{"${type}.$_"}) {
 105         if ((my (@exp) = $self->$exp($val)) == 1) {
 106           ($_ => $exp[0])
 107         } else {
 108           @exp
 109         }
 110       } else {
 111         ($_ => $val)
 112       }
 113     } sort keys %$args
 114   } };
 115 }
 116
 117 sub _render_statement {
 118   my ($self, $type, $args) = @_;
 119   my @parts;
 120   foreach my $clause (@{$self->{clauses_of}{$type}}) {
 121     next unless my $clause_expr = $args->{$clause};
 122     local $self->{convert_where} = $self->{convert} if $clause eq 'where';
 123     my ($sql) = my @part = do {
 124       if (my $rdr = $self->{render_clause}{"${type}.${clause}"}) {
 125         $self->$rdr($clause_expr);
 126       } else {
 127         my ($clause_sql, @bind) = $self->render_aqt($clause_expr);
 128         my $sql = join ' ',
 129           $self->_sqlcase(join ' ', split '_', $clause),
 130           $clause_sql;
 131         ($sql, @bind);
 132       }
 133     };
 134     next unless defined($sql) and length($sql);
 135     push @parts, \@part;
 136   }
 137   return $self->_join_parts(' ', @parts);
 138 }
 139
 140 sub select {
 141   my ($self, @args) = @_;
 142   my %clauses;
 143   @clauses{qw(from select where order_by)} = @args;
 144
 145   # This oddity is to literalify since historically SQLA doesn't quote
 146   # a single identifier argument, so we convert it into a literal
 147
 148   $clauses{select} = { -literal => [ $clauses{select}||'*' ] }
 149     unless ref($clauses{select});
 150
 151   my ($sql, @bind) = $self->render_expr({ -select => \%clauses });
 152   return wantarray ? ($sql, @bind) : $sql;
 153 }
 154
 155 sub update {
 156   my ($self, $table, $set, $where, $options) = @_;
 157   my %clauses;
 158   @clauses{qw(update set where)} = ($table, $set, $where);
 159   puke "Unsupported data type specified to \$sql->update"
 160     unless ref($clauses{set}) eq 'HASH';
 161   @clauses{keys %$options} = values %$options;
 162   my ($sql, @bind) = $self->render_expr({ -update => \%clauses });
 163   return wantarray ? ($sql, @bind) : $sql;
 164 }
 165
 166 sub delete {
 167   my ($self, $table, $where, $options) = @_;
 168   my %clauses = (delete_from => $table, where => $where, %{$options||{}});
 169   my ($sql, @bind) = $self->render_expr({ -delete => \%clauses });
 170   return wantarray ? ($sql, @bind) : $sql;
 171 }
 172
 173 sub insert {
 174   my ($self, $table, $data, $options) = @_;
 175   my %clauses = (insert_into => $table, values => $data, %{$options||{}});
 176   my ($sql, @bind) = $self->render_expr({ -insert => \%clauses });
 177   return wantarray ? ($sql, @bind) : $sql;
 178 }
 179
 180 sub _expand_insert_clause_values {
 181   my ($self, $data) = @_;
 182   return $data if ref($data) eq 'HASH' and $data->{-row};
 183   my ($f_aqt, $v_aqt) = $self->_expand_insert_values($data);
 184   return (values => $v_aqt, ($f_aqt ? (fields => $f_aqt) : ()));
 185 }
 186
 187 1;