lib/SQL/Abstract/Clauses.pm

   1 package SQL::Abstract::Clauses;
   2
   3 use strict;
   4 use warnings;
   5 use if $] < '5.010', 'MRO::Compat';
   6 use mro 'c3';
   7 use base 'SQL::Abstract';
   8
   9 BEGIN { *puke = \&SQL::Abstract::puke }
  10
  11 sub new {
  12   shift->next::method(@_)->register_defaults
  13 }
  14
  15 sub register_defaults {
  16   my ($self) = @_;
  17   $self->{clauses_of}{select} = [ qw(select from where order_by) ];
  18   $self->{expand}{select} = sub { shift->_expand_statement(@_) };
  19   $self->{render}{select} = sub { shift->_render_statement(@_) };
  20   $self->{expand_clause}{"select.$_"} = "_expand_select_clause_$_"
  21     for @{$self->{clauses_of}{select}};
  22   $self->{clauses_of}{update} = [ qw(target set where returning) ];
  23   $self->{expand}{update} = sub { shift->_expand_statement(@_) };
  24   $self->{render}{update} = sub { shift->_render_statement(@_) };
  25   $self->{expand_clause}{"update.$_"} = "_expand_update_clause_$_"
  26     for @{$self->{clauses_of}{update}};
  27   $self->{expand_clause}{'update.update'} = '_expand_update_clause_target';
  28   $self->{render_clause}{'update.target'} = sub {
  29     my ($self, $target) = @_;
  30     my ($sql, @bind) = $self->render_aqt($target);
  31     ($self->_sqlcase('update ').$sql, @bind);
  32   };
  33   $self->{clauses_of}{delete} = [ qw(target where returning) ];
  34   $self->{expand}{delete} = sub { shift->_expand_statement(@_) };
  35   $self->{render}{delete} = sub { shift->_render_statement(@_) };
  36   $self->{expand_clause}{"delete.$_"} = "_expand_delete_clause_$_"
  37     for @{$self->{clauses_of}{delete}};
  38   $self->{expand_clause}{"delete.from"} = '_expand_delete_clause_target';
  39   $self->{render_clause}{'delete.target'} = sub {
  40     my ($self, $from) = @_;
  41     my ($sql, @bind) = $self->render_aqt($from);
  42     ($self->_sqlcase('delete from ').$sql, @bind);
  43   };
  44   $self->{clauses_of}{insert} = [
  45     'target', 'fields', 'from', 'returning'
  46   ];
  47   $self->{expand}{insert} = sub { shift->_expand_statement(@_) };
  48   $self->{render}{insert} = sub { shift->_render_statement(@_) };
  49   $self->{expand_clause}{'insert.into'} = '_expand_insert_clause_target';
  50   $self->{expand_clause}{'insert.target'} = '_expand_insert_clause_target';
  51   $self->{expand_clause}{'insert.fields'} = sub {
  52     return +{ -row => [
  53       shift->_expand_maybe_list_expr(@_, -ident)
  54     ] } if ref($_[1]) eq 'ARRAY';
  55     return $_[1]; # should maybe still expand somewhat?
  56   };
  57   $self->{expand_clause}{'insert.values'} = '_expand_insert_clause_values';
  58   $self->{expand_clause}{'insert.returning'} = sub {
  59     shift->_expand_maybe_list_expr(@_, -ident);
  60   };
  61   $self->{render_clause}{'insert.fields'} = sub {
  62     return $_[0]->render_aqt($_[1]);
  63   };
  64   $self->{render_clause}{'insert.target'} = sub {
  65     my ($self, $from) = @_;
  66     my ($sql, @bind) = $self->render_aqt($from);
  67     ($self->_sqlcase('insert into ').$sql, @bind);
  68   };
  69   $self->{render_clause}{'insert.from'} = sub {
  70     return $_[0]->render_aqt($_[1], 1);
  71   };
  72   $self->{expand}{values} = '_expand_values';
  73   $self->{render}{values} = '_render_values';
  74   $self->{expand}{exists} = sub {
  75     $_[0]->_expand_op(undef, [ exists => $_[2] ]);
  76   };
  77   return $self;
  78 }
  79
  80 sub _expand_select_clause_select {
  81   my ($self, $select) = @_;
  82   +(select => $self->_expand_maybe_list_expr($select, -ident));
  83 }
  84
  85 sub _expand_select_clause_from {
  86   my ($self, $from) = @_;
  87   +(from => $self->_expand_maybe_list_expr($from, -ident));
  88 }
  89
  90 sub _expand_select_clause_where {
  91   my ($self, $where) = @_;
  92   +(where => $self->expand_expr($where));
  93 }
  94
  95 sub _expand_select_clause_order_by {
  96   my ($self, $order_by) = @_;
  97   +(order_by => $self->_expand_order_by($order_by));
  98 }
  99
 100 sub _expand_update_clause_target {
 101   my ($self, $target) = @_;
 102   +(target => $self->_expand_maybe_list_expr($target, -ident));
 103 }
 104
 105 sub _expand_update_clause_set {
 106   return $_[1] if ref($_[1]) eq 'HASH' and ($_[1]->{-op}||[''])->[0] eq ',';
 107   +(set => shift->_expand_update_set_values(@_));
 108 }
 109
 110 sub _expand_update_clause_where {
 111   +(where => shift->expand_expr(@_));
 112 }
 113
 114 sub _expand_update_clause_returning {
 115   +(returning => shift->_expand_maybe_list_expr(@_, -ident));
 116 }
 117
 118 sub _expand_delete_clause_target {
 119   +(target => shift->_expand_maybe_list_expr(@_, -ident));
 120 }
 121
 122 sub _expand_delete_clause_where { +(where => shift->expand_expr(@_)); }
 123
 124 sub _expand_delete_clause_returning {
 125   +(returning => shift->_expand_maybe_list_expr(@_, -ident));
 126 }
 127
 128 sub _expand_statement {
 129   my ($self, $type, $args) = @_;
 130   my $ec = $self->{expand_clause};
 131   if ($args->{_}) {
 132     $args = { %$args };
 133     $args->{$type} = delete $args->{_}
 134   }
 135   return +{ "-${type}" => +{
 136     map {
 137       my $val = $args->{$_};
 138       if (defined($val) and my $exp = $ec->{"${type}.$_"}) {
 139         if ((my (@exp) = $self->$exp($val)) == 1) {
 140           ($_ => $exp[0])
 141         } else {
 142           @exp
 143         }
 144       } else {
 145         ($_ => $self->expand_expr($val))
 146       }
 147     } sort keys %$args
 148   } };
 149 }
 150
 151 sub _render_statement {
 152   my ($self, $type, $args) = @_;
 153   my @parts;
 154   foreach my $clause (@{$self->{clauses_of}{$type}}) {
 155     next unless my $clause_expr = $args->{$clause};
 156     local $self->{convert_where} = $self->{convert} if $clause eq 'where';
 157     my ($sql) = my @part = do {
 158       if (my $rdr = $self->{render_clause}{"${type}.${clause}"}) {
 159         $self->$rdr($clause_expr);
 160       } else {
 161         my ($clause_sql, @bind) = $self->render_aqt($clause_expr, 1);
 162         my $sql = join ' ',
 163           $self->_sqlcase(join ' ', split '_', $clause),
 164           $clause_sql;
 165         ($sql, @bind);
 166       }
 167     };
 168     next unless defined($sql) and length($sql);
 169     push @parts, \@part;
 170   }
 171   my ($sql, @bind) = $self->join_clauses(' ', @parts);
 172   return (
 173     (our $Render_Top_Level ? $sql : '('.$sql.')'),
 174     @bind
 175   );
 176 }
 177
 178 sub render_aqt {
 179   my ($self, $aqt, $top_level) = @_;
 180   local our $Render_Top_Level = $top_level;
 181   return $self->next::method($aqt);
 182 }
 183
 184 sub render_statement {
 185   my ($self, $expr, $default_scalar_to) = @_;
 186   my ($sql, @bind) = $self->render_aqt(
 187     $self->expand_expr($expr, $default_scalar_to), 1
 188   );
 189   return (wantarray ? ($sql, @bind) : $sql);
 190 }
 191
 192 sub select {
 193   my ($self, @args) = @_;
 194
 195   return $self->render_statement({ -select => $_[1] }) if ref($_[1]) eq 'HASH';
 196
 197   my %clauses;
 198   @clauses{qw(from select where order_by)} = @args;
 199
 200   # This oddity is to literalify since historically SQLA doesn't quote
 201   # a single identifier argument, so we convert it into a literal
 202
 203   $clauses{select} = { -literal => [ $clauses{select}||'*' ] }
 204     unless ref($clauses{select});
 205
 206   return $self->render_statement({ -select => \%clauses });
 207 }
 208
 209 sub update {
 210   my ($self, $table, $set, $where, $options) = @_;
 211
 212   return $self->render_statement({ -update => $_[1] }) if ref($_[1]) eq 'HASH';
 213
 214   my %clauses;
 215   @clauses{qw(target set where)} = ($table, $set, $where);
 216   puke "Unsupported data type specified to \$sql->update"
 217     unless ref($clauses{set}) eq 'HASH';
 218   @clauses{keys %$options} = values %$options;
 219   return $self->render_statement({ -update => \%clauses });
 220 }
 221
 222 sub delete {
 223   my ($self, $table, $where, $options) = @_;
 224
 225   return $self->render_statement({ -delete => $_[1] }) if ref($_[1]) eq 'HASH';
 226
 227   my %clauses = (target => $table, where => $where, %{$options||{}});
 228   return $self->render_statement({ -delete => \%clauses });
 229 }
 230
 231 sub insert {
 232   my ($self, $table, $data, $options) = @_;
 233
 234   return $self->render_statement({ -insert => $_[1] }) if ref($_[1]) eq 'HASH';
 235
 236   my %clauses = (target => $table, values => $data, %{$options||{}});
 237   return $self->render_statement({ -insert => \%clauses });
 238 }
 239
 240 sub _expand_insert_clause_target {
 241   +(target => shift->_expand_maybe_list_expr(@_, -ident));
 242 }
 243
 244 sub _expand_insert_clause_values {
 245   my ($self, $data) = @_;
 246   if (ref($data) eq 'HASH' and (keys(%$data))[0] =~ /^-/) {
 247     return $self->expand_expr($data);
 248   }
 249   return $data if ref($data) eq 'HASH' and $data->{-row};
 250   my ($f_aqt, $v_aqt) = $self->_expand_insert_values($data);
 251   return (from => { -values => $v_aqt }, ($f_aqt ? (fields => $f_aqt) : ()));
 252 }
 253
 254 sub _expand_values {
 255   my ($self, undef, $values) = @_;
 256   return { -values => [
 257     map +(
 258       ref($_) eq 'HASH'
 259         ? $self->expand_expr($_)
 260         : +{ -row => [ map $self->expand_expr($_), @$_ ] }
 261     ), ref($values) eq 'ARRAY' ? @$values : $values
 262   ] };
 263 }
 264
 265 sub _render_values {
 266   my ($self, undef, $values) = @_;
 267   my ($v_sql, @bind) = $self->join_clauses(
 268     ', ',
 269     map [ $self->render_aqt($_) ],
 270       ref($values) eq 'ARRAY' ? @$values : $values
 271   );
 272   my $sql = $self->_sqlcase('values').' '.$v_sql;
 273   return (
 274     (our $Render_Top_Level ? $sql : '('.$sql.')'),
 275     @bind
 276   );
 277 }
 278
 279 sub _ext_rw {
 280   my ($self, $name, $key, $value) = @_;
 281   return $self->{$name}{$key} unless @_ > 3;
 282   $self->{$name}{$key} = $value;
 283   return $self;
 284 }
 285
 286 BEGIN {
 287   foreach my $type (qw(
 288     expand op_expand render op_render clause_expand clause_render
 289   )) {
 290     my $key = join '_', reverse split '_', $type;
 291     my $singular = "${type}er";
 292     eval qq{sub ${singular} { shift->_ext_rw($key => \@_) }; 1 }
 293       or die "Method builder failed for ${type}er: $@";
 294     eval qq{sub ${singular}s {
 295       my (\$self, \@args) = \@_;
 296       while (my (\$this_key, \$this_value) = splice(\@args, 0, 2)) {
 297         \$self->{${key}}{\$this_key} = \$this_value;
 298       }
 299       return \$self;
 300     }; 1 } or die "Method builder failed for ${singular}s: $@";
 301   }
 302 }
 303
 304 sub clauses_of {
 305   my ($self, $of, @clauses) = @_;
 306   unless (@clauses) {
 307     return @{$self->{clauses_of}{$of}||[]};
 308   }
 309   if (ref($clauses[0]) eq 'CODE') {
 310     @clauses = $self->${\($clauses[0])}(@{$self->{clauses_of}{$of}||[]});
 311   }
 312   $self->{clauses_of}{$of} = \@clauses;
 313   return $self;
 314 }
 315
 316 sub clone {
 317   my ($self) = @_;
 318   bless(
 319     {
 320       (map +($_ => (
 321         ref($self->{$_}) eq 'HASH'
 322           ? { %{$self->{$_}} }
 323           : $self->{$_}
 324       )), keys %$self),
 325     },
 326     ref($self)
 327   );
 328 }
 329
 330
 331 1;