lib/SQL/Abstract/Clauses.pm

   1 package SQL::Abstract::Clauses;
   2
   3 use strict;
   4 use warnings;
   5 use if $] < '5.010', 'MRO::Compat';
   6 use mro 'c3';
   7 use base 'SQL::Abstract';
   8
   9 BEGIN { *puke = \&SQL::Abstract::puke }
  10
  11 sub new {
  12   shift->next::method(@_)->register_defaults
  13 }
  14
  15 sub register_defaults {
  16   my ($self) = @_;
  17   $self->{clauses_of}{select} = [ qw(select from where order_by) ];
  18   $self->{expand}{select} = sub { shift->_expand_statement(@_) };
  19   $self->{render}{select} = sub { shift->_render_statement(@_) };
  20   $self->{expand_clause}{"select.$_"} = "_expand_select_clause_$_"
  21     for @{$self->{clauses_of}{select}};
  22   $self->{clauses_of}{update} = [ qw(target set where returning) ];
  23   $self->{expand}{update} = sub { shift->_expand_statement(@_) };
  24   $self->{render}{update} = sub { shift->_render_statement(@_) };
  25   $self->{expand_clause}{"update.$_"} = "_expand_update_clause_$_"
  26     for @{$self->{clauses_of}{update}};
  27   $self->{expand_clause}{'update.update'} = '_expand_update_clause_target';
  28   $self->{render_clause}{'update.target'} = sub {
  29     my ($self, undef, $target) = @_;
  30     $self->join_query_parts(' ', $self->format_keyword('update'), $target);
  31   };
  32   $self->{clauses_of}{delete} = [ qw(target where returning) ];
  33   $self->{expand}{delete} = sub { shift->_expand_statement(@_) };
  34   $self->{render}{delete} = sub { shift->_render_statement(@_) };
  35   $self->{expand_clause}{"delete.$_"} = "_expand_delete_clause_$_"
  36     for @{$self->{clauses_of}{delete}};
  37   $self->{expand_clause}{"delete.from"} = '_expand_delete_clause_target';
  38   $self->{render_clause}{'delete.target'} = sub {
  39     my ($self, undef, $from) = @_;
  40     $self->join_query_parts(' ', $self->format_keyword('delete from'), $from);
  41   };
  42   $self->{clauses_of}{insert} = [
  43     'target', 'fields', 'from', 'returning'
  44   ];
  45   $self->{expand}{insert} = sub { shift->_expand_statement(@_) };
  46   $self->{render}{insert} = sub { shift->_render_statement(@_) };
  47   $self->{expand_clause}{"insert.$_"} = "_expand_insert_clause_$_"
  48     for @{$self->{clauses_of}{insert}};
  49   $self->{expand_clause}{'insert.into'} = '_expand_insert_clause_target';
  50   $self->{expand_clause}{'insert.values'} = '_expand_insert_clause_from';
  51   $self->{render_clause}{'insert.fields'} = sub {
  52     return $_[0]->render_aqt($_[2]);
  53   };
  54   $self->{render_clause}{'insert.target'} = sub {
  55     my ($self, undef, $from) = @_;
  56     $self->join_query_parts(' ', $self->format_keyword('insert into'), $from);
  57   };
  58   $self->{render_clause}{'insert.from'} = sub {
  59     return $_[0]->render_aqt($_[2], 1);
  60   };
  61   $self->{expand}{values} = '_expand_values';
  62   $self->{render}{values} = '_render_values';
  63   $self->{expand}{exists} = sub {
  64     $_[0]->_expand_op(undef, [ exists => $_[2] ]);
  65   };
  66   $self->{render}{convert_where} = sub {
  67     my $self = shift;
  68     local $self->{convert_where} = $self->{convert};
  69     $self->render_aqt($_[1]);
  70   };
  71   return $self;
  72 }
  73
  74 sub _expand_select_clause_select {
  75   my ($self, undef, $select) = @_;
  76   +(select => $self->_expand_maybe_list_expr($select, -ident));
  77 }
  78
  79 sub _expand_select_clause_from {
  80   my ($self, undef, $from) = @_;
  81   +(from => $self->_expand_maybe_list_expr($from, -ident));
  82 }
  83
  84 sub _expand_select_clause_where {
  85   my ($self, undef, $where) = @_;
  86   my $exp = $self->expand_expr($where);
  87   +(where => ($self->{convert} ? +{ -convert_where => $exp } : $exp));
  88 }
  89
  90 sub _expand_select_clause_order_by {
  91   my ($self, undef, $order_by) = @_;
  92   +(order_by => $self->_expand_order_by($order_by));
  93 }
  94
  95 sub _expand_update_clause_target {
  96   my ($self, undef, $target) = @_;
  97   +(target => $self->_expand_maybe_list_expr($target, -ident));
  98 }
  99
 100 sub _expand_update_clause_set {
 101   return $_[2] if ref($_[2]) eq 'HASH' and ($_[2]->{-op}||[''])->[0] eq ',';
 102   +(set => $_[0]->_expand_update_set_values($_[1], $_[2]));
 103 }
 104
 105 sub _expand_update_clause_where {
 106   +(where => $_[0]->expand_expr($_[2]));
 107 }
 108
 109 sub _expand_update_clause_returning {
 110   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 111 }
 112
 113 sub _expand_delete_clause_target {
 114   +(target => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 115 }
 116
 117 sub _expand_delete_clause_where { +(where => $_[0]->expand_expr($_[2])); }
 118
 119 sub _expand_delete_clause_returning {
 120   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 121 }
 122
 123 sub _expand_statement {
 124   my ($self, $type, $args) = @_;
 125   my $ec = $self->{expand_clause};
 126   if ($args->{_}) {
 127     $args = { %$args };
 128     $args->{$type} = delete $args->{_}
 129   }
 130   return +{ "-${type}" => +{
 131     map {
 132       my $val = $args->{$_};
 133       if (defined($val) and my $exp = $ec->{"${type}.$_"}) {
 134         if ((my (@exp) = $self->$exp($_ => $val)) == 1) {
 135           ($_ => $exp[0])
 136         } else {
 137           @exp
 138         }
 139       } else {
 140         ($_ => $self->expand_expr($val))
 141       }
 142     } sort keys %$args
 143   } };
 144 }
 145
 146 sub _render_statement {
 147   my ($self, $type, $args) = @_;
 148   my @parts;
 149   foreach my $clause (@{$self->{clauses_of}{$type}}) {
 150     next unless my $clause_expr = $args->{$clause};
 151     my $part = do {
 152       if (my $rdr = $self->{render_clause}{"${type}.${clause}"}) {
 153         $self->$rdr($clause, $clause_expr);
 154       } else {
 155         $self->join_query_parts(' ',
 156           $self->format_keyword($clause),
 157           $self->render_aqt($clause_expr, 1)
 158         );
 159       }
 160     };
 161     push @parts, $part;
 162   }
 163   my ($sql, @bind) = @{ $self->join_query_parts(' ', @parts) };
 164   return [
 165     (our $Render_Top_Level ? $sql : '('.$sql.')'),
 166     @bind
 167   ];
 168 }
 169
 170 sub render_aqt {
 171   my ($self, $aqt, $top_level) = @_;
 172   local our $Render_Top_Level = $top_level;
 173   return $self->next::method($aqt);
 174 }
 175
 176 sub render_statement {
 177   my ($self, $expr, $default_scalar_to) = @_;
 178   $self->render_aqt(
 179     $self->expand_expr($expr, $default_scalar_to), 1
 180   );
 181 }
 182
 183 sub select {
 184   my ($self, @args) = @_;
 185
 186   my $stmt = do {
 187     if (ref(my $sel = $args[0]) eq 'HASH') {
 188       $self->render_statement({ -select => $sel });
 189     } else {
 190       my %clauses;
 191       @clauses{qw(from select where order_by)} = @args;
 192
 193       # This oddity is to literalify since historically SQLA doesn't quote
 194       # a single identifier argument, so we convert it into a literal
 195
 196       $clauses{select} = { -literal => [ $clauses{select}||'*' ] }
 197         unless ref($clauses{select});
 198       \%clauses;
 199     }
 200   };
 201
 202   my $rendered = $self->render_statement({ -select => $stmt });
 203   return wantarray ? @$rendered : $rendered->[0];
 204 }
 205
 206 sub update {
 207   my ($self, $table, $set, $where, $options) = @_;
 208
 209   return $self->render_statement({ -update => $_[1] }) if ref($_[1]) eq 'HASH';
 210
 211   my %clauses;
 212   @clauses{qw(target set where)} = ($table, $set, $where);
 213   puke "Unsupported data type specified to \$sql->update"
 214     unless ref($clauses{set}) eq 'HASH';
 215   @clauses{keys %$options} = values %$options;
 216   return $self->render_statement({ -update => \%clauses });
 217 }
 218
 219 sub delete {
 220   my ($self, $table, $where, $options) = @_;
 221
 222   return $self->render_statement({ -delete => $_[1] }) if ref($_[1]) eq 'HASH';
 223
 224   my %clauses = (target => $table, where => $where, %{$options||{}});
 225   return $self->render_statement({ -delete => \%clauses });
 226 }
 227
 228 sub insert {
 229   my ($self, $table, $data, $options) = @_;
 230
 231   return $self->render_statement({ -insert => $_[1] }) if ref($_[1]) eq 'HASH';
 232
 233   my %clauses = (target => $table, values => $data, %{$options||{}});
 234   return $self->render_statement({ -insert => \%clauses });
 235 }
 236
 237 sub _expand_insert_clause_target {
 238   +(target => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 239 }
 240
 241 sub _expand_insert_clause_fields {
 242   return +{ -row => [
 243     $_[0]->_expand_maybe_list_expr($_[2], -ident)
 244   ] } if ref($_[2]) eq 'ARRAY';
 245   return $_[2]; # should maybe still expand somewhat?
 246 }
 247
 248 sub _expand_insert_clause_from {
 249   my ($self, undef, $data) = @_;
 250   if (ref($data) eq 'HASH' and (keys(%$data))[0] =~ /^-/) {
 251     return $self->expand_expr($data);
 252   }
 253   return $data if ref($data) eq 'HASH' and $data->{-row};
 254   my ($f_aqt, $v_aqt) = $self->_expand_insert_values($data);
 255   return (from => { -values => $v_aqt }, ($f_aqt ? (fields => $f_aqt) : ()));
 256 }
 257
 258 sub _expand_insert_clause_returning {
 259   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 260 }
 261
 262 sub _expand_values {
 263   my ($self, undef, $values) = @_;
 264   return { -values => [
 265     map +(
 266       ref($_) eq 'HASH'
 267         ? $self->expand_expr($_)
 268         : +{ -row => [ map $self->expand_expr($_), @$_ ] }
 269     ), ref($values) eq 'ARRAY' ? @$values : $values
 270   ] };
 271 }
 272
 273 sub _render_values {
 274   my ($self, undef, $values) = @_;
 275   my $inner = [
 276     $self->join_query_parts(' ',
 277       $self->format_keyword('values'),
 278       $self->join_query_parts(', ',
 279         ref($values) eq 'ARRAY' ? @$values : $values
 280       ),
 281     ),
 282   ];
 283   return $self->join_query_parts('',
 284     (our $Render_Top_Level ? $inner : ('(', $inner, ')'))
 285   );
 286 }
 287
 288 sub _ext_rw {
 289   my ($self, $name, $key, $value) = @_;
 290   return $self->{$name}{$key} unless @_ > 3;
 291   $self->{$name}{$key} = $value;
 292   return $self;
 293 }
 294
 295 BEGIN {
 296   foreach my $type (qw(
 297     expand op_expand render op_render clause_expand clause_render
 298   )) {
 299     my $name = join '_', reverse split '_', $type;
 300     my $singular = "${type}er";
 301     eval qq{sub ${singular} { shift->_ext_rw($name => \@_) }; 1 }
 302       or die "Method builder failed for ${singular}: $@";
 303     eval qq{sub wrap_${singular} {
 304       my (\$self, \$key, \$builder) = \@_;
 305       my \$orig = \$self->_ext_rw('${name}', \$key);
 306       \$self->_ext_rw(
 307         '${name}', \$key,
 308         \$builder->(\$orig, '${name}', \$key)
 309       );
 310     }; 1 } or die "Method builder failed for wrap_${singular}: $@";
 311     eval qq{sub ${singular}s {
 312       my (\$self, \@args) = \@_;
 313       while (my (\$this_key, \$this_value) = splice(\@args, 0, 2)) {
 314         \$self->{${name}}{\$this_key} = \$this_value;
 315       }
 316       return \$self;
 317     }; 1 } or die "Method builder failed for ${singular}s: $@";
 318     eval qq{sub ${singular}_list { sort keys %{\$_[0]->{\$name}} }; 1; }
 319      or die "Method builder failed for ${singular}_list: $@";
 320   }
 321 }
 322
 323 sub statement_list { sort keys %{$_[0]->{clauses_of}} }
 324
 325 sub clauses_of {
 326   my ($self, $of, @clauses) = @_;
 327   unless (@clauses) {
 328     return @{$self->{clauses_of}{$of}||[]};
 329   }
 330   if (ref($clauses[0]) eq 'CODE') {
 331     @clauses = $self->${\($clauses[0])}(@{$self->{clauses_of}{$of}||[]});
 332   }
 333   $self->{clauses_of}{$of} = \@clauses;
 334   return $self;
 335 }
 336
 337 sub clone {
 338   my ($self) = @_;
 339   bless(
 340     {
 341       (map +($_ => (
 342         ref($self->{$_}) eq 'HASH'
 343           ? { %{$self->{$_}} }
 344           : $self->{$_}
 345       )), keys %$self),
 346     },
 347     ref($self)
 348   );
 349 }
 350
 351 1;