lib/SQL/Abstract/Clauses.pm

   1 package SQL::Abstract::Clauses;
   2
   3 use strict;
   4 use warnings;
   5 use if $] < '5.010', 'MRO::Compat';
   6 use mro 'c3';
   7 use base 'SQL::Abstract';
   8
   9 BEGIN { *puke = \&SQL::Abstract::puke }
  10
  11 sub new {
  12   shift->next::method(@_)->register_defaults
  13 }
  14
  15 sub register_defaults {
  16   my ($self) = @_;
  17   $self->{clauses_of}{select} = [ qw(select from where order_by) ];
  18   $self->{expand}{select} = sub { shift->_expand_statement(@_) };
  19   $self->{render}{select} = sub { shift->_render_statement(@_) };
  20   $self->{expand_clause}{"select.$_"} = "_expand_select_clause_$_"
  21     for @{$self->{clauses_of}{select}};
  22   $self->{clauses_of}{update} = [ qw(target set where returning) ];
  23   $self->{expand}{update} = sub { shift->_expand_statement(@_) };
  24   $self->{render}{update} = sub { shift->_render_statement(@_) };
  25   $self->{expand_clause}{"update.$_"} = "_expand_update_clause_$_"
  26     for @{$self->{clauses_of}{update}};
  27   $self->{expand_clause}{'update.update'} = '_expand_update_clause_target';
  28   $self->{render_clause}{'update.target'} = sub {
  29     my ($self, undef, $target) = @_;
  30     $self->join_query_parts(' ', $self->format_keyword('update'), $target);
  31   };
  32   $self->{clauses_of}{delete} = [ qw(target where returning) ];
  33   $self->{expand}{delete} = sub { shift->_expand_statement(@_) };
  34   $self->{render}{delete} = sub { shift->_render_statement(@_) };
  35   $self->{expand_clause}{"delete.$_"} = "_expand_delete_clause_$_"
  36     for @{$self->{clauses_of}{delete}};
  37   $self->{expand_clause}{"delete.from"} = '_expand_delete_clause_target';
  38   $self->{render_clause}{'delete.target'} = sub {
  39     my ($self, undef, $from) = @_;
  40     $self->join_query_parts(' ', $self->format_keyword('delete from'), $from);
  41   };
  42   $self->{clauses_of}{insert} = [
  43     'target', 'fields', 'from', 'returning'
  44   ];
  45   $self->{expand}{insert} = sub { shift->_expand_statement(@_) };
  46   $self->{render}{insert} = sub { shift->_render_statement(@_) };
  47   $self->{expand_clause}{"insert.$_"} = "_expand_insert_clause_$_"
  48     for @{$self->{clauses_of}{insert}};
  49   $self->{expand_clause}{'insert.into'} = '_expand_insert_clause_target';
  50   $self->{expand_clause}{'insert.values'} = '_expand_insert_clause_from';
  51   $self->{render_clause}{'insert.fields'} = sub {
  52     return $_[0]->render_aqt($_[2]);
  53   };
  54   $self->{render_clause}{'insert.target'} = sub {
  55     my ($self, undef, $from) = @_;
  56     $self->join_query_parts(' ', $self->format_keyword('insert into'), $from);
  57   };
  58   $self->{render_clause}{'insert.from'} = sub {
  59     return $_[0]->render_aqt($_[2], 1);
  60   };
  61   $self->{expand}{values} = '_expand_values';
  62   $self->{render}{values} = '_render_values';
  63   $self->{expand}{exists} = sub {
  64     $_[0]->_expand_op(undef, [ exists => $_[2] ]);
  65   };
  66   return $self;
  67 }
  68
  69 sub _expand_select_clause_select {
  70   my ($self, undef, $select) = @_;
  71   +(select => $self->_expand_maybe_list_expr($select, -ident));
  72 }
  73
  74 sub _expand_select_clause_from {
  75   my ($self, undef, $from) = @_;
  76   +(from => $self->_expand_maybe_list_expr($from, -ident));
  77 }
  78
  79 sub _expand_select_clause_where {
  80   my ($self, undef, $where) = @_;
  81
  82   local (@{$self->{expand}}{qw(ident value)},
  83          @{$self->{expand_op}}{qw(ident value)},
  84          $self->{expand_op}{bind})
  85      = (map {
  86       my $orig = $self->{expand}{$_};
  87       sub {
  88         my $self = shift;
  89         +{ -func => [
  90           $self->{convert},
  91           $self->$orig(@_)
  92         ] };
  93       }
  94     } qw(ident value ident value bind)
  95   ) if $self->{convert};
  96
  97   local $self->{expand}{func} = do {
  98     my $orig = $self->{expand}{func};
  99     sub {
 100       my ($self, $type, $thing) = @_;
 101       if (ref($thing) eq 'ARRAY' and $thing->[0] eq $self->{convert}
 102           and @$thing == 2 and ref($thing->[1]) eq 'HASH'
 103           and (
 104             $thing->[1]{-ident}
 105             or $thing->[1]{-value}
 106             or $thing->[1]{-bind})
 107           ) {
 108         return { -func => $thing }; # already went through our expander
 109       }
 110       return $self->$orig($type, $thing);
 111     }
 112   } if $self->{convert};
 113
 114   my $exp = $self->expand_expr($where);
 115   +(where => $exp);
 116 }
 117
 118 sub _expand_select_clause_order_by {
 119   my ($self, undef, $order_by) = @_;
 120   +(order_by => $self->_expand_order_by($order_by));
 121 }
 122
 123 sub _expand_update_clause_target {
 124   my ($self, undef, $target) = @_;
 125   +(target => $self->_expand_maybe_list_expr($target, -ident));
 126 }
 127
 128 sub _expand_update_clause_set {
 129   return $_[2] if ref($_[2]) eq 'HASH' and ($_[2]->{-op}||[''])->[0] eq ',';
 130   +(set => $_[0]->_expand_update_set_values($_[1], $_[2]));
 131 }
 132
 133 sub _expand_update_clause_where {
 134   +(where => $_[0]->expand_expr($_[2]));
 135 }
 136
 137 sub _expand_update_clause_returning {
 138   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 139 }
 140
 141 sub _expand_delete_clause_target {
 142   +(target => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 143 }
 144
 145 sub _expand_delete_clause_where { +(where => $_[0]->expand_expr($_[2])); }
 146
 147 sub _expand_delete_clause_returning {
 148   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 149 }
 150
 151 sub _expand_statement {
 152   my ($self, $type, $args) = @_;
 153   my $ec = $self->{expand_clause};
 154   if ($args->{_}) {
 155     $args = { %$args };
 156     $args->{$type} = delete $args->{_}
 157   }
 158   return +{ "-${type}" => +{
 159     map {
 160       my $val = $args->{$_};
 161       if (defined($val) and my $exp = $ec->{"${type}.$_"}) {
 162         if ((my (@exp) = $self->$exp($_ => $val)) == 1) {
 163           ($_ => $exp[0])
 164         } else {
 165           @exp
 166         }
 167       } else {
 168         ($_ => $self->expand_expr($val))
 169       }
 170     } sort keys %$args
 171   } };
 172 }
 173
 174 sub _render_statement {
 175   my ($self, $type, $args) = @_;
 176   my @parts;
 177   foreach my $clause (@{$self->{clauses_of}{$type}}) {
 178     next unless my $clause_expr = $args->{$clause};
 179     my $part = do {
 180       if (my $rdr = $self->{render_clause}{"${type}.${clause}"}) {
 181         $self->$rdr($clause, $clause_expr);
 182       } else {
 183         $self->join_query_parts(' ',
 184           $self->format_keyword($clause),
 185           $self->render_aqt($clause_expr, 1)
 186         );
 187       }
 188     };
 189     push @parts, $part;
 190   }
 191   my $q = $self->join_query_parts(' ', @parts);
 192   return $self->join_query_parts('',
 193     (our $Render_Top_Level ? $q : ('(', $q, ')'))
 194   );
 195 }
 196
 197 sub render_aqt {
 198   my ($self, $aqt, $top_level) = @_;
 199   local our $Render_Top_Level = $top_level;
 200   return $self->next::method($aqt);
 201 }
 202
 203 sub render_statement {
 204   my ($self, $expr, $default_scalar_to) = @_;
 205   $self->render_aqt(
 206     $self->expand_expr($expr, $default_scalar_to), 1
 207   );
 208 }
 209
 210 sub select {
 211   my ($self, @args) = @_;
 212
 213   my $stmt = do {
 214     if (ref(my $sel = $args[0]) eq 'HASH') {
 215       $sel
 216     } else {
 217       my %clauses;
 218       @clauses{qw(from select where order_by)} = @args;
 219
 220       # This oddity is to literalify since historically SQLA doesn't quote
 221       # a single identifier argument, so we convert it into a literal
 222
 223       $clauses{select} = { -literal => [ $clauses{select}||'*' ] }
 224         unless ref($clauses{select});
 225       \%clauses;
 226     }
 227   };
 228
 229   my $rendered = $self->render_statement({ -select => $stmt });
 230   return wantarray ? @$rendered : $rendered->[0];
 231 }
 232
 233 sub update {
 234   my ($self, $table, $set, $where, $options) = @_;
 235
 236   my $stmt = do {
 237     if (ref($table) eq 'HASH') {
 238       $table
 239     } else {
 240       my %clauses;
 241       @clauses{qw(target set where)} = ($table, $set, $where);
 242       puke "Unsupported data type specified to \$sql->update"
 243         unless ref($clauses{set}) eq 'HASH';
 244       @clauses{keys %$options} = values %$options;
 245       \%clauses;
 246     }
 247   };
 248   my $rendered = $self->render_statement({ -update => $stmt });
 249   return wantarray ? @$rendered : $rendered->[0];
 250 }
 251
 252 sub delete {
 253   my ($self, $table, $where, $options) = @_;
 254
 255   my $stmt = do {
 256     if (ref($table) eq 'HASH') {
 257       $table;
 258     } else {
 259       my %clauses = (target => $table, where => $where, %{$options||{}});
 260       \%clauses;
 261     }
 262   };
 263   my $rendered = $self->render_statement({ -delete => $stmt });
 264   return wantarray ? @$rendered : $rendered->[0];
 265 }
 266
 267 sub insert {
 268   my ($self, $table, $data, $options) = @_;
 269
 270   my $stmt = do {
 271     if (ref($table) eq 'HASH') {
 272       $table;
 273     } else {
 274       my %clauses = (target => $table, values => $data, %{$options||{}});
 275       \%clauses;
 276     }
 277   };
 278   my $rendered = $self->render_statement({ -insert => $stmt });
 279   return wantarray ? @$rendered : $rendered->[0];
 280 }
 281
 282 sub _expand_insert_clause_target {
 283   +(target => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 284 }
 285
 286 sub _expand_insert_clause_fields {
 287   return +{ -row => [
 288     $_[0]->_expand_maybe_list_expr($_[2], -ident)
 289   ] } if ref($_[2]) eq 'ARRAY';
 290   return $_[2]; # should maybe still expand somewhat?
 291 }
 292
 293 sub _expand_insert_clause_from {
 294   my ($self, undef, $data) = @_;
 295   if (ref($data) eq 'HASH' and (keys(%$data))[0] =~ /^-/) {
 296     return $self->expand_expr($data);
 297   }
 298   return $data if ref($data) eq 'HASH' and $data->{-row};
 299   my ($f_aqt, $v_aqt) = $self->_expand_insert_values($data);
 300   return (
 301     from => { -values => [ $v_aqt ] },
 302     ($f_aqt ? (fields => $f_aqt) : ()),
 303   );
 304 }
 305
 306 sub _expand_insert_clause_returning {
 307   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 308 }
 309
 310 sub _expand_values {
 311   my ($self, undef, $values) = @_;
 312   return { -values => [
 313     map +(
 314       ref($_) eq 'HASH'
 315         ? $self->expand_expr($_)
 316         : +{ -row => [ map $self->expand_expr($_), @$_ ] }
 317     ), ref($values) eq 'ARRAY' ? @$values : $values
 318   ] };
 319 }
 320
 321 sub _render_values {
 322   my ($self, undef, $values) = @_;
 323   my $inner = $self->join_query_parts(' ',
 324     $self->format_keyword('values'),
 325     $self->join_query_parts(', ',
 326       ref($values) eq 'ARRAY' ? @$values : $values
 327     ),
 328   );
 329   return $self->join_query_parts('',
 330     (our $Render_Top_Level ? $inner : ('(', $inner, ')'))
 331   );
 332 }
 333
 334 sub _ext_rw {
 335   my ($self, $name, $key, $value) = @_;
 336   return $self->{$name}{$key} unless @_ > 3;
 337   $self->{$name}{$key} = $value;
 338   return $self;
 339 }
 340
 341 BEGIN {
 342   foreach my $type (qw(
 343     expand op_expand render op_render clause_expand clause_render
 344   )) {
 345     my $name = join '_', reverse split '_', $type;
 346     my $singular = "${type}er";
 347     eval qq{sub ${singular} { shift->_ext_rw($name => \@_) }; 1 }
 348       or die "Method builder failed for ${singular}: $@";
 349     eval qq{sub wrap_${singular} {
 350       my (\$self, \$key, \$builder) = \@_;
 351       my \$orig = \$self->_ext_rw('${name}', \$key);
 352       \$self->_ext_rw(
 353         '${name}', \$key,
 354         \$builder->(\$orig, '${name}', \$key)
 355       );
 356     }; 1 } or die "Method builder failed for wrap_${singular}: $@";
 357     eval qq{sub ${singular}s {
 358       my (\$self, \@args) = \@_;
 359       while (my (\$this_key, \$this_value) = splice(\@args, 0, 2)) {
 360         \$self->{${name}}{\$this_key} = \$this_value;
 361       }
 362       return \$self;
 363     }; 1 } or die "Method builder failed for ${singular}s: $@";
 364     eval qq{sub ${singular}_list { sort keys %{\$_[0]->{\$name}} }; 1; }
 365      or die "Method builder failed for ${singular}_list: $@";
 366   }
 367 }
 368
 369 sub statement_list { sort keys %{$_[0]->{clauses_of}} }
 370
 371 sub clauses_of {
 372   my ($self, $of, @clauses) = @_;
 373   unless (@clauses) {
 374     return @{$self->{clauses_of}{$of}||[]};
 375   }
 376   if (ref($clauses[0]) eq 'CODE') {
 377     @clauses = $self->${\($clauses[0])}(@{$self->{clauses_of}{$of}||[]});
 378   }
 379   $self->{clauses_of}{$of} = \@clauses;
 380   return $self;
 381 }
 382
 383 sub clone {
 384   my ($self) = @_;
 385   bless(
 386     {
 387       (map +($_ => (
 388         ref($self->{$_}) eq 'HASH'
 389           ? { %{$self->{$_}} }
 390           : $self->{$_}
 391       )), keys %$self),
 392     },
 393     ref($self)
 394   );
 395 }
 396
 397 1;