lib/SQL/Abstract/Clauses.pm

   1 package SQL::Abstract::Clauses;
   2
   3 use strict;
   4 use warnings;
   5 use if $] < '5.010', 'MRO::Compat';
   6 use mro 'c3';
   7 use base 'SQL::Abstract';
   8
   9 BEGIN { *puke = \&SQL::Abstract::puke }
  10
  11 sub new {
  12   shift->next::method(@_)->register_defaults
  13 }
  14
  15 sub register_defaults {
  16   my ($self) = @_;
  17   $self->{clauses_of}{select} = [ qw(select from where order_by) ];
  18   $self->{expand}{select} = sub { shift->_expand_statement(@_) };
  19   $self->{render}{select} = sub { shift->_render_statement(@_) };
  20   $self->{expand_clause}{"select.$_"} = "_expand_select_clause_$_"
  21     for @{$self->{clauses_of}{select}};
  22   $self->{clauses_of}{update} = [ qw(target set where returning) ];
  23   $self->{expand}{update} = sub { shift->_expand_statement(@_) };
  24   $self->{render}{update} = sub { shift->_render_statement(@_) };
  25   $self->{expand_clause}{"update.$_"} = "_expand_update_clause_$_"
  26     for @{$self->{clauses_of}{update}};
  27   $self->{expand_clause}{'update.update'} = '_expand_update_clause_target';
  28   $self->{render_clause}{'update.target'} = sub {
  29     my ($self, undef, $target) = @_;
  30     $self->join_query_parts(' ', $self->format_keyword('update'), $target);
  31   };
  32   $self->{clauses_of}{delete} = [ qw(target where returning) ];
  33   $self->{expand}{delete} = sub { shift->_expand_statement(@_) };
  34   $self->{render}{delete} = sub { shift->_render_statement(@_) };
  35   $self->{expand_clause}{"delete.$_"} = "_expand_delete_clause_$_"
  36     for @{$self->{clauses_of}{delete}};
  37   $self->{expand_clause}{"delete.from"} = '_expand_delete_clause_target';
  38   $self->{render_clause}{'delete.target'} = sub {
  39     my ($self, undef, $from) = @_;
  40     $self->join_query_parts(' ', $self->format_keyword('delete from'), $from);
  41   };
  42   $self->{clauses_of}{insert} = [
  43     'target', 'fields', 'from', 'returning'
  44   ];
  45   $self->{expand}{insert} = sub { shift->_expand_statement(@_) };
  46   $self->{render}{insert} = sub { shift->_render_statement(@_) };
  47   $self->{expand_clause}{"insert.$_"} = "_expand_insert_clause_$_"
  48     for @{$self->{clauses_of}{insert}};
  49   $self->{expand_clause}{'insert.into'} = '_expand_insert_clause_target';
  50   $self->{expand_clause}{'insert.values'} = '_expand_insert_clause_from';
  51   $self->{render_clause}{'insert.fields'} = sub {
  52     return $_[0]->render_aqt($_[2]);
  53   };
  54   $self->{render_clause}{'insert.target'} = sub {
  55     my ($self, undef, $from) = @_;
  56     $self->join_query_parts(' ', $self->format_keyword('insert into'), $from);
  57   };
  58   $self->{render_clause}{'insert.from'} = sub {
  59     return $_[0]->render_aqt($_[2], 1);
  60   };
  61   $self->{expand}{values} = '_expand_values';
  62   $self->{render}{values} = '_render_values';
  63   $self->{expand}{exists} = sub {
  64     $_[0]->_expand_op(undef, [ exists => $_[2] ]);
  65   };
  66
  67   # check for overriden methods
  68   if ($self->can('_table') ne SQL::Abstract->can('_table')) {
  69     $self->{expand_clause}{'select.from'} = sub {
  70       return +{ -literal => [ $_[0]->_table($_[2]) ] };
  71     };
  72   }
  73   if ($self->can('_order_by') ne SQL::Abstract->can('_order_by')) {
  74     $self->{expand_clause}{'select.order_by'} = sub {
  75       my ($osql, @obind) = $_[0]->_order_by($_[2]);
  76       $osql =~ s/^order by //i;
  77       return undef unless length($osql);
  78       return +{ -literal => [ $osql, @obind ] };
  79     };
  80   }
  81   return $self;
  82 }
  83
  84 sub _expand_select_clause_select {
  85   my ($self, undef, $select) = @_;
  86   +(select => $self->_expand_maybe_list_expr($select, -ident));
  87 }
  88
  89 sub _expand_select_clause_from {
  90   my ($self, undef, $from) = @_;
  91   +(from => $self->_expand_maybe_list_expr($from, -ident));
  92 }
  93
  94 sub _expand_select_clause_where {
  95   my ($self, undef, $where) = @_;
  96
  97   my $sqla = do {
  98     if (my $conv = $self->{convert}) {
  99       my $_wrap = sub {
 100         my $orig = shift;
 101         sub {
 102           my $self = shift;
 103           +{ -func => [
 104             $conv,
 105             $self->$orig(@_)
 106           ] };
 107         };
 108       };
 109       $self->clone
 110            ->wrap_expanders(map +($_ => $_wrap), qw(ident value bind))
 111            ->wrap_op_expanders(map +($_ => $_wrap), qw(ident value bind))
 112            ->wrap_expander(func => sub {
 113                my $orig = shift;
 114                sub {
 115                  my ($self, $type, $thing) = @_;
 116                  if (ref($thing) eq 'ARRAY' and $thing->[0] eq $conv
 117                      and @$thing == 2 and ref($thing->[1]) eq 'HASH'
 118                      and (
 119                        $thing->[1]{-ident}
 120                        or $thing->[1]{-value}
 121                        or $thing->[1]{-bind})
 122                      ) {
 123                    return { -func => $thing }; # already went through our expander
 124                  }
 125                  return $self->$orig($type, $thing);
 126                }
 127              });
 128     } else {
 129       $self;
 130     }
 131   };
 132
 133   return +(where => $sqla->expand_expr($where));
 134 }
 135
 136 sub _expand_select_clause_order_by {
 137   my ($self, undef, $order_by) = @_;
 138   +(order_by => $self->_expand_order_by($order_by));
 139 }
 140
 141 sub _expand_update_clause_target {
 142   my ($self, undef, $target) = @_;
 143   +(target => $self->_expand_maybe_list_expr($target, -ident));
 144 }
 145
 146 sub _expand_update_clause_set {
 147   return $_[2] if ref($_[2]) eq 'HASH' and ($_[2]->{-op}||[''])->[0] eq ',';
 148   +(set => $_[0]->_expand_update_set_values($_[1], $_[2]));
 149 }
 150
 151 sub _expand_update_clause_where {
 152   +(where => $_[0]->expand_expr($_[2]));
 153 }
 154
 155 sub _expand_update_clause_returning {
 156   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 157 }
 158
 159 sub _expand_delete_clause_target {
 160   +(target => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 161 }
 162
 163 sub _expand_delete_clause_where { +(where => $_[0]->expand_expr($_[2])); }
 164
 165 sub _expand_delete_clause_returning {
 166   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 167 }
 168
 169 sub _expand_statement {
 170   my ($self, $type, $args) = @_;
 171   my $ec = $self->{expand_clause};
 172   if ($args->{_}) {
 173     $args = { %$args };
 174     $args->{$type} = delete $args->{_}
 175   }
 176   return +{ "-${type}" => +{
 177     map {
 178       my $val = $args->{$_};
 179       if (defined($val) and my $exp = $ec->{"${type}.$_"}) {
 180         if ((my (@exp) = $self->$exp($_ => $val)) == 1) {
 181           ($_ => $exp[0])
 182         } else {
 183           @exp
 184         }
 185       } else {
 186         ($_ => $self->expand_expr($val))
 187       }
 188     } sort keys %$args
 189   } };
 190 }
 191
 192 sub _render_statement {
 193   my ($self, $type, $args) = @_;
 194   my @parts;
 195   foreach my $clause (@{$self->{clauses_of}{$type}}) {
 196     next unless my $clause_expr = $args->{$clause};
 197     my $part = do {
 198       if (my $rdr = $self->{render_clause}{"${type}.${clause}"}) {
 199         $self->$rdr($clause, $clause_expr);
 200       } else {
 201         $self->join_query_parts(' ',
 202           $self->format_keyword($clause),
 203           $self->render_aqt($clause_expr, 1)
 204         );
 205       }
 206     };
 207     push @parts, $part;
 208   }
 209   my $q = $self->join_query_parts(' ', @parts);
 210   return $self->join_query_parts('',
 211     (our $Render_Top_Level ? $q : ('(', $q, ')'))
 212   );
 213 }
 214
 215 sub render_aqt {
 216   my ($self, $aqt, $top_level) = @_;
 217   local our $Render_Top_Level = $top_level;
 218   return $self->next::method($aqt);
 219 }
 220
 221 sub render_statement {
 222   my ($self, $expr, $default_scalar_to) = @_;
 223   @{$self->render_aqt(
 224     $self->expand_expr($expr, $default_scalar_to), 1
 225   )};
 226 }
 227
 228 sub select {
 229   my ($self, @args) = @_;
 230   my $stmt = do {
 231     if (ref(my $sel = $args[0]) eq 'HASH') {
 232       $sel
 233     } else {
 234       my %clauses;
 235       @clauses{qw(from select where order_by)} = @args;
 236
 237       # This oddity is to literalify since historically SQLA doesn't quote
 238       # a single identifier argument, so we convert it into a literal
 239
 240       $clauses{select} = { -literal => [ $clauses{select}||'*' ] }
 241         unless ref($clauses{select});
 242       \%clauses;
 243     }
 244   };
 245
 246   my @rendered = $self->render_statement({ -select => $stmt });
 247   return wantarray ? @rendered : $rendered[0];
 248 }
 249
 250 sub update {
 251   my ($self, $table, $set, $where, $options) = @_;
 252
 253   my $stmt = do {
 254     if (ref($table) eq 'HASH') {
 255       $table
 256     } else {
 257       my %clauses;
 258       @clauses{qw(target set where)} = ($table, $set, $where);
 259       puke "Unsupported data type specified to \$sql->update"
 260         unless ref($clauses{set}) eq 'HASH';
 261       @clauses{keys %$options} = values %$options;
 262       \%clauses;
 263     }
 264   };
 265   my @rendered = $self->render_statement({ -update => $stmt });
 266   return wantarray ? @rendered : $rendered[0];
 267 }
 268
 269 sub delete {
 270   my ($self, $table, $where, $options) = @_;
 271
 272   my $stmt = do {
 273     if (ref($table) eq 'HASH') {
 274       $table;
 275     } else {
 276       my %clauses = (target => $table, where => $where, %{$options||{}});
 277       \%clauses;
 278     }
 279   };
 280   my @rendered = $self->render_statement({ -delete => $stmt });
 281   return wantarray ? @rendered : $rendered[0];
 282 }
 283
 284 sub insert {
 285   my ($self, $table, $data, $options) = @_;
 286
 287   my $stmt = do {
 288     if (ref($table) eq 'HASH') {
 289       $table;
 290     } else {
 291       my %clauses = (target => $table, values => $data, %{$options||{}});
 292       \%clauses;
 293     }
 294   };
 295   my @rendered = $self->render_statement({ -insert => $stmt });
 296   return wantarray ? @rendered : $rendered[0];
 297 }
 298
 299 sub _expand_insert_clause_target {
 300   +(target => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 301 }
 302
 303 sub _expand_insert_clause_fields {
 304   return +{ -row => [
 305     $_[0]->_expand_maybe_list_expr($_[2], -ident)
 306   ] } if ref($_[2]) eq 'ARRAY';
 307   return $_[2]; # should maybe still expand somewhat?
 308 }
 309
 310 sub _expand_insert_clause_from {
 311   my ($self, undef, $data) = @_;
 312   if (ref($data) eq 'HASH' and (keys(%$data))[0] =~ /^-/) {
 313     return $self->expand_expr($data);
 314   }
 315   return $data if ref($data) eq 'HASH' and $data->{-row};
 316   my ($f_aqt, $v_aqt) = $self->_expand_insert_values($data);
 317   return (
 318     from => { -values => [ $v_aqt ] },
 319     ($f_aqt ? (fields => $f_aqt) : ()),
 320   );
 321 }
 322
 323 sub _expand_insert_clause_returning {
 324   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 325 }
 326
 327 sub _expand_values {
 328   my ($self, undef, $values) = @_;
 329   return { -values => [
 330     map +(
 331       ref($_) eq 'HASH'
 332         ? $self->expand_expr($_)
 333         : +{ -row => [ map $self->expand_expr($_), @$_ ] }
 334     ), ref($values) eq 'ARRAY' ? @$values : $values
 335   ] };
 336 }
 337
 338 sub _render_values {
 339   my ($self, undef, $values) = @_;
 340   my $inner = $self->join_query_parts(' ',
 341     $self->format_keyword('values'),
 342     $self->join_query_parts(', ',
 343       ref($values) eq 'ARRAY' ? @$values : $values
 344     ),
 345   );
 346   return $self->join_query_parts('',
 347     (our $Render_Top_Level ? $inner : ('(', $inner, ')'))
 348   );
 349 }
 350
 351 sub _ext_rw {
 352   my ($self, $name, $key, $value) = @_;
 353   return $self->{$name}{$key} unless @_ > 3;
 354   $self->{$name}{$key} = $value;
 355   return $self;
 356 }
 357
 358 BEGIN {
 359   foreach my $type (qw(
 360     expand op_expand render op_render clause_expand clause_render
 361   )) {
 362     my $name = join '_', reverse split '_', $type;
 363     my $singular = "${type}er";
 364     eval qq{sub ${singular} { shift->_ext_rw($name => \@_) }; 1 }
 365       or die "Method builder failed for ${singular}: $@";
 366     eval qq{sub wrap_${singular} {
 367       my (\$self, \$key, \$builder) = \@_;
 368       my \$orig = \$self->_ext_rw('${name}', \$key);
 369       \$self->_ext_rw(
 370         '${name}', \$key,
 371         \$builder->(\$orig, '${name}', \$key)
 372       );
 373     }; 1 } or die "Method builder failed for wrap_${singular}: $@";
 374     eval qq{sub ${singular}s {
 375       my (\$self, \@args) = \@_;
 376       while (my (\$this_key, \$this_value) = splice(\@args, 0, 2)) {
 377         \$self->_ext_rw('${name}', \$this_key, \$this_value);
 378       }
 379       return \$self;
 380     }; 1 } or die "Method builder failed for ${singular}s: $@";
 381     eval qq{sub wrap_${singular}s {
 382       my (\$self, \@args) = \@_;
 383       while (my (\$this_key, \$this_builder) = splice(\@args, 0, 2)) {
 384         my \$orig = \$self->_ext_rw('${name}', \$this_key);
 385         \$self->_ext_rw(
 386           '${name}', \$this_key,
 387            \$this_builder->(\$orig, '${name}', \$this_key),
 388         );
 389       }
 390       return \$self;
 391     }; 1 } or die "Method builder failed for wrap_${singular}s: $@";
 392     eval qq{sub ${singular}_list { sort keys %{\$_[0]->{\$name}} }; 1; }
 393      or die "Method builder failed for ${singular}_list: $@";
 394   }
 395 }
 396
 397 sub register_op { $_[0]->{is_op}{$_[1]} = 1; $_[0] }
 398
 399 sub statement_list { sort keys %{$_[0]->{clauses_of}} }
 400
 401 sub clauses_of {
 402   my ($self, $of, @clauses) = @_;
 403   unless (@clauses) {
 404     return @{$self->{clauses_of}{$of}||[]};
 405   }
 406   if (ref($clauses[0]) eq 'CODE') {
 407     @clauses = $self->${\($clauses[0])}(@{$self->{clauses_of}{$of}||[]});
 408   }
 409   $self->{clauses_of}{$of} = \@clauses;
 410   return $self;
 411 }
 412
 413 sub clone {
 414   my ($self) = @_;
 415   bless(
 416     {
 417       (map +($_ => (
 418         ref($self->{$_}) eq 'HASH'
 419           ? { %{$self->{$_}} }
 420           : $self->{$_}
 421       )), keys %$self),
 422     },
 423     ref($self)
 424   );
 425 }
 426
 427 1;