lib/SQL/Abstract/Clauses.pm

   1 package SQL::Abstract::Clauses;
   2
   3 use strict;
   4 use warnings;
   5 use if $] < '5.010', 'MRO::Compat';
   6 use mro 'c3';
   7 use base 'SQL::Abstract';
   8
   9 BEGIN { *puke = \&SQL::Abstract::puke }
  10
  11 sub new {
  12   shift->next::method(@_)->register_defaults
  13 }
  14
  15 sub register_defaults {
  16   my ($self) = @_;
  17   $self->{clauses_of}{select} = [ qw(select from where order_by) ];
  18   $self->{expand}{select} = sub { shift->_expand_statement(@_) };
  19   $self->{render}{select} = sub { shift->_render_statement(@_) };
  20   $self->{expand_clause}{"select.$_"} = "_expand_select_clause_$_"
  21     for @{$self->{clauses_of}{select}};
  22   $self->{clauses_of}{update} = [ qw(target set where returning) ];
  23   $self->{expand}{update} = sub { shift->_expand_statement(@_) };
  24   $self->{render}{update} = sub { shift->_render_statement(@_) };
  25   $self->{expand_clause}{"update.$_"} = "_expand_update_clause_$_"
  26     for @{$self->{clauses_of}{update}};
  27   $self->{expand_clause}{'update.update'} = '_expand_update_clause_target';
  28   $self->{render_clause}{'update.target'} = sub {
  29     my ($self, undef, $target) = @_;
  30     my ($sql, @bind) = $self->render_aqt($target);
  31     ($self->_sqlcase('update ').$sql, @bind);
  32   };
  33   $self->{clauses_of}{delete} = [ qw(target where returning) ];
  34   $self->{expand}{delete} = sub { shift->_expand_statement(@_) };
  35   $self->{render}{delete} = sub { shift->_render_statement(@_) };
  36   $self->{expand_clause}{"delete.$_"} = "_expand_delete_clause_$_"
  37     for @{$self->{clauses_of}{delete}};
  38   $self->{expand_clause}{"delete.from"} = '_expand_delete_clause_target';
  39   $self->{render_clause}{'delete.target'} = sub {
  40     my ($self, undef, $from) = @_;
  41     my ($sql, @bind) = $self->render_aqt($from);
  42     ($self->_sqlcase('delete from ').$sql, @bind);
  43   };
  44   $self->{clauses_of}{insert} = [
  45     'target', 'fields', 'from', 'returning'
  46   ];
  47   $self->{expand}{insert} = sub { shift->_expand_statement(@_) };
  48   $self->{render}{insert} = sub { shift->_render_statement(@_) };
  49   $self->{expand_clause}{'insert.into'} = '_expand_insert_clause_target';
  50   $self->{expand_clause}{'insert.target'} = '_expand_insert_clause_target';
  51   $self->{expand_clause}{'insert.fields'} = sub {
  52     return +{ -row => [
  53       shift->_expand_maybe_list_expr($_[2], -ident)
  54     ] } if ref($_[2]) eq 'ARRAY';
  55     return $_[2]; # should maybe still expand somewhat?
  56   };
  57   $self->{expand_clause}{'insert.values'} = '_expand_insert_clause_values';
  58   $self->{expand_clause}{'insert.returning'} = sub {
  59     shift->_expand_maybe_list_expr(@_, -ident);
  60   };
  61   $self->{render_clause}{'insert.fields'} = sub {
  62     return $_[0]->render_aqt($_[2]);
  63   };
  64   $self->{render_clause}{'insert.target'} = sub {
  65     my ($self, undef, $from) = @_;
  66     my ($sql, @bind) = $self->render_aqt($from);
  67     ($self->_sqlcase('insert into ').$sql, @bind);
  68   };
  69   $self->{render_clause}{'insert.from'} = sub {
  70     return $_[0]->render_aqt($_[2], 1);
  71   };
  72   $self->{expand}{values} = '_expand_values';
  73   $self->{render}{values} = '_render_values';
  74   $self->{expand}{exists} = sub {
  75     $_[0]->_expand_op(undef, [ exists => $_[2] ]);
  76   };
  77   $self->{render}{convert_where} = sub {
  78     my $self = shift;
  79     local $self->{convert_where} = $self->{convert};
  80     $self->render_aqt($_[0]);
  81   };
  82   return $self;
  83 }
  84
  85 sub _expand_select_clause_select {
  86   my ($self, undef, $select) = @_;
  87   +(select => $self->_expand_maybe_list_expr($select, -ident));
  88 }
  89
  90 sub _expand_select_clause_from {
  91   my ($self, undef, $from) = @_;
  92   +(from => $self->_expand_maybe_list_expr($from, -ident));
  93 }
  94
  95 sub _expand_select_clause_where {
  96   my ($self, undef, $where) = @_;
  97   my $exp = $self->expand_expr($where);
  98   +(where => ($self->{convert} ? { -convert_where => $exp } : $exp));
  99 }
 100
 101 sub _expand_select_clause_order_by {
 102   my ($self, undef, $order_by) = @_;
 103   +(order_by => $self->_expand_order_by($order_by));
 104 }
 105
 106 sub _expand_update_clause_target {
 107   my ($self, undef, $target) = @_;
 108   +(target => $self->_expand_maybe_list_expr($target, -ident));
 109 }
 110
 111 sub _expand_update_clause_set {
 112   return $_[2] if ref($_[2]) eq 'HASH' and ($_[2]->{-op}||[''])->[0] eq ',';
 113   +(set => $_[0]->_expand_update_set_values($_[1], $_[2]));
 114 }
 115
 116 sub _expand_update_clause_where {
 117   +(where => $_[0]->expand_expr($_[2]));
 118 }
 119
 120 sub _expand_update_clause_returning {
 121   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 122 }
 123
 124 sub _expand_delete_clause_target {
 125   +(target => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 126 }
 127
 128 sub _expand_delete_clause_where { +(where => $_[0]->expand_expr($_[2])); }
 129
 130 sub _expand_delete_clause_returning {
 131   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 132 }
 133
 134 sub _expand_statement {
 135   my ($self, $type, $args) = @_;
 136   my $ec = $self->{expand_clause};
 137   if ($args->{_}) {
 138     $args = { %$args };
 139     $args->{$type} = delete $args->{_}
 140   }
 141   return +{ "-${type}" => +{
 142     map {
 143       my $val = $args->{$_};
 144       if (defined($val) and my $exp = $ec->{"${type}.$_"}) {
 145         if ((my (@exp) = $self->$exp($_ => $val)) == 1) {
 146           ($_ => $exp[0])
 147         } else {
 148           @exp
 149         }
 150       } else {
 151         ($_ => $self->expand_expr($val))
 152       }
 153     } sort keys %$args
 154   } };
 155 }
 156
 157 sub _render_statement {
 158   my ($self, $type, $args) = @_;
 159   my @parts;
 160   foreach my $clause (@{$self->{clauses_of}{$type}}) {
 161     next unless my $clause_expr = $args->{$clause};
 162     my @part = do {
 163       if (my $rdr = $self->{render_clause}{"${type}.${clause}"}) {
 164         $self->$rdr($clause, $clause_expr);
 165       } else {
 166         my ($clause_sql, @bind) = $self->render_aqt($clause_expr, 1);
 167         my $sql = join ' ',
 168           $self->_sqlcase(join ' ', split '_', $clause),
 169           $clause_sql;
 170         ($sql, @bind);
 171       }
 172     };
 173     push @parts, \@part;
 174   }
 175   my ($sql, @bind) = $self->join_query_parts(' ', @parts);
 176   return (
 177     (our $Render_Top_Level ? $sql : '('.$sql.')'),
 178     @bind
 179   );
 180 }
 181
 182 sub render_aqt {
 183   my ($self, $aqt, $top_level) = @_;
 184   local our $Render_Top_Level = $top_level;
 185   return $self->next::method($aqt);
 186 }
 187
 188 sub render_statement {
 189   my ($self, $expr, $default_scalar_to) = @_;
 190   my ($sql, @bind) = $self->render_aqt(
 191     $self->expand_expr($expr, $default_scalar_to), 1
 192   );
 193   return (wantarray ? ($sql, @bind) : $sql);
 194 }
 195
 196 sub select {
 197   my ($self, @args) = @_;
 198
 199   return $self->render_statement({ -select => $_[1] }) if ref($_[1]) eq 'HASH';
 200
 201   my %clauses;
 202   @clauses{qw(from select where order_by)} = @args;
 203
 204   # This oddity is to literalify since historically SQLA doesn't quote
 205   # a single identifier argument, so we convert it into a literal
 206
 207   $clauses{select} = { -literal => [ $clauses{select}||'*' ] }
 208     unless ref($clauses{select});
 209
 210   return $self->render_statement({ -select => \%clauses });
 211 }
 212
 213 sub update {
 214   my ($self, $table, $set, $where, $options) = @_;
 215
 216   return $self->render_statement({ -update => $_[1] }) if ref($_[1]) eq 'HASH';
 217
 218   my %clauses;
 219   @clauses{qw(target set where)} = ($table, $set, $where);
 220   puke "Unsupported data type specified to \$sql->update"
 221     unless ref($clauses{set}) eq 'HASH';
 222   @clauses{keys %$options} = values %$options;
 223   return $self->render_statement({ -update => \%clauses });
 224 }
 225
 226 sub delete {
 227   my ($self, $table, $where, $options) = @_;
 228
 229   return $self->render_statement({ -delete => $_[1] }) if ref($_[1]) eq 'HASH';
 230
 231   my %clauses = (target => $table, where => $where, %{$options||{}});
 232   return $self->render_statement({ -delete => \%clauses });
 233 }
 234
 235 sub insert {
 236   my ($self, $table, $data, $options) = @_;
 237
 238   return $self->render_statement({ -insert => $_[1] }) if ref($_[1]) eq 'HASH';
 239
 240   my %clauses = (target => $table, values => $data, %{$options||{}});
 241   return $self->render_statement({ -insert => \%clauses });
 242 }
 243
 244 sub _expand_insert_clause_target {
 245   +(target => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 246 }
 247
 248 sub _expand_insert_clause_values {
 249   my ($self, undef, $data) = @_;
 250   if (ref($data) eq 'HASH' and (keys(%$data))[0] =~ /^-/) {
 251     return $self->expand_expr($data);
 252   }
 253   return $data if ref($data) eq 'HASH' and $data->{-row};
 254   my ($f_aqt, $v_aqt) = $self->_expand_insert_values($data);
 255   return (from => { -values => $v_aqt }, ($f_aqt ? (fields => $f_aqt) : ()));
 256 }
 257
 258 sub _expand_values {
 259   my ($self, undef, $values) = @_;
 260   return { -values => [
 261     map +(
 262       ref($_) eq 'HASH'
 263         ? $self->expand_expr($_)
 264         : +{ -row => [ map $self->expand_expr($_), @$_ ] }
 265     ), ref($values) eq 'ARRAY' ? @$values : $values
 266   ] };
 267 }
 268
 269 sub _render_values {
 270   my ($self, undef, $values) = @_;
 271   my ($v_sql, @bind) = $self->join_query_parts(
 272     ', ',
 273     ref($values) eq 'ARRAY' ? @$values : $values
 274   );
 275   my $sql = $self->_sqlcase('values').' '.$v_sql;
 276   return (
 277     (our $Render_Top_Level ? $sql : '('.$sql.')'),
 278     @bind
 279   );
 280 }
 281
 282 sub _ext_rw {
 283   my ($self, $name, $key, $value) = @_;
 284   return $self->{$name}{$key} unless @_ > 3;
 285   $self->{$name}{$key} = $value;
 286   return $self;
 287 }
 288
 289 BEGIN {
 290   foreach my $type (qw(
 291     expand op_expand render op_render clause_expand clause_render
 292   )) {
 293     my $name = join '_', reverse split '_', $type;
 294     my $singular = "${type}er";
 295     eval qq{sub ${singular} { shift->_ext_rw($name => \@_) }; 1 }
 296       or die "Method builder failed for ${singular}: $@";
 297     eval qq{sub wrap_${singular} {
 298       my (\$self, \$key, \$builder) = \@_;
 299       my \$orig = \$self->_ext_rw('${name}', \$key);
 300       \$self->_ext_rw(
 301         '${name}', \$key,
 302         \$builder->(\$orig, '${name}', \$key)
 303       );
 304     }; 1 } or die "Method builder failed for wrap_${singular}: $@";
 305     eval qq{sub ${singular}s {
 306       my (\$self, \@args) = \@_;
 307       while (my (\$this_key, \$this_value) = splice(\@args, 0, 2)) {
 308         \$self->{${name}}{\$this_key} = \$this_value;
 309       }
 310       return \$self;
 311     }; 1 } or die "Method builder failed for ${singular}s: $@";
 312     eval qq{sub ${singular}_list { sort keys %{\$_[0]->{\$name}} }; 1; }
 313      or die "Method builder failed for ${singular}_list: $@";
 314   }
 315 }
 316
 317 sub statement_list { sort keys %{$_[0]->{clauses_of}} }
 318
 319 sub clauses_of {
 320   my ($self, $of, @clauses) = @_;
 321   unless (@clauses) {
 322     return @{$self->{clauses_of}{$of}||[]};
 323   }
 324   if (ref($clauses[0]) eq 'CODE') {
 325     @clauses = $self->${\($clauses[0])}(@{$self->{clauses_of}{$of}||[]});
 326   }
 327   $self->{clauses_of}{$of} = \@clauses;
 328   return $self;
 329 }
 330
 331 sub clone {
 332   my ($self) = @_;
 333   bless(
 334     {
 335       (map +($_ => (
 336         ref($self->{$_}) eq 'HASH'
 337           ? { %{$self->{$_}} }
 338           : $self->{$_}
 339       )), keys %$self),
 340     },
 341     ref($self)
 342   );
 343 }
 344
 345 1;