lib/SQL/Abstract/Clauses.pm

   1 package SQL::Abstract::Clauses;
   2
   3 use strict;
   4 use warnings;
   5 use if $] < '5.010', 'MRO::Compat';
   6 use mro 'c3';
   7 use base 'SQL::Abstract';
   8
   9 BEGIN { *puke = \&SQL::Abstract::puke }
  10
  11 sub new {
  12   shift->next::method(@_)->register_defaults
  13 }
  14
  15 sub register_defaults {
  16   my ($self) = @_;
  17   $self->{clauses_of}{select} = [ qw(select from where order_by) ];
  18   $self->{expand}{select} = sub { shift->_expand_statement(@_) };
  19   $self->{render}{select} = sub { shift->_render_statement(select => @_) };
  20   $self->{expand_clause}{"select.$_"} = "_expand_select_clause_$_"
  21     for @{$self->{clauses_of}{select}};
  22   $self->{clauses_of}{update} = [ qw(target set where returning) ];
  23   $self->{expand}{update} = sub { shift->_expand_statement(@_) };
  24   $self->{render}{update} = sub { shift->_render_statement(update => @_) };
  25   $self->{expand_clause}{"update.$_"} = "_expand_update_clause_$_"
  26     for @{$self->{clauses_of}{update}};
  27   $self->{expand_clause}{'update.update'} = '_expand_update_clause_target';
  28   $self->{render_clause}{'update.target'} = sub {
  29     my ($self, $target) = @_;
  30     my ($sql, @bind) = $self->render_aqt($target);
  31     ($self->_sqlcase('update ').$sql, @bind);
  32   };
  33   $self->{clauses_of}{delete} = [ qw(target where returning) ];
  34   $self->{expand}{delete} = sub { shift->_expand_statement(@_) };
  35   $self->{render}{delete} = sub { shift->_render_statement(delete => @_) };
  36   $self->{expand_clause}{"delete.$_"} = "_expand_delete_clause_$_"
  37     for @{$self->{clauses_of}{delete}};
  38   $self->{expand_clause}{"delete.from"} = '_expand_delete_clause_target';
  39   $self->{render_clause}{'delete.target'} = sub {
  40     my ($self, $from) = @_;
  41     my ($sql, @bind) = $self->render_aqt($from);
  42     ($self->_sqlcase('delete from ').$sql, @bind);
  43   };
  44   $self->{clauses_of}{insert} = [
  45     'target', 'fields', 'from', 'returning'
  46   ];
  47   $self->{expand}{insert} = sub { shift->_expand_statement(@_) };
  48   $self->{render}{insert} = sub { shift->_render_statement(insert => @_) };
  49   $self->{expand_clause}{'insert.into'} = '_expand_insert_clause_target';
  50   $self->{expand_clause}{'insert.target'} = '_expand_insert_clause_target';
  51   $self->{expand_clause}{'insert.fields'} = sub {
  52     return +{ -row => [
  53       shift->_expand_maybe_list_expr(@_, -ident)
  54     ] } if ref($_[1]) eq 'ARRAY';
  55     return $_[1]; # should maybe still expand somewhat?
  56   };
  57   $self->{expand_clause}{'insert.values'} = '_expand_insert_clause_values';
  58   $self->{expand_clause}{'insert.returning'} = sub {
  59     shift->_expand_maybe_list_expr(@_, -ident);
  60   };
  61   $self->{render_clause}{'insert.fields'} = sub {
  62     return $_[0]->render_aqt($_[1]);
  63   };
  64   $self->{render_clause}{'insert.target'} = sub {
  65     my ($self, $from) = @_;
  66     my ($sql, @bind) = $self->render_aqt($from);
  67     ($self->_sqlcase('insert into ').$sql, @bind);
  68   };
  69   $self->{render_clause}{'insert.from'} = sub {
  70     return $_[0]->render_aqt($_[1], 1);
  71   };
  72   $self->{expand}{values} = '_expand_values';
  73   $self->{render}{values} = '_render_values';
  74   return $self;
  75 }
  76
  77 sub _expand_select_clause_select {
  78   my ($self, $select) = @_;
  79   +(select => $self->_expand_maybe_list_expr($select, -ident));
  80 }
  81
  82 sub _expand_select_clause_from {
  83   my ($self, $from) = @_;
  84   +(from => $self->_expand_maybe_list_expr($from, -ident));
  85 }
  86
  87 sub _expand_select_clause_where {
  88   my ($self, $where) = @_;
  89   +(where => $self->expand_expr($where));
  90 }
  91
  92 sub _expand_select_clause_order_by {
  93   my ($self, $order_by) = @_;
  94   +(order_by => $self->_expand_order_by($order_by));
  95 }
  96
  97 sub _expand_update_clause_target {
  98   my ($self, $target) = @_;
  99   +(target => $self->_expand_maybe_list_expr($target, -ident));
 100 }
 101
 102 sub _expand_update_clause_set {
 103   return $_[1] if ref($_[1]) eq 'HASH' and ($_[1]->{-op}||[''])->[0] eq ',';
 104   +(set => shift->_expand_update_set_values(@_));
 105 }
 106
 107 sub _expand_update_clause_where {
 108   +(where => shift->expand_expr(@_));
 109 }
 110
 111 sub _expand_update_clause_returning {
 112   +(returning => shift->_expand_maybe_list_expr(@_, -ident));
 113 }
 114
 115 sub _expand_delete_clause_target {
 116   +(target => shift->_expand_maybe_list_expr(@_, -ident));
 117 }
 118
 119 sub _expand_delete_clause_where { +(where => shift->expand_expr(@_)); }
 120
 121 sub _expand_delete_clause_returning {
 122   +(returning => shift->_expand_maybe_list_expr(@_, -ident));
 123 }
 124
 125 sub _expand_statement {
 126   my ($self, $type, $args) = @_;
 127   my $ec = $self->{expand_clause};
 128   return +{ "-${type}" => +{
 129     map {
 130       my $val = $args->{$_};
 131       if (defined($val) and my $exp = $ec->{"${type}.$_"}) {
 132         if ((my (@exp) = $self->$exp($val)) == 1) {
 133           ($_ => $exp[0])
 134         } else {
 135           @exp
 136         }
 137       } else {
 138         ($_ => $self->expand_expr($val))
 139       }
 140     } sort keys %$args
 141   } };
 142 }
 143
 144 sub _render_statement {
 145   my ($self, $type, $args) = @_;
 146   my @parts;
 147   foreach my $clause (@{$self->{clauses_of}{$type}}) {
 148     next unless my $clause_expr = $args->{$clause};
 149     local $self->{convert_where} = $self->{convert} if $clause eq 'where';
 150     my ($sql) = my @part = do {
 151       if (my $rdr = $self->{render_clause}{"${type}.${clause}"}) {
 152         $self->$rdr($clause_expr);
 153       } else {
 154         my ($clause_sql, @bind) = $self->render_aqt($clause_expr, 1);
 155         my $sql = join ' ',
 156           $self->_sqlcase(join ' ', split '_', $clause),
 157           $clause_sql;
 158         ($sql, @bind);
 159       }
 160     };
 161     next unless defined($sql) and length($sql);
 162     push @parts, \@part;
 163   }
 164   my ($sql, @bind) = $self->_join_parts(' ', @parts);
 165   return (
 166     (our $Render_Top_Level ? $sql : '('.$sql.')'),
 167     @bind
 168   );
 169 }
 170
 171 sub render_aqt {
 172   my ($self, $aqt, $top_level) = @_;
 173   local our $Render_Top_Level = $top_level;
 174   return $self->next::method($aqt);
 175 }
 176
 177 sub render_statement {
 178   my ($self, $expr, $default_scalar_to) = @_;
 179   my ($sql, @bind) = $self->render_aqt(
 180     $self->expand_expr($expr, $default_scalar_to), 1
 181   );
 182   return (wantarray ? ($sql, @bind) : $sql);
 183 }
 184
 185 sub select {
 186   my ($self, @args) = @_;
 187
 188   return $self->render_statement({ -select => $_[1] }) if ref($_[1]) eq 'HASH';
 189
 190   my %clauses;
 191   @clauses{qw(from select where order_by)} = @args;
 192
 193   # This oddity is to literalify since historically SQLA doesn't quote
 194   # a single identifier argument, so we convert it into a literal
 195
 196   $clauses{select} = { -literal => [ $clauses{select}||'*' ] }
 197     unless ref($clauses{select});
 198
 199   return $self->render_statement({ -select => \%clauses });
 200 }
 201
 202 sub update {
 203   my ($self, $table, $set, $where, $options) = @_;
 204
 205   return $self->render_statement({ -update => $_[1] }) if ref($_[1]) eq 'HASH';
 206
 207   my %clauses;
 208   @clauses{qw(target set where)} = ($table, $set, $where);
 209   puke "Unsupported data type specified to \$sql->update"
 210     unless ref($clauses{set}) eq 'HASH';
 211   @clauses{keys %$options} = values %$options;
 212   return $self->render_statement({ -update => \%clauses });
 213 }
 214
 215 sub delete {
 216   my ($self, $table, $where, $options) = @_;
 217
 218   return $self->render_statement({ -delete => $_[1] }) if ref($_[1]) eq 'HASH';
 219
 220   my %clauses = (target => $table, where => $where, %{$options||{}});
 221   return $self->render_statement({ -delete => \%clauses });
 222 }
 223
 224 sub insert {
 225   my ($self, $table, $data, $options) = @_;
 226
 227   return $self->render_statement({ -insert => $_[1] }) if ref($_[1]) eq 'HASH';
 228
 229   my %clauses = (target => $table, values => $data, %{$options||{}});
 230   return $self->render_statement({ -insert => \%clauses });
 231 }
 232
 233 sub _expand_insert_clause_target {
 234   +(target => shift->_expand_maybe_list_expr(@_, -ident));
 235 }
 236
 237 sub _expand_insert_clause_values {
 238   my ($self, $data) = @_;
 239   if (ref($data) eq 'HASH' and (keys(%$data))[0] =~ /^-/) {
 240     return $self->expand_expr($data);
 241   }
 242   return $data if ref($data) eq 'HASH' and $data->{-row};
 243   my ($f_aqt, $v_aqt) = $self->_expand_insert_values($data);
 244   return (from => { -values => $v_aqt }, ($f_aqt ? (fields => $f_aqt) : ()));
 245 }
 246
 247 sub _expand_values {
 248   my ($self, undef, $values) = @_;
 249   return { -values => [
 250     map +(
 251       ref($_) eq 'HASH'
 252         ? $self->expand_expr($_)
 253         : +{ -row => [ map $self->expand_expr($_), @$_ ] }
 254     ), ref($values) eq 'ARRAY' ? @$values : $values
 255   ] };
 256 }
 257
 258 sub _render_values {
 259   my ($self, $values) = @_;
 260   my ($v_sql, @bind) = $self->_join_parts(
 261     ', ',
 262     map [ $self->render_aqt($_) ],
 263       ref($values) eq 'ARRAY' ? @$values : $values
 264   );
 265   my $sql = $self->_sqlcase('values').' '.$v_sql;
 266   return (
 267     (our $Render_Top_Level ? $sql : '('.$sql.')'),
 268     @bind
 269   );
 270 }
 271
 272
 273 1;