lib/SQL/Abstract/Clauses.pm

   1 package SQL::Abstract::Clauses;
   2
   3 use strict;
   4 use warnings;
   5 use if $] < '5.010', 'MRO::Compat';
   6 use mro 'c3';
   7 use base 'SQL::Abstract';
   8
   9 BEGIN { *puke = \&SQL::Abstract::puke }
  10
  11 sub new {
  12   shift->next::method(@_)->register_defaults
  13 }
  14
  15 sub register_defaults {
  16   my ($self) = @_;
  17   $self->{clauses_of}{select} = [ qw(select from where order_by) ];
  18   $self->{expand}{select} = sub { shift->_expand_statement(@_) };
  19   $self->{render}{select} = sub { shift->_render_statement(select => @_) };
  20   $self->{expand_clause}{"select.$_"} = "_expand_select_clause_$_"
  21     for @{$self->{clauses_of}{select}};
  22   $self->{clauses_of}{update} = [ qw(target set where returning) ];
  23   $self->{expand}{update} = sub { shift->_expand_statement(@_) };
  24   $self->{render}{update} = sub { shift->_render_statement(update => @_) };
  25   $self->{expand_clause}{"update.$_"} = "_expand_update_clause_$_"
  26     for @{$self->{clauses_of}{update}};
  27   $self->{expand_clause}{'update.update'} = '_expand_update_clause_target';
  28   $self->{render_clause}{'update.target'} = sub {
  29     my ($self, $target) = @_;
  30     my ($sql, @bind) = $self->render_aqt($target);
  31     ($self->_sqlcase('update ').$sql, @bind);
  32   };
  33   $self->{clauses_of}{delete} = [ qw(target where returning) ];
  34   $self->{expand}{delete} = sub { shift->_expand_statement(@_) };
  35   $self->{render}{delete} = sub { shift->_render_statement(delete => @_) };
  36   $self->{expand_clause}{"delete.$_"} = "_expand_delete_clause_$_"
  37     for @{$self->{clauses_of}{delete}};
  38   $self->{expand_clause}{"delete.from"} = '_expand_delete_clause_target';
  39   $self->{render_clause}{'delete.target'} = sub {
  40     my ($self, $from) = @_;
  41     my ($sql, @bind) = $self->render_aqt($from);
  42     ($self->_sqlcase('delete from ').$sql, @bind);
  43   };
  44   $self->{clauses_of}{insert} = [
  45     'target', 'fields', 'from', 'returning'
  46   ];
  47   $self->{expand}{insert} = sub { shift->_expand_statement(@_) };
  48   $self->{render}{insert} = sub { shift->_render_statement(insert => @_) };
  49   $self->{expand_clause}{'insert.into'} = '_expand_insert_clause_target';
  50   $self->{expand_clause}{'insert.target'} = '_expand_insert_clause_target';
  51   $self->{expand_clause}{'insert.fields'} = sub {
  52     return +{ -row => [
  53       shift->_expand_maybe_list_expr(@_, -ident)
  54     ] } if ref($_[1]) eq 'ARRAY';
  55     return $_[1]; # should maybe still expand somewhat?
  56   };
  57   $self->{expand_clause}{'insert.values'} = '_expand_insert_clause_values';
  58   $self->{expand_clause}{'insert.returning'} = sub {
  59     shift->_expand_maybe_list_expr(@_, -ident);
  60   };
  61   $self->{render_clause}{'insert.fields'} = sub {
  62     return $_[0]->render_aqt($_[1]);
  63   };
  64   $self->{render_clause}{'insert.target'} = sub {
  65     my ($self, $from) = @_;
  66     my ($sql, @bind) = $self->render_aqt($from);
  67     ($self->_sqlcase('insert into ').$sql, @bind);
  68   };
  69   $self->{render_clause}{'insert.from'} = sub {
  70     return $_[0]->render_aqt($_[1], 1);
  71   };
  72   $self->{expand}{values} = '_expand_values';
  73   $self->{render}{values} = '_render_values';
  74   $self->{expand}{exists} = sub {
  75     $_[0]->_expand_op(undef, [ exists => $_[2] ]);
  76   };
  77   return $self;
  78 }
  79
  80 sub _expand_select_clause_select {
  81   my ($self, $select) = @_;
  82   +(select => $self->_expand_maybe_list_expr($select, -ident));
  83 }
  84
  85 sub _expand_select_clause_from {
  86   my ($self, $from) = @_;
  87   +(from => $self->_expand_maybe_list_expr($from, -ident));
  88 }
  89
  90 sub _expand_select_clause_where {
  91   my ($self, $where) = @_;
  92   +(where => $self->expand_expr($where));
  93 }
  94
  95 sub _expand_select_clause_order_by {
  96   my ($self, $order_by) = @_;
  97   +(order_by => $self->_expand_order_by($order_by));
  98 }
  99
 100 sub _expand_update_clause_target {
 101   my ($self, $target) = @_;
 102   +(target => $self->_expand_maybe_list_expr($target, -ident));
 103 }
 104
 105 sub _expand_update_clause_set {
 106   return $_[1] if ref($_[1]) eq 'HASH' and ($_[1]->{-op}||[''])->[0] eq ',';
 107   +(set => shift->_expand_update_set_values(@_));
 108 }
 109
 110 sub _expand_update_clause_where {
 111   +(where => shift->expand_expr(@_));
 112 }
 113
 114 sub _expand_update_clause_returning {
 115   +(returning => shift->_expand_maybe_list_expr(@_, -ident));
 116 }
 117
 118 sub _expand_delete_clause_target {
 119   +(target => shift->_expand_maybe_list_expr(@_, -ident));
 120 }
 121
 122 sub _expand_delete_clause_where { +(where => shift->expand_expr(@_)); }
 123
 124 sub _expand_delete_clause_returning {
 125   +(returning => shift->_expand_maybe_list_expr(@_, -ident));
 126 }
 127
 128 sub _expand_statement {
 129   my ($self, $type, $args) = @_;
 130   my $ec = $self->{expand_clause};
 131   return +{ "-${type}" => +{
 132     map {
 133       my $val = $args->{$_};
 134       if (defined($val) and my $exp = $ec->{"${type}.$_"}) {
 135         if ((my (@exp) = $self->$exp($val)) == 1) {
 136           ($_ => $exp[0])
 137         } else {
 138           @exp
 139         }
 140       } else {
 141         ($_ => $self->expand_expr($val))
 142       }
 143     } sort keys %$args
 144   } };
 145 }
 146
 147 sub _render_statement {
 148   my ($self, $type, $args) = @_;
 149   my @parts;
 150   foreach my $clause (@{$self->{clauses_of}{$type}}) {
 151     next unless my $clause_expr = $args->{$clause};
 152     local $self->{convert_where} = $self->{convert} if $clause eq 'where';
 153     my ($sql) = my @part = do {
 154       if (my $rdr = $self->{render_clause}{"${type}.${clause}"}) {
 155         $self->$rdr($clause_expr);
 156       } else {
 157         my ($clause_sql, @bind) = $self->render_aqt($clause_expr, 1);
 158         my $sql = join ' ',
 159           $self->_sqlcase(join ' ', split '_', $clause),
 160           $clause_sql;
 161         ($sql, @bind);
 162       }
 163     };
 164     next unless defined($sql) and length($sql);
 165     push @parts, \@part;
 166   }
 167   my ($sql, @bind) = $self->_join_parts(' ', @parts);
 168   return (
 169     (our $Render_Top_Level ? $sql : '('.$sql.')'),
 170     @bind
 171   );
 172 }
 173
 174 sub render_aqt {
 175   my ($self, $aqt, $top_level) = @_;
 176   local our $Render_Top_Level = $top_level;
 177   return $self->next::method($aqt);
 178 }
 179
 180 sub render_statement {
 181   my ($self, $expr, $default_scalar_to) = @_;
 182   my ($sql, @bind) = $self->render_aqt(
 183     $self->expand_expr($expr, $default_scalar_to), 1
 184   );
 185   return (wantarray ? ($sql, @bind) : $sql);
 186 }
 187
 188 sub select {
 189   my ($self, @args) = @_;
 190
 191   return $self->render_statement({ -select => $_[1] }) if ref($_[1]) eq 'HASH';
 192
 193   my %clauses;
 194   @clauses{qw(from select where order_by)} = @args;
 195
 196   # This oddity is to literalify since historically SQLA doesn't quote
 197   # a single identifier argument, so we convert it into a literal
 198
 199   $clauses{select} = { -literal => [ $clauses{select}||'*' ] }
 200     unless ref($clauses{select});
 201
 202   return $self->render_statement({ -select => \%clauses });
 203 }
 204
 205 sub update {
 206   my ($self, $table, $set, $where, $options) = @_;
 207
 208   return $self->render_statement({ -update => $_[1] }) if ref($_[1]) eq 'HASH';
 209
 210   my %clauses;
 211   @clauses{qw(target set where)} = ($table, $set, $where);
 212   puke "Unsupported data type specified to \$sql->update"
 213     unless ref($clauses{set}) eq 'HASH';
 214   @clauses{keys %$options} = values %$options;
 215   return $self->render_statement({ -update => \%clauses });
 216 }
 217
 218 sub delete {
 219   my ($self, $table, $where, $options) = @_;
 220
 221   return $self->render_statement({ -delete => $_[1] }) if ref($_[1]) eq 'HASH';
 222
 223   my %clauses = (target => $table, where => $where, %{$options||{}});
 224   return $self->render_statement({ -delete => \%clauses });
 225 }
 226
 227 sub insert {
 228   my ($self, $table, $data, $options) = @_;
 229
 230   return $self->render_statement({ -insert => $_[1] }) if ref($_[1]) eq 'HASH';
 231
 232   my %clauses = (target => $table, values => $data, %{$options||{}});
 233   return $self->render_statement({ -insert => \%clauses });
 234 }
 235
 236 sub _expand_insert_clause_target {
 237   +(target => shift->_expand_maybe_list_expr(@_, -ident));
 238 }
 239
 240 sub _expand_insert_clause_values {
 241   my ($self, $data) = @_;
 242   if (ref($data) eq 'HASH' and (keys(%$data))[0] =~ /^-/) {
 243     return $self->expand_expr($data);
 244   }
 245   return $data if ref($data) eq 'HASH' and $data->{-row};
 246   my ($f_aqt, $v_aqt) = $self->_expand_insert_values($data);
 247   return (from => { -values => $v_aqt }, ($f_aqt ? (fields => $f_aqt) : ()));
 248 }
 249
 250 sub _expand_values {
 251   my ($self, undef, $values) = @_;
 252   return { -values => [
 253     map +(
 254       ref($_) eq 'HASH'
 255         ? $self->expand_expr($_)
 256         : +{ -row => [ map $self->expand_expr($_), @$_ ] }
 257     ), ref($values) eq 'ARRAY' ? @$values : $values
 258   ] };
 259 }
 260
 261 sub _render_values {
 262   my ($self, $values) = @_;
 263   my ($v_sql, @bind) = $self->_join_parts(
 264     ', ',
 265     map [ $self->render_aqt($_) ],
 266       ref($values) eq 'ARRAY' ? @$values : $values
 267   );
 268   my $sql = $self->_sqlcase('values').' '.$v_sql;
 269   return (
 270     (our $Render_Top_Level ? $sql : '('.$sql.')'),
 271     @bind
 272   );
 273 }
 274
 275 sub _ext_rw {
 276   my ($self, $name, $key, $value) = @_;
 277   return $self->{$name}{$key} unless @_ > 2;
 278   $self->{$name}{$key} = $value;
 279   return $self;
 280 }
 281
 282 BEGIN {
 283   foreach my $type (qw(
 284     expand op_expand render op_renderer clause_expand clause_render
 285   )) {
 286     my $key = join '_', reverse split '_', $type;
 287     my $singular = "${type}er";
 288     eval qq{sub ${singular} { shift->_ext_rw($key => \@_) }; 1 }
 289       or die "Method builder failed for ${type}er: $@";
 290     eval qq{sub ${singular}s {
 291       my (\$self, \@args) = \@_;
 292       while (my (\$this_key, \$this_value) = splice(\@args, 0, 2)) {
 293         \$self->{${key}}{\$this_key} = \$this_value;
 294       }
 295       return \$self;
 296     }; 1 } or die "Method builder failed for ${singular}s: $@";
 297   }
 298 }
 299
 300 sub clauses_of {
 301   my ($self, $of, @clauses) = @_;
 302   unless (@clauses) {
 303     return @{$self->{clauses_of}{$of}||[]};
 304   }
 305   if (ref($clauses[0]) eq 'CODE') {
 306     @clauses = $self->${\($clauses[0])}(@{$self->{clauses_of}{$of}||[]});
 307   }
 308   $self->{clauses_of}{$of} = \@clauses;
 309   return $self;
 310 }
 311
 312 sub clone {
 313   my ($self) = @_;
 314   bless(
 315     {
 316       (map +($_ => (
 317         ref($self->{$_}) eq 'HASH'
 318           ? { %{$self->{$_}} }
 319           : $self->{$_}
 320       )), keys %$self),
 321     },
 322     ref($self)
 323   );
 324 }
 325
 326
 327 1;