lib/SQL/Abstract/Clauses.pm

   1 package SQL::Abstract::Clauses;
   2
   3 use strict;
   4 use warnings;
   5 use if $] < '5.010', 'MRO::Compat';
   6 use mro 'c3';
   7 use base 'SQL::Abstract';
   8
   9 BEGIN { *puke = \&SQL::Abstract::puke }
  10
  11 sub new {
  12   shift->next::method(@_)->register_defaults
  13 }
  14
  15 sub register_defaults {
  16   my ($self) = @_;
  17   $self->{clauses_of}{select} = [ qw(select from where order_by) ];
  18   $self->{expand}{select} = sub { shift->_expand_statement(@_) };
  19   $self->{render}{select} = sub { shift->_render_statement(select => @_) };
  20   $self->{expand_clause}{"select.$_"} = "_expand_select_clause_$_"
  21     for @{$self->{clauses_of}{select}};
  22   $self->{clauses_of}{update} = [ qw(target set where returning) ];
  23   $self->{expand}{update} = sub { shift->_expand_statement(@_) };
  24   $self->{render}{update} = sub { shift->_render_statement(update => @_) };
  25   $self->{expand_clause}{"update.$_"} = "_expand_update_clause_$_"
  26     for @{$self->{clauses_of}{update}};
  27   $self->{expand_clause}{'update.update'} = '_expand_update_clause_target';
  28   $self->{render_clause}{'update.target'} = sub {
  29     my ($self, $target) = @_;
  30     my ($sql, @bind) = $self->render_aqt($target);
  31     ($self->_sqlcase('update ').$sql, @bind);
  32   };
  33   $self->{clauses_of}{delete} = [ qw(target where returning) ];
  34   $self->{expand}{delete} = sub { shift->_expand_statement(@_) };
  35   $self->{render}{delete} = sub { shift->_render_statement(delete => @_) };
  36   $self->{expand_clause}{"delete.$_"} = "_expand_delete_clause_$_"
  37     for @{$self->{clauses_of}{delete}};
  38   $self->{expand_clause}{"delete.from"} = '_expand_delete_clause_target';
  39   $self->{render_clause}{'delete.target'} = sub {
  40     my ($self, $from) = @_;
  41     my ($sql, @bind) = $self->render_aqt($from);
  42     ($self->_sqlcase('delete from ').$sql, @bind);
  43   };
  44   $self->{clauses_of}{insert} = [
  45     'target', 'fields', 'values', 'returning'
  46   ];
  47   $self->{expand}{insert} = sub { shift->_expand_statement(@_) };
  48   $self->{render}{insert} = sub { shift->_render_statement(insert => @_) };
  49   $self->{expand_clause}{'insert.into'} = '_expand_insert_clause_target';
  50   $self->{expand_clause}{'insert.target'} = '_expand_insert_clause_target';
  51   $self->{expand_clause}{'insert.fields'} = sub {
  52     return +{ -row => [
  53       shift->_expand_maybe_list_expr(@_, -ident)
  54     ] } if ref($_[1]) eq 'ARRAY';
  55     return $_[1]; # should maybe still expand somewhat?
  56   };
  57   $self->{expand_clause}{'insert.values'} = '_expand_insert_clause_values';
  58   $self->{expand_clause}{'insert.returning'} = sub {
  59     shift->_expand_maybe_list_expr(@_, -ident);
  60   };
  61   $self->{render_clause}{'insert.fields'} = sub {
  62     return $_[0]->render_aqt($_[1]);
  63   };
  64   $self->{render_clause}{'insert.target'} = sub {
  65     my ($self, $from) = @_;
  66     my ($sql, @bind) = $self->render_aqt($from);
  67     ($self->_sqlcase('insert into ').$sql, @bind);
  68   };
  69   return $self;
  70 }
  71
  72 sub _expand_select_clause_select {
  73   my ($self, $select) = @_;
  74   +(select => $self->_expand_maybe_list_expr($select, -ident));
  75 }
  76
  77 sub _expand_select_clause_from {
  78   my ($self, $from) = @_;
  79   +(from => $self->_expand_maybe_list_expr($from, -ident));
  80 }
  81
  82 sub _expand_select_clause_where {
  83   my ($self, $where) = @_;
  84   +(where => $self->expand_expr($where));
  85 }
  86
  87 sub _expand_select_clause_order_by {
  88   my ($self, $order_by) = @_;
  89   +(order_by => $self->_expand_order_by($order_by));
  90 }
  91
  92 sub _expand_update_clause_target {
  93   my ($self, $target) = @_;
  94   +(target => $self->expand_expr($target, -ident));
  95 }
  96
  97 sub _expand_update_clause_set {
  98   return $_[1] if ref($_[1]) eq 'HASH' and ($_[1]->{-op}||[''])->[0] eq ',';
  99   +(set => shift->_expand_update_set_values(@_));
 100 }
 101
 102 sub _expand_update_clause_where {
 103   +(where => shift->expand_expr(@_));
 104 }
 105
 106 sub _expand_update_clause_returning {
 107   +(returning => shift->_expand_maybe_list_expr(@_, -ident));
 108 }
 109
 110 sub _expand_delete_clause_target {
 111   +(target => shift->_expand_maybe_list_expr(@_, -ident));
 112 }
 113
 114 sub _expand_delete_clause_where { +(where => shift->expand_expr(@_)); }
 115
 116 sub _expand_delete_clause_returning {
 117   +(returning => shift->_expand_maybe_list_expr(@_, -ident));
 118 }
 119
 120 sub _expand_statement {
 121   my ($self, $type, $args) = @_;
 122   my $ec = $self->{expand_clause};
 123   return +{ "-${type}" => +{
 124     map {
 125       my $val = $args->{$_};
 126       if (defined($val) and my $exp = $ec->{"${type}.$_"}) {
 127         if ((my (@exp) = $self->$exp($val)) == 1) {
 128           ($_ => $exp[0])
 129         } else {
 130           @exp
 131         }
 132       } else {
 133         ($_ => $val)
 134       }
 135     } sort keys %$args
 136   } };
 137 }
 138
 139 sub _render_statement {
 140   my ($self, $type, $args) = @_;
 141   my @parts;
 142   foreach my $clause (@{$self->{clauses_of}{$type}}) {
 143     next unless my $clause_expr = $args->{$clause};
 144     local $self->{convert_where} = $self->{convert} if $clause eq 'where';
 145     my ($sql) = my @part = do {
 146       if (my $rdr = $self->{render_clause}{"${type}.${clause}"}) {
 147         $self->$rdr($clause_expr);
 148       } else {
 149         my ($clause_sql, @bind) = $self->render_aqt($clause_expr);
 150         my $sql = join ' ',
 151           $self->_sqlcase(join ' ', split '_', $clause),
 152           $clause_sql;
 153         ($sql, @bind);
 154       }
 155     };
 156     next unless defined($sql) and length($sql);
 157     push @parts, \@part;
 158   }
 159   return $self->_join_parts(' ', @parts);
 160 }
 161
 162 sub select {
 163   my ($self, @args) = @_;
 164
 165   return $self->render_expr({ -select => $_[1] }) if ref($_[1]) eq 'HASH';
 166
 167   my %clauses;
 168   @clauses{qw(from select where order_by)} = @args;
 169
 170   # This oddity is to literalify since historically SQLA doesn't quote
 171   # a single identifier argument, so we convert it into a literal
 172
 173   $clauses{select} = { -literal => [ $clauses{select}||'*' ] }
 174     unless ref($clauses{select});
 175
 176   return $self->render_expr({ -select => \%clauses });
 177 }
 178
 179 sub update {
 180   my ($self, $table, $set, $where, $options) = @_;
 181
 182   return $self->render_expr({ -update => $_[1] }) if ref($_[1]) eq 'HASH';
 183
 184   my %clauses;
 185   @clauses{qw(target set where)} = ($table, $set, $where);
 186   puke "Unsupported data type specified to \$sql->update"
 187     unless ref($clauses{set}) eq 'HASH';
 188   @clauses{keys %$options} = values %$options;
 189   return $self->render_expr({ -update => \%clauses });
 190 }
 191
 192 sub delete {
 193   my ($self, $table, $where, $options) = @_;
 194
 195   return $self->render_expr({ -delete => $_[1] }) if ref($_[1]) eq 'HASH';
 196
 197   my %clauses = (target => $table, where => $where, %{$options||{}});
 198   return $self->render_expr({ -delete => \%clauses });
 199 }
 200
 201 sub insert {
 202   my ($self, $table, $data, $options) = @_;
 203
 204   return $self->render_expr({ -insert => $_[1] }) if ref($_[1]) eq 'HASH';
 205
 206   my %clauses = (target => $table, values => $data, %{$options||{}});
 207   return $self->render_expr({ -insert => \%clauses });
 208 }
 209
 210 sub _expand_insert_clause_target {
 211   +(target => shift->_expand_maybe_list_expr(@_, -ident));
 212 }
 213
 214 sub _expand_insert_clause_values {
 215   my ($self, $data) = @_;
 216   return $data if ref($data) eq 'HASH' and $data->{-row};
 217   my ($f_aqt, $v_aqt) = $self->_expand_insert_values($data);
 218   return (values => $v_aqt, ($f_aqt ? (fields => $f_aqt) : ()));
 219 }
 220
 221 1;