lib/SQL/Abstract/Clauses.pm

   1 package SQL::Abstract::Clauses;
   2
   3 use strict;
   4 use warnings;
   5 use if $] < '5.010', 'MRO::Compat';
   6 use mro 'c3';
   7 use base 'SQL::Abstract';
   8
   9 BEGIN { *puke = \&SQL::Abstract::puke }
  10
  11 sub new {
  12   shift->next::method(@_)->register_defaults
  13 }
  14
  15 sub register_defaults {
  16   my ($self) = @_;
  17   $self->{clauses_of}{select} = [ qw(select from where order_by) ];
  18   $self->{expand}{select} = sub { shift->_expand_statement(@_) };
  19   $self->{render}{select} = sub { shift->_render_statement(@_) };
  20   $self->{expand_clause}{"select.$_"} = "_expand_select_clause_$_"
  21     for @{$self->{clauses_of}{select}};
  22   $self->{clauses_of}{update} = [ qw(target set where returning) ];
  23   $self->{expand}{update} = sub { shift->_expand_statement(@_) };
  24   $self->{render}{update} = sub { shift->_render_statement(@_) };
  25   $self->{expand_clause}{"update.$_"} = "_expand_update_clause_$_"
  26     for @{$self->{clauses_of}{update}};
  27   $self->{expand_clause}{'update.update'} = '_expand_update_clause_target';
  28   $self->{render_clause}{'update.target'} = sub {
  29     my ($self, undef, $target) = @_;
  30     $self->join_query_parts(' ', $self->format_keyword('update'), $target);
  31   };
  32   $self->{clauses_of}{delete} = [ qw(target where returning) ];
  33   $self->{expand}{delete} = sub { shift->_expand_statement(@_) };
  34   $self->{render}{delete} = sub { shift->_render_statement(@_) };
  35   $self->{expand_clause}{"delete.$_"} = "_expand_delete_clause_$_"
  36     for @{$self->{clauses_of}{delete}};
  37   $self->{expand_clause}{"delete.from"} = '_expand_delete_clause_target';
  38   $self->{render_clause}{'delete.target'} = sub {
  39     my ($self, undef, $from) = @_;
  40     $self->join_query_parts(' ', $self->format_keyword('delete from'), $from);
  41   };
  42   $self->{clauses_of}{insert} = [
  43     'target', 'fields', 'from', 'returning'
  44   ];
  45   $self->{expand}{insert} = sub { shift->_expand_statement(@_) };
  46   $self->{render}{insert} = sub { shift->_render_statement(@_) };
  47   $self->{expand_clause}{"insert.$_"} = "_expand_insert_clause_$_"
  48     for @{$self->{clauses_of}{insert}};
  49   $self->{expand_clause}{'insert.into'} = '_expand_insert_clause_target';
  50   $self->{expand_clause}{'insert.values'} = '_expand_insert_clause_from';
  51   $self->{render_clause}{'insert.fields'} = sub {
  52     return $_[0]->render_aqt($_[2]);
  53   };
  54   $self->{render_clause}{'insert.target'} = sub {
  55     my ($self, undef, $from) = @_;
  56     $self->join_query_parts(' ', $self->format_keyword('insert into'), $from);
  57   };
  58   $self->{render_clause}{'insert.from'} = sub {
  59     return $_[0]->render_aqt($_[2], 1);
  60   };
  61   $self->{expand}{values} = '_expand_values';
  62   $self->{render}{values} = '_render_values';
  63   $self->{expand}{exists} = sub {
  64     $_[0]->_expand_op(undef, [ exists => $_[2] ]);
  65   };
  66   $self->{render}{convert_where} = sub {
  67     my $self = shift;
  68     local $self->{convert_where} = $self->{convert};
  69     $self->render_aqt($_[1]);
  70   };
  71   return $self;
  72 }
  73
  74 sub _expand_select_clause_select {
  75   my ($self, undef, $select) = @_;
  76   +(select => $self->_expand_maybe_list_expr($select, -ident));
  77 }
  78
  79 sub _expand_select_clause_from {
  80   my ($self, undef, $from) = @_;
  81   +(from => $self->_expand_maybe_list_expr($from, -ident));
  82 }
  83
  84 sub _expand_select_clause_where {
  85   my ($self, undef, $where) = @_;
  86   my $exp = $self->expand_expr($where);
  87   +(where => ($self->{convert} ? +{ -convert_where => $exp } : $exp));
  88 }
  89
  90 sub _expand_select_clause_order_by {
  91   my ($self, undef, $order_by) = @_;
  92   +(order_by => $self->_expand_order_by($order_by));
  93 }
  94
  95 sub _expand_update_clause_target {
  96   my ($self, undef, $target) = @_;
  97   +(target => $self->_expand_maybe_list_expr($target, -ident));
  98 }
  99
 100 sub _expand_update_clause_set {
 101   return $_[2] if ref($_[2]) eq 'HASH' and ($_[2]->{-op}||[''])->[0] eq ',';
 102   +(set => $_[0]->_expand_update_set_values($_[1], $_[2]));
 103 }
 104
 105 sub _expand_update_clause_where {
 106   +(where => $_[0]->expand_expr($_[2]));
 107 }
 108
 109 sub _expand_update_clause_returning {
 110   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 111 }
 112
 113 sub _expand_delete_clause_target {
 114   +(target => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 115 }
 116
 117 sub _expand_delete_clause_where { +(where => $_[0]->expand_expr($_[2])); }
 118
 119 sub _expand_delete_clause_returning {
 120   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 121 }
 122
 123 sub _expand_statement {
 124   my ($self, $type, $args) = @_;
 125   my $ec = $self->{expand_clause};
 126   if ($args->{_}) {
 127     $args = { %$args };
 128     $args->{$type} = delete $args->{_}
 129   }
 130   return +{ "-${type}" => +{
 131     map {
 132       my $val = $args->{$_};
 133       if (defined($val) and my $exp = $ec->{"${type}.$_"}) {
 134         if ((my (@exp) = $self->$exp($_ => $val)) == 1) {
 135           ($_ => $exp[0])
 136         } else {
 137           @exp
 138         }
 139       } else {
 140         ($_ => $self->expand_expr($val))
 141       }
 142     } sort keys %$args
 143   } };
 144 }
 145
 146 sub _render_statement {
 147   my ($self, $type, $args) = @_;
 148   my @parts;
 149   foreach my $clause (@{$self->{clauses_of}{$type}}) {
 150     next unless my $clause_expr = $args->{$clause};
 151     my $part = do {
 152       if (my $rdr = $self->{render_clause}{"${type}.${clause}"}) {
 153         $self->$rdr($clause, $clause_expr);
 154       } else {
 155         $self->join_query_parts(' ',
 156           $self->format_keyword($clause),
 157           $self->render_aqt($clause_expr, 1)
 158         );
 159       }
 160     };
 161     push @parts, $part;
 162   }
 163   my $q = $self->join_query_parts(' ', @parts);
 164   return $self->join_query_parts('',
 165     (our $Render_Top_Level ? $q : ('(', $q, ')'))
 166   );
 167 }
 168
 169 sub render_aqt {
 170   my ($self, $aqt, $top_level) = @_;
 171   local our $Render_Top_Level = $top_level;
 172   return $self->next::method($aqt);
 173 }
 174
 175 sub render_statement {
 176   my ($self, $expr, $default_scalar_to) = @_;
 177   $self->render_aqt(
 178     $self->expand_expr($expr, $default_scalar_to), 1
 179   );
 180 }
 181
 182 sub select {
 183   my ($self, @args) = @_;
 184
 185   my $stmt = do {
 186     if (ref(my $sel = $args[0]) eq 'HASH') {
 187       $sel
 188     } else {
 189       my %clauses;
 190       @clauses{qw(from select where order_by)} = @args;
 191
 192       # This oddity is to literalify since historically SQLA doesn't quote
 193       # a single identifier argument, so we convert it into a literal
 194
 195       $clauses{select} = { -literal => [ $clauses{select}||'*' ] }
 196         unless ref($clauses{select});
 197       \%clauses;
 198     }
 199   };
 200
 201   my $rendered = $self->render_statement({ -select => $stmt });
 202   return wantarray ? @$rendered : $rendered->[0];
 203 }
 204
 205 sub update {
 206   my ($self, $table, $set, $where, $options) = @_;
 207
 208   my $stmt = do {
 209     if (ref($table) eq 'HASH') {
 210       $table
 211     } else {
 212       my %clauses;
 213       @clauses{qw(target set where)} = ($table, $set, $where);
 214       puke "Unsupported data type specified to \$sql->update"
 215         unless ref($clauses{set}) eq 'HASH';
 216       @clauses{keys %$options} = values %$options;
 217       \%clauses;
 218     }
 219   };
 220   my $rendered = $self->render_statement({ -update => $stmt });
 221   return wantarray ? @$rendered : $rendered->[0];
 222 }
 223
 224 sub delete {
 225   my ($self, $table, $where, $options) = @_;
 226
 227   my $stmt = do {
 228     if (ref($table) eq 'HASH') {
 229       $table;
 230     } else {
 231       my %clauses = (target => $table, where => $where, %{$options||{}});
 232       \%clauses;
 233     }
 234   };
 235   my $rendered = $self->render_statement({ -delete => $stmt });
 236   return wantarray ? @$rendered : $rendered->[0];
 237 }
 238
 239 sub insert {
 240   my ($self, $table, $data, $options) = @_;
 241
 242   my $stmt = do {
 243     if (ref($table) eq 'HASH') {
 244       $table;
 245     } else {
 246       my %clauses = (target => $table, values => $data, %{$options||{}});
 247       \%clauses;
 248     }
 249   };
 250   my $rendered = $self->render_statement({ -insert => $stmt });
 251   return wantarray ? @$rendered : $rendered->[0];
 252 }
 253
 254 sub _expand_insert_clause_target {
 255   +(target => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 256 }
 257
 258 sub _expand_insert_clause_fields {
 259   return +{ -row => [
 260     $_[0]->_expand_maybe_list_expr($_[2], -ident)
 261   ] } if ref($_[2]) eq 'ARRAY';
 262   return $_[2]; # should maybe still expand somewhat?
 263 }
 264
 265 sub _expand_insert_clause_from {
 266   my ($self, undef, $data) = @_;
 267   if (ref($data) eq 'HASH' and (keys(%$data))[0] =~ /^-/) {
 268     return $self->expand_expr($data);
 269   }
 270   return $data if ref($data) eq 'HASH' and $data->{-row};
 271   my ($f_aqt, $v_aqt) = $self->_expand_insert_values($data);
 272   return (from => { -values => $v_aqt }, ($f_aqt ? (fields => $f_aqt) : ()));
 273 }
 274
 275 sub _expand_insert_clause_returning {
 276   +(returning => $_[0]->_expand_maybe_list_expr($_[2], -ident));
 277 }
 278
 279 sub _expand_values {
 280   my ($self, undef, $values) = @_;
 281   return { -values => [
 282     map +(
 283       ref($_) eq 'HASH'
 284         ? $self->expand_expr($_)
 285         : +{ -row => [ map $self->expand_expr($_), @$_ ] }
 286     ), ref($values) eq 'ARRAY' ? @$values : $values
 287   ] };
 288 }
 289
 290 sub _render_values {
 291   my ($self, undef, $values) = @_;
 292   my $inner = $self->join_query_parts(' ',
 293     $self->format_keyword('values'),
 294     $self->join_query_parts(', ',
 295       ref($values) eq 'ARRAY' ? @$values : $values
 296     ),
 297   );
 298   return $self->join_query_parts('',
 299     (our $Render_Top_Level ? $inner : ('(', $inner, ')'))
 300   );
 301 }
 302
 303 sub _ext_rw {
 304   my ($self, $name, $key, $value) = @_;
 305   return $self->{$name}{$key} unless @_ > 3;
 306   $self->{$name}{$key} = $value;
 307   return $self;
 308 }
 309
 310 BEGIN {
 311   foreach my $type (qw(
 312     expand op_expand render op_render clause_expand clause_render
 313   )) {
 314     my $name = join '_', reverse split '_', $type;
 315     my $singular = "${type}er";
 316     eval qq{sub ${singular} { shift->_ext_rw($name => \@_) }; 1 }
 317       or die "Method builder failed for ${singular}: $@";
 318     eval qq{sub wrap_${singular} {
 319       my (\$self, \$key, \$builder) = \@_;
 320       my \$orig = \$self->_ext_rw('${name}', \$key);
 321       \$self->_ext_rw(
 322         '${name}', \$key,
 323         \$builder->(\$orig, '${name}', \$key)
 324       );
 325     }; 1 } or die "Method builder failed for wrap_${singular}: $@";
 326     eval qq{sub ${singular}s {
 327       my (\$self, \@args) = \@_;
 328       while (my (\$this_key, \$this_value) = splice(\@args, 0, 2)) {
 329         \$self->{${name}}{\$this_key} = \$this_value;
 330       }
 331       return \$self;
 332     }; 1 } or die "Method builder failed for ${singular}s: $@";
 333     eval qq{sub ${singular}_list { sort keys %{\$_[0]->{\$name}} }; 1; }
 334      or die "Method builder failed for ${singular}_list: $@";
 335   }
 336 }
 337
 338 sub statement_list { sort keys %{$_[0]->{clauses_of}} }
 339
 340 sub clauses_of {
 341   my ($self, $of, @clauses) = @_;
 342   unless (@clauses) {
 343     return @{$self->{clauses_of}{$of}||[]};
 344   }
 345   if (ref($clauses[0]) eq 'CODE') {
 346     @clauses = $self->${\($clauses[0])}(@{$self->{clauses_of}{$of}||[]});
 347   }
 348   $self->{clauses_of}{$of} = \@clauses;
 349   return $self;
 350 }
 351
 352 sub clone {
 353   my ($self) = @_;
 354   bless(
 355     {
 356       (map +($_ => (
 357         ref($self->{$_}) eq 'HASH'
 358           ? { %{$self->{$_}} }
 359           : $self->{$_}
 360       )), keys %$self),
 361     },
 362     ref($self)
 363   );
 364 }
 365
 366 1;