lib/strictures.pm

   1 package strictures;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5
   6 use constant _PERL_LT_5_8_4 => ($] < 5.008004) ? 1 : 0;
   7
   8 our $VERSION = '1.004003'; # 1.4.3
   9
  10 sub VERSION {
  11   for ($_[1]) {
  12     last unless defined && !ref && int != 1;
  13     die "Major version specified as $_ - this is strictures version 1";
  14   }
  15   # disable this since Foo->VERSION(undef) correctly returns the version
  16   # and that can happen either if our caller passes undef explicitly or
  17   # because the for above autovivified $_[1] - I could make it stop but
  18   # it's pointless since we don't want to blow up if the caller does
  19   # something valid either.
  20   no warnings 'uninitialized';
  21   shift->SUPER::VERSION(@_);
  22 }
  23
  24 my $extra_load_states;
  25
  26 our $Smells_Like_VCS = (-e '.git' || -e '.svn'
  27   || (-e '../../dist.ini' && (-e '../../.git' || -e '../../.svn')));
  28
  29 sub import {
  30   strict->import;
  31   warnings->import(FATAL => 'all');
  32
  33   my $extra_tests = do {
  34     if (exists $ENV{PERL_STRICTURES_EXTRA}) {
  35       if (_PERL_LT_5_8_4 and $ENV{PERL_STRICTURES_EXTRA}) {
  36         die 'PERL_STRICTURES_EXTRA checks are not available on perls older than 5.8.4: '
  37           . "please unset \$ENV{PERL_STRICTURES_EXTRA}\n";
  38       }
  39       $ENV{PERL_STRICTURES_EXTRA};
  40     } elsif (! _PERL_LT_5_8_4) {
  41       !!((caller)[1] =~ /^(?:t|xt|lib|blib)/
  42          and $Smells_Like_VCS)
  43     }
  44   };
  45   if ($extra_tests) {
  46     $extra_load_states ||= do {
  47
  48       my (%rv, @failed);
  49       for my $mod (qw(indirect multidimensional bareword::filehandles)) {
  50         eval "require $mod; \$rv{'$mod'} = 1;" or do {
  51           push @failed, $mod;
  52
  53           # courtesy of the 5.8 require bug
  54           $mod =~ s|::|/|g;
  55           delete $INC{"$mod.pm"};
  56         };
  57       }
  58
  59       if (@failed) {
  60         my $failed = join ' ', @failed;
  61         print STDERR <<EOE;
  62 strictures.pm extra testing active but couldn't load all modules. Missing were:
  63
  64   $failed
  65
  66 Extra testing is auto-enabled in checkouts only, so if you're the author
  67 of a strictures-using module you need to run:
  68
  69   cpan indirect multidimensional bareword::filehandles
  70
  71 but these modules are not required by your users.
  72 EOE
  73       }
  74
  75       \%rv;
  76     };
  77
  78     indirect->unimport(':fatal') if $extra_load_states->{indirect};
  79     multidimensional->unimport if $extra_load_states->{multidimensional};
  80     bareword::filehandles->unimport if $extra_load_states->{'bareword::filehandles'};
  81   }
  82 }
  83
  84 1;
  85
  86 __END__
  87 =head1 NAME
  88
  89 strictures - turn on strict and make all warnings fatal
  90
  91 =head1 SYNOPSIS
  92
  93   use strictures 1;
  94
  95 is equivalent to
  96
  97   use strict;
  98   use warnings FATAL => 'all';
  99
 100 except when called from a file which matches:
 101
 102   (caller)[1] =~ /^(?:t|xt|lib|blib)/
 103
 104 and when either C<.git> or C<.svn> is present in the current directory (with
 105 the intention of only forcing extra tests on the author side) -- or when C<.git>
 106 or C<.svn> is present two directories up along with C<dist.ini> (which would
 107 indicate we are in a C<dzil test> operation, via L<Dist::Zilla>) --
 108 or when the C<PERL_STRICTURES_EXTRA> environment variable is set, in which case
 109
 110   use strictures 1;
 111
 112 is equivalent to
 113
 114   use strict;
 115   use warnings FATAL => 'all';
 116   no indirect 'fatal';
 117   no multidimensional;
 118   no bareword::filehandles;
 119
 120 Note that C<PERL_STRICTURES_EXTRA> may at some point add even more tests, with only a minor
 121 version increase, but any changes to the effect of C<use strictures> in
 122 normal mode will involve a major version bump.
 123
 124 If any of the extra testing modules are not present, L<strictures> will
 125 complain loudly, once, via C<warn()>, and then shut up. But you really
 126 should consider installing them, they're all great anti-footgun tools.
 127
 128 =head1 DESCRIPTION
 129
 130 I've been writing the equivalent of this module at the top of my code for
 131 about a year now. I figured it was time to make it shorter.
 132
 133 Things like the importer in C<use Moose> don't help me because they turn
 134 warnings on but don't make them fatal -- which from my point of view is
 135 useless because I want an exception to tell me my code isn't warnings-clean.
 136
 137 Any time I see a warning from my code, that indicates a mistake.
 138
 139 Any time my code encounters a mistake, I want a crash -- not spew to STDERR
 140 and then unknown (and probably undesired) subsequent behaviour.
 141
 142 I also want to ensure that obvious coding mistakes, like indirect object
 143 syntax (and not so obvious mistakes that cause things to accidentally compile
 144 as such) get caught, but not at the cost of an XS dependency and not at the
 145 cost of blowing things up on another machine.
 146
 147 Therefore, L<strictures> turns on additional checking, but only when it thinks
 148 it's running in a test file in a VCS checkout -- although if this causes
 149 undesired behaviour this can be overridden by setting the
 150 C<PERL_STRICTURES_EXTRA> environment variable.
 151
 152 If additional useful author side checks come to mind, I'll add them to the
 153 C<PERL_STRICTURES_EXTRA> code path only -- this will result in a minor version increase (e.g.
 154 1.000000 to 1.001000 (1.1.0) or similar). Any fixes only to the mechanism of
 155 this code will result in a sub-version increase (e.g. 1.000000 to 1.000001
 156 (1.0.1)).
 157
 158 If the behaviour of C<use strictures> in normal mode changes in any way, that
 159 will constitute a major version increase -- and the code already checks
 160 when its version is tested to ensure that
 161
 162   use strictures 1;
 163
 164 will continue to only introduce the current set of strictures even if 2.0 is
 165 installed.
 166
 167 =head1 METHODS
 168
 169 =head2 import
 170
 171 This method does the setup work described above in L</DESCRIPTION>
 172
 173 =head2 VERSION
 174
 175 This method traps the C<< strictures->VERSION(1) >> call produced by a use line
 176 with a version number on it and does the version check.
 177
 178 =head1 EXTRA TESTING RATIONALE
 179
 180 Every so often, somebody complains that they're deploying via C<git pull>
 181 and that they don't want L<strictures> to enable itself in this case -- and that
 182 setting C<PERL_STRICTURES_EXTRA> to 0 isn't acceptable (additional ways to
 183 disable extra testing would be welcome but the discussion never seems to get
 184 that far).
 185
 186 In order to allow us to skip a couple of stages and get straight to a
 187 productive conversation, here's my current rationale for turning the
 188 extra testing on via a heuristic:
 189
 190 The extra testing is all stuff that only ever blows up at compile time;
 191 this is intentional. So the oft-raised concern that it's different code being
 192 tested is only sort of the case -- none of the modules involved affect the
 193 final optree to my knowledge, so the author gets some additional compile
 194 time crashes which he/she then fixes, and the rest of the testing is
 195 completely valid for all environments.
 196
 197 The point of the extra testing -- especially C<no indirect> -- is to catch
 198 mistakes that newbie users won't even realise are mistakes without
 199 help. For example,
 200
 201   foo { ... };
 202
 203 where foo is an & prototyped sub that you forgot to import -- this is
 204 pernicious to track down since all I<seems> fine until it gets called
 205 and you get a crash. Worse still, you can fail to have imported it due
 206 to a circular require, at which point you have a load order dependent
 207 bug which I've seen before now I<only> show up in production due to tiny
 208 differences between the production and the development environment. I wrote
 209 L<http://shadow.cat/blog/matt-s-trout/indirect-but-still-fatal/> to explain
 210 this particular problem before L<strictures> itself existed.
 211
 212 As such, in my experience so far L<strictures>' extra testing has
 213 I<avoided> production versus development differences, not caused them.
 214
 215 Additionally, L<strictures>' policy is very much "try and provide as much
 216 protection as possible for newbies -- who won't think about whether there's
 217 an option to turn on or not" -- so having only the environment variable
 218 is not sufficient to achieve that (I get to explain that you need to add
 219 C<use strict> at least once a week on freenode #perl -- newbies sometimes
 220 completely skip steps because they don't understand that that step
 221 is important).
 222
 223 I make no claims that the heuristic is perfect -- it's already been evolved
 224 significantly over time, especially for 1.004 where we changed things to
 225 ensure it only fires on files in your checkout (rather than L<strictures>-using
 226 modules you happened to have installed, which was just silly). However, I
 227 hope the above clarifies why a heuristic approach is not only necessary but
 228 desirable from a point of view of providing new users with as much safety as possible,
 229 and will allow any future discussion on the subject to focus on "how do we
 230 minimise annoyance to people deploying from checkouts intentionally".
 231
 232 =head1 COMMUNITY AND SUPPORT
 233
 234 =head2 IRC channel
 235
 236 irc.perl.org #toolchain
 237
 238 (or bug 'mst' in query on there or freenode)
 239
 240 =head2 Git repository
 241
 242 Gitweb is on http://git.shadowcat.co.uk/ and the clone URL is:
 243
 244   git clone git://git.shadowcat.co.uk/p5sagit/strictures.git
 245
 246 The web interface to the repository is at:
 247
 248   http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=p5sagit/strictures.git
 249
 250 =head1 AUTHOR
 251
 252 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 253
 254 =head1 CONTRIBUTORS
 255
 256 None required yet. Maybe this module is perfect (hahahahaha ...).
 257
 258 =head1 COPYRIGHT
 259
 260 Copyright (c) 2010 the strictures L</AUTHOR> and L</CONTRIBUTORS>
 261 as listed above.
 262
 263 =head1 LICENSE
 264
 265 This library is free software and may be distributed under the same terms
 266 as perl itself.
 267
 268 =cut