lib/strictures.pm

   1 package strictures;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5
   6 our $VERSION = '1.002002'; # 1.2.2
   7
   8 sub VERSION {
   9   for ($_[1]) {
  10     last unless defined && !ref && int != 1;
  11     die "Major version specified as $_ - this is strictures version 1";
  12   }
  13   # disable this since Foo->VERSION(undef) correctly returns the version
  14   # and that can happen either if our caller passes undef explicitly or
  15   # because the for above autovivified $_[1] - I could make it stop but
  16   # it's pointless since we don't want to blow up if the caller does
  17   # something valid either.
  18   no warnings 'uninitialized';
  19   shift->SUPER::VERSION(@_);
  20 }
  21
  22 sub import {
  23   strict->import;
  24   warnings->import(FATAL => 'all');
  25   my $extra_tests = do {
  26     if (exists $ENV{PERL_STRICTURES_EXTRA}) {
  27       $ENV{PERL_STRICTURES_EXTRA}
  28     } else {
  29       !!($0 =~ /^x?t\/.*(?:load|compile|coverage|use_ok).*\.t$/
  30          and (-e '.git' or -e '.svn'))
  31     }
  32   };
  33   if ($extra_tests) {
  34     if (eval {
  35           require indirect;
  36           require multidimensional;
  37           require bareword::filehandles;
  38           1
  39         }) {
  40       indirect->unimport(':fatal');
  41       multidimensional->unimport;
  42       bareword::filehandles->unimport;
  43     } else {
  44       die "strictures.pm extra testing active but couldn't load modules.
  45 Extra testing is auto-enabled in checkouts only, so if you're the author
  46 of a strictures using module you need to run:
  47
  48   cpan indirect multidimensional bareword::filehandles
  49
  50 but these modules are not required by your users.
  51
  52 Error loading modules was: $@";
  53     }
  54   }
  55 }
  56
  57 1;
  58
  59 __END__
  60 =head1 NAME
  61
  62 strictures - turn on strict and make all warnings fatal
  63
  64 =head1 SYNOPSIS
  65
  66   use strictures 1;
  67
  68 is equivalent to
  69
  70   use strict;
  71   use warnings FATAL => 'all';
  72
  73 except when called from a file where $0 matches:
  74
  75   /^x?t\/.*(?:load|compile|coverage|use_ok).*\.t$/
  76
  77 and when either '.git' or '.svn' is present in the current directory (with
  78 the intention of only forcing extra tests on the author side) - or when the
  79 PERL_STRICTURES_EXTRA environment variable is set, in which case
  80
  81   use strictures 1;
  82
  83 is equivalent to
  84
  85   use strict;
  86   use warnings FATAL => 'all';
  87   no indirect 'fatal';
  88   no multidimensional;
  89   no bareword::filehandles;
  90
  91 Note that _EXTRA may at some point add even more tests, with only a minor
  92 version increase, but any changes to the effect of 'use strictures' in
  93 normal mode will involve a major version bump.
  94
  95 Be aware: THIS MEANS THE EXTRA TEST MODULES ARE REQUIRED FOR AUTHORS OF
  96 STRICTURES USING CODE - but not by end users thereof.
  97
  98 =head1 DESCRIPTION
  99
 100 I've been writing the equivalent of this module at the top of my code for
 101 about a year now. I figured it was time to make it shorter.
 102
 103 Things like the importer in 'use Moose' don't help me because they turn
 104 warnings on but don't make them fatal - which from my point of view is
 105 useless because I want an exception to tell me my code isn't warnings clean.
 106
 107 Any time I see a warning from my code, that indicates a mistake.
 108
 109 Any time my code encounters a mistake, I want a crash - not spew to STDERR
 110 and then unknown (and probably undesired) subsequent behaviour.
 111
 112 I also want to ensure that obvious coding mistakes, like indirect object
 113 syntax (and not so obvious mistakes that cause things to accidentally compile
 114 as such) get caught, but not at the cost of an XS dependency and not at the
 115 cost of blowing things up on another machine.
 116
 117 Therefore, strictures turns on indirect checking only when it thinks it's
 118 running in a compilation (or pod coverage) test - though if this causes
 119 undesired behaviour this can be overridden by setting the
 120 PERL_STRICTURES_EXTRA environment variable.
 121
 122 If additional useful author side checks come to mind, I'll add them to the
 123 _EXTRA code path only - this will result in a minor version increase (i.e.
 124 1.000000 to 1.001000 (1.1.0) or similar). Any fixes only to the mechanism of
 125 this code will result in a subversion increas (i.e. 1.000000 to 1.000001
 126 (1.0.1)).
 127
 128 If the behaviour of 'use strictures' in normal mode changes in any way, that
 129 will constitute a major version increase - and the code already checks
 130 when its version is tested to ensure that
 131
 132   use strictures 1;
 133
 134 will continue to only introduce the current set of strictures even if 2.0 is
 135 installed.
 136
 137 =head1 METHODS
 138
 139 =head2 import
 140
 141 This method does the setup work described above in L</DESCRIPTION>
 142
 143 =head2 VERSION
 144
 145 This method traps the strictures->VERSION(1) call produced by a use line
 146 with a version number on it and does the version check.
 147
 148 =head1 COMMUNITY AND SUPPORT
 149
 150 =head2 IRC channel
 151
 152 irc.perl.org #toolchain
 153
 154 (or bug 'mst' in query on there or freenode)
 155
 156 =head2 Git repository
 157
 158 Gitweb is on http://git.shadowcat.co.uk/ and the clone URL is:
 159
 160   git clone git://git.shadowcat.co.uk/p5sagit/strictures.git
 161
 162 =head1 AUTHOR
 163
 164 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 165
 166 =head1 CONTRIBUTORS
 167
 168 None required yet. Maybe this module is perfect (hahahahaha ...).
 169
 170 =head1 COPYRIGHT
 171
 172 Copyright (c) 2010 the strictures L</AUTHOR> and L</CONTRIBUTORS>
 173 as listed above.
 174
 175 =head1 LICENSE
 176
 177 This library is free software and may be distributed under the same terms
 178 as perl itself.
 179
 180 =cut