lib/strictures.pm

   1 package strictures;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5
   6 BEGIN {
   7   *_PERL_LT_5_8_4 = ($] < 5.008004) ? sub(){1} : sub(){0};
   8 }
   9
  10 our $VERSION = '1.005002'; # 1.5.2
  11
  12 sub VERSION {
  13   for ($_[1]) {
  14     last unless defined && !ref && int != 1;
  15     die "Major version specified as $_ - this is strictures version 1";
  16   }
  17   # disable this since Foo->VERSION(undef) correctly returns the version
  18   # and that can happen either if our caller passes undef explicitly or
  19   # because the for above autovivified $_[1] - I could make it stop but
  20   # it's pointless since we don't want to blow up if the caller does
  21   # something valid either.
  22   no warnings 'uninitialized';
  23   shift->SUPER::VERSION(@_);
  24 }
  25
  26 our $extra_load_states;
  27
  28 our $Smells_Like_VCS = (-e '.git' || -e '.svn' || -e '.hg'
  29   || (-e '../../dist.ini'
  30       && (-e '../../.git' || -e '../../.svn' || -e '../../.hg' )));
  31
  32 sub import {
  33   strict->import;
  34   warnings->import(FATAL => 'all');
  35
  36   my $extra_tests = do {
  37     if (exists $ENV{PERL_STRICTURES_EXTRA}) {
  38       if (_PERL_LT_5_8_4 and $ENV{PERL_STRICTURES_EXTRA}) {
  39         die 'PERL_STRICTURES_EXTRA checks are not available on perls older than 5.8.4: '
  40           . "please unset \$ENV{PERL_STRICTURES_EXTRA}\n";
  41       }
  42       $ENV{PERL_STRICTURES_EXTRA};
  43     } elsif (! _PERL_LT_5_8_4) {
  44       !!((caller)[1] =~ /^(?:t|xt|lib|blib)/
  45          and $Smells_Like_VCS)
  46     }
  47   };
  48   if ($extra_tests) {
  49     $extra_load_states ||= do {
  50
  51       my (%rv, @failed);
  52       foreach my $mod (qw(indirect multidimensional bareword::filehandles)) {
  53         eval "require $mod; \$rv{'$mod'} = 1;" or do {
  54           push @failed, $mod;
  55
  56           # courtesy of the 5.8 require bug
  57           # (we do a copy because 5.16.2 at least uses the same read-only
  58           # scalars for the qw() list and it doesn't seem worth a $^V check)
  59
  60           (my $file = $mod) =~ s|::|/|g;
  61           delete $INC{"${file}.pm"};
  62         };
  63       }
  64
  65       if (@failed) {
  66         my $failed = join ' ', @failed;
  67         print STDERR <<EOE;
  68 strictures.pm extra testing active but couldn't load all modules. Missing were:
  69
  70   $failed
  71
  72 Extra testing is auto-enabled in checkouts only, so if you're the author
  73 of a strictures-using module you need to run:
  74
  75   cpan indirect multidimensional bareword::filehandles
  76
  77 but these modules are not required by your users.
  78 EOE
  79       }
  80
  81       \%rv;
  82     };
  83
  84     indirect->unimport(':fatal') if $extra_load_states->{indirect};
  85     multidimensional->unimport if $extra_load_states->{multidimensional};
  86     bareword::filehandles->unimport if $extra_load_states->{'bareword::filehandles'};
  87   }
  88 }
  89
  90 1;
  91
  92 __END__
  93 =head1 NAME
  94
  95 strictures - turn on strict and make all warnings fatal
  96
  97 =head1 SYNOPSIS
  98
  99   use strictures 1;
 100
 101 is equivalent to
 102
 103   use strict;
 104   use warnings FATAL => 'all';
 105
 106 except when called from a file which matches:
 107
 108   (caller)[1] =~ /^(?:t|xt|lib|blib)/
 109
 110 and when either C<.git>, C<.svn>, or C<.hg> is present in the current directory (with
 111 the intention of only forcing extra tests on the author side) -- or when C<.git>,
 112 C<.svn>, or C<.hg> is present two directories up along with C<dist.ini> (which would
 113 indicate we are in a C<dzil test> operation, via L<Dist::Zilla>) --
 114 or when the C<PERL_STRICTURES_EXTRA> environment variable is set, in which case
 115
 116   use strictures 1;
 117
 118 is equivalent to
 119
 120   use strict;
 121   use warnings FATAL => 'all';
 122   no indirect 'fatal';
 123   no multidimensional;
 124   no bareword::filehandles;
 125
 126 Note that C<PERL_STRICTURES_EXTRA> may at some point add even more tests, with only a minor
 127 version increase, but any changes to the effect of C<use strictures> in
 128 normal mode will involve a major version bump.
 129
 130 If any of the extra testing modules are not present, L<strictures> will
 131 complain loudly, once, via C<warn()>, and then shut up. But you really
 132 should consider installing them, they're all great anti-footgun tools.
 133
 134 =head1 DESCRIPTION
 135
 136 I've been writing the equivalent of this module at the top of my code for
 137 about a year now. I figured it was time to make it shorter.
 138
 139 Things like the importer in C<use Moose> don't help me because they turn
 140 warnings on but don't make them fatal -- which from my point of view is
 141 useless because I want an exception to tell me my code isn't warnings-clean.
 142
 143 Any time I see a warning from my code, that indicates a mistake.
 144
 145 Any time my code encounters a mistake, I want a crash -- not spew to STDERR
 146 and then unknown (and probably undesired) subsequent behaviour.
 147
 148 I also want to ensure that obvious coding mistakes, like indirect object
 149 syntax (and not so obvious mistakes that cause things to accidentally compile
 150 as such) get caught, but not at the cost of an XS dependency and not at the
 151 cost of blowing things up on another machine.
 152
 153 Therefore, L<strictures> turns on additional checking, but only when it thinks
 154 it's running in a test file in a VCS checkout -- although if this causes
 155 undesired behaviour this can be overridden by setting the
 156 C<PERL_STRICTURES_EXTRA> environment variable.
 157
 158 If additional useful author side checks come to mind, I'll add them to the
 159 C<PERL_STRICTURES_EXTRA> code path only -- this will result in a minor version increase (e.g.
 160 1.000000 to 1.001000 (1.1.0) or similar). Any fixes only to the mechanism of
 161 this code will result in a sub-version increase (e.g. 1.000000 to 1.000001
 162 (1.0.1)).
 163
 164 If the behaviour of C<use strictures> in normal mode changes in any way, that
 165 will constitute a major version increase -- and the code already checks
 166 when its version is tested to ensure that
 167
 168   use strictures 1;
 169
 170 will continue to only introduce the current set of strictures even if 2.0 is
 171 installed.
 172
 173 =head1 METHODS
 174
 175 =head2 import
 176
 177 This method does the setup work described above in L</DESCRIPTION>
 178
 179 =head2 VERSION
 180
 181 This method traps the C<< strictures->VERSION(1) >> call produced by a use line
 182 with a version number on it and does the version check.
 183
 184 =head1 EXTRA TESTING RATIONALE
 185
 186 Every so often, somebody complains that they're deploying via C<git pull>
 187 and that they don't want L<strictures> to enable itself in this case -- and that
 188 setting C<PERL_STRICTURES_EXTRA> to 0 isn't acceptable (additional ways to
 189 disable extra testing would be welcome but the discussion never seems to get
 190 that far).
 191
 192 In order to allow us to skip a couple of stages and get straight to a
 193 productive conversation, here's my current rationale for turning the
 194 extra testing on via a heuristic:
 195
 196 The extra testing is all stuff that only ever blows up at compile time;
 197 this is intentional. So the oft-raised concern that it's different code being
 198 tested is only sort of the case -- none of the modules involved affect the
 199 final optree to my knowledge, so the author gets some additional compile
 200 time crashes which he/she then fixes, and the rest of the testing is
 201 completely valid for all environments.
 202
 203 The point of the extra testing -- especially C<no indirect> -- is to catch
 204 mistakes that newbie users won't even realise are mistakes without
 205 help. For example,
 206
 207   foo { ... };
 208
 209 where foo is an & prototyped sub that you forgot to import -- this is
 210 pernicious to track down since all I<seems> fine until it gets called
 211 and you get a crash. Worse still, you can fail to have imported it due
 212 to a circular require, at which point you have a load order dependent
 213 bug which I've seen before now I<only> show up in production due to tiny
 214 differences between the production and the development environment. I wrote
 215 L<http://shadow.cat/blog/matt-s-trout/indirect-but-still-fatal/> to explain
 216 this particular problem before L<strictures> itself existed.
 217
 218 As such, in my experience so far L<strictures>' extra testing has
 219 I<avoided> production versus development differences, not caused them.
 220
 221 Additionally, L<strictures>' policy is very much "try and provide as much
 222 protection as possible for newbies -- who won't think about whether there's
 223 an option to turn on or not" -- so having only the environment variable
 224 is not sufficient to achieve that (I get to explain that you need to add
 225 C<use strict> at least once a week on freenode #perl -- newbies sometimes
 226 completely skip steps because they don't understand that that step
 227 is important).
 228
 229 I make no claims that the heuristic is perfect -- it's already been evolved
 230 significantly over time, especially for 1.004 where we changed things to
 231 ensure it only fires on files in your checkout (rather than L<strictures>-using
 232 modules you happened to have installed, which was just silly). However, I
 233 hope the above clarifies why a heuristic approach is not only necessary but
 234 desirable from a point of view of providing new users with as much safety as possible,
 235 and will allow any future discussion on the subject to focus on "how do we
 236 minimise annoyance to people deploying from checkouts intentionally".
 237
 238 =head1 SEE ALSO
 239
 240 =over 4
 241
 242 =item *
 243
 244 L<indirect>
 245
 246 =item *
 247
 248 L<multidimensional>
 249
 250 =item *
 251
 252 L<bareword::filehandles>
 253
 254 =back
 255
 256 =head1 COMMUNITY AND SUPPORT
 257
 258 =head2 IRC channel
 259
 260 irc.perl.org #toolchain
 261
 262 (or bug 'mst' in query on there or freenode)
 263
 264 =head2 Git repository
 265
 266 Gitweb is on http://git.shadowcat.co.uk/ and the clone URL is:
 267
 268   git clone git://git.shadowcat.co.uk/p5sagit/strictures.git
 269
 270 The web interface to the repository is at:
 271
 272   http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=p5sagit/strictures.git
 273
 274 =head1 AUTHOR
 275
 276 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 277
 278 =head1 CONTRIBUTORS
 279
 280 Karen Etheridge (cpan:ETHER) <ether@cpan.org>
 281
 282 Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@gmail.com>
 283
 284 haarg - Graham Knop (cpan:HAARG) <haarg@haarg.org>
 285
 286 =head1 COPYRIGHT
 287
 288 Copyright (c) 2010 the strictures L</AUTHOR> and L</CONTRIBUTORS>
 289 as listed above.
 290
 291 =head1 LICENSE
 292
 293 This library is free software and may be distributed under the same terms
 294 as perl itself.
 295
 296 =cut