lib/strictures.pm

   1 package strictures;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5
   6 use constant _PERL_LT_5_8_4 => ($] < 5.008004) ? 1 : 0;
   7
   8 our $VERSION = '1.004004'; # 1.4.4
   9
  10 sub VERSION {
  11   for ($_[1]) {
  12     last unless defined && !ref && int != 1;
  13     die "Major version specified as $_ - this is strictures version 1";
  14   }
  15   # disable this since Foo->VERSION(undef) correctly returns the version
  16   # and that can happen either if our caller passes undef explicitly or
  17   # because the for above autovivified $_[1] - I could make it stop but
  18   # it's pointless since we don't want to blow up if the caller does
  19   # something valid either.
  20   no warnings 'uninitialized';
  21   shift->SUPER::VERSION(@_);
  22 }
  23
  24 our $extra_load_states;
  25
  26 our $Smells_Like_VCS = (-e '.git' || -e '.svn'
  27   || (-e '../../dist.ini' && (-e '../../.git' || -e '../../.svn')));
  28
  29 sub import {
  30   strict->import;
  31   warnings->import(FATAL => 'all');
  32
  33   my $caller_file;
  34   my $depth = 0;
  35   while (my @caller = caller(++$depth)) {
  36     if ($caller[3] =~ /::BEGIN$/) {
  37       # older perls report the BEGIN in the wrong file
  38       $caller_file = $depth > 1 ? (caller($depth-1))[1] : $caller[1];
  39       $caller_file = $caller[1];
  40     }
  41   }
  42
  43   my $extra_tests = do {
  44     if (exists $ENV{PERL_STRICTURES_EXTRA}) {
  45       if (_PERL_LT_5_8_4 and $ENV{PERL_STRICTURES_EXTRA}) {
  46         die 'PERL_STRICTURES_EXTRA checks are not available on perls older than 5.8.4: '
  47           . "please unset \$ENV{PERL_STRICTURES_EXTRA}\n";
  48       }
  49       $ENV{PERL_STRICTURES_EXTRA};
  50     } elsif (! _PERL_LT_5_8_4) {
  51       !!($caller_file =~ /^(?:t|xt|lib|blib)/
  52          and $Smells_Like_VCS)
  53     }
  54   };
  55   if ($extra_tests) {
  56     $extra_load_states ||= do {
  57
  58       my (%rv, @failed);
  59       foreach my $mod (qw(indirect multidimensional bareword::filehandles)) {
  60         eval "require $mod; \$rv{'$mod'} = 1;" or do {
  61           push @failed, $mod;
  62
  63           # courtesy of the 5.8 require bug
  64           # (we do a copy because 5.16.2 at least uses the same read-only
  65           # scalars for the qw() list and it doesn't seem worth a $^V check)
  66
  67           (my $file = $mod) =~ s|::|/|g;
  68           delete $INC{"${file}.pm"};
  69         };
  70       }
  71
  72       if (@failed) {
  73         my $failed = join ' ', @failed;
  74         print STDERR <<EOE;
  75 strictures.pm extra testing active but couldn't load all modules. Missing were:
  76
  77   $failed
  78
  79 Extra testing is auto-enabled in checkouts only, so if you're the author
  80 of a strictures-using module you need to run:
  81
  82   cpan indirect multidimensional bareword::filehandles
  83
  84 but these modules are not required by your users.
  85 EOE
  86       }
  87
  88       \%rv;
  89     };
  90
  91     indirect->unimport(':fatal') if $extra_load_states->{indirect};
  92     multidimensional->unimport if $extra_load_states->{multidimensional};
  93     bareword::filehandles->unimport if $extra_load_states->{'bareword::filehandles'};
  94   }
  95 }
  96
  97 1;
  98
  99 __END__
 100 =head1 NAME
 101
 102 strictures - turn on strict and make all warnings fatal
 103
 104 =head1 SYNOPSIS
 105
 106   use strictures 1;
 107
 108 is equivalent to
 109
 110   use strict;
 111   use warnings FATAL => 'all';
 112
 113 except when called from a file which matches:
 114
 115   (caller)[1] =~ /^(?:t|xt|lib|blib)/
 116
 117 and when either C<.git> or C<.svn> is present in the current directory (with
 118 the intention of only forcing extra tests on the author side) -- or when C<.git>
 119 or C<.svn> is present two directories up along with C<dist.ini> (which would
 120 indicate we are in a C<dzil test> operation, via L<Dist::Zilla>) --
 121 or when the C<PERL_STRICTURES_EXTRA> environment variable is set, in which case
 122
 123   use strictures 1;
 124
 125 is equivalent to
 126
 127   use strict;
 128   use warnings FATAL => 'all';
 129   no indirect 'fatal';
 130   no multidimensional;
 131   no bareword::filehandles;
 132
 133 Note that C<PERL_STRICTURES_EXTRA> may at some point add even more tests, with only a minor
 134 version increase, but any changes to the effect of C<use strictures> in
 135 normal mode will involve a major version bump.
 136
 137 If any of the extra testing modules are not present, L<strictures> will
 138 complain loudly, once, via C<warn()>, and then shut up. But you really
 139 should consider installing them, they're all great anti-footgun tools.
 140
 141 =head1 DESCRIPTION
 142
 143 I've been writing the equivalent of this module at the top of my code for
 144 about a year now. I figured it was time to make it shorter.
 145
 146 Things like the importer in C<use Moose> don't help me because they turn
 147 warnings on but don't make them fatal -- which from my point of view is
 148 useless because I want an exception to tell me my code isn't warnings-clean.
 149
 150 Any time I see a warning from my code, that indicates a mistake.
 151
 152 Any time my code encounters a mistake, I want a crash -- not spew to STDERR
 153 and then unknown (and probably undesired) subsequent behaviour.
 154
 155 I also want to ensure that obvious coding mistakes, like indirect object
 156 syntax (and not so obvious mistakes that cause things to accidentally compile
 157 as such) get caught, but not at the cost of an XS dependency and not at the
 158 cost of blowing things up on another machine.
 159
 160 Therefore, L<strictures> turns on additional checking, but only when it thinks
 161 it's running in a test file in a VCS checkout -- although if this causes
 162 undesired behaviour this can be overridden by setting the
 163 C<PERL_STRICTURES_EXTRA> environment variable.
 164
 165 If additional useful author side checks come to mind, I'll add them to the
 166 C<PERL_STRICTURES_EXTRA> code path only -- this will result in a minor version increase (e.g.
 167 1.000000 to 1.001000 (1.1.0) or similar). Any fixes only to the mechanism of
 168 this code will result in a sub-version increase (e.g. 1.000000 to 1.000001
 169 (1.0.1)).
 170
 171 If the behaviour of C<use strictures> in normal mode changes in any way, that
 172 will constitute a major version increase -- and the code already checks
 173 when its version is tested to ensure that
 174
 175   use strictures 1;
 176
 177 will continue to only introduce the current set of strictures even if 2.0 is
 178 installed.
 179
 180 =head1 METHODS
 181
 182 =head2 import
 183
 184 This method does the setup work described above in L</DESCRIPTION>
 185
 186 =head2 VERSION
 187
 188 This method traps the C<< strictures->VERSION(1) >> call produced by a use line
 189 with a version number on it and does the version check.
 190
 191 =head1 EXTRA TESTING RATIONALE
 192
 193 Every so often, somebody complains that they're deploying via C<git pull>
 194 and that they don't want L<strictures> to enable itself in this case -- and that
 195 setting C<PERL_STRICTURES_EXTRA> to 0 isn't acceptable (additional ways to
 196 disable extra testing would be welcome but the discussion never seems to get
 197 that far).
 198
 199 In order to allow us to skip a couple of stages and get straight to a
 200 productive conversation, here's my current rationale for turning the
 201 extra testing on via a heuristic:
 202
 203 The extra testing is all stuff that only ever blows up at compile time;
 204 this is intentional. So the oft-raised concern that it's different code being
 205 tested is only sort of the case -- none of the modules involved affect the
 206 final optree to my knowledge, so the author gets some additional compile
 207 time crashes which he/she then fixes, and the rest of the testing is
 208 completely valid for all environments.
 209
 210 The point of the extra testing -- especially C<no indirect> -- is to catch
 211 mistakes that newbie users won't even realise are mistakes without
 212 help. For example,
 213
 214   foo { ... };
 215
 216 where foo is an & prototyped sub that you forgot to import -- this is
 217 pernicious to track down since all I<seems> fine until it gets called
 218 and you get a crash. Worse still, you can fail to have imported it due
 219 to a circular require, at which point you have a load order dependent
 220 bug which I've seen before now I<only> show up in production due to tiny
 221 differences between the production and the development environment. I wrote
 222 L<http://shadow.cat/blog/matt-s-trout/indirect-but-still-fatal/> to explain
 223 this particular problem before L<strictures> itself existed.
 224
 225 As such, in my experience so far L<strictures>' extra testing has
 226 I<avoided> production versus development differences, not caused them.
 227
 228 Additionally, L<strictures>' policy is very much "try and provide as much
 229 protection as possible for newbies -- who won't think about whether there's
 230 an option to turn on or not" -- so having only the environment variable
 231 is not sufficient to achieve that (I get to explain that you need to add
 232 C<use strict> at least once a week on freenode #perl -- newbies sometimes
 233 completely skip steps because they don't understand that that step
 234 is important).
 235
 236 I make no claims that the heuristic is perfect -- it's already been evolved
 237 significantly over time, especially for 1.004 where we changed things to
 238 ensure it only fires on files in your checkout (rather than L<strictures>-using
 239 modules you happened to have installed, which was just silly). However, I
 240 hope the above clarifies why a heuristic approach is not only necessary but
 241 desirable from a point of view of providing new users with as much safety as possible,
 242 and will allow any future discussion on the subject to focus on "how do we
 243 minimise annoyance to people deploying from checkouts intentionally".
 244
 245 =head1 COMMUNITY AND SUPPORT
 246
 247 =head2 IRC channel
 248
 249 irc.perl.org #toolchain
 250
 251 (or bug 'mst' in query on there or freenode)
 252
 253 =head2 Git repository
 254
 255 Gitweb is on http://git.shadowcat.co.uk/ and the clone URL is:
 256
 257   git clone git://git.shadowcat.co.uk/p5sagit/strictures.git
 258
 259 The web interface to the repository is at:
 260
 261   http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=p5sagit/strictures.git
 262
 263 =head1 AUTHOR
 264
 265 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 266
 267 =head1 CONTRIBUTORS
 268
 269 None required yet. Maybe this module is perfect (hahahahaha ...).
 270
 271 =head1 COPYRIGHT
 272
 273 Copyright (c) 2010 the strictures L</AUTHOR> and L</CONTRIBUTORS>
 274 as listed above.
 275
 276 =head1 LICENSE
 277
 278 This library is free software and may be distributed under the same terms
 279 as perl itself.
 280
 281 =cut