lib/strictures.pm

   1 package strictures;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5
   6 BEGIN {
   7   *_PERL_LT_5_8_4 = ($] < 5.008004) ? sub(){1} : sub(){0};
   8   *_CAN_GOTO_VERSION = ($] >= 5.008000) ? sub(){1} : sub(){0};
   9 }
  10
  11 our $VERSION = '1.999_001';
  12 $VERSION = eval $VERSION;
  13 $VERSION = 2; # a bit of a cheat, but requesting v2 needs to be possible
  14
  15 our @WARNING_CATEGORIES = grep { exists $warnings::Offsets{$_} } qw(
  16   closure
  17   deprecated
  18   exiting
  19   experimental
  20     experimental::autoderef
  21     experimental::const_attr
  22     experimental::lexical_subs
  23     experimental::lexical_topic
  24     experimental::postderef
  25     experimental::re_strict
  26     experimental::refaliasing
  27     experimental::regex_sets
  28     experimental::signatures
  29     experimental::smartmatch
  30     experimental::win32_perlio
  31   glob
  32   imprecision
  33   io
  34     closed
  35     exec
  36     layer
  37     newline
  38     pipe
  39     syscalls
  40     unopened
  41   locale
  42   misc
  43   missing
  44   numeric
  45   once
  46   overflow
  47   pack
  48   portable
  49   recursion
  50   redefine
  51   redundant
  52   regexp
  53   severe
  54     debugging
  55     inplace
  56     internal
  57     malloc
  58   signal
  59   substr
  60   syntax
  61     ambiguous
  62     bareword
  63     digit
  64     illegalproto
  65     parenthesis
  66     precedence
  67     printf
  68     prototype
  69     qw
  70     reserved
  71     semicolon
  72   taint
  73   threads
  74   uninitialized
  75   unpack
  76   untie
  77   utf8
  78     non_unicode
  79     nonchar
  80     surrogate
  81   void
  82   void_unusual
  83   y2k
  84 );
  85
  86 sub VERSION {
  87   {
  88     no warnings;
  89     local $@;
  90     if (defined $_[1] && eval { &UNIVERSAL::VERSION; 1}) {
  91       $^H |= 0x20000
  92         unless _PERL_LT_5_8_4;
  93       $^H{strictures_enable} = int $_[1];
  94     }
  95   }
  96   _CAN_GOTO_VERSION ? goto &UNIVERSAL::VERSION : &UNIVERSAL::VERSION;
  97 }
  98
  99 our %extra_load_states;
 100
 101 our $Smells_Like_VCS;
 102
 103 sub import {
 104   my $class = shift;
 105   my %opts = ref $_[0] ? %{$_[0]} : @_;
 106   if (!exists $opts{version}) {
 107     $opts{version}
 108       = exists $^H{strictures_enable} ? delete $^H{strictures_enable}
 109       : int $VERSION;
 110   }
 111   $opts{file} = (caller)[1];
 112   $class->_enable(\%opts);
 113 }
 114
 115 sub _enable {
 116   my ($class, $opts) = @_;
 117   my $version = $opts->{version};
 118   $version = 'undef'
 119     if !defined $version;
 120   my $method = "_enable_$version";
 121   if (!$class->can($method)) {
 122     require Carp;
 123     Carp::croak("Major version specified as $version - not supported!");
 124   }
 125   $class->$method($opts);
 126 }
 127
 128 sub _enable_1 {
 129   my ($class, $opts) = @_;
 130   strict->import;
 131   warnings->import(FATAL => 'all');
 132
 133   if (_want_extra($opts->{file})) {
 134     _load_extras(qw(indirect multidimensional bareword::filehandles));
 135     indirect->unimport(':fatal')
 136       if $extra_load_states{indirect};
 137     multidimensional->unimport
 138       if $extra_load_states{multidimensional};
 139     bareword::filehandles->unimport
 140       if $extra_load_states{'bareword::filehandles'};
 141   }
 142 }
 143
 144 our @V2_NONFATAL = grep { exists $warnings::Offsets{$_} } (
 145   'exec',         # not safe to catch
 146   'recursion',    # will be caught by other mechanisms
 147   'internal',     # not safe to catch
 148   'malloc',       # not safe to catch
 149   'newline',      # stat on nonexistent file with a newline in it
 150   'experimental', # no reason for these to be fatal
 151   'deprecated',   # unfortunately can't make these fatal
 152   'portable',     # everything worked fine here, just may not elsewhere
 153 );
 154 our @V2_DISABLE = grep { exists $warnings::Offsets{$_} } (
 155   'once'          # triggers inconsistently, can't be fatalized
 156 );
 157
 158 sub _enable_2 {
 159   my ($class, $opts) = @_;
 160   strict->import;
 161   warnings->import;
 162   warnings->import(FATAL => @WARNING_CATEGORIES);
 163   warnings->unimport(FATAL => @V2_NONFATAL);
 164   warnings->import(@V2_NONFATAL);
 165   warnings->unimport(@V2_DISABLE);
 166
 167   if (_want_extra($opts->{file})) {
 168     _load_extras(qw(indirect multidimensional bareword::filehandles));
 169     indirect->unimport(':fatal')
 170       if $extra_load_states{indirect};
 171     multidimensional->unimport
 172       if $extra_load_states{multidimensional};
 173     bareword::filehandles->unimport
 174       if $extra_load_states{'bareword::filehandles'};
 175   }
 176 }
 177
 178 sub _want_extra_env {
 179   if (exists $ENV{PERL_STRICTURES_EXTRA}) {
 180     if (_PERL_LT_5_8_4 and $ENV{PERL_STRICTURES_EXTRA}) {
 181       die 'PERL_STRICTURES_EXTRA checks are not available on perls older'
 182         . "than 5.8.4: please unset \$ENV{PERL_STRICTURES_EXTRA}\n";
 183     }
 184     return $ENV{PERL_STRICTURES_EXTRA} ? 1 : 0;
 185   }
 186   return undef;
 187 }
 188
 189 sub _want_extra {
 190   my $file = shift;
 191   my $want_env = _want_extra_env();
 192   return $want_env
 193     if defined $want_env;
 194   return (
 195     !_PERL_LT_5_8_4
 196     and $file =~ /^(?:t|xt|lib|blib)[\\\/]/
 197     and defined $Smells_Like_VCS ? $Smells_Like_VCS
 198       : ( $Smells_Like_VCS = !!(
 199         -e '.git' || -e '.svn' || -e '.hg'
 200         || (-e '../../dist.ini'
 201           && (-e '../../.git' || -e '../../.svn' || -e '../../.hg' ))
 202       ))
 203   );
 204 }
 205
 206 sub _load_extras {
 207   my @extras = @_;
 208   my @failed;
 209   foreach my $mod (@extras) {
 210     next
 211       if exists $extra_load_states{$mod};
 212
 213     $extra_load_states{$mod} = eval "require $mod; 1;" or do {
 214       push @failed, $mod;
 215
 216       #work around 5.8 require bug
 217       (my $file = $mod) =~ s|::|/|g;
 218       delete $INC{"${file}.pm"};
 219     };
 220   }
 221
 222   if (@failed) {
 223     my $failed = join ' ', @failed;
 224     my $extras = join ' ', @extras;
 225     print STDERR <<EOE;
 226 strictures.pm extra testing active but couldn't load all modules. Missing were:
 227
 228   $failed
 229
 230 Extra testing is auto-enabled in checkouts only, so if you're the author
 231 of a strictures-using module you need to run:
 232
 233   cpan $extras
 234
 235 but these modules are not required by your users.
 236 EOE
 237   }
 238 }
 239
 240 1;
 241
 242 __END__
 243 =head1 NAME
 244
 245 strictures - turn on strict and make all warnings fatal
 246
 247 =head1 SYNOPSIS
 248
 249   use strictures 2;
 250
 251 is equivalent to
 252
 253   use strict;
 254   use warnings FATAL => 'all';
 255   use warnings NONFATAL => qw(
 256     exec
 257     recursion
 258     internal
 259     malloc
 260     newline
 261     experimental
 262     deprecated
 263     portable
 264   );
 265   no warnings 'once';
 266
 267 except when called from a file which matches:
 268
 269   (caller)[1] =~ /^(?:t|xt|lib|blib)[\\\/]/
 270
 271 and when either C<.git>, C<.svn>, or C<.hg> is present in the current directory
 272 (with the intention of only forcing extra tests on the author side) -- or when
 273 C<.git>, C<.svn>, or C<.hg> is present two directories up along with
 274 C<dist.ini> (which would indicate we are in a C<dzil test> operation, via
 275 L<Dist::Zilla>) -- or when the C<PERL_STRICTURES_EXTRA> environment variable is
 276 set, in which case it also does the equivalent of
 277
 278   no indirect 'fatal';
 279   no multidimensional;
 280   no bareword::filehandles;
 281
 282 Note that C<PERL_STRICTURES_EXTRA> may at some point add even more tests, with
 283 only a minor version increase, but any changes to the effect of C<use
 284 strictures> in normal mode will involve a major version bump.
 285
 286 If any of the extra testing modules are not present, L<strictures> will
 287 complain loudly, once, via C<warn()>, and then shut up. But you really
 288 should consider installing them, they're all great anti-footgun tools.
 289
 290 =head1 DESCRIPTION
 291
 292 I've been writing the equivalent of this module at the top of my code for
 293 about a year now. I figured it was time to make it shorter.
 294
 295 Things like the importer in C<use Moose> don't help me because they turn
 296 warnings on but don't make them fatal -- which from my point of view is
 297 useless because I want an exception to tell me my code isn't warnings-clean.
 298
 299 Any time I see a warning from my code, that indicates a mistake.
 300
 301 Any time my code encounters a mistake, I want a crash -- not spew to STDERR
 302 and then unknown (and probably undesired) subsequent behaviour.
 303
 304 I also want to ensure that obvious coding mistakes, like indirect object
 305 syntax (and not so obvious mistakes that cause things to accidentally compile
 306 as such) get caught, but not at the cost of an XS dependency and not at the
 307 cost of blowing things up on another machine.
 308
 309 Therefore, L<strictures> turns on additional checking, but only when it thinks
 310 it's running in a test file in a VCS checkout -- although if this causes
 311 undesired behaviour this can be overridden by setting the
 312 C<PERL_STRICTURES_EXTRA> environment variable.
 313
 314 If additional useful author side checks come to mind, I'll add them to the
 315 C<PERL_STRICTURES_EXTRA> code path only -- this will result in a minor version
 316 increase (e.g. 1.000000 to 1.001000 (1.1.0) or similar). Any fixes only to the
 317 mechanism of this code will result in a sub-version increase (e.g. 1.000000 to
 318 1.000001 (1.0.1)).
 319
 320 =head1 CATEGORY SELECTIONS
 321
 322 strictures does not enable fatal warnings for all categories.
 323
 324 =over 4
 325
 326 =item exec
 327
 328 Includes a warning that can cause your program to continue running
 329 unintentionally after an internal fork.  Not safe to fatalize.
 330
 331 =item recursion
 332
 333 Infinite recursion will end up overflowing the stack eventually anyway.
 334
 335 =item internal
 336
 337 Triggers deep within perl, in places that are not safe to trap.
 338
 339 =item malloc
 340
 341 Triggers deep within perl, in places that are not safe to trap.
 342
 343 =item newline
 344
 345 Includes a warning for using stat on a valid but suspect filename, ending in a
 346 newline.
 347
 348 =item experimental
 349
 350 Experimental features are used intentionally.
 351
 352 =item deprecated
 353
 354 Deprecations will inherently be added to in the future in unexpected ways,
 355 so making them fatal won't be reliable.
 356
 357 =item portable
 358
 359 Doesn't indicate an actual problem with the program, only that it may not
 360 behave properly if run on a different machine.
 361
 362 =item once
 363
 364 Can't be fatalized.  Also triggers very inconsistently, so we just disable it.
 365
 366 =back
 367
 368 =head1 VERSIONS
 369
 370 Depending on the version of strictures requested, different warnings will be
 371 enabled.  If no specific version is requested, the current version's behavior
 372 will be used.  Versions can be requested using perl's standard mechanism:
 373
 374   use strictures 2;
 375
 376 Or, by passing in a C<version> option:
 377
 378   use strictures version => 2;
 379
 380 =head2 VERSION 2
 381
 382 Equivalent to:
 383
 384   use strict;
 385   use warnings FATAL => 'all';
 386   use warnings NONFATAL => qw(
 387     exec
 388     recursion
 389     internal
 390     malloc
 391     newline
 392     experimental
 393     deprecated
 394     portable
 395   );
 396   no warnings 'once';
 397
 398   # and if in dev mode:
 399   no indirect 'fatal';
 400   no multidimensional;
 401   no bareword::filehandles;
 402
 403 Additionally, any warnings created by modules using L<warnings::register> or
 404 C<warnings::register_categories()> will not be fatalized.
 405
 406 =head2 VERSION 1
 407
 408 Equivalent to:
 409
 410   use strict;
 411   use warnings FATAL => 'all';
 412   # and if in dev mode:
 413   no indirect 'fatal';
 414   no multidimensional;
 415   no bareword::filehandles;
 416
 417 =head1 METHODS
 418
 419 =head2 import
 420
 421 This method does the setup work described above in L</DESCRIPTION>.  Optionally
 422 accepts a C<version> option to request a specific version's behavior.
 423
 424 =head2 VERSION
 425
 426 This method traps the C<< strictures->VERSION(1) >> call produced by a use line
 427 with a version number on it and does the version check.
 428
 429 =head1 EXTRA TESTING RATIONALE
 430
 431 Every so often, somebody complains that they're deploying via C<git pull>
 432 and that they don't want L<strictures> to enable itself in this case -- and that
 433 setting C<PERL_STRICTURES_EXTRA> to 0 isn't acceptable (additional ways to
 434 disable extra testing would be welcome but the discussion never seems to get
 435 that far).
 436
 437 In order to allow us to skip a couple of stages and get straight to a
 438 productive conversation, here's my current rationale for turning the
 439 extra testing on via a heuristic:
 440
 441 The extra testing is all stuff that only ever blows up at compile time;
 442 this is intentional. So the oft-raised concern that it's different code being
 443 tested is only sort of the case -- none of the modules involved affect the
 444 final optree to my knowledge, so the author gets some additional compile
 445 time crashes which he/she then fixes, and the rest of the testing is
 446 completely valid for all environments.
 447
 448 The point of the extra testing -- especially C<no indirect> -- is to catch
 449 mistakes that newbie users won't even realise are mistakes without
 450 help. For example,
 451
 452   foo { ... };
 453
 454 where foo is an & prototyped sub that you forgot to import -- this is
 455 pernicious to track down since all I<seems> fine until it gets called
 456 and you get a crash. Worse still, you can fail to have imported it due
 457 to a circular require, at which point you have a load order dependent
 458 bug which I've seen before now I<only> show up in production due to tiny
 459 differences between the production and the development environment. I wrote
 460 L<http://shadow.cat/blog/matt-s-trout/indirect-but-still-fatal/> to explain
 461 this particular problem before L<strictures> itself existed.
 462
 463 As such, in my experience so far L<strictures>' extra testing has
 464 I<avoided> production versus development differences, not caused them.
 465
 466 Additionally, L<strictures>' policy is very much "try and provide as much
 467 protection as possible for newbies -- who won't think about whether there's
 468 an option to turn on or not" -- so having only the environment variable
 469 is not sufficient to achieve that (I get to explain that you need to add
 470 C<use strict> at least once a week on freenode #perl -- newbies sometimes
 471 completely skip steps because they don't understand that that step
 472 is important).
 473
 474 I make no claims that the heuristic is perfect -- it's already been evolved
 475 significantly over time, especially for 1.004 where we changed things to
 476 ensure it only fires on files in your checkout (rather than L<strictures>-using
 477 modules you happened to have installed, which was just silly). However, I
 478 hope the above clarifies why a heuristic approach is not only necessary but
 479 desirable from a point of view of providing new users with as much safety as
 480 possible, and will allow any future discussion on the subject to focus on "how
 481 do we minimise annoyance to people deploying from checkouts intentionally".
 482
 483 =head1 SEE ALSO
 484
 485 =over 4
 486
 487 =item *
 488
 489 L<indirect>
 490
 491 =item *
 492
 493 L<multidimensional>
 494
 495 =item *
 496
 497 L<bareword::filehandles>
 498
 499 =back
 500
 501 =head1 COMMUNITY AND SUPPORT
 502
 503 =head2 IRC channel
 504
 505 irc.perl.org #toolchain
 506
 507 (or bug 'mst' in query on there or freenode)
 508
 509 =head2 Git repository
 510
 511 Gitweb is on http://git.shadowcat.co.uk/ and the clone URL is:
 512
 513   git clone git://git.shadowcat.co.uk/p5sagit/strictures.git
 514
 515 The web interface to the repository is at:
 516
 517   http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=p5sagit/strictures.git
 518
 519 =head1 AUTHOR
 520
 521 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 522
 523 =head1 CONTRIBUTORS
 524
 525 Karen Etheridge (cpan:ETHER) <ether@cpan.org>
 526
 527 Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@gmail.com>
 528
 529 haarg - Graham Knop (cpan:HAARG) <haarg@haarg.org>
 530
 531 =head1 COPYRIGHT
 532
 533 Copyright (c) 2010 the strictures L</AUTHOR> and L</CONTRIBUTORS>
 534 as listed above.
 535
 536 =head1 LICENSE
 537
 538 This library is free software and may be distributed under the same terms
 539 as perl itself.
 540
 541 =cut