lib/strictures.pm

   1 package strictures;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5
   6 BEGIN {
   7   *_PERL_LT_5_8_4 = ($] < 5.008004) ? sub(){1} : sub(){0};
   8 }
   9
  10 our $VERSION = '1.005005';
  11 $VERSION = eval $VERSION;
  12
  13 sub VERSION {
  14   my ($class, $version) = @_;
  15   for ($version) {
  16     last unless defined && !ref && int != 1;
  17     die "Major version specified as $_ - this is strictures version 1";
  18   }
  19   # passing undef here may either warn or die depending on the version of perl.
  20   # we can't match the caller's warning state in this case, so just disable the
  21   # warning.
  22   no warnings 'uninitialized';
  23   shift->SUPER::VERSION(@_);
  24 }
  25
  26 our $extra_load_states;
  27
  28 our $Smells_Like_VCS;
  29
  30 sub import {
  31   strict->import;
  32   warnings->import(FATAL => 'all');
  33
  34   my $extra_tests = do {
  35     if (exists $ENV{PERL_STRICTURES_EXTRA}) {
  36       if (_PERL_LT_5_8_4 and $ENV{PERL_STRICTURES_EXTRA}) {
  37         die 'PERL_STRICTURES_EXTRA checks are not available on perls older than 5.8.4: '
  38           . "please unset \$ENV{PERL_STRICTURES_EXTRA}\n";
  39       }
  40       $ENV{PERL_STRICTURES_EXTRA};
  41     } elsif (! _PERL_LT_5_8_4) {
  42       (caller)[1] =~ /^(?:t|xt|lib|blib)[\\\/]/
  43         and defined $Smells_Like_VCS ? $Smells_Like_VCS
  44           : ( $Smells_Like_VCS = !!(
  45             -e '.git' || -e '.svn' || -e '.hg'
  46             || (-e '../../dist.ini'
  47               && (-e '../../.git' || -e '../../.svn' || -e '../../.hg' ))
  48           ))
  49     }
  50   };
  51   if ($extra_tests) {
  52     $extra_load_states ||= do {
  53
  54       my (%rv, @failed);
  55       foreach my $mod (qw(indirect multidimensional bareword::filehandles)) {
  56         eval "require $mod; \$rv{'$mod'} = 1;" or do {
  57           push @failed, $mod;
  58
  59           # courtesy of the 5.8 require bug
  60           # (we do a copy because 5.16.2 at least uses the same read-only
  61           # scalars for the qw() list and it doesn't seem worth a $^V check)
  62
  63           (my $file = $mod) =~ s|::|/|g;
  64           delete $INC{"${file}.pm"};
  65         };
  66       }
  67
  68       if (@failed) {
  69         my $failed = join ' ', @failed;
  70         print STDERR <<EOE;
  71 strictures.pm extra testing active but couldn't load all modules. Missing were:
  72
  73   $failed
  74
  75 Extra testing is auto-enabled in checkouts only, so if you're the author
  76 of a strictures-using module you need to run:
  77
  78   cpan indirect multidimensional bareword::filehandles
  79
  80 but these modules are not required by your users.
  81 EOE
  82       }
  83
  84       \%rv;
  85     };
  86
  87     indirect->unimport(':fatal') if $extra_load_states->{indirect};
  88     multidimensional->unimport if $extra_load_states->{multidimensional};
  89     bareword::filehandles->unimport if $extra_load_states->{'bareword::filehandles'};
  90   }
  91 }
  92
  93 1;
  94
  95 __END__
  96 =head1 NAME
  97
  98 strictures - turn on strict and make all warnings fatal
  99
 100 =head1 SYNOPSIS
 101
 102   use strictures 1;
 103
 104 is equivalent to
 105
 106   use strict;
 107   use warnings FATAL => 'all';
 108
 109 except when called from a file which matches:
 110
 111   (caller)[1] =~ /^(?:t|xt|lib|blib)[\\\/]/
 112
 113 and when either C<.git>, C<.svn>, or C<.hg> is present in the current directory (with
 114 the intention of only forcing extra tests on the author side) -- or when C<.git>,
 115 C<.svn>, or C<.hg> is present two directories up along with C<dist.ini> (which would
 116 indicate we are in a C<dzil test> operation, via L<Dist::Zilla>) --
 117 or when the C<PERL_STRICTURES_EXTRA> environment variable is set, in which case
 118
 119   use strictures 1;
 120
 121 is equivalent to
 122
 123   use strict;
 124   use warnings FATAL => 'all';
 125   no indirect 'fatal';
 126   no multidimensional;
 127   no bareword::filehandles;
 128
 129 Note that C<PERL_STRICTURES_EXTRA> may at some point add even more tests, with only a minor
 130 version increase, but any changes to the effect of C<use strictures> in
 131 normal mode will involve a major version bump.
 132
 133 If any of the extra testing modules are not present, L<strictures> will
 134 complain loudly, once, via C<warn()>, and then shut up. But you really
 135 should consider installing them, they're all great anti-footgun tools.
 136
 137 =head1 DESCRIPTION
 138
 139 I've been writing the equivalent of this module at the top of my code for
 140 about a year now. I figured it was time to make it shorter.
 141
 142 Things like the importer in C<use Moose> don't help me because they turn
 143 warnings on but don't make them fatal -- which from my point of view is
 144 useless because I want an exception to tell me my code isn't warnings-clean.
 145
 146 Any time I see a warning from my code, that indicates a mistake.
 147
 148 Any time my code encounters a mistake, I want a crash -- not spew to STDERR
 149 and then unknown (and probably undesired) subsequent behaviour.
 150
 151 I also want to ensure that obvious coding mistakes, like indirect object
 152 syntax (and not so obvious mistakes that cause things to accidentally compile
 153 as such) get caught, but not at the cost of an XS dependency and not at the
 154 cost of blowing things up on another machine.
 155
 156 Therefore, L<strictures> turns on additional checking, but only when it thinks
 157 it's running in a test file in a VCS checkout -- although if this causes
 158 undesired behaviour this can be overridden by setting the
 159 C<PERL_STRICTURES_EXTRA> environment variable.
 160
 161 If additional useful author side checks come to mind, I'll add them to the
 162 C<PERL_STRICTURES_EXTRA> code path only -- this will result in a minor version increase (e.g.
 163 1.000000 to 1.001000 (1.1.0) or similar). Any fixes only to the mechanism of
 164 this code will result in a sub-version increase (e.g. 1.000000 to 1.000001
 165 (1.0.1)).
 166
 167 If the behaviour of C<use strictures> in normal mode changes in any way, that
 168 will constitute a major version increase -- and the code already checks
 169 when its version is tested to ensure that
 170
 171   use strictures 1;
 172
 173 will continue to only introduce the current set of strictures even if 2.0 is
 174 installed.
 175
 176 =head1 METHODS
 177
 178 =head2 import
 179
 180 This method does the setup work described above in L</DESCRIPTION>
 181
 182 =head2 VERSION
 183
 184 This method traps the C<< strictures->VERSION(1) >> call produced by a use line
 185 with a version number on it and does the version check.
 186
 187 =head1 EXTRA TESTING RATIONALE
 188
 189 Every so often, somebody complains that they're deploying via C<git pull>
 190 and that they don't want L<strictures> to enable itself in this case -- and that
 191 setting C<PERL_STRICTURES_EXTRA> to 0 isn't acceptable (additional ways to
 192 disable extra testing would be welcome but the discussion never seems to get
 193 that far).
 194
 195 In order to allow us to skip a couple of stages and get straight to a
 196 productive conversation, here's my current rationale for turning the
 197 extra testing on via a heuristic:
 198
 199 The extra testing is all stuff that only ever blows up at compile time;
 200 this is intentional. So the oft-raised concern that it's different code being
 201 tested is only sort of the case -- none of the modules involved affect the
 202 final optree to my knowledge, so the author gets some additional compile
 203 time crashes which he/she then fixes, and the rest of the testing is
 204 completely valid for all environments.
 205
 206 The point of the extra testing -- especially C<no indirect> -- is to catch
 207 mistakes that newbie users won't even realise are mistakes without
 208 help. For example,
 209
 210   foo { ... };
 211
 212 where foo is an & prototyped sub that you forgot to import -- this is
 213 pernicious to track down since all I<seems> fine until it gets called
 214 and you get a crash. Worse still, you can fail to have imported it due
 215 to a circular require, at which point you have a load order dependent
 216 bug which I've seen before now I<only> show up in production due to tiny
 217 differences between the production and the development environment. I wrote
 218 L<http://shadow.cat/blog/matt-s-trout/indirect-but-still-fatal/> to explain
 219 this particular problem before L<strictures> itself existed.
 220
 221 As such, in my experience so far L<strictures>' extra testing has
 222 I<avoided> production versus development differences, not caused them.
 223
 224 Additionally, L<strictures>' policy is very much "try and provide as much
 225 protection as possible for newbies -- who won't think about whether there's
 226 an option to turn on or not" -- so having only the environment variable
 227 is not sufficient to achieve that (I get to explain that you need to add
 228 C<use strict> at least once a week on freenode #perl -- newbies sometimes
 229 completely skip steps because they don't understand that that step
 230 is important).
 231
 232 I make no claims that the heuristic is perfect -- it's already been evolved
 233 significantly over time, especially for 1.004 where we changed things to
 234 ensure it only fires on files in your checkout (rather than L<strictures>-using
 235 modules you happened to have installed, which was just silly). However, I
 236 hope the above clarifies why a heuristic approach is not only necessary but
 237 desirable from a point of view of providing new users with as much safety as possible,
 238 and will allow any future discussion on the subject to focus on "how do we
 239 minimise annoyance to people deploying from checkouts intentionally".
 240
 241 =head1 SEE ALSO
 242
 243 =over 4
 244
 245 =item *
 246
 247 L<indirect>
 248
 249 =item *
 250
 251 L<multidimensional>
 252
 253 =item *
 254
 255 L<bareword::filehandles>
 256
 257 =back
 258
 259 =head1 COMMUNITY AND SUPPORT
 260
 261 =head2 IRC channel
 262
 263 irc.perl.org #toolchain
 264
 265 (or bug 'mst' in query on there or freenode)
 266
 267 =head2 Git repository
 268
 269 Gitweb is on http://git.shadowcat.co.uk/ and the clone URL is:
 270
 271   git clone git://git.shadowcat.co.uk/p5sagit/strictures.git
 272
 273 The web interface to the repository is at:
 274
 275   http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=p5sagit/strictures.git
 276
 277 =head1 AUTHOR
 278
 279 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 280
 281 =head1 CONTRIBUTORS
 282
 283 Karen Etheridge (cpan:ETHER) <ether@cpan.org>
 284
 285 Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@gmail.com>
 286
 287 haarg - Graham Knop (cpan:HAARG) <haarg@haarg.org>
 288
 289 =head1 COPYRIGHT
 290
 291 Copyright (c) 2010 the strictures L</AUTHOR> and L</CONTRIBUTORS>
 292 as listed above.
 293
 294 =head1 LICENSE
 295
 296 This library is free software and may be distributed under the same terms
 297 as perl itself.
 298
 299 =cut