lib/strictures.pm

   1 package strictures;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5
   6 BEGIN {
   7   *_PERL_LT_5_8_4 = ($] < 5.008004) ? sub(){1} : sub(){0};
   8 }
   9
  10 our $VERSION = '1.005006';
  11 $VERSION = eval $VERSION;
  12
  13 sub VERSION {
  14   no warnings;
  15   local $@;
  16   if (defined $_[1] && eval { $_[0]->UNIVERSAL::VERSION($_[1]); 1}) {
  17     $^H |= 0x20000
  18       unless _PERL_LT_5_8_4;
  19     $^H{strictures_enable} = int $_[1];
  20   }
  21   goto &UNIVERSAL::VERSION;
  22 }
  23
  24 our %extra_load_states;
  25
  26 our $Smells_Like_VCS;
  27
  28 sub import {
  29   my $class = shift;
  30   my %opts = ref $_[0] ? %{$_[0]} : @_;
  31   if (!exists $opts{version}) {
  32     $opts{version}
  33       = exists $^H{strictures_enable} ? delete $^H{strictures_enable}
  34       : int $VERSION;
  35   }
  36   $opts{file} = (caller)[1];
  37   $class->_enable(\%opts);
  38 }
  39
  40 sub _enable {
  41   my ($class, $opts) = @_;
  42   my $version = $opts->{version};
  43   $version = 'undef'
  44     if !defined $version;
  45   my $method = "_enable_$version";
  46   if (!$class->can($method)) {
  47     require Carp;
  48     Carp::croak("Major version specified as $version - not supported!");
  49   }
  50   $class->$method($opts);
  51 }
  52
  53 sub _enable_1 {
  54   my ($class, $opts) = @_;
  55   strict->import;
  56   warnings->import(FATAL => 'all');
  57
  58   if (_want_extra($opts->{file})) {
  59     _load_extras(qw(indirect multidimensional bareword::filehandles));
  60     indirect->unimport(':fatal')
  61       if $extra_load_states{indirect};
  62     multidimensional->unimport
  63       if $extra_load_states{multidimensional};
  64     bareword::filehandles->unimport
  65       if $extra_load_states{'bareword::filehandles'};
  66   }
  67 }
  68
  69 sub _want_extra_env {
  70   if (exists $ENV{PERL_STRICTURES_EXTRA}) {
  71     if (_PERL_LT_5_8_4 and $ENV{PERL_STRICTURES_EXTRA}) {
  72       die 'PERL_STRICTURES_EXTRA checks are not available on perls older'
  73         . "than 5.8.4: please unset \$ENV{PERL_STRICTURES_EXTRA}\n";
  74     }
  75     return $ENV{PERL_STRICTURES_EXTRA} ? 1 : 0;
  76   }
  77   return undef;
  78 }
  79
  80 sub _want_extra {
  81   my $file = shift;
  82   my $want_env = _want_extra_env();
  83   return $want_env
  84     if defined $want_env;
  85   return (
  86     !_PERL_LT_5_8_4
  87     and $file =~ /^(?:t|xt|lib|blib)[\\\/]/
  88     and defined $Smells_Like_VCS ? $Smells_Like_VCS
  89       : ( $Smells_Like_VCS = !!(
  90         -e '.git' || -e '.svn' || -e '.hg'
  91         || (-e '../../dist.ini'
  92           && (-e '../../.git' || -e '../../.svn' || -e '../../.hg' ))
  93       ))
  94   );
  95 }
  96
  97 sub _load_extras {
  98   my @extras = @_;
  99   my @failed;
 100   foreach my $mod (@extras) {
 101     next
 102       if exists $extra_load_states{$mod};
 103
 104     $extra_load_states{$mod} = eval "require $mod; 1;" or do {
 105       push @failed, $mod;
 106
 107       #work around 5.8 require bug
 108       (my $file = $mod) =~ s|::|/|g;
 109       delete $INC{"${file}.pm"};
 110     };
 111   }
 112
 113   if (@failed) {
 114     my $failed = join ' ', @failed;
 115     my $extras = join ' ', @extras;
 116     print STDERR <<EOE;
 117 strictures.pm extra testing active but couldn't load all modules. Missing were:
 118
 119   $failed
 120
 121 Extra testing is auto-enabled in checkouts only, so if you're the author
 122 of a strictures-using module you need to run:
 123
 124   cpan $extras
 125
 126 but these modules are not required by your users.
 127 EOE
 128   }
 129 }
 130
 131 1;
 132
 133 __END__
 134 =head1 NAME
 135
 136 strictures - turn on strict and make all warnings fatal
 137
 138 =head1 SYNOPSIS
 139
 140   use strictures 1;
 141
 142 is equivalent to
 143
 144   use strict;
 145   use warnings FATAL => 'all';
 146
 147 except when called from a file which matches:
 148
 149   (caller)[1] =~ /^(?:t|xt|lib|blib)[\\\/]/
 150
 151 and when either C<.git>, C<.svn>, or C<.hg> is present in the current directory
 152 (with the intention of only forcing extra tests on the author side) -- or when
 153 C<.git>, C<.svn>, or C<.hg> is present two directories up along with
 154 C<dist.ini> (which would indicate we are in a C<dzil test> operation, via
 155 L<Dist::Zilla>) -- or when the C<PERL_STRICTURES_EXTRA> environment variable is
 156 set, in which case
 157
 158   use strictures 1;
 159
 160 is equivalent to
 161
 162   use strict;
 163   use warnings FATAL => 'all';
 164   no indirect 'fatal';
 165   no multidimensional;
 166   no bareword::filehandles;
 167
 168 Note that C<PERL_STRICTURES_EXTRA> may at some point add even more tests, with
 169 only a minor version increase, but any changes to the effect of C<use
 170 strictures> in normal mode will involve a major version bump.
 171
 172 If any of the extra testing modules are not present, L<strictures> will
 173 complain loudly, once, via C<warn()>, and then shut up. But you really
 174 should consider installing them, they're all great anti-footgun tools.
 175
 176 =head1 DESCRIPTION
 177
 178 I've been writing the equivalent of this module at the top of my code for
 179 about a year now. I figured it was time to make it shorter.
 180
 181 Things like the importer in C<use Moose> don't help me because they turn
 182 warnings on but don't make them fatal -- which from my point of view is
 183 useless because I want an exception to tell me my code isn't warnings-clean.
 184
 185 Any time I see a warning from my code, that indicates a mistake.
 186
 187 Any time my code encounters a mistake, I want a crash -- not spew to STDERR
 188 and then unknown (and probably undesired) subsequent behaviour.
 189
 190 I also want to ensure that obvious coding mistakes, like indirect object
 191 syntax (and not so obvious mistakes that cause things to accidentally compile
 192 as such) get caught, but not at the cost of an XS dependency and not at the
 193 cost of blowing things up on another machine.
 194
 195 Therefore, L<strictures> turns on additional checking, but only when it thinks
 196 it's running in a test file in a VCS checkout -- although if this causes
 197 undesired behaviour this can be overridden by setting the
 198 C<PERL_STRICTURES_EXTRA> environment variable.
 199
 200 If additional useful author side checks come to mind, I'll add them to the
 201 C<PERL_STRICTURES_EXTRA> code path only -- this will result in a minor version
 202 increase (e.g. 1.000000 to 1.001000 (1.1.0) or similar). Any fixes only to the
 203 mechanism of this code will result in a sub-version increase (e.g. 1.000000 to
 204 1.000001 (1.0.1)).
 205
 206 If the behaviour of C<use strictures> in normal mode changes in any way, that
 207 will constitute a major version increase -- and the code already checks
 208 when its version is tested to ensure that
 209
 210   use strictures 1;
 211
 212 will continue to only introduce the current set of strictures even if 2.0 is
 213 installed.
 214
 215 =head1 METHODS
 216
 217 =head2 import
 218
 219 This method does the setup work described above in L</DESCRIPTION>
 220
 221 =head2 VERSION
 222
 223 This method traps the C<< strictures->VERSION(1) >> call produced by a use line
 224 with a version number on it and does the version check.
 225
 226 =head1 EXTRA TESTING RATIONALE
 227
 228 Every so often, somebody complains that they're deploying via C<git pull>
 229 and that they don't want L<strictures> to enable itself in this case -- and that
 230 setting C<PERL_STRICTURES_EXTRA> to 0 isn't acceptable (additional ways to
 231 disable extra testing would be welcome but the discussion never seems to get
 232 that far).
 233
 234 In order to allow us to skip a couple of stages and get straight to a
 235 productive conversation, here's my current rationale for turning the
 236 extra testing on via a heuristic:
 237
 238 The extra testing is all stuff that only ever blows up at compile time;
 239 this is intentional. So the oft-raised concern that it's different code being
 240 tested is only sort of the case -- none of the modules involved affect the
 241 final optree to my knowledge, so the author gets some additional compile
 242 time crashes which he/she then fixes, and the rest of the testing is
 243 completely valid for all environments.
 244
 245 The point of the extra testing -- especially C<no indirect> -- is to catch
 246 mistakes that newbie users won't even realise are mistakes without
 247 help. For example,
 248
 249   foo { ... };
 250
 251 where foo is an & prototyped sub that you forgot to import -- this is
 252 pernicious to track down since all I<seems> fine until it gets called
 253 and you get a crash. Worse still, you can fail to have imported it due
 254 to a circular require, at which point you have a load order dependent
 255 bug which I've seen before now I<only> show up in production due to tiny
 256 differences between the production and the development environment. I wrote
 257 L<http://shadow.cat/blog/matt-s-trout/indirect-but-still-fatal/> to explain
 258 this particular problem before L<strictures> itself existed.
 259
 260 As such, in my experience so far L<strictures>' extra testing has
 261 I<avoided> production versus development differences, not caused them.
 262
 263 Additionally, L<strictures>' policy is very much "try and provide as much
 264 protection as possible for newbies -- who won't think about whether there's
 265 an option to turn on or not" -- so having only the environment variable
 266 is not sufficient to achieve that (I get to explain that you need to add
 267 C<use strict> at least once a week on freenode #perl -- newbies sometimes
 268 completely skip steps because they don't understand that that step
 269 is important).
 270
 271 I make no claims that the heuristic is perfect -- it's already been evolved
 272 significantly over time, especially for 1.004 where we changed things to
 273 ensure it only fires on files in your checkout (rather than L<strictures>-using
 274 modules you happened to have installed, which was just silly). However, I
 275 hope the above clarifies why a heuristic approach is not only necessary but
 276 desirable from a point of view of providing new users with as much safety as
 277 possible, and will allow any future discussion on the subject to focus on "how
 278 do we minimise annoyance to people deploying from checkouts intentionally".
 279
 280 =head1 SEE ALSO
 281
 282 =over 4
 283
 284 =item *
 285
 286 L<indirect>
 287
 288 =item *
 289
 290 L<multidimensional>
 291
 292 =item *
 293
 294 L<bareword::filehandles>
 295
 296 =back
 297
 298 =head1 COMMUNITY AND SUPPORT
 299
 300 =head2 IRC channel
 301
 302 irc.perl.org #toolchain
 303
 304 (or bug 'mst' in query on there or freenode)
 305
 306 =head2 Git repository
 307
 308 Gitweb is on http://git.shadowcat.co.uk/ and the clone URL is:
 309
 310   git clone git://git.shadowcat.co.uk/p5sagit/strictures.git
 311
 312 The web interface to the repository is at:
 313
 314   http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=p5sagit/strictures.git
 315
 316 =head1 AUTHOR
 317
 318 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 319
 320 =head1 CONTRIBUTORS
 321
 322 Karen Etheridge (cpan:ETHER) <ether@cpan.org>
 323
 324 Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@gmail.com>
 325
 326 haarg - Graham Knop (cpan:HAARG) <haarg@haarg.org>
 327
 328 =head1 COPYRIGHT
 329
 330 Copyright (c) 2010 the strictures L</AUTHOR> and L</CONTRIBUTORS>
 331 as listed above.
 332
 333 =head1 LICENSE
 334
 335 This library is free software and may be distributed under the same terms
 336 as perl itself.
 337
 338 =cut