lib/Import/Into.pm

   1 package Import::Into;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5 use Module::Runtime;
   6
   7 our $VERSION = '1.002002';
   8
   9 sub _prelude {
  10   my $target = shift;
  11   my ($package, $file, $line, $level)
  12     = ref $target         ? @{$target}{qw(package filename line)}
  13     : $target =~ /[^0-9]/ ? ($target)
  14                           : (undef, undef, undef, $target);
  15   if (defined $level) {
  16     my ($p, $fn, $ln) = caller($level + 2);
  17     $package ||= $p;
  18     $file    ||= $fn;
  19     $line    ||= $ln;
  20   }
  21   qq{package $package;\n}
  22     . ($file ? "#line $line \"$file\"\n" : '')
  23 }
  24
  25 sub _make_action {
  26   my ($action, $target) = @_;
  27   my $version = ref $target && $target->{version};
  28   my $ver_check = $version ? ', $version' : '';
  29   eval _prelude($target)
  30     . qq{sub { Module::Runtime::use_module( shift$ver_check )->$action(\@_) }}
  31     or die "Failed to build action sub to ${action} for ${target}: $@";
  32 }
  33
  34 sub import::into {
  35   my ($class, $target, @args) = @_;
  36   _make_action(import => $target)->($class, @args);
  37 }
  38
  39 sub unimport::out_of {
  40   my ($class, $target, @args) = @_;
  41   _make_action(unimport => $target)->($class, @args);
  42 }
  43
  44 1;
  45
  46 __END__
  47
  48 =head1 NAME
  49
  50 Import::Into - Import packages into other packages
  51
  52 =head1 SYNOPSIS
  53
  54   package My::MultiExporter;
  55
  56   use Import::Into;
  57
  58   # simple
  59   sub import {
  60     Thing1->import::into(scalar caller);
  61   }
  62
  63   # multiple
  64   sub import {
  65     my $target = caller;
  66     Thing1->import::into($target);
  67     Thing2->import::into($target, qw(import arguments));
  68   }
  69
  70   # by level
  71   sub import {
  72     Thing1->import::into(1);
  73   }
  74
  75   # with exporter
  76   use base qw(Exporter);
  77   sub import {
  78     shift->export_to_level(1);
  79     Thing1->import::into(1);
  80   }
  81
  82   # no My::MultiExporter == no Thing1
  83   sub unimport {
  84     Thing1->unimport::out_of(scalar caller);
  85   }
  86
  87 People wanting to re-export your module should also be using L<Import::Into>.
  88 Any exporter or pragma will work seamlessly.
  89
  90 Note: You do B<not> need to make any changes to Thing1 to be able to call
  91 C<import::into> on it. This is a global method, and is callable on any
  92 package (and in fact on any object as well, although it's rarer that you'd
  93 want to do that).
  94
  95 =head1 DESCRIPTION
  96
  97 Writing exporters is a pain. Some use L<Exporter>, some use L<Sub::Exporter>,
  98 some use L<Moose::Exporter>, some use L<Exporter::Declare> ... and some things
  99 are pragmas.
 100
 101 Exporting on someone else's behalf is harder.  The exporters don't provide a
 102 consistent API for this, and pragmas need to have their import method called
 103 directly, since they effect the current unit of compilation.
 104
 105 C<Import::Into> provides global methods to make this painless.
 106
 107 =head1 METHODS
 108
 109 =head2 $package->import::into( $target, @arguments );
 110
 111 A global method, callable on any package.  Loads and imports the given package
 112 into C<$target>.  C<@arguments> are passed along to the package's import method.
 113
 114 C<$target> can be an package name to export to, an integer for the
 115 caller level to export to, or a hashref with the following options:
 116
 117 =over 4
 118
 119 =item package
 120
 121 The target package to export to.
 122
 123 =item filename
 124
 125 The apparent filename to export to.  Some exporting modules, such as
 126 L<autodie> or L<strictures>, care about the filename they are being imported
 127 to.
 128
 129 =item line
 130
 131 The apparent line number to export to.  To be combined with the C<filename>
 132 option.
 133
 134 =item level
 135
 136 The caller level to export to.  This will automatically populate the
 137 C<package>, C<filename>, and C<line> options, making it the easiest most
 138 constent option.
 139
 140 =item version
 141
 142 A version number to check for the module.  The equivalent of specifying the
 143 version number on a C<use> line.
 144
 145 =back
 146
 147 =head2 $package->unimport::out_of( $target, @arguments );
 148
 149 Equivalent to C<import::into>, but dispatches to C<$package>'s C<unimport>
 150 method instead of C<import>.
 151
 152 =head1 WHY USE THIS MODULE
 153
 154 The APIs for exporting modules aren't consistent.  L<Exporter> subclasses
 155 provide export_to_level, but if they overrode their import method all bets
 156 are off.  L<Sub::Exporter> provides an into parameter but figuring out
 157 something used it isn't trivial. Pragmas need to have their C<import> method
 158 called directly since they affect the current unit of compilation.
 159
 160 It's ... annoying.
 161
 162 However, there is an approach that actually works for all of these types.
 163
 164   eval "package $target; use $thing;"
 165
 166 will work for anything checking caller, which is everything except pragmas.
 167 But it doesn't work for pragmas - pragmas need:
 168
 169   $thing->import;
 170
 171 because they're designed to affect the code currently being compiled - so
 172 within an eval, that's the scope of the eval itself, not the module that
 173 just C<use>d you - so
 174
 175   sub import {
 176     eval "use strict;"
 177   }
 178
 179 doesn't do what you wanted, but
 180
 181   sub import {
 182     strict->import;
 183   }
 184
 185 will apply L<strict> to the calling file correctly.
 186
 187 Of course, now you have two new problems - first, that you still need to
 188 know if something's a pragma, and second that you can't use either of
 189 these approaches alone on something like L<Moose> or L<Moo> that's both
 190 an exporter and a pragma.
 191
 192 So, a solution for that is:
 193
 194   use Module::Runtime;
 195   my $sub = eval "package $target; sub { use_module(shift)->import(\@_) }";
 196   $sub->($thing, @import_args);
 197
 198 which means that import is called from the right place for pragmas to take
 199 effect, and from the right package for caller checking to work - and so
 200 behaves correctly for all types of exporter, for pragmas, and for hybrids.
 201
 202 Additionally, some import routines check the filename they are being imported
 203 to.  This can be dealt with by generating a L<#line directive|perlsyn/Plain
 204 Old Comments (Not!)> in the eval, which will change what C<caller> reports for
 205 the filename when called in the importer. The filename and line number to use
 206 in the directive then need to be fetched using C<caller>:
 207
 208   my ($target, $file, $line) = caller(1);
 209   my $sub = eval qq{
 210     package $target;
 211   #line $line "$file"
 212     sub { use_module(shift)->import(\@_) }
 213   };
 214   $sub->($thing, @import_args);
 215
 216 And you need to switch between these implementations depending on if you are
 217 targeting a specific package, or something in your call stack.
 218
 219 Remembering all this, however, is excessively irritating. So I wrote a module
 220 so I didn't have to anymore. Loading L<Import::Into> creates a global method
 221 C<import::into> which you can call on any package to import it into another
 222 package. So now you can simply write:
 223
 224   use Import::Into;
 225
 226   $thing->import::into($target, @import_args);
 227
 228 This works because of how perl resolves method calls - a call to a simple
 229 method name is resolved against the package of the class or object, so
 230
 231   $thing->method_name(@args);
 232
 233 is roughly equivalent to:
 234
 235   my $code_ref = $thing->can('method_name');
 236   $code_ref->($thing, @args);
 237
 238 while if a C<::> is found, the lookup is made relative to the package name
 239 (i.e. everything before the last C<::>) so
 240
 241   $thing->Package::Name::method_name(@args);
 242
 243 is roughly equivalent to:
 244
 245   my $code_ref = Package::Name->can('method_name');
 246   $code_ref->($thing, @args);
 247
 248 So since L<Import::Into> defines a method C<into> in package C<import>
 249 the syntax reliably calls that.
 250
 251 For more craziness of this order, have a look at the article I wrote at
 252 L<http://shadow.cat/blog/matt-s-trout/madness-with-methods> which covers
 253 coderef abuse and the C<${\...}> syntax.
 254
 255 And that's it.
 256
 257 =head1 SEE ALSO
 258
 259 I gave a lightning talk on this module (and L<curry> and L<Safe::Isa>) at
 260 L<YAPC::NA 2013|https://www.youtube.com/watch?v=wFXWV2yY7gE&t=46m05s>.
 261
 262 =head1 ACKNOWLEDGEMENTS
 263
 264 Thanks to Getty for asking "how can I get C<< use strict; use warnings; >>
 265 turned on for all consumers of my code?" and then "why is this not a
 266 module?!".
 267
 268 =head1 AUTHOR
 269
 270 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 271
 272 =head1 CONTRIBUTORS
 273
 274 haarg - Graham Knop (cpan:HAARG) <haarg@haarg.org>
 275
 276 Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@gmail.com>
 277
 278 =head1 COPYRIGHT
 279
 280 Copyright (c) 2012 the Import::Into L</AUTHOR> and L</CONTRIBUTORS>
 281 as listed above.
 282
 283 =head1 LICENSE
 284
 285 This library is free software and may be distributed under the same terms
 286 as perl itself.
 287
 288 =cut