SIGINT does not quit the REPL.
[p5sagit/Devel-REPL.git] / lib / Devel / REPL / Plugin / Interrupt.pm
index 1d79bd8..d7d7d76 100644 (file)
@@ -1,18 +1,67 @@
 package Devel::REPL::Plugin::Interrupt;
 
-use Moose::Role;
+use Devel::REPL::Plugin;
+use Sys::SigAction qw(set_sig_handler);
 use namespace::clean -except => [ 'meta' ];
 
-around 'eval' => sub {
-    my $orig = shift;
-    my ($self, $line) = @_;
+around 'run' => sub {
+    my ($orig, $self) = (shift, shift);
 
-    local $SIG{INT} = sub {
+    local $SIG{INT} = 'IGNORE';
+
+    return $self->$orig(@_);
+};
+
+around 'run_once' => sub {
+    my ($orig, $self) = (shift, shift);
+
+    # We have to use Sys::SigAction: Perl 5.8+ has safe signal handling by
+    # default, and Term::ReadLine::Gnu restarts the interrupted system calls.
+    # The result is that the signal handler is not fired until you hit Enter.
+    my $sig_action = set_sig_handler INT => sub {
         die "Interrupted.\n";
     };
 
-    return $self->$orig($line);
+    return $self->$orig(@_);
+};
+
+around 'read' => sub {
+    my ($orig, $self) = (shift, shift);
+
+    # here SIGINT is caught and only kills the line being edited
+    while (1) {
+        my $line = eval { $self->$orig(@_) };
+        return $line unless $@;
+
+        die unless $@ =~ /^Interrupted\./;
+
+        # (Term::ReadLine::Gnu kills the line by default, but needs a LF -
+        # maybe I missed something?)
+        print "\n";
+    }
 };
 
 1;
 
+__END__
+
+=head1 NAME
+
+Devel::REPL::Plugin::Interrupt - traps SIGINT to kill long-running lines
+
+=head1 DESCRIPTION
+
+By default L<Devel::REPL> exits on SIGINT (usually Ctrl-C). If you load this
+module, SIGINT will be trapped and used to kill long-running commands
+(statements) and also to kill the line being edited (like eg. BASH do). (You
+can still use Ctrl-D to exit.)
+
+=head1 AUTHOR
+
+Shawn M Moore, C<< <sartak at gmail dot com> >>
+
+=head1 CONTRIBUTORS
+
+Norbert Buchmuller C<< <norbi@nix.hu> >>
+
+=cut