lib/Devel/REPL/Script.pm

   1 package Devel::REPL::Script;
   2
   3 use Moose;
   4 use Devel::REPL;
   5 use File::HomeDir;
   6 use File::Spec;
   7 use vars qw($CURRENT_SCRIPT);
   8 use namespace::clean -except => [ qw(meta) ];
   9
  10 with 'MooseX::Getopt';
  11
  12 has 'rcfile' => (
  13   is => 'ro', isa => 'Str', required => 1, default => sub { 'repl.rc' },
  14 );
  15
  16 has 'profile' => (
  17   is => 'ro', isa => 'Str', required => 1, default => sub { 'Default' },
  18 );
  19
  20 has '_repl' => (
  21   is => 'ro', isa => 'Devel::REPL', required => 1,
  22   default => sub { Devel::REPL->new() }
  23 );
  24
  25 sub BUILD {
  26   my ($self) = @_;
  27   $self->load_profile($self->profile);
  28   $self->load_rcfile($self->rcfile);
  29 }
  30
  31 sub load_profile {
  32   my ($self, $profile) = @_;
  33   $profile = "Devel::REPL::Profile::${profile}" unless $profile =~ /::/;
  34   Class::MOP::load_class($profile);
  35   confess "Profile class ${profile} doesn't do 'Devel::REPL::Profile'"
  36     unless $profile->does('Devel::REPL::Profile');
  37   $profile->new->apply_profile($self->_repl);
  38 }
  39
  40 sub load_rcfile {
  41   my ($self, $rc_file) = @_;
  42
  43   # plain name => ~/.re.pl/${rc_file}
  44   if ($rc_file !~ m!/!) {
  45     $rc_file = File::Spec->catfile(File::HomeDir->my_home, '.re.pl', $rc_file);
  46   }
  47
  48   $self->apply_script($rc_file);
  49 }
  50
  51 sub apply_script {
  52   my ($self, $script, $warn_on_unreadable) = @_;
  53
  54   if (!-e $script) {
  55     warn "File '$script' does not exist" if $warn_on_unreadable;
  56     return;
  57   }
  58   elsif (!-r _) {
  59     warn "File '$script' is unreadable" if $warn_on_unreadable;
  60     return;
  61   }
  62
  63   open RCFILE, '<', $script or die "Couldn't open ${script}: $!";
  64   my $rc_data;
  65   { local $/; $rc_data = <RCFILE>; }
  66   close RCFILE; # Don't care if this fails
  67   $self->eval_script($rc_data);
  68   warn "Error executing script ${script}: $@\n" if $@;
  69 }
  70
  71 sub eval_script {
  72   my ($self, $data) = @_;
  73   local $CURRENT_SCRIPT = $self;
  74   $self->_repl->eval($data);
  75 }
  76
  77 sub run {
  78   my ($self) = @_;
  79   $self->_repl->run;
  80 }
  81
  82 sub import {
  83   my ($class, @opts) = @_;
  84   return unless (@opts == 1 && $opts[0] eq 'run');
  85   $class->new_with_options->run;
  86 }
  87
  88 sub current {
  89   confess "->current should only be called as class method" if ref($_[0]);
  90   confess "No current instance (valid only during rc parse)"
  91     unless $CURRENT_SCRIPT;
  92   return $CURRENT_SCRIPT;
  93 }
  94
  95 1;