lib/Devel/REPL/Script.pm

   1 package Devel::REPL::Script;
   2
   3 use Moose;
   4 use Devel::REPL;
   5 use File::HomeDir;
   6 use File::Spec;
   7 use vars qw($CURRENT_SCRIPT);
   8 use namespace::autoclean;
   9
  10 with 'MooseX::Getopt';
  11
  12 has 'rcfile' => (
  13   is => 'ro', isa => 'Str', required => 1, default => sub { 'repl.rc' },
  14 );
  15
  16 has 'profile' => (
  17   is       => 'ro',
  18   isa      => 'Str',
  19   required => 1,
  20   default  => sub { $ENV{DEVEL_REPL_PROFILE} || 'Default' },
  21 );
  22
  23 has '_repl' => (
  24   is => 'ro', isa => 'Devel::REPL', required => 1,
  25   default => sub { Devel::REPL->new() }
  26 );
  27
  28 sub BUILD {
  29   my ($self) = @_;
  30   $self->load_profile($self->profile);
  31   $self->load_rcfile($self->rcfile);
  32 }
  33
  34 sub load_profile {
  35   my ($self, $profile) = @_;
  36   $profile = "Devel::REPL::Profile::${profile}" unless $profile =~ /::/;
  37   Class::MOP::load_class($profile);
  38   confess "Profile class ${profile} doesn't do 'Devel::REPL::Profile'"
  39     unless $profile->does('Devel::REPL::Profile');
  40   $profile->new->apply_profile($self->_repl);
  41 }
  42
  43 sub load_rcfile {
  44   my ($self, $rc_file) = @_;
  45
  46   # plain name => ~/.re.pl/${rc_file}
  47   if ($rc_file !~ m!/!) {
  48     $rc_file = File::Spec->catfile(File::HomeDir->my_home, '.re.pl', $rc_file);
  49   }
  50
  51   $self->apply_script($rc_file);
  52 }
  53
  54 sub apply_script {
  55   my ($self, $script, $warn_on_unreadable) = @_;
  56
  57   if (!-e $script) {
  58     warn "File '$script' does not exist" if $warn_on_unreadable;
  59     return;
  60   }
  61   elsif (!-r _) {
  62     warn "File '$script' is unreadable" if $warn_on_unreadable;
  63     return;
  64   }
  65
  66   open RCFILE, '<', $script or die "Couldn't open ${script}: $!";
  67   my $rc_data;
  68   { local $/; $rc_data = <RCFILE>; }
  69   close RCFILE; # Don't care if this fails
  70   $self->eval_script($rc_data);
  71   warn "Error executing script ${script}: $@\n" if $@;
  72 }
  73
  74 sub eval_script {
  75   my ($self, $data) = @_;
  76   local $CURRENT_SCRIPT = $self;
  77   $self->_repl->eval($data);
  78 }
  79
  80 sub run {
  81   my ($self) = @_;
  82   $self->_repl->run;
  83 }
  84
  85 sub import {
  86   my ($class, @opts) = @_;
  87   return unless (@opts == 1 && $opts[0] eq 'run');
  88   $class->new_with_options->run;
  89 }
  90
  91 sub current {
  92   confess "->current should only be called as class method" if ref($_[0]);
  93   confess "No current instance (valid only during rc parse)"
  94     unless $CURRENT_SCRIPT;
  95   return $CURRENT_SCRIPT;
  96 }
  97
  98 1;