[p5sagit/Config-Any.git] / lib / Config / Any.pm

package Config::Any;

use strict;
use warnings;

use Carp;
use Module::Pluggable::Object ();

our $VERSION = '0.13';

=head1 NAME

Config::Any - Load configuration from different file formats, transparently

=head1 SYNOPSIS

    use Config::Any;

    my $cfg = Config::Any->load_stems({stems => \@filepath_stems, ... });
    # or
    my $cfg = Config::Any->load_files({files => \@filepaths, ... });

    for (@$cfg) {
        my ($filename, $config) = %$_;
        $class->config($config);
        warn "loaded config from file: $filename";
    }

=head1 DESCRIPTION

L<Config::Any|Config::Any> provides a facility for Perl applications and libraries
to load configuration data from multiple different file formats. It supports XML, YAML,
JSON, Apache-style configuration, Windows INI files, and even Perl code.

The rationale for this module is as follows: Perl programs are deployed on many different
platforms and integrated with many different systems. Systems administrators and end 
users may prefer different configuration formats than the developers. The flexibility
inherent in a multiple format configuration loader allows different users to make 
different choices, without generating extra work for the developers. As a developer
you only need to learn a single interface to be able to use the power of different
configuration formats.

=head1 INTERFACE 

=cut

=head2 load_files( \%args )

    Config::Any->load_files( { files => \@files } );
    Config::Any->load_files( { files => \@files, filter  => \&filter } );
    Config::Any->load_files( { files => \@files, use_ext => 1 } );
    Config::Any->load_files( { files => \@files, flatten_to_hash => 1 } );

C<load_files()> attempts to load configuration from the list of files passed in
the C<files> parameter, if the file exists.

If the C<filter> parameter is set, it is used as a callback to modify the configuration 
data before it is returned. It will be passed a single hash-reference parameter which 
it should modify in-place.

If the C<use_ext> parameter is defined, the loader will attempt to parse the file
extension from each filename and will skip the file unless it matches a standard
extension for the loading plugins. Only plugins whose standard extensions match the
file extension will be used. For efficiency reasons, its use is encouraged, but
be aware that you will lose flexibility -- for example, a file called C<myapp.cfg> 
containing YAML data will not be offered to the YAML plugin, whereas C<myapp.yml>
or C<myapp.yaml> would be.

When the C<flatten_to_hash> parameter is defined, the loader will return a hash
keyed on the file names, as opposed to the usual list of single-key hashes.

C<load_files()> also supports a 'force_plugins' parameter, whose value should be an
arrayref of plugin names like C<Config::Any::INI>. Its intended use is to allow the use 
of a non-standard file extension while forcing it to be offered to a particular parser.
It is not compatible with 'use_ext'. 

You can supply a C<driver_args> hashref to pass special options to a particular
parser object. Example:

    Config::Any->load_files( { files => \@files, driver_args => {
        General => { -LowerCaseNames => 1 }
    } )

=cut

sub load_files {
    my ( $class, $args ) = @_;

    unless ( $args && exists $args->{ files } ) {
        warn "No files specified!";
        return;
    }

    return $class->_load( $args );
}

=head2 load_stems( \%args )

    Config::Any->load_stems( { stems => \@stems } );
    Config::Any->load_stems( { stems => \@stems, filter  => \&filter } );
    Config::Any->load_stems( { stems => \@stems, use_ext => 1 } );
    Config::Any->load_stems( { stems => \@stems, flatten_to_hash => 1 } );

C<load_stems()> attempts to load configuration from a list of files which it generates
by combining the filename stems list passed in the C<stems> parameter with the 
potential filename extensions from each loader, which you can check with the
C<extensions()> classmethod described below. Once this list of possible filenames is
built it is treated exactly as in C<load_files()> above, as which it takes the same
parameters. Please read the C<load_files()> documentation before using this method.

=cut

sub load_stems {
    my ( $class, $args ) = @_;

    unless ( $args && exists $args->{ stems } ) {
        warn "No stems specified!";
        return;
    }

    my $stems = delete $args->{ stems };
    my @files;
    for my $s ( @$stems ) {
        for my $ext ( $class->extensions ) {
            push @files, "$s.$ext";
        }
    }

    $args->{ files } = \@files;
    return $class->_load( $args );
}

sub _load {
    my ( $class, $args ) = @_;
    croak "_load requires a arrayref of file paths" unless $args->{ files };

    my $force = defined $args->{ force_plugins };
    if ( !$force and !defined $args->{ use_ext } ) {
        warn
            "use_ext argument was not explicitly set, as of 0.09, this is true by default";
        $args->{ use_ext } = 1;
    }

    # figure out what plugins we're using
    my @plugins = $force ? @{ $args->{ force_plugins } } : $class->plugins;

    # map extensions if we have to
    my ( %extension_lut, $extension_re );
    my $use_ext_lut = !$force && $args->{ use_ext };
    if ( $use_ext_lut ) {
        for my $plugin ( @plugins ) {
            $extension_lut{ $_ } = $plugin for $plugin->extensions;
        }

        $extension_re = join( '|', keys %extension_lut );
    }

    # map args to plugins
    my $base_class = __PACKAGE__;
    my %loader_args;
    for my $plugin ( @plugins ) {
        $plugin =~ m{^$base_class\::(.+)};
        $loader_args{ $plugin } = $args->{ driver_args }->{ $1 } || {};
    }

    my @results;

    for my $filename ( @{ $args->{ files } } ) {

        # don't even bother if it's not there
        next unless -f $filename;

        my @try_plugins = @plugins;

        if ( $use_ext_lut ) {
            $filename =~ m{\.($extension_re)\z};
            next unless $1;
            @try_plugins = $extension_lut{ $1 };
        }

        for my $loader ( @try_plugins ) {
            next unless $loader->is_supported;
            my @configs
                = eval { $loader->load( $filename, $loader_args{ $loader } ); };

            # fatal error if we used extension matching
            croak "Error parsing $filename: $@" if $@ and $use_ext_lut;
            next if $@ or !@configs;

            # post-process config with a filter callback
            if ( $args->{ filter } ) {
                $args->{ filter }->( $_ ) for @configs;
            }

            push @results,
                { $filename => @configs == 1 ? $configs[ 0 ] : \@configs };
            last;
        }
    }

    if ( defined $args->{ flatten_to_hash } ) {
        my %flattened = map { %$_ } @results;
        return \%flattened;
    }

    return \@results;
}

=head2 finder( )

The C<finder()> classmethod returns the 
L<Module::Pluggable::Object|Module::Pluggable::Object>
object which is used to load the plugins. See the documentation for that module for
more information.

=cut

sub finder {
    my $class  = shift;
    my $finder = Module::Pluggable::Object->new(
        search_path => [ __PACKAGE__ ],
        require     => 1
    );
    return $finder;
}

=head2 plugins( )

The C<plugins()> classmethod returns the names of configuration loading plugins as 
found by L<Module::Pluggable::Object|Module::Pluggable::Object>.

=cut

sub plugins {
    my $class = shift;
    return $class->finder->plugins;
}

=head2 extensions( )

The C<extensions()> classmethod returns the possible file extensions which can be loaded
by C<load_stems()> and C<load_files()>. This may be useful if you set the C<use_ext>
parameter to those methods.

=cut

sub extensions {
    my $class = shift;
    my @ext = map { $_->extensions } $class->plugins;
    return wantarray ? @ext : \@ext;
}

=head1 DIAGNOSTICS

=over

=item C<No files specified!> or C<No stems specified!>

The C<load_files()> and C<load_stems()> methods will issue this warning if
called with an empty list of files/stems to load.

=item C<_load requires a arrayref of file paths>

This fatal error will be thrown by the internal C<_load> method. It should not occur
but is specified here for completeness. If your code dies with this error, please
email a failing test case to the authors below.

=back

=head1 CONFIGURATION AND ENVIRONMENT

Config::Any requires no configuration files or environment variables.

=head1 DEPENDENCIES

L<Module::Pluggable|Module::Pluggable>

And at least one of the following:
L<Config::General|Config::General>
L<Config::Tiny|Config::Tiny>
L<JSON|JSON>
L<YAML|YAML>
L<JSON::Syck|JSON::Syck>
L<YAML::Syck|YAML::Syck>
L<XML::Simple|XML::Simple>

=head1 INCOMPATIBILITIES

None reported.

=head1 BUGS AND LIMITATIONS

No bugs have been reported.

Please report any bugs or feature requests to
C<bug-config-any@rt.cpan.org>, or through the web interface at
L<http://rt.cpan.org>.

=head1 AUTHOR

Joel Bernstein  E<lt>rataxis@cpan.orgE<gt>

=head1 CONTRIBUTORS

This module was based on the original 
L<Catalyst::Plugin::ConfigLoader|Catalyst::Plugin::ConfigLoader>
module by Brian Cassidy C<< <bricas@cpan.org> >>.

With ideas and support from Matt S Trout C<< <mst@shadowcatsystems.co.uk> >>.

Further enhancements suggested by Evan Kaufman C<< <evank@cpan.org> >>.

=head1 LICENCE AND COPYRIGHT

Copyright (c) 2006, Portugal Telecom C<< http://www.sapo.pt/ >>. All rights reserved.
Portions copyright 2007, Joel Bernstein C<< <rataxis@cpan.org> >>.

This module is free software; you can redistribute it and/or
modify it under the same terms as Perl itself. See L<perlartistic>.

=head1 DISCLAIMER OF WARRANTY

BECAUSE THIS SOFTWARE IS LICENSED FREE OF CHARGE, THERE IS NO WARRANTY
FOR THE SOFTWARE, TO THE EXTENT PERMITTED BY APPLICABLE LAW. EXCEPT WHEN
OTHERWISE STATED IN WRITING THE COPYRIGHT HOLDERS AND/OR OTHER PARTIES
PROVIDE THE SOFTWARE "AS IS" WITHOUT WARRANTY OF ANY KIND, EITHER
EXPRESSED OR IMPLIED, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE. THE
ENTIRE RISK AS TO THE QUALITY AND PERFORMANCE OF THE SOFTWARE IS WITH
YOU. SHOULD THE SOFTWARE PROVE DEFECTIVE, YOU ASSUME THE COST OF ALL
NECESSARY SERVICING, REPAIR, OR CORRECTION.

IN NO EVENT UNLESS REQUIRED BY APPLICABLE LAW OR AGREED TO IN WRITING
WILL ANY COPYRIGHT HOLDER, OR ANY OTHER PARTY WHO MAY MODIFY AND/OR
REDISTRIBUTE THE SOFTWARE AS PERMITTED BY THE ABOVE LICENCE, BE
LIABLE TO YOU FOR DAMAGES, INCLUDING ANY GENERAL, SPECIAL, INCIDENTAL,
OR CONSEQUENTIAL DAMAGES ARISING OUT OF THE USE OR INABILITY TO USE
THE SOFTWARE (INCLUDING BUT NOT LIMITED TO LOSS OF DATA OR DATA BEING
RENDERED INACCURATE OR LOSSES SUSTAINED BY YOU OR THIRD PARTIES OR A
FAILURE OF THE SOFTWARE TO OPERATE WITH ANY OTHER SOFTWARE), EVEN IF
SUCH HOLDER OR OTHER PARTY HAS BEEN ADVISED OF THE POSSIBILITY OF
SUCH DAMAGES.

=head1 SEE ALSO

L<Catalyst::Plugin::ConfigLoader|Catalyst::Plugin::ConfigLoader> 
-- now a wrapper around this module.

=cut

"Drink more beer";
Commit	Line	Data
c80a0905	1	package Config::Any;
92a04e78	2
c80a0905	3	use strict;
92a04e78	4	use warnings;
92a04e78	5
c80a0905	6	use Carp;
c80a0905	7	use Module::Pluggable::Object ();
59a80452	8
5770ffc0	9	our $VERSION = '0.13';
c80a0905	10
59a80452	11	=head1 NAME
	12
	13	Config::Any - Load configuration from different file formats, transparently
	14
59a80452	15	=head1 SYNOPSIS
	16
	17	use Config::Any;
	18
f0e3c221	19	my $cfg = Config::Any->load_stems({stems => \@filepath_stems, ... });
	20	# or
	21	my $cfg = Config::Any->load_files({files => \@filepaths, ... });
59a80452	22
f0e3c221	23	for (@$cfg) {
0c6989c6	24	my ($filename, $config) = %$_;
f0e3c221	25	$class->config($config);
	26	warn "loaded config from file: $filename";
	27	}
59a80452	28
	29	=head1 DESCRIPTION
	30
	31	L<Config::Any\|Config::Any> provides a facility for Perl applications and libraries
	32	to load configuration data from multiple different file formats. It supports XML, YAML,
	33	JSON, Apache-style configuration, Windows INI files, and even Perl code.
	34
	35	The rationale for this module is as follows: Perl programs are deployed on many different
	36	platforms and integrated with many different systems. Systems administrators and end
	37	users may prefer different configuration formats than the developers. The flexibility
	38	inherent in a multiple format configuration loader allows different users to make
	39	different choices, without generating extra work for the developers. As a developer
	40	you only need to learn a single interface to be able to use the power of different
	41	configuration formats.
	42
	43	=head1 INTERFACE
	44
	45	=cut
	46
7c218182	47	=head2 load_files( \%args )
59a80452	48
4efab558	49	Config::Any->load_files( { files => \@files } );
	50	Config::Any->load_files( { files => \@files, filter => \&filter } );
	51	Config::Any->load_files( { files => \@files, use_ext => 1 } );
aa7bd7c3	52	Config::Any->load_files( { files => \@files, flatten_to_hash => 1 } );
59a80452	53
	54	C<load_files()> attempts to load configuration from the list of files passed in
	55	the C<files> parameter, if the file exists.
	56
	57	If the C<filter> parameter is set, it is used as a callback to modify the configuration
	58	data before it is returned. It will be passed a single hash-reference parameter which
	59	it should modify in-place.
	60
	61	If the C<use_ext> parameter is defined, the loader will attempt to parse the file
	62	extension from each filename and will skip the file unless it matches a standard
	63	extension for the loading plugins. Only plugins whose standard extensions match the
	64	file extension will be used. For efficiency reasons, its use is encouraged, but
	65	be aware that you will lose flexibility -- for example, a file called C<myapp.cfg>
	66	containing YAML data will not be offered to the YAML plugin, whereas C<myapp.yml>
	67	or C<myapp.yaml> would be.
	68
aa7bd7c3	69	When the C<flatten_to_hash> parameter is defined, the loader will return a hash
	70	keyed on the file names, as opposed to the usual list of single-key hashes.
	71
41f47406	72	C<load_files()> also supports a 'force_plugins' parameter, whose value should be an
	73	arrayref of plugin names like C<Config::Any::INI>. Its intended use is to allow the use
	74	of a non-standard file extension while forcing it to be offered to a particular parser.
	75	It is not compatible with 'use_ext'.
	76
ef87b7dc	77	You can supply a C<driver_args> hashref to pass special options to a particular
	78	parser object. Example:
	79
	80	Config::Any->load_files( { files => \@files, driver_args => {
	81	General => { -LowerCaseNames => 1 }
	82	} )
	83
59a80452	84	=cut
59a80452	85
c80a0905	86	sub load_files {
92a04e78	87	my ( $class, $args ) = @_;
4efab558	88
	89	unless ( $args && exists $args->{ files } ) {
	90	warn "No files specified!";
59a80452	91	return;
	92	}
	93
4efab558	94	return $class->_load( $args );
c80a0905	95	}
c80a0905	96
7c218182	97	=head2 load_stems( \%args )
59a80452	98
bef9e9a5	99	Config::Any->load_stems( { stems => \@stems } );
	100	Config::Any->load_stems( { stems => \@stems, filter => \&filter } );
	101	Config::Any->load_stems( { stems => \@stems, use_ext => 1 } );
aa7bd7c3	102	Config::Any->load_stems( { stems => \@stems, flatten_to_hash => 1 } );
59a80452	103
	104	C<load_stems()> attempts to load configuration from a list of files which it generates
	105	by combining the filename stems list passed in the C<stems> parameter with the
	106	potential filename extensions from each loader, which you can check with the
	107	C<extensions()> classmethod described below. Once this list of possible filenames is
	108	built it is treated exactly as in C<load_files()> above, as which it takes the same
	109	parameters. Please read the C<load_files()> documentation before using this method.
	110
	111	=cut
	112
c80a0905	113	sub load_stems {
92a04e78	114	my ( $class, $args ) = @_;
bef9e9a5	115
	116	unless ( $args && exists $args->{ stems } ) {
	117	warn "No stems specified!";
59a80452	118	return;
59a80452	119	}
92a04e78	120
bef9e9a5	121	my $stems = delete $args->{ stems };
c80a0905	122	my @files;
92a04e78	123	for my $s ( @$stems ) {
92a04e78	124	for my $ext ( $class->extensions ) {
4efab558	125	push @files, "$s.$ext";
c80a0905	126	}
c80a0905	127	}
c80a0905	128
bef9e9a5	129	$args->{ files } = \@files;
	130	return $class->_load( $args );
	131	}
41f47406	132
c80a0905	133	sub _load {
92a04e78	134	my ( $class, $args ) = @_;
a918b0b8	135	croak "_load requires a arrayref of file paths" unless $args->{ files };
a918b0b8	136
c84f1613	137	my $force = defined $args->{ force_plugins };
c84f1613	138	if ( !$force and !defined $args->{ use_ext } ) {
72628dc7	139	warn
72628dc7	140	"use_ext argument was not explicitly set, as of 0.09, this is true by default";
a918b0b8	141	$args->{ use_ext } = 1;
	142	}
	143
	144	# figure out what plugins we're using
ade8c46e	145	my @plugins = $force ? @{ $args->{ force_plugins } } : $class->plugins;
a918b0b8	146
a918b0b8	147	# map extensions if we have to
72628dc7	148	my ( %extension_lut, $extension_re );
a918b0b8	149	my $use_ext_lut = !$force && $args->{ use_ext };
72628dc7	150	if ( $use_ext_lut ) {
a918b0b8	151	for my $plugin ( @plugins ) {
	152	$extension_lut{ $_ } = $plugin for $plugin->extensions;
	153	}
	154
	155	$extension_re = join( '\|', keys %extension_lut );
	156	}
59a80452	157
a918b0b8	158	# map args to plugins
	159	my $base_class = __PACKAGE__;
	160	my %loader_args;
	161	for my $plugin ( @plugins ) {
	162	$plugin =~ m{^$base_class\::(.+)};
	163	$loader_args{ $plugin } = $args->{ driver_args }->{ $1 } \|\| {};
	164	}
	165
	166	my @results;
	167
	168	for my $filename ( @{ $args->{ files } } ) {
72628dc7	169
a918b0b8	170	# don't even bother if it's not there
	171	next unless -f $filename;
	172
	173	my @try_plugins = @plugins;
41f47406	174
72628dc7	175	if ( $use_ext_lut ) {
a918b0b8	176	$filename =~ m{\.($extension_re)\z};
	177	next unless $1;
	178	@try_plugins = $extension_lut{ $1 };
	179	}
	180
	181	for my $loader ( @try_plugins ) {
ade8c46e	182	next unless $loader->is_supported;
72628dc7	183	my @configs
72628dc7	184	= eval { $loader->load( $filename, $loader_args{ $loader } ); };
41f47406	185
a918b0b8	186	# fatal error if we used extension matching
92c29326	187	croak "Error parsing $filename: $@" if $@ and $use_ext_lut;
a918b0b8	188	next if $@ or !@configs;
	189
	190	# post-process config with a filter callback
	191	if ( $args->{ filter } ) {
	192	$args->{ filter }->( $_ ) for @configs;
	193	}
41f47406	194
72628dc7	195	push @results,
72628dc7	196	{ $filename => @configs == 1 ? $configs[ 0 ] : \@configs };
a918b0b8	197	last;
c80a0905	198	}
c80a0905	199	}
7c218182	200
aa7bd7c3	201	if ( defined $args->{ flatten_to_hash } ) {
	202	my %flattened = map { %$_ } @results;
	203	return \%flattened;
	204	}
	205
a918b0b8	206	return \@results;
c80a0905	207	}
c80a0905	208
59a80452	209	=head2 finder( )
	210
	211	The C<finder()> classmethod returns the
	212	L<Module::Pluggable::Object\|Module::Pluggable::Object>
	213	object which is used to load the plugins. See the documentation for that module for
	214	more information.
	215
	216	=cut
	217
c80a0905	218	sub finder {
92a04e78	219	my $class = shift;
c80a0905	220	my $finder = Module::Pluggable::Object->new(
	221	search_path => [ __PACKAGE__ ],
	222	require => 1
	223	);
bef9e9a5	224	return $finder;
c80a0905	225	}
c80a0905	226
59a80452	227	=head2 plugins( )
	228
	229	The C<plugins()> classmethod returns the names of configuration loading plugins as
	230	found by L<Module::Pluggable::Object\|Module::Pluggable::Object>.
	231
	232	=cut
	233
c80a0905	234	sub plugins {
	235	my $class = shift;
	236	return $class->finder->plugins;
	237	}
	238
59a80452	239	=head2 extensions( )
c80a0905	240
59a80452	241	The C<extensions()> classmethod returns the possible file extensions which can be loaded
	242	by C<load_stems()> and C<load_files()>. This may be useful if you set the C<use_ext>
	243	parameter to those methods.
c80a0905	244
59a80452	245	=cut
c80a0905	246
59a80452	247	sub extensions {
	248	my $class = shift;
	249	my @ext = map { $_->extensions } $class->plugins;
4efab558	250	return wantarray ? @ext : \@ext;
59a80452	251	}
c80a0905	252
	253	=head1 DIAGNOSTICS
	254
c80a0905	255	=over
c80a0905	256
7c218182	257	=item C<No files specified!> or C<No stems specified!>
c80a0905	258
59a80452	259	The C<load_files()> and C<load_stems()> methods will issue this warning if
59a80452	260	called with an empty list of files/stems to load.
c80a0905	261
59a80452	262	=item C<_load requires a arrayref of file paths>
c80a0905	263
59a80452	264	This fatal error will be thrown by the internal C<_load> method. It should not occur
	265	but is specified here for completeness. If your code dies with this error, please
	266	email a failing test case to the authors below.
c80a0905	267
	268	=back
	269
c80a0905	270	=head1 CONFIGURATION AND ENVIRONMENT
c80a0905	271
c80a0905	272	Config::Any requires no configuration files or environment variables.
c80a0905	273
c80a0905	274	=head1 DEPENDENCIES
c80a0905	275
59a80452	276	L<Module::Pluggable\|Module::Pluggable>
c80a0905	277
59a80452	278	And at least one of the following:
	279	L<Config::General\|Config::General>
	280	L<Config::Tiny\|Config::Tiny>
	281	L<JSON\|JSON>
	282	L<YAML\|YAML>
	283	L<JSON::Syck\|JSON::Syck>
	284	L<YAML::Syck\|YAML::Syck>
	285	L<XML::Simple\|XML::Simple>
c80a0905	286
	287	=head1 INCOMPATIBILITIES
	288
c80a0905	289	None reported.
c80a0905	290
c80a0905	291	=head1 BUGS AND LIMITATIONS
c80a0905	292
c80a0905	293	No bugs have been reported.
	294
	295	Please report any bugs or feature requests to
	296	C<bug-config-any@rt.cpan.org>, or through the web interface at
	297	L<http://rt.cpan.org>.
	298
c80a0905	299	=head1 AUTHOR
c80a0905	300
f0e3c221	301	Joel Bernstein E<lt>rataxis@cpan.orgE<gt>
c80a0905	302
59a80452	303	=head1 CONTRIBUTORS
	304
	305	This module was based on the original
	306	L<Catalyst::Plugin::ConfigLoader\|Catalyst::Plugin::ConfigLoader>
	307	module by Brian Cassidy C<< <bricas@cpan.org> >>.
	308
	309	With ideas and support from Matt S Trout C<< <mst@shadowcatsystems.co.uk> >>.
c80a0905	310
41f47406	311	Further enhancements suggested by Evan Kaufman C<< <evank@cpan.org> >>.
41f47406	312
c80a0905	313	=head1 LICENCE AND COPYRIGHT
	314
	315	Copyright (c) 2006, Portugal Telecom C<< http://www.sapo.pt/ >>. All rights reserved.
41f47406	316	Portions copyright 2007, Joel Bernstein C<< <rataxis@cpan.org> >>.
c80a0905	317
	318	This module is free software; you can redistribute it and/or
	319	modify it under the same terms as Perl itself. See L<perlartistic>.
	320
c80a0905	321	=head1 DISCLAIMER OF WARRANTY
	322
	323	BECAUSE THIS SOFTWARE IS LICENSED FREE OF CHARGE, THERE IS NO WARRANTY
	324	FOR THE SOFTWARE, TO THE EXTENT PERMITTED BY APPLICABLE LAW. EXCEPT WHEN
	325	OTHERWISE STATED IN WRITING THE COPYRIGHT HOLDERS AND/OR OTHER PARTIES
	326	PROVIDE THE SOFTWARE "AS IS" WITHOUT WARRANTY OF ANY KIND, EITHER
	327	EXPRESSED OR IMPLIED, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
	328	WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE. THE
	329	ENTIRE RISK AS TO THE QUALITY AND PERFORMANCE OF THE SOFTWARE IS WITH
	330	YOU. SHOULD THE SOFTWARE PROVE DEFECTIVE, YOU ASSUME THE COST OF ALL
	331	NECESSARY SERVICING, REPAIR, OR CORRECTION.
	332
	333	IN NO EVENT UNLESS REQUIRED BY APPLICABLE LAW OR AGREED TO IN WRITING
	334	WILL ANY COPYRIGHT HOLDER, OR ANY OTHER PARTY WHO MAY MODIFY AND/OR
	335	REDISTRIBUTE THE SOFTWARE AS PERMITTED BY THE ABOVE LICENCE, BE
	336	LIABLE TO YOU FOR DAMAGES, INCLUDING ANY GENERAL, SPECIAL, INCIDENTAL,
	337	OR CONSEQUENTIAL DAMAGES ARISING OUT OF THE USE OR INABILITY TO USE
	338	THE SOFTWARE (INCLUDING BUT NOT LIMITED TO LOSS OF DATA OR DATA BEING
	339	RENDERED INACCURATE OR LOSSES SUSTAINED BY YOU OR THIRD PARTIES OR A
	340	FAILURE OF THE SOFTWARE TO OPERATE WITH ANY OTHER SOFTWARE), EVEN IF
	341	SUCH HOLDER OR OTHER PARTY HAS BEEN ADVISED OF THE POSSIBILITY OF
	342	SUCH DAMAGES.
59a80452	343
	344	=head1 SEE ALSO
	345
	346	L<Catalyst::Plugin::ConfigLoader\|Catalyst::Plugin::ConfigLoader>
	347	-- now a wrapper around this module.
	348
	349	=cut
	350
41f47406	351	"Drink more beer";