[p5sagit/Config-Any.git] / lib / Config / Any.pm

package Config::Any;

use strict;
use warnings;

use Carp;
use Module::Pluggable::Object ();
use English qw(-no_match_vars);

our $VERSION = '0.09';

=head1 NAME

Config::Any - Load configuration from different file formats, transparently

=head1 VERSION

This document describes Config::Any version 0.0.8

=head1 SYNOPSIS

    use Config::Any;

    my $cfg = Config::Any->load_stems({stems => \@filepath_stems, ... });
    # or
    my $cfg = Config::Any->load_files({files => \@filepaths, ... });

    for (@$cfg) {
        my ($filename, $config) = each %$_;
        $class->config($config);
        warn "loaded config from file: $filename";
    }

=head1 DESCRIPTION

L<Config::Any|Config::Any> provides a facility for Perl applications and libraries
to load configuration data from multiple different file formats. It supports XML, YAML,
JSON, Apache-style configuration, Windows INI files, and even Perl code.

The rationale for this module is as follows: Perl programs are deployed on many different
platforms and integrated with many different systems. Systems administrators and end 
users may prefer different configuration formats than the developers. The flexibility
inherent in a multiple format configuration loader allows different users to make 
different choices, without generating extra work for the developers. As a developer
you only need to learn a single interface to be able to use the power of different
configuration formats.

=head1 INTERFACE 

=cut

=head2 load_files( )

    Config::Any->load_files( { files => \@files } );
    Config::Any->load_files( { files => \@files, filter  => \&filter } );
    Config::Any->load_files( { files => \@files, use_ext => 1 } );

C<load_files()> attempts to load configuration from the list of files passed in
the C<files> parameter, if the file exists.

If the C<filter> parameter is set, it is used as a callback to modify the configuration 
data before it is returned. It will be passed a single hash-reference parameter which 
it should modify in-place.

If the C<use_ext> parameter is defined, the loader will attempt to parse the file
extension from each filename and will skip the file unless it matches a standard
extension for the loading plugins. Only plugins whose standard extensions match the
file extension will be used. For efficiency reasons, its use is encouraged, but
be aware that you will lose flexibility -- for example, a file called C<myapp.cfg> 
containing YAML data will not be offered to the YAML plugin, whereas C<myapp.yml>
or C<myapp.yaml> would be.

C<load_files()> also supports a 'force_plugins' parameter, whose value should be an
arrayref of plugin names like C<Config::Any::INI>. Its intended use is to allow the use 
of a non-standard file extension while forcing it to be offered to a particular parser.
It is not compatible with 'use_ext'. 

You can supply a C<driver_args> hashref to pass special options to a particular
parser object. Example:

    Config::Any->load_files( { files => \@files, driver_args => {
        General => { -LowerCaseNames => 1 }
    } )

=cut

sub load_files {
    my ( $class, $args ) = @_;

    unless ( $args && exists $args->{ files } ) {
        warn "No files specified!";
        return;
    }

    return $class->_load( $args );
}

=head2 load_stems( )

    Config::Any->load_stems( { stems => \@stems } );
    Config::Any->load_stems( { stems => \@stems, filter  => \&filter } );
    Config::Any->load_stems( { stems => \@stems, use_ext => 1 } );

C<load_stems()> attempts to load configuration from a list of files which it generates
by combining the filename stems list passed in the C<stems> parameter with the 
potential filename extensions from each loader, which you can check with the
C<extensions()> classmethod described below. Once this list of possible filenames is
built it is treated exactly as in C<load_files()> above, as which it takes the same
parameters. Please read the C<load_files()> documentation before using this method.

=cut

sub load_stems {
    my ( $class, $args ) = @_;

    unless ( $args && exists $args->{ stems } ) {
        warn "No stems specified!";
        return;
    }

    my $stems = delete $args->{ stems };
    my @files;
    for my $s ( @$stems ) {
        for my $ext ( $class->extensions ) {
            push @files, "$s.$ext";
        }
    }

    $args->{ files } = \@files;
    return $class->_load( $args );
}

# this is where we do the real work
# it's a private class-method because users should use the interface described
# in the POD.
sub _load {
    my ( $class, $args ) = @_;
    my ( $files_ref, $filter_cb, $use_ext, $force_plugins_ref )
        = @{ $args }{ qw(files filter use_ext force_plugins) };
    croak "_load requires a arrayref of file paths" unless defined $files_ref;

    my %files         = map { $_ => 1 } @$files_ref;
    my %force_plugins = map { $_ => 1 } @$force_plugins_ref;
    my $enforcing     = keys %force_plugins ? 1 : 0;

    my $final_configs     = [];
    my $originally_loaded = {};

    # perform a separate file loop for each loader
    for my $loader ( $class->plugins ) {
        next if $enforcing && not defined $force_plugins{ $loader };
        last unless keys %files;
        my %ext = map { $_ => 1 } $loader->extensions;

        my ( $loader_class ) = $loader =~ /::([^:]+)$/;
        my $driver_args = $args->{ driver_args }{ $loader_class } || {};

    FILE:
        for my $filename ( keys %files ) {
            next unless -f $filename;

       # use file extension to decide whether this loader should try this file
       # use_ext => 1 hits this block
            if ( defined $use_ext && !$enforcing ) {
                my $matched_ext = 0;
            EXT:
                for my $e ( keys %ext ) {
                    next EXT unless $filename =~ m{ \. $e \z }xms;
                    next FILE unless exists $ext{ $e };
                    $matched_ext = 1;
                }

                next FILE unless $matched_ext;
            }

            my $config;
            eval { $config = $loader->load( $filename, $driver_args ); };

            next if $EVAL_ERROR;    # if it croaked or warned, we can't use it
            next if !$config;
            delete $files{ $filename };

            # post-process config with a filter callback, if we got one
            $filter_cb->( $config ) if defined $filter_cb;

            push @$final_configs, { $filename => $config };
        }
    }
    $final_configs;
}

=head2 finder( )

The C<finder()> classmethod returns the 
L<Module::Pluggable::Object|Module::Pluggable::Object>
object which is used to load the plugins. See the documentation for that module for
more information.

=cut

sub finder {
    my $class  = shift;
    my $finder = Module::Pluggable::Object->new(
        search_path => [ __PACKAGE__ ],
        require     => 1
    );
    return $finder;
}

=head2 plugins( )

The C<plugins()> classmethod returns the names of configuration loading plugins as 
found by L<Module::Pluggable::Object|Module::Pluggable::Object>.

=cut

sub plugins {
    my $class = shift;
    return $class->finder->plugins;
}

=head2 extensions( )

The C<extensions()> classmethod returns the possible file extensions which can be loaded
by C<load_stems()> and C<load_files()>. This may be useful if you set the C<use_ext>
parameter to those methods.

=cut

sub extensions {
    my $class = shift;
    my @ext = map { $_->extensions } $class->plugins;
    return wantarray ? @ext : \@ext;
}

=head1 DIAGNOSTICS

=over

=item C<no files specified> or C<no stems specified>

The C<load_files()> and C<load_stems()> methods will issue this warning if
called with an empty list of files/stems to load.

=item C<_load requires a arrayref of file paths>

This fatal error will be thrown by the internal C<_load> method. It should not occur
but is specified here for completeness. If your code dies with this error, please
email a failing test case to the authors below.

=back

=head1 CONFIGURATION AND ENVIRONMENT

Config::Any requires no configuration files or environment variables.

=head1 DEPENDENCIES

L<Module::Pluggable|Module::Pluggable>

And at least one of the following:
L<Config::General|Config::General>
L<Config::Tiny|Config::Tiny>
L<JSON|JSON>
L<YAML|YAML>
L<JSON::Syck|JSON::Syck>
L<YAML::Syck|YAML::Syck>
L<XML::Simple|XML::Simple>

=head1 INCOMPATIBILITIES

None reported.

=head1 BUGS AND LIMITATIONS

No bugs have been reported.

Please report any bugs or feature requests to
C<bug-config-any@rt.cpan.org>, or through the web interface at
L<http://rt.cpan.org>.

=head1 AUTHOR

Joel Bernstein  E<lt>rataxis@cpan.orgE<gt>

=head1 CONTRIBUTORS

This module was based on the original 
L<Catalyst::Plugin::ConfigLoader|Catalyst::Plugin::ConfigLoader>
module by Brian Cassidy C<< <bricas@cpan.org> >>.

With ideas and support from Matt S Trout C<< <mst@shadowcatsystems.co.uk> >>.

Further enhancements suggested by Evan Kaufman C<< <evank@cpan.org> >>.

=head1 LICENCE AND COPYRIGHT

Copyright (c) 2006, Portugal Telecom C<< http://www.sapo.pt/ >>. All rights reserved.
Portions copyright 2007, Joel Bernstein C<< <rataxis@cpan.org> >>.

This module is free software; you can redistribute it and/or
modify it under the same terms as Perl itself. See L<perlartistic>.

=head1 DISCLAIMER OF WARRANTY

BECAUSE THIS SOFTWARE IS LICENSED FREE OF CHARGE, THERE IS NO WARRANTY
FOR THE SOFTWARE, TO THE EXTENT PERMITTED BY APPLICABLE LAW. EXCEPT WHEN
OTHERWISE STATED IN WRITING THE COPYRIGHT HOLDERS AND/OR OTHER PARTIES
PROVIDE THE SOFTWARE "AS IS" WITHOUT WARRANTY OF ANY KIND, EITHER
EXPRESSED OR IMPLIED, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE. THE
ENTIRE RISK AS TO THE QUALITY AND PERFORMANCE OF THE SOFTWARE IS WITH
YOU. SHOULD THE SOFTWARE PROVE DEFECTIVE, YOU ASSUME THE COST OF ALL
NECESSARY SERVICING, REPAIR, OR CORRECTION.

IN NO EVENT UNLESS REQUIRED BY APPLICABLE LAW OR AGREED TO IN WRITING
WILL ANY COPYRIGHT HOLDER, OR ANY OTHER PARTY WHO MAY MODIFY AND/OR
REDISTRIBUTE THE SOFTWARE AS PERMITTED BY THE ABOVE LICENCE, BE
LIABLE TO YOU FOR DAMAGES, INCLUDING ANY GENERAL, SPECIAL, INCIDENTAL,
OR CONSEQUENTIAL DAMAGES ARISING OUT OF THE USE OR INABILITY TO USE
THE SOFTWARE (INCLUDING BUT NOT LIMITED TO LOSS OF DATA OR DATA BEING
RENDERED INACCURATE OR LOSSES SUSTAINED BY YOU OR THIRD PARTIES OR A
FAILURE OF THE SOFTWARE TO OPERATE WITH ANY OTHER SOFTWARE), EVEN IF
SUCH HOLDER OR OTHER PARTY HAS BEEN ADVISED OF THE POSSIBILITY OF
SUCH DAMAGES.

=head1 SEE ALSO

L<Catalyst::Plugin::ConfigLoader|Catalyst::Plugin::ConfigLoader> 
-- now a wrapper around this module.

=cut

"Drink more beer";
Commit	Line	Data
c80a0905	1	package Config::Any;
92a04e78	2
c80a0905	3	use strict;
92a04e78	4	use warnings;
92a04e78	5
c80a0905	6	use Carp;
c80a0905	7	use Module::Pluggable::Object ();
59a80452	8	use English qw(-no_match_vars);
59a80452	9
4efab558	10	our $VERSION = '0.09';
c80a0905	11
59a80452	12	=head1 NAME
	13
	14	Config::Any - Load configuration from different file formats, transparently
	15
	16	=head1 VERSION
	17
e0c0c283	18	This document describes Config::Any version 0.0.8
59a80452	19
	20	=head1 SYNOPSIS
	21
	22	use Config::Any;
	23
f0e3c221	24	my $cfg = Config::Any->load_stems({stems => \@filepath_stems, ... });
	25	# or
	26	my $cfg = Config::Any->load_files({files => \@filepaths, ... });
59a80452	27
f0e3c221	28	for (@$cfg) {
	29	my ($filename, $config) = each %$_;
	30	$class->config($config);
	31	warn "loaded config from file: $filename";
	32	}
59a80452	33
	34	=head1 DESCRIPTION
	35
	36	L<Config::Any\|Config::Any> provides a facility for Perl applications and libraries
	37	to load configuration data from multiple different file formats. It supports XML, YAML,
	38	JSON, Apache-style configuration, Windows INI files, and even Perl code.
	39
	40	The rationale for this module is as follows: Perl programs are deployed on many different
	41	platforms and integrated with many different systems. Systems administrators and end
	42	users may prefer different configuration formats than the developers. The flexibility
	43	inherent in a multiple format configuration loader allows different users to make
	44	different choices, without generating extra work for the developers. As a developer
	45	you only need to learn a single interface to be able to use the power of different
	46	configuration formats.
	47
	48	=head1 INTERFACE
	49
	50	=cut
	51
	52	=head2 load_files( )
	53
4efab558	54	Config::Any->load_files( { files => \@files } );
	55	Config::Any->load_files( { files => \@files, filter => \&filter } );
	56	Config::Any->load_files( { files => \@files, use_ext => 1 } );
59a80452	57
	58	C<load_files()> attempts to load configuration from the list of files passed in
	59	the C<files> parameter, if the file exists.
	60
	61	If the C<filter> parameter is set, it is used as a callback to modify the configuration
	62	data before it is returned. It will be passed a single hash-reference parameter which
	63	it should modify in-place.
	64
	65	If the C<use_ext> parameter is defined, the loader will attempt to parse the file
	66	extension from each filename and will skip the file unless it matches a standard
	67	extension for the loading plugins. Only plugins whose standard extensions match the
	68	file extension will be used. For efficiency reasons, its use is encouraged, but
	69	be aware that you will lose flexibility -- for example, a file called C<myapp.cfg>
	70	containing YAML data will not be offered to the YAML plugin, whereas C<myapp.yml>
	71	or C<myapp.yaml> would be.
	72
41f47406	73	C<load_files()> also supports a 'force_plugins' parameter, whose value should be an
	74	arrayref of plugin names like C<Config::Any::INI>. Its intended use is to allow the use
	75	of a non-standard file extension while forcing it to be offered to a particular parser.
	76	It is not compatible with 'use_ext'.
	77
ef87b7dc	78	You can supply a C<driver_args> hashref to pass special options to a particular
	79	parser object. Example:
	80
	81	Config::Any->load_files( { files => \@files, driver_args => {
	82	General => { -LowerCaseNames => 1 }
	83	} )
	84
59a80452	85	=cut
59a80452	86
c80a0905	87	sub load_files {
92a04e78	88	my ( $class, $args ) = @_;
4efab558	89
	90	unless ( $args && exists $args->{ files } ) {
	91	warn "No files specified!";
59a80452	92	return;
	93	}
	94
4efab558	95	return $class->_load( $args );
c80a0905	96	}
c80a0905	97
59a80452	98	=head2 load_stems( )
59a80452	99
bef9e9a5	100	Config::Any->load_stems( { stems => \@stems } );
	101	Config::Any->load_stems( { stems => \@stems, filter => \&filter } );
	102	Config::Any->load_stems( { stems => \@stems, use_ext => 1 } );
59a80452	103
	104	C<load_stems()> attempts to load configuration from a list of files which it generates
	105	by combining the filename stems list passed in the C<stems> parameter with the
	106	potential filename extensions from each loader, which you can check with the
	107	C<extensions()> classmethod described below. Once this list of possible filenames is
	108	built it is treated exactly as in C<load_files()> above, as which it takes the same
	109	parameters. Please read the C<load_files()> documentation before using this method.
	110
	111	=cut
	112
c80a0905	113	sub load_stems {
92a04e78	114	my ( $class, $args ) = @_;
bef9e9a5	115
	116	unless ( $args && exists $args->{ stems } ) {
	117	warn "No stems specified!";
59a80452	118	return;
59a80452	119	}
92a04e78	120
bef9e9a5	121	my $stems = delete $args->{ stems };
c80a0905	122	my @files;
92a04e78	123	for my $s ( @$stems ) {
92a04e78	124	for my $ext ( $class->extensions ) {
4efab558	125	push @files, "$s.$ext";
c80a0905	126	}
c80a0905	127	}
c80a0905	128
bef9e9a5	129	$args->{ files } = \@files;
	130	return $class->_load( $args );
	131	}
41f47406	132
59a80452	133	# this is where we do the real work
	134	# it's a private class-method because users should use the interface described
	135	# in the POD.
c80a0905	136	sub _load {
92a04e78	137	my ( $class, $args ) = @_;
	138	my ( $files_ref, $filter_cb, $use_ext, $force_plugins_ref )
	139	= @{ $args }{ qw(files filter use_ext force_plugins) };
c80a0905	140	croak "_load requires a arrayref of file paths" unless defined $files_ref;
c80a0905	141
bef9e9a5	142	my %files = map { $_ => 1 } @$files_ref;
bef9e9a5	143	my %force_plugins = map { $_ => 1 } @$force_plugins_ref;
92a04e78	144	my $enforcing = keys %force_plugins ? 1 : 0;
41f47406	145
92a04e78	146	my $final_configs = [];
92a04e78	147	my $originally_loaded = {};
c80a0905	148
41f47406	149	# perform a separate file loop for each loader
c80a0905	150	for my $loader ( $class->plugins ) {
92a04e78	151	next if $enforcing && not defined $force_plugins{ $loader };
f0e3c221	152	last unless keys %files;
bef9e9a5	153	my %ext = map { $_ => 1 } $loader->extensions;
41f47406	154
92a04e78	155	my ( $loader_class ) = $loader =~ /::([^:]+)$/;
	156	my $driver_args = $args->{ driver_args }{ $loader_class } \|\| {};
	157
	158	FILE:
	159	for my $filename ( keys %files ) {
4efab558	160	next unless -f $filename;
92a04e78	161
	162	# use file extension to decide whether this loader should try this file
	163	# use_ext => 1 hits this block
	164	if ( defined $use_ext && !$enforcing ) {
f0e3c221	165	my $matched_ext = 0;
92a04e78	166	EXT:
	167	for my $e ( keys %ext ) {
	168	next EXT unless $filename =~ m{ \. $e \z }xms;
	169	next FILE unless exists $ext{ $e };
f0e3c221	170	$matched_ext = 1;
59a80452	171	}
41f47406	172
f0e3c221	173	next FILE unless $matched_ext;
59a80452	174	}
	175
	176	my $config;
92a04e78	177	eval { $config = $loader->load( $filename, $driver_args ); };
41f47406	178
92a04e78	179	next if $EVAL_ERROR; # if it croaked or warned, we can't use it
c80a0905	180	next if !$config;
92a04e78	181	delete $files{ $filename };
41f47406	182
41f47406	183	# post-process config with a filter callback, if we got one
c80a0905	184	$filter_cb->( $config ) if defined $filter_cb;
41f47406	185
c80a0905	186	push @$final_configs, { $filename => $config };
	187	}
	188	}
	189	$final_configs;
	190	}
	191
59a80452	192	=head2 finder( )
	193
	194	The C<finder()> classmethod returns the
	195	L<Module::Pluggable::Object\|Module::Pluggable::Object>
	196	object which is used to load the plugins. See the documentation for that module for
	197	more information.
	198
	199	=cut
	200
c80a0905	201	sub finder {
92a04e78	202	my $class = shift;
c80a0905	203	my $finder = Module::Pluggable::Object->new(
	204	search_path => [ __PACKAGE__ ],
	205	require => 1
	206	);
bef9e9a5	207	return $finder;
c80a0905	208	}
c80a0905	209
59a80452	210	=head2 plugins( )
	211
	212	The C<plugins()> classmethod returns the names of configuration loading plugins as
	213	found by L<Module::Pluggable::Object\|Module::Pluggable::Object>.
	214
	215	=cut
	216
c80a0905	217	sub plugins {
	218	my $class = shift;
	219	return $class->finder->plugins;
	220	}
	221
59a80452	222	=head2 extensions( )
c80a0905	223
59a80452	224	The C<extensions()> classmethod returns the possible file extensions which can be loaded
	225	by C<load_stems()> and C<load_files()>. This may be useful if you set the C<use_ext>
	226	parameter to those methods.
c80a0905	227
59a80452	228	=cut
c80a0905	229
59a80452	230	sub extensions {
	231	my $class = shift;
	232	my @ext = map { $_->extensions } $class->plugins;
4efab558	233	return wantarray ? @ext : \@ext;
59a80452	234	}
c80a0905	235
	236	=head1 DIAGNOSTICS
	237
c80a0905	238	=over
c80a0905	239
59a80452	240	=item C<no files specified> or C<no stems specified>
c80a0905	241
59a80452	242	The C<load_files()> and C<load_stems()> methods will issue this warning if
59a80452	243	called with an empty list of files/stems to load.
c80a0905	244
59a80452	245	=item C<_load requires a arrayref of file paths>
c80a0905	246
59a80452	247	This fatal error will be thrown by the internal C<_load> method. It should not occur
	248	but is specified here for completeness. If your code dies with this error, please
	249	email a failing test case to the authors below.
c80a0905	250
	251	=back
	252
c80a0905	253	=head1 CONFIGURATION AND ENVIRONMENT
c80a0905	254
c80a0905	255	Config::Any requires no configuration files or environment variables.
c80a0905	256
c80a0905	257	=head1 DEPENDENCIES
c80a0905	258
59a80452	259	L<Module::Pluggable\|Module::Pluggable>
c80a0905	260
59a80452	261	And at least one of the following:
	262	L<Config::General\|Config::General>
	263	L<Config::Tiny\|Config::Tiny>
	264	L<JSON\|JSON>
	265	L<YAML\|YAML>
	266	L<JSON::Syck\|JSON::Syck>
	267	L<YAML::Syck\|YAML::Syck>
	268	L<XML::Simple\|XML::Simple>
c80a0905	269
	270	=head1 INCOMPATIBILITIES
	271
c80a0905	272	None reported.
c80a0905	273
c80a0905	274	=head1 BUGS AND LIMITATIONS
c80a0905	275
c80a0905	276	No bugs have been reported.
	277
	278	Please report any bugs or feature requests to
	279	C<bug-config-any@rt.cpan.org>, or through the web interface at
	280	L<http://rt.cpan.org>.
	281
c80a0905	282	=head1 AUTHOR
c80a0905	283
f0e3c221	284	Joel Bernstein E<lt>rataxis@cpan.orgE<gt>
c80a0905	285
59a80452	286	=head1 CONTRIBUTORS
	287
	288	This module was based on the original
	289	L<Catalyst::Plugin::ConfigLoader\|Catalyst::Plugin::ConfigLoader>
	290	module by Brian Cassidy C<< <bricas@cpan.org> >>.
	291
	292	With ideas and support from Matt S Trout C<< <mst@shadowcatsystems.co.uk> >>.
c80a0905	293
41f47406	294	Further enhancements suggested by Evan Kaufman C<< <evank@cpan.org> >>.
41f47406	295
c80a0905	296	=head1 LICENCE AND COPYRIGHT
	297
	298	Copyright (c) 2006, Portugal Telecom C<< http://www.sapo.pt/ >>. All rights reserved.
41f47406	299	Portions copyright 2007, Joel Bernstein C<< <rataxis@cpan.org> >>.
c80a0905	300
	301	This module is free software; you can redistribute it and/or
	302	modify it under the same terms as Perl itself. See L<perlartistic>.
	303
c80a0905	304	=head1 DISCLAIMER OF WARRANTY
	305
	306	BECAUSE THIS SOFTWARE IS LICENSED FREE OF CHARGE, THERE IS NO WARRANTY
	307	FOR THE SOFTWARE, TO THE EXTENT PERMITTED BY APPLICABLE LAW. EXCEPT WHEN
	308	OTHERWISE STATED IN WRITING THE COPYRIGHT HOLDERS AND/OR OTHER PARTIES
	309	PROVIDE THE SOFTWARE "AS IS" WITHOUT WARRANTY OF ANY KIND, EITHER
	310	EXPRESSED OR IMPLIED, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
	311	WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE. THE
	312	ENTIRE RISK AS TO THE QUALITY AND PERFORMANCE OF THE SOFTWARE IS WITH
	313	YOU. SHOULD THE SOFTWARE PROVE DEFECTIVE, YOU ASSUME THE COST OF ALL
	314	NECESSARY SERVICING, REPAIR, OR CORRECTION.
	315
	316	IN NO EVENT UNLESS REQUIRED BY APPLICABLE LAW OR AGREED TO IN WRITING
	317	WILL ANY COPYRIGHT HOLDER, OR ANY OTHER PARTY WHO MAY MODIFY AND/OR
	318	REDISTRIBUTE THE SOFTWARE AS PERMITTED BY THE ABOVE LICENCE, BE
	319	LIABLE TO YOU FOR DAMAGES, INCLUDING ANY GENERAL, SPECIAL, INCIDENTAL,
	320	OR CONSEQUENTIAL DAMAGES ARISING OUT OF THE USE OR INABILITY TO USE
	321	THE SOFTWARE (INCLUDING BUT NOT LIMITED TO LOSS OF DATA OR DATA BEING
	322	RENDERED INACCURATE OR LOSSES SUSTAINED BY YOU OR THIRD PARTIES OR A
	323	FAILURE OF THE SOFTWARE TO OPERATE WITH ANY OTHER SOFTWARE), EVEN IF
	324	SUCH HOLDER OR OTHER PARTY HAS BEEN ADVISED OF THE POSSIBILITY OF
	325	SUCH DAMAGES.
59a80452	326
	327	=head1 SEE ALSO
	328
	329	L<Catalyst::Plugin::ConfigLoader\|Catalyst::Plugin::ConfigLoader>
	330	-- now a wrapper around this module.
	331
	332	=cut
	333
41f47406	334	"Drink more beer";