lib/Perl/Critic/Policy/DynamicMoose/ClassOverridesRole.pm

   1 package Perl::Critic::Policy::DynamicMoose::ClassOverridesRole;
   2 use Moose;
   3 extends 'Perl::Critic::Policy::DynamicMoose';
   4
   5 use Perl::Critic::Utils ':severities';
   6
   7 Readonly::Scalar my $EXPL => q{Explicitly exclude overriden methods};
   8 sub default_severity { $SEVERITY_MEDIUM }
   9
  10 # Class::MOP::Class has no roles
  11 sub applies_to_metaclass { 'Moose::Meta::Class' }
  12
  13 sub violates_metaclass {
  14     my $self  = shift;
  15     my $class = shift;
  16
  17     my @violations;
  18
  19     for my $application ($class->role_applications) {
  20         my $role = $application->role;
  21         for my $method ($role->get_method_list) {
  22             next if $application->is_method_excluded($method);
  23
  24             my $method_object = $class->get_method($method)
  25                 or next;
  26
  27             # no metadata, should check source role to make sure it's the
  28             # same as $role
  29             if ($method_object->isa('Moose::Meta::Role::Method')) {
  30                 next if $method_object->original_package_name eq $role->name;
  31             }
  32
  33             my $class_name = $class->name;
  34             my $role_name  = $role->name;
  35
  36             my $desc = "Class '$class_name' method '$method' implicitly overrides the same method from role '$role_name'";
  37             push @violations, $self->violation($desc, $EXPL);
  38         }
  39     }
  40
  41     return @violations;
  42 }
  43
  44 no Moose;
  45
  46 1;
  47
  48 __END__
  49
  50 =head1 NAME
  51
  52 Perl::Critic::Policy::DynamicMoose::ClassOverridesRole
  53
  54 =head1 DESCRIPTION
  55
  56
  57 =head1 WARNING
  58
  59 B<VERY IMPORTANT:> Most L<Perl::Critic> Policies (including all the ones that
  60 ship with Perl::Critic> use pure static analysis -- they never compile nor
  61 execute any of the code that they analyze.  However, this policy is very
  62 different.  It actually attempts to compile your code and then compares the
  63 subroutines mentioned in your code to those found in the symbol table.
  64 Therefore you should B<not> use this Policy on any code that you do not trust,
  65 or may have undesirable side-effects at compile-time (such as connecting to the
  66 network or mutating files).
  67
  68 For this Policy to work, all the modules included in your code must be
  69 installed locally, and must compile without error.
  70
  71 =head1 AUTHOR
  72
  73 Shawn M Moore, C<sartak@bestpractical.com>
  74
  75 =cut
  76