t/030_roles/003_apply_role.t

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use Test::Exception;
   8
   9 {
  10     package FooRole;
  11     use Mouse::Role;
  12
  13     has 'bar' => ( is => 'rw', isa => 'FooClass' );
  14     has 'baz' => ( is => 'ro' );
  15
  16     sub goo {'FooRole::goo'}
  17     sub foo {'FooRole::foo'}
  18
  19     override 'boo' => sub { 'FooRole::boo -> ' . super() };
  20
  21     around 'blau' => sub {
  22         my $c = shift;
  23         'FooRole::blau -> ' . $c->();
  24     };
  25 }
  26
  27 {
  28     package BarRole;
  29     use Mouse::Role;
  30     sub woot {'BarRole::woot'}
  31 }
  32
  33 {
  34     package BarClass;
  35     use Mouse;
  36
  37     sub boo {'BarClass::boo'}
  38     sub foo {'BarClass::foo'}    # << the role overrides this ...
  39 }
  40
  41 {
  42     package FooClass;
  43     use Mouse;
  44
  45     extends 'BarClass';
  46     with 'FooRole';
  47
  48     sub blau {'FooClass::blau'}    # << the role wraps this ...
  49
  50     sub goo {'FooClass::goo'}      # << overrides the one from the role ...
  51 }
  52
  53 {
  54     package FooBarClass;
  55     use Mouse;
  56
  57     extends 'FooClass';
  58     with 'FooRole', 'BarRole';
  59 }
  60
  61 my $foo_class_meta = FooClass->meta;
  62 isa_ok( $foo_class_meta, 'Mouse::Meta::Class' );
  63
  64 my $foobar_class_meta = FooBarClass->meta;
  65 isa_ok( $foobar_class_meta, 'Mouse::Meta::Class' );
  66
  67 dies_ok {
  68     $foo_class_meta->does_role();
  69 }
  70 '... does_role requires a role name';
  71
  72 dies_ok {
  73     $foo_class_meta->add_role();
  74 }
  75 '... apply_role requires a role';
  76
  77 dies_ok {
  78     $foo_class_meta->add_role( bless( {} => 'Fail' ) );
  79 }
  80 '... apply_role requires a role';
  81
  82 ok( $foo_class_meta->does_role('FooRole'),
  83     '... the FooClass->meta does_role FooRole' );
  84 ok( !$foo_class_meta->does_role('OtherRole'),
  85     '... the FooClass->meta !does_role OtherRole' );
  86
  87 ok( $foobar_class_meta->does_role('FooRole'),
  88     '... the FooBarClass->meta does_role FooRole' );
  89 ok( $foobar_class_meta->does_role('BarRole'),
  90     '... the FooBarClass->meta does_role BarRole' );
  91 ok( !$foobar_class_meta->does_role('OtherRole'),
  92     '... the FooBarClass->meta !does_role OtherRole' );
  93
  94 foreach my $method_name (qw(bar baz foo boo blau goo)) {
  95     ok( $foo_class_meta->has_method($method_name),
  96         '... FooClass has the method ' . $method_name );
  97     ok( $foobar_class_meta->has_method($method_name),
  98         '... FooBarClass has the method ' . $method_name );
  99 }
 100
 101 ok( !$foo_class_meta->has_method('woot'),
 102     '... FooClass lacks the method woot' );
 103 ok( $foobar_class_meta->has_method('woot'),
 104     '... FooBarClass has the method woot' );
 105
 106 foreach my $attr_name (qw(bar baz)) {
 107     ok( $foo_class_meta->has_attribute($attr_name),
 108         '... FooClass has the attribute ' . $attr_name );
 109     ok( $foobar_class_meta->has_attribute($attr_name),
 110         '... FooBarClass has the attribute ' . $attr_name );
 111 }
 112
 113 can_ok( 'FooClass', 'does' );
 114 ok( FooClass->does('FooRole'),    '... the FooClass does FooRole' );
 115 ok( !FooClass->does('BarRole'),   '... the FooClass does not do BarRole' );
 116 ok( !FooClass->does('OtherRole'), '... the FooClass does not do OtherRole' );
 117
 118 can_ok( 'FooBarClass', 'does' );
 119 ok( FooBarClass->does('FooRole'), '... the FooClass does FooRole' );
 120 ok( FooBarClass->does('BarRole'), '... the FooBarClass does FooBarRole' );
 121 ok( !FooBarClass->does('OtherRole'),
 122     '... the FooBarClass does not do OtherRole' );
 123
 124 my $foo = FooClass->new();
 125 isa_ok( $foo, 'FooClass' );
 126
 127 my $foobar = FooBarClass->new();
 128 isa_ok( $foobar, 'FooBarClass' );
 129
 130 is( $foo->goo,    'FooClass::goo', '... got the right value of goo' );
 131 is( $foobar->goo, 'FooRole::goo',  '... got the right value of goo' );
 132
 133 is( $foo->boo, 'FooRole::boo -> BarClass::boo',
 134     '... got the right value from ->boo' );
 135 is( $foobar->boo, 'FooRole::boo -> FooRole::boo -> BarClass::boo',
 136     '... got the right value from ->boo (double wrapped)' );
 137
 138 is( $foo->blau, 'FooRole::blau -> FooClass::blau',
 139     '... got the right value from ->blau' );
 140 is( $foobar->blau, 'FooRole::blau -> FooRole::blau -> FooClass::blau',
 141     '... got the right value from ->blau' );
 142
 143 foreach my $foo ( $foo, $foobar ) {
 144     can_ok( $foo, 'does' );
 145     ok( $foo->does('FooRole'), '... an instance of FooClass does FooRole' );
 146     ok( !$foo->does('OtherRole'),
 147         '... and instance of FooClass does not do OtherRole' );
 148
 149     can_ok( $foobar, 'does' );
 150     ok( $foobar->does('FooRole'),
 151         '... an instance of FooBarClass does FooRole' );
 152     ok( $foobar->does('BarRole'),
 153         '... an instance of FooBarClass does BarRole' );
 154     ok( !$foobar->does('OtherRole'),
 155         '... and instance of FooBarClass does not do OtherRole' );
 156
 157     for my $method (qw/bar baz foo boo goo blau/) {
 158         can_ok( $foo, $method );
 159     }
 160
 161     is( $foo->foo, 'FooRole::foo', '... got the right value of foo' );
 162
 163     ok( !defined( $foo->baz ), '... $foo->baz is undefined' );
 164     ok( !defined( $foo->bar ), '... $foo->bar is undefined' );
 165
 166     dies_ok {
 167         $foo->baz(1);
 168     }
 169     '... baz is a read-only accessor';
 170
 171     dies_ok {
 172         $foo->bar(1);
 173     }
 174     '... bar is a read-write accessor with a type constraint';
 175
 176     my $foo2 = FooClass->new();
 177     isa_ok( $foo2, 'FooClass' );
 178
 179     lives_ok {
 180         $foo->bar($foo2);
 181     }
 182     '... bar is a read-write accessor with a type constraint';
 183
 184     is( $foo->bar, $foo2, '... got the right value for bar now' );
 185 }
 186
 187 done_testing;