lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use strict;
   3 use warnings;
   4
   5 use Scalar::Util qw/blessed weaken/;
   6
   7 use Mouse::Util qw/:meta get_linear_isa not_supported/;
   8
   9 use Mouse::Meta::Method::Constructor;
  10 use Mouse::Meta::Method::Destructor;
  11 use Mouse::Meta::Module;
  12 our @ISA = qw(Mouse::Meta::Module);
  13
  14 sub method_metaclass()    { 'Mouse::Meta::Method'    }
  15 sub attribute_metaclass() { 'Mouse::Meta::Attribute' }
  16
  17 sub _construct_meta {
  18     my($class, %args) = @_;
  19
  20     $args{attributes} ||= {};
  21     $args{methods}    ||= {};
  22     $args{roles}      ||= [];
  23
  24     $args{superclasses} = do {
  25         no strict 'refs';
  26         \@{ $args{package} . '::ISA' };
  27     };
  28
  29     my $self = bless \%args, ref($class) || $class;
  30     if($class ne __PACKAGE__){
  31         $self->meta->_initialize_object($self, \%args);
  32     }
  33     return $self;
  34 }
  35
  36 sub create_anon_class{
  37     my $self = shift;
  38     return $self->create(undef, @_);
  39 }
  40
  41 sub is_anon_class{
  42     return exists $_[0]->{anon_serial_id};
  43 }
  44
  45 sub roles { $_[0]->{roles} }
  46
  47 sub superclasses {
  48     my $self = shift;
  49
  50     if (@_) {
  51         Mouse::load_class($_) for @_;
  52         @{ $self->{superclasses} } = @_;
  53     }
  54
  55     return @{ $self->{superclasses} };
  56 }
  57
  58 sub find_method_by_name{
  59     my($self, $method_name) = @_;
  60     defined($method_name)
  61         or $self->throw_error('You must define a method name to find');
  62     foreach my $class( $self->linearized_isa ){
  63         my $method = $self->initialize($class)->get_method($method_name);
  64         return $method if defined $method;
  65     }
  66     return undef;
  67 }
  68
  69 sub get_all_methods {
  70     my($self) = @_;
  71     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
  72 }
  73
  74 sub get_all_method_names {
  75     my $self = shift;
  76     my %uniq;
  77     return grep { $uniq{$_}++ == 0 }
  78             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
  79             $self->linearized_isa;
  80 }
  81
  82 sub add_attribute {
  83     my $self = shift;
  84
  85     my($attr, $name);
  86
  87     if(blessed $_[0]){
  88         $attr = $_[0];
  89
  90         $attr->isa('Mouse::Meta::Attribute')
  91             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
  92
  93         $name = $attr->name;
  94     }
  95     else{
  96         # _process_attribute
  97         $name = shift;
  98
  99         my %args = (@_ == 1) ? %{$_[0]} : @_;
 100
 101         defined($name)
 102             or $self->throw_error('You must provide a name for the attribute');
 103
 104         if ($name =~ s/^\+//) { # inherited attributes
 105             my $inherited_attr;
 106
 107             foreach my $class($self->linearized_isa){
 108                 my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
 109                 $inherited_attr = $meta->get_attribute($name) and last;
 110             }
 111
 112             defined($inherited_attr)
 113                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 114
 115             $attr = $inherited_attr->clone_and_inherit_options($name, \%args);
 116         }
 117         else{
 118             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class($name, \%args);
 119             $args{traits} = \@traits if @traits;
 120
 121             $attr = $attribute_class->new($name, %args);
 122         }
 123     }
 124
 125     weaken( $attr->{associated_class} = $self );
 126
 127     $self->{attributes}{$attr->name} = $attr;
 128     $attr->install_accessors();
 129
 130     if(_MOUSE_VERBOSE && !$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 131         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 132     }
 133     return $attr;
 134 }
 135
 136 sub compute_all_applicable_attributes {
 137     Carp::cluck('compute_all_applicable_attributes() has been deprecated');
 138     return shift->get_all_attributes(@_)
 139 }
 140
 141 sub get_all_attributes {
 142     my $self = shift;
 143     my (@attr, %seen);
 144
 145     for my $class ($self->linearized_isa) {
 146         my $meta = Mouse::Util::get_metaclass_by_name($class)
 147             or next;
 148
 149         for my $name ($meta->get_attribute_list) {
 150             next if $seen{$name}++;
 151             push @attr, $meta->get_attribute($name);
 152         }
 153     }
 154
 155     return @attr;
 156 }
 157
 158 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 159
 160 sub new_object {
 161     my $self = shift;
 162     my %args = (@_ == 1 ? %{$_[0]} : @_);
 163
 164     my $object = bless {}, $self->name;
 165
 166     $self->_initialize_object($object, \%args);
 167     return $object;
 168 }
 169
 170 sub _initialize_object{
 171     my($self, $object, $args) = @_;
 172
 173     my @triggers_queue;
 174
 175     foreach my $attribute ($self->get_all_attributes) {
 176         my $from = $attribute->init_arg;
 177         my $key  = $attribute->name;
 178
 179         if (defined($from) && exists($args->{$from})) {
 180             $object->{$key} = $attribute->_coerce_and_verify($args->{$from});
 181
 182             weaken($object->{$key})
 183                 if ref($object->{$key}) && $attribute->is_weak_ref;
 184
 185             if ($attribute->has_trigger) {
 186                 push @triggers_queue, [ $attribute->trigger, $object->{$key} ];
 187             }
 188         }
 189         else {
 190             if ($attribute->has_default || $attribute->has_builder) {
 191                 unless ($attribute->is_lazy) {
 192                     my $default = $attribute->default;
 193                     my $builder = $attribute->builder;
 194                     my $value =   $builder                ? $object->$builder()
 195                                 : ref($default) eq 'CODE' ? $object->$default()
 196                                 :                           $default;
 197
 198                     # XXX: we cannot use $attribute->set_value() because it invokes triggers.
 199                     $object->{$key} = $attribute->_coerce_and_verify($value, $object);;
 200
 201                     weaken($object->{$key})
 202                         if ref($object->{$key}) && $attribute->is_weak_ref;
 203                 }
 204             }
 205             else {
 206                 if ($attribute->is_required) {
 207                     $self->throw_error("Attribute (".$attribute->name.") is required");
 208                 }
 209             }
 210         }
 211     }
 212
 213     foreach my $trigger_and_value(@triggers_queue){
 214         my($trigger, $value) = @{$trigger_and_value};
 215         $trigger->($object, $value);
 216     }
 217
 218     if($self->is_anon_class){
 219         $object->{__METACLASS__} = $self;
 220     }
 221
 222     return $object;
 223 }
 224
 225 sub clone_object {
 226     my $class  = shift;
 227     my $object = shift;
 228     my %params = (@_ == 1) ? %{$_[0]} : @_;
 229
 230     (blessed($object) && $object->isa($class->name))
 231         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 232
 233     my $cloned = bless { %$object }, ref $object;
 234     $class->_initialize_object($cloned, \%params);
 235
 236     return $cloned;
 237 }
 238
 239 sub clone_instance {
 240     my ($class, $instance, %params) = @_;
 241
 242     Carp::cluck('clone_instance has been deprecated. Use clone_object instead')
 243         if _MOUSE_VERBOSE;
 244     return $class->clone_object($instance, %params);
 245 }
 246
 247 sub make_immutable {
 248     my $self = shift;
 249     my %args = (
 250         inline_constructor => 1,
 251         inline_destructor  => 1,
 252         constructor_name   => 'new',
 253         @_,
 254     );
 255
 256     $self->{is_immutable}++;
 257
 258     if ($args{inline_constructor}) {
 259         # generate and install
 260         Mouse::Meta::Method::Constructor->_generate_constructor_method($self, \%args);
 261     }
 262
 263     if ($args{inline_destructor}) {
 264         # generate and install
 265         Mouse::Meta::Method::Destructor->_generate_destructor_method($self, \%args);
 266     }
 267
 268     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 269     # at the end of a source file.
 270     return 1;
 271 }
 272
 273 sub make_mutable { not_supported }
 274
 275 sub is_immutable {  $_[0]->{is_immutable} }
 276 sub is_mutable   { !$_[0]->{is_immutable} }
 277
 278 sub _install_modifier_pp{
 279     my( $self, $into, $type, $name, $code ) = @_;
 280
 281     my $original = $into->can($name)
 282         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 283
 284     my $modifier_table = $self->{modifiers}{$name};
 285
 286     if(!$modifier_table){
 287         my(@before, @after, @around, $cache, $modified);
 288
 289         $cache = $original;
 290
 291         $modified = sub {
 292             for my $c (@before) { $c->(@_) }
 293
 294             if(wantarray){ # list context
 295                 my @rval = $cache->(@_);
 296
 297                 for my $c(@after){ $c->(@_) }
 298                 return @rval;
 299             }
 300             elsif(defined wantarray){ # scalar context
 301                 my $rval = $cache->(@_);
 302
 303                 for my $c(@after){ $c->(@_) }
 304                 return $rval;
 305             }
 306             else{ # void context
 307                 $cache->(@_);
 308
 309                 for my $c(@after){ $c->(@_) }
 310                 return;
 311             }
 312         };
 313
 314         $self->{modifiers}{$name} = $modifier_table = {
 315             original => $original,
 316
 317             before   => \@before,
 318             after    => \@after,
 319             around   => \@around,
 320
 321             cache    => \$cache, # cache for around modifiers
 322         };
 323
 324         $self->add_method($name => $modified);
 325     }
 326
 327     if($type eq 'before'){
 328         unshift @{$modifier_table->{before}}, $code;
 329     }
 330     elsif($type eq 'after'){
 331         push @{$modifier_table->{after}}, $code;
 332     }
 333     else{ # around
 334         push @{$modifier_table->{around}}, $code;
 335
 336         my $next = ${ $modifier_table->{cache} };
 337         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 338     }
 339
 340     return;
 341 }
 342
 343 sub _install_modifier {
 344     my ( $self, $into, $type, $name, $code ) = @_;
 345
 346     # load Class::Method::Modifiers first
 347     my $no_cmm_fast = do{
 348         local $@;
 349         eval q{ require Class::Method::Modifiers::Fast };
 350         $@;
 351     };
 352
 353     my $impl;
 354     if($no_cmm_fast){
 355         $impl = \&_install_modifier_pp;
 356     }
 357     else{
 358         my $install_modifier = Class::Method::Modifiers::Fast->can('_install_modifier');
 359         $impl = sub {
 360             my ( $self, $into, $type, $name, $code ) = @_;
 361             $install_modifier->(
 362                 $into,
 363                 $type,
 364                 $name,
 365                 $code
 366             );
 367             $self->{methods}{$name}++; # register it to the method map
 368             return;
 369         };
 370     }
 371
 372     # replace this method itself :)
 373     {
 374         no warnings 'redefine';
 375         *_install_modifier = $impl;
 376     }
 377
 378     $self->$impl( $into, $type, $name, $code );
 379 }
 380
 381 sub add_before_method_modifier {
 382     my ( $self, $name, $code ) = @_;
 383     $self->_install_modifier( $self->name, 'before', $name, $code );
 384 }
 385
 386 sub add_around_method_modifier {
 387     my ( $self, $name, $code ) = @_;
 388     $self->_install_modifier( $self->name, 'around', $name, $code );
 389 }
 390
 391 sub add_after_method_modifier {
 392     my ( $self, $name, $code ) = @_;
 393     $self->_install_modifier( $self->name, 'after', $name, $code );
 394 }
 395
 396 sub add_override_method_modifier {
 397     my ($self, $name, $code) = @_;
 398
 399     my $package = $self->name;
 400
 401     my $body = $package->can($name)
 402         or $self->throw_error("You cannot override '$name' because it has no super method");
 403
 404     $self->add_method($name => sub { $code->($package, $body, @_) });
 405 }
 406
 407 sub does_role {
 408     my ($self, $role_name) = @_;
 409
 410     (defined $role_name)
 411         || $self->throw_error("You must supply a role name to look for");
 412
 413     for my $class ($self->linearized_isa) {
 414         my $meta = Mouse::Util::get_metaclass_by_name($class);
 415         next unless $meta && $meta->can('roles');
 416
 417         for my $role (@{ $meta->roles }) {
 418
 419             return 1 if $role->does_role($role_name);
 420         }
 421     }
 422
 423     return 0;
 424 }
 425
 426 1;
 427
 428 __END__
 429
 430 =head1 NAME
 431
 432 Mouse::Meta::Class - The Mouse class metaclass
 433
 434 =head1 METHODS
 435
 436 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 437
 438 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 439 one instance should exist for a given class.
 440
 441 =head2 C<< name -> ClassName >>
 442
 443 Returns the name of the owner class.
 444
 445 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 446
 447 Gets (or sets) the list of superclasses of the owner class.
 448
 449 =head2 C<< add_method(name => CodeRef) >>
 450
 451 Adds a method to the owner class.
 452
 453 =head2 C<< has_method(name) -> Bool >>
 454
 455 Returns whether we have a method with the given name.
 456
 457 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 458
 459 Returns a L<Mouse::Meta::Method> with the given name.
 460
 461 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 462
 463 =head2 C<< get_method_list -> Names >>
 464
 465 Returns a list of method names which are defined in the local class.
 466 If you want a list of all applicable methods for a class, use the
 467 C<get_all_methods> method.
 468
 469 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 470
 471 Return the list of all L<Mouse::Meta::Method> instances associated with
 472 the class and its superclasses.
 473
 474 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 475
 476 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 477 class.
 478
 479 =head2 C<< has_attribute(Name) -> Bool >>
 480
 481 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 482
 483 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 484
 485 Returns the L<Mouse::Meta::Attribute> with the given name.
 486
 487 =head2 C<< get_attribute_list -> Names >>
 488
 489 Returns a list of attribute names which are defined in the local
 490 class. If you want a list of all applicable attributes for a class,
 491 use the C<get_all_attributes> method.
 492
 493 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 494
 495 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 496 this class and its superclasses.
 497
 498 =head2 C<< linearized_isa -> [ClassNames] >>
 499
 500 Returns the list of classes in method dispatch order, with duplicates removed.
 501
 502 =head2 C<< new_object(Parameters) -> Instance >>
 503
 504 Creates a new instance.
 505
 506 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 507
 508 Clones the given instance which must be an instance governed by this
 509 metaclass.
 510
 511 =head2 C<< throw_error(Message, Parameters) >>
 512
 513 Throws an error with the given message.
 514
 515 =head1 SEE ALSO
 516
 517 L<Moose::Meta::Class>
 518
 519 L<Class::MOP::Class>
 520
 521 =cut
 522