lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta/; # enables strict and warnings
   3
   4 use Scalar::Util ();
   5
   6 use Mouse::Meta::Module;
   7 our @ISA = qw(Mouse::Meta::Module);
   8
   9 our @CARP_NOT = qw(Mouse); # trust Mouse
  10
  11 sub attribute_metaclass;
  12 sub method_metaclass;
  13
  14 sub constructor_class;
  15 sub destructor_class;
  16
  17
  18 sub _construct_meta {
  19     my($class, %args) = @_;
  20
  21     $args{attributes} = {};
  22     $args{methods}    = {};
  23     $args{roles}      = [];
  24
  25     $args{superclasses} = do {
  26         no strict 'refs';
  27         \@{ $args{package} . '::ISA' };
  28     };
  29
  30     my $self = bless \%args, ref($class) || $class;
  31     if(ref($self) ne __PACKAGE__){
  32         $self->meta->_initialize_object($self, \%args);
  33     }
  34     return $self;
  35 }
  36
  37 sub create_anon_class{
  38     my $self = shift;
  39     return $self->create(undef, @_);
  40 }
  41
  42 sub is_anon_class;
  43
  44 sub roles;
  45
  46 sub calculate_all_roles {
  47     my $self = shift;
  48     my %seen;
  49     return grep { !$seen{ $_->name }++ }
  50            map  { $_->calculate_all_roles } @{ $self->roles };
  51 }
  52
  53 sub superclasses {
  54     my $self = shift;
  55
  56     if (@_) {
  57         foreach my $super(@_){
  58             Mouse::Util::load_class($super);
  59             my $meta = Mouse::Util::get_metaclass_by_name($super);
  60             next if $self->verify_superclass($super, $meta);
  61             $self->_reconcile_with_superclass_meta($meta);
  62         }
  63         return @{ $self->{superclasses} } = @_;
  64     }
  65
  66     return @{ $self->{superclasses} };
  67 }
  68
  69 sub verify_superclass {
  70     my($self, $super, $super_meta) = @_;
  71
  72     if(defined $super_meta) {
  73         if(Mouse::Util::is_a_metarole($super_meta)){
  74             $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  75         }
  76     }
  77     else {
  78         # The metaclass of $super is not initialized.
  79         # i.e. it might be Mouse::Object, a mixin package (e.g. Exporter),
  80         # or a foreign class including Moose classes.
  81         # See also Mouse::Foreign::Meta::Role::Class.
  82         my $mm = $super->can('meta');
  83         if(!($mm && $mm == \&Mouse::Util::meta)) {
  84             if($super->can('new') or $super->can('DESTROY')) {
  85                 $self->inherit_from_foreign_class($super);
  86             }
  87         }
  88         return 1; # always ok
  89     }
  90
  91     return $self->isa(ref $super_meta); # checks metaclass compatibility
  92 }
  93
  94 sub inherit_from_foreign_class {
  95     my($class, $super) = @_;
  96     if($ENV{PERL_MOUSE_STRICT}) {
  97         Carp::carp("You inherit from non-Mouse class ($super),"
  98             . " but it is unlikely to work correctly."
  99             . " Please consider using MouseX::Foreign");
 100     }
 101     return;
 102 }
 103
 104 my @MetaClassTypes = (
 105     'attribute',   # Mouse::Meta::Attribute
 106     'method',      # Mouse::Meta::Method
 107     'constructor', # Mouse::Meta::Method::Constructor
 108     'destructor',  # Mouse::Meta::Method::Destructor
 109 );
 110
 111 sub _reconcile_with_superclass_meta {
 112     my($self, $other) = @_;
 113
 114     # find incompatible traits
 115     my %metaroles;
 116     foreach my $metaclass_type(@MetaClassTypes){
 117         my $accessor = $self->can($metaclass_type . '_metaclass')
 118             || $self->can($metaclass_type . '_class');
 119
 120         my $other_c = $other->$accessor();
 121         my $self_c  = $self->$accessor();
 122
 123         if(!$self_c->isa($other_c)){
 124             $metaroles{$metaclass_type}
 125                 = [ $self_c->meta->_collect_roles($other_c->meta) ];
 126         }
 127     }
 128
 129     $metaroles{class} = [$self->meta->_collect_roles($other->meta)];
 130
 131     #use Data::Dumper; print Data::Dumper->new([\%metaroles], ['*metaroles'])->Indent(1)->Dump;
 132
 133     require Mouse::Util::MetaRole;
 134     $_[0] = Mouse::Util::MetaRole::apply_metaroles(
 135         for             => $self,
 136         class_metaroles => \%metaroles,
 137     );
 138     return;
 139 }
 140
 141 sub _collect_roles {
 142     my ($self, $other) = @_;
 143
 144     # find common ancestor
 145     my @self_lin_isa  = $self->linearized_isa;
 146     my @other_lin_isa = $other->linearized_isa;
 147
 148     my(@self_anon_supers, @other_anon_supers);
 149     push @self_anon_supers,  shift @self_lin_isa  while $self_lin_isa[0]->meta->is_anon_class;
 150     push @other_anon_supers, shift @other_lin_isa while $other_lin_isa[0]->meta->is_anon_class;
 151
 152     my $common_ancestor = $self_lin_isa[0] eq $other_lin_isa[0] && $self_lin_isa[0];
 153
 154     if(!$common_ancestor){
 155         $self->throw_error(sprintf '%s cannot have %s as a super class because of their metaclass incompatibility',
 156             $self->name, $other->name);
 157     }
 158
 159     my %seen;
 160     return sort grep { !$seen{$_}++ } ## no critic
 161         (map{ $_->name } map{ $_->meta->calculate_all_roles } @self_anon_supers),
 162         (map{ $_->name } map{ $_->meta->calculate_all_roles } @other_anon_supers),
 163     ;
 164 }
 165
 166
 167 sub find_method_by_name {
 168     my($self, $method_name) = @_;
 169     defined($method_name)
 170         or $self->throw_error('You must define a method name to find');
 171
 172     foreach my $class( $self->linearized_isa ){
 173         my $method = $self->initialize($class)->get_method($method_name);
 174         return $method if defined $method;
 175     }
 176     return undef;
 177 }
 178
 179 sub get_all_methods {
 180     my($self) = @_;
 181     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
 182 }
 183
 184 sub get_all_method_names {
 185     my $self = shift;
 186     my %uniq;
 187     return grep { $uniq{$_}++ == 0 }
 188             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
 189             $self->linearized_isa;
 190 }
 191
 192 sub find_attribute_by_name {
 193     my($self, $name) = @_;
 194     defined($name)
 195         or $self->throw_error('You must define an attribute name to find');
 196     foreach my $attr($self->get_all_attributes) {
 197         return $attr if $attr->name eq $name;
 198     }
 199     return undef;
 200 }
 201
 202 sub add_attribute {
 203     my $self = shift;
 204
 205     my($attr, $name);
 206
 207     if(Scalar::Util::blessed($_[0])){
 208         $attr = $_[0];
 209
 210         $attr->isa('Mouse::Meta::Attribute')
 211             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 212
 213         $name = $attr->name;
 214     }
 215     else{
 216         # _process_attribute
 217         $name = shift;
 218
 219         my %args = (@_ == 1) ? %{$_[0]} : @_;
 220
 221         defined($name)
 222             or $self->throw_error('You must provide a name for the attribute');
 223
 224         if ($name =~ s/^\+//) { # inherited attributes
 225             my $inherited_attr = $self->find_attribute_by_name($name)
 226                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 227
 228             $attr = $inherited_attr->clone_and_inherit_options(%args);
 229         }
 230         else{
 231             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 232             $args{traits} = \@traits if @traits;
 233
 234             $attr = $attribute_class->new($name, %args);
 235         }
 236     }
 237
 238     Scalar::Util::weaken( $attr->{associated_class} = $self );
 239
 240     # install accessors first
 241     $attr->install_accessors();
 242
 243     # then register the attribute to the metaclass
 244     $attr->{insertion_order}   = keys %{ $self->{attributes} };
 245     $self->{attributes}{$name} = $attr;
 246     $self->_invalidate_metaclass_cache();
 247
 248     if(!$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 249         Carp::carp(qq{Attribute ($name) of class }.$self->name
 250             .qq{ has no associated methods (did you mean to provide an "is" argument?)});
 251     }
 252     return $attr;
 253 }
 254
 255 sub _calculate_all_attributes {
 256     my($self) = @_;
 257     my %seen;
 258     my @all_attrs;
 259     foreach my $class($self->linearized_isa) {
 260         my $meta  = Mouse::Util::get_metaclass_by_name($class) or next;
 261         my @attrs = grep { !$seen{$_->name}++ } values %{$meta->{attributes}};
 262         @attrs = sort {
 263                 $b->{insertion_order} <=> $a->{insertion_order}
 264             } @attrs;
 265         push @all_attrs, @attrs;
 266     }
 267     return [reverse @all_attrs];
 268 }
 269
 270 sub linearized_isa;
 271
 272 sub new_object;
 273 sub clone_object;
 274
 275 sub immutable_options {
 276     my ( $self, @args ) = @_;
 277
 278     return (
 279         inline_constructor => 1,
 280         inline_destructor  => 1,
 281         constructor_name   => 'new',
 282         @args,
 283     );
 284 }
 285
 286 sub make_immutable {
 287     my $self = shift;
 288     my %args = $self->immutable_options(@_);
 289
 290     $self->{is_immutable}++;
 291
 292     if ($args{inline_constructor}) {
 293         $self->add_method($args{constructor_name} =>
 294             Mouse::Util::load_class($self->constructor_class)
 295                 ->_generate_constructor($self, \%args));
 296     }
 297
 298     if ($args{inline_destructor}) {
 299         $self->add_method(DESTROY =>
 300             Mouse::Util::load_class($self->destructor_class)
 301                 ->_generate_destructor($self, \%args));
 302     }
 303
 304     # Moose's make_immutable returns true allowing calling code to skip
 305     # setting an explicit true value at the end of a source file.
 306     return 1;
 307 }
 308
 309 sub make_mutable {
 310     my($self) = @_;
 311     $self->{is_immutable} = 0;
 312     return;
 313 }
 314
 315 sub is_immutable;
 316 sub is_mutable   { !$_[0]->is_immutable }
 317
 318 sub _install_modifier {
 319     my( $self, $type, $name, $code ) = @_;
 320     my $into = $self->name;
 321
 322     my $original = $into->can($name)
 323         or $self->throw_error("The method '$name' was not found in the inheritance hierarchy for $into");
 324
 325     my $modifier_table = $self->{modifiers}{$name};
 326
 327     if(!$modifier_table){
 328         my(@before, @after, @around);
 329         my $cache = $original;
 330         my $modified = sub {
 331             if(@before) {
 332                 for my $c (@before) { $c->(@_) }
 333             }
 334             unless(@after) {
 335                 return $cache->(@_);
 336             }
 337
 338             if(wantarray){ # list context
 339                 my @rval = $cache->(@_);
 340
 341                 for my $c(@after){ $c->(@_) }
 342                 return @rval;
 343             }
 344             elsif(defined wantarray){ # scalar context
 345                 my $rval = $cache->(@_);
 346
 347                 for my $c(@after){ $c->(@_) }
 348                 return $rval;
 349             }
 350             else{ # void context
 351                 $cache->(@_);
 352
 353                 for my $c(@after){ $c->(@_) }
 354                 return;
 355             }
 356         };
 357
 358         $self->{modifiers}{$name} = $modifier_table = {
 359             original => $original,
 360
 361             before   => \@before,
 362             after    => \@after,
 363             around   => \@around,
 364
 365             cache    => \$cache, # cache for around modifiers
 366         };
 367
 368         $self->add_method($name => $modified);
 369     }
 370
 371     if($type eq 'before'){
 372         unshift @{$modifier_table->{before}}, $code;
 373     }
 374     elsif($type eq 'after'){
 375         push @{$modifier_table->{after}}, $code;
 376     }
 377     else{ # around
 378         push @{$modifier_table->{around}}, $code;
 379
 380         my $next = ${ $modifier_table->{cache} };
 381         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 382     }
 383
 384     return;
 385 }
 386
 387 sub add_before_method_modifier {
 388     my ( $self, $name, $code ) = @_;
 389     $self->_install_modifier( 'before', $name, $code );
 390 }
 391
 392 sub add_around_method_modifier {
 393     my ( $self, $name, $code ) = @_;
 394     $self->_install_modifier( 'around', $name, $code );
 395 }
 396
 397 sub add_after_method_modifier {
 398     my ( $self, $name, $code ) = @_;
 399     $self->_install_modifier( 'after', $name, $code );
 400 }
 401
 402 sub add_override_method_modifier {
 403     my ($self, $name, $code) = @_;
 404
 405     if($self->has_method($name)){
 406         $self->throw_error("Cannot add an override method if a local method is already present");
 407     }
 408
 409     my $package = $self->name;
 410
 411     my $super_body = $package->can($name)
 412         or $self->throw_error("You cannot override '$name' because it has no super method");
 413
 414     $self->add_method($name => sub {
 415         local $Mouse::SUPER_PACKAGE = $package;
 416         local $Mouse::SUPER_BODY    = $super_body;
 417         local @Mouse::SUPER_ARGS    = @_;
 418         &{$code};
 419     });
 420     return;
 421 }
 422
 423 sub add_augment_method_modifier {
 424     my ($self, $name, $code) = @_;
 425     if($self->has_method($name)){
 426         $self->throw_error("Cannot add an augment method if a local method is already present");
 427     }
 428
 429     my $super = $self->find_method_by_name($name)
 430         or $self->throw_error("You cannot augment '$name' because it has no super method");
 431
 432     my $super_package = $super->package_name;
 433     my $super_body    = $super->body;
 434
 435     $self->add_method($name => sub {
 436         local $Mouse::INNER_BODY{$super_package} = $code;
 437         local $Mouse::INNER_ARGS{$super_package} = [@_];
 438         &{$super_body};
 439     });
 440     return;
 441 }
 442
 443 sub does_role {
 444     my ($self, $role_name) = @_;
 445
 446     (defined $role_name)
 447         || $self->throw_error("You must supply a role name to look for");
 448
 449     $role_name = $role_name->name if ref $role_name;
 450
 451     for my $class ($self->linearized_isa) {
 452         my $meta = Mouse::Util::get_metaclass_by_name($class)
 453             or next;
 454
 455         for my $role (@{ $meta->roles }) {
 456
 457             return 1 if $role->does_role($role_name);
 458         }
 459     }
 460
 461     return 0;
 462 }
 463
 464 1;
 465 __END__
 466
 467 =head1 NAME
 468
 469 Mouse::Meta::Class - The Mouse class metaclass
 470
 471 =head1 VERSION
 472
 473 This document describes Mouse version 0.95
 474
 475 =head1 DESCRIPTION
 476
 477 This class is a meta object protocol for Mouse classes,
 478 which is a subset of Moose::Meta:::Class.
 479
 480 =head1 METHODS
 481
 482 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 483
 484 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 485 one instance should exist for a given class.
 486
 487 =head2 C<< name -> ClassName >>
 488
 489 Returns the name of the owner class.
 490
 491 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 492
 493 Gets (or sets) the list of superclasses of the owner class.
 494
 495 =head2 C<< add_method(name => CodeRef) >>
 496
 497 Adds a method to the owner class.
 498
 499 =head2 C<< has_method(name) -> Bool >>
 500
 501 Returns whether we have a method with the given name.
 502
 503 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 504
 505 Returns a L<Mouse::Meta::Method> with the given name.
 506
 507 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 508
 509 =head2 C<< get_method_list -> Names >>
 510
 511 Returns a list of method names which are defined in the local class.
 512 If you want a list of all applicable methods for a class, use the
 513 C<get_all_methods> method.
 514
 515 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 516
 517 Return the list of all L<Mouse::Meta::Method> instances associated with
 518 the class and its superclasses.
 519
 520 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 521
 522 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 523 class.
 524
 525 =head2 C<< has_attribute(Name) -> Bool >>
 526
 527 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 528
 529 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 530
 531 Returns the L<Mouse::Meta::Attribute> with the given name.
 532
 533 =head2 C<< get_attribute_list -> Names >>
 534
 535 Returns a list of attribute names which are defined in the local
 536 class. If you want a list of all applicable attributes for a class,
 537 use the C<get_all_attributes> method.
 538
 539 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 540
 541 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 542 this class and its superclasses.
 543
 544 =head2 C<< linearized_isa -> [ClassNames] >>
 545
 546 Returns the list of classes in method dispatch order, with duplicates removed.
 547
 548 =head2 C<< new_object(Parameters) -> Instance >>
 549
 550 Creates a new instance.
 551
 552 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 553
 554 Clones the given instance which must be an instance governed by this
 555 metaclass.
 556
 557 =head2 C<< throw_error(Message, Parameters) >>
 558
 559 Throws an error with the given message.
 560
 561 =head1 SEE ALSO
 562
 563 L<Mouse::Meta::Module>
 564
 565 L<Moose::Meta::Class>
 566
 567 L<Class::MOP::Class>
 568
 569 =cut
 570