lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Module;
   7 our @ISA = qw(Mouse::Meta::Module);
   8
   9 our @CARP_NOT = qw(Mouse); # trust Mouse
  10
  11 sub attribute_metaclass;
  12 sub method_metaclass;
  13
  14 sub constructor_class;
  15 sub destructor_class;
  16
  17
  18 sub _construct_meta {
  19     my($class, %args) = @_;
  20
  21     $args{attributes} = {};
  22     $args{methods}    = {};
  23     $args{roles}      = [];
  24
  25     $args{superclasses} = do {
  26         no strict 'refs';
  27         \@{ $args{package} . '::ISA' };
  28     };
  29
  30     my $self = bless \%args, ref($class) || $class;
  31     if(ref($self) ne __PACKAGE__){
  32         $self->meta->_initialize_object($self, \%args);
  33     }
  34     return $self;
  35 }
  36
  37 sub create_anon_class{
  38     my $self = shift;
  39     return $self->create(undef, @_);
  40 }
  41
  42 sub is_anon_class;
  43
  44 sub roles;
  45
  46 sub calculate_all_roles {
  47     my $self = shift;
  48     my %seen;
  49     return grep { !$seen{ $_->name }++ }
  50            map  { $_->calculate_all_roles } @{ $self->roles };
  51 }
  52
  53 sub superclasses {
  54     my $self = shift;
  55
  56     if (@_) {
  57         foreach my $super(@_){
  58             Mouse::Util::load_class($super);
  59             my $meta = Mouse::Util::get_metaclass_by_name($super);
  60
  61             next if not defined $meta;
  62
  63             if(Mouse::Util::is_a_metarole($meta)){
  64                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  65             }
  66
  67             next if $self->isa(ref $meta); # _superclass_meta_is_compatible
  68
  69             $self->_reconcile_with_superclass_meta($meta);
  70         }
  71         @{ $self->{superclasses} } = @_;
  72     }
  73
  74     return @{ $self->{superclasses} };
  75 }
  76 my @MetaClassTypes = (
  77     'attribute',   # Mouse::Meta::Attribute
  78     'method',      # Mouse::Meta::Method
  79     'constructor', # Mouse::Meta::Method::Constructor
  80     'destructor',  # Mouse::Meta::Method::Destructor
  81 );
  82
  83 sub _reconcile_with_superclass_meta {
  84     my($self, $other) = @_;
  85
  86     # find incompatible traits
  87     my %metaroles;
  88     foreach my $metaclass_type(@MetaClassTypes){
  89         my $accessor = $self->can($metaclass_type . '_metaclass')
  90             || $self->can($metaclass_type . '_class');
  91
  92         my $other_c = $other->$accessor();
  93         my $self_c  = $self->$accessor();
  94
  95         if(!$self_c->isa($other_c)){
  96             $metaroles{$metaclass_type}
  97                 = [ $self_c->meta->_collect_roles($other_c->meta) ];
  98         }
  99     }
 100
 101     $metaroles{class} = [$self->meta->_collect_roles($other->meta)];
 102
 103     #use Data::Dumper; print Data::Dumper->new([\%metaroles], ['*metaroles'])->Indent(1)->Dump;
 104
 105     require Mouse::Util::MetaRole;
 106     $_[0] = Mouse::Util::MetaRole::apply_metaroles(
 107         for             => $self,
 108         class_metaroles => \%metaroles,
 109     );
 110     return;
 111 }
 112
 113 sub _collect_roles {
 114     my ($self, $other) = @_;
 115
 116     # find common ancestor
 117     my @self_lin_isa  = $self->linearized_isa;
 118     my @other_lin_isa = $other->linearized_isa;
 119
 120     my(@self_anon_supers, @other_anon_supers);
 121     push @self_anon_supers,  shift @self_lin_isa  while $self_lin_isa[0]->meta->is_anon_class;
 122     push @other_anon_supers, shift @other_lin_isa while $other_lin_isa[0]->meta->is_anon_class;
 123
 124     my $common_ancestor = $self_lin_isa[0] eq $other_lin_isa[0] && $self_lin_isa[0];
 125
 126     if(!$common_ancestor){
 127         $self->throw_error(sprintf '%s cannot have %s as a super class because of their metaclass incompatibility',
 128             $self->name, $other->name);
 129     }
 130
 131     my %seen;
 132     return sort grep { !$seen{$_}++ } ## no critic
 133         (map{ $_->name } map{ $_->meta->calculate_all_roles } @self_anon_supers),
 134         (map{ $_->name } map{ $_->meta->calculate_all_roles } @other_anon_supers),
 135     ;
 136 }
 137
 138
 139 sub find_method_by_name{
 140     my($self, $method_name) = @_;
 141     defined($method_name)
 142         or $self->throw_error('You must define a method name to find');
 143
 144     foreach my $class( $self->linearized_isa ){
 145         my $method = $self->initialize($class)->get_method($method_name);
 146         return $method if defined $method;
 147     }
 148     return undef;
 149 }
 150
 151 sub get_all_methods {
 152     my($self) = @_;
 153     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
 154 }
 155
 156 sub get_all_method_names {
 157     my $self = shift;
 158     my %uniq;
 159     return grep { $uniq{$_}++ == 0 }
 160             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
 161             $self->linearized_isa;
 162 }
 163
 164 sub find_attribute_by_name{
 165     my($self, $name) = @_;
 166     my $attr;
 167     foreach my $class($self->linearized_isa){
 168         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
 169         $attr = $meta->get_attribute($name) and last;
 170     }
 171     return $attr;
 172 }
 173
 174 sub add_attribute {
 175     my $self = shift;
 176
 177     my($attr, $name);
 178
 179     if(blessed $_[0]){
 180         $attr = $_[0];
 181
 182         $attr->isa('Mouse::Meta::Attribute')
 183             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 184
 185         $name = $attr->name;
 186     }
 187     else{
 188         # _process_attribute
 189         $name = shift;
 190
 191         my %args = (@_ == 1) ? %{$_[0]} : @_;
 192
 193         defined($name)
 194             or $self->throw_error('You must provide a name for the attribute');
 195
 196         if ($name =~ s/^\+//) { # inherited attributes
 197             my $inherited_attr = $self->find_attribute_by_name($name)
 198                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 199
 200             $attr = $inherited_attr->clone_and_inherit_options(%args);
 201         }
 202         else{
 203             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 204             $args{traits} = \@traits if @traits;
 205
 206             $attr = $attribute_class->new($name, %args);
 207         }
 208     }
 209
 210     weaken( $attr->{associated_class} = $self );
 211
 212     # install accessors first
 213     $attr->install_accessors();
 214
 215     # then register the attribute to the metaclass
 216     $attr->{insertion_order} = keys %{ $self->{attributes} };
 217     $self->{attributes}{$attr->name} = $attr;
 218
 219     if(!$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 220         Carp::carp(qq{Attribute ($name) of class }.$self->name
 221             .qq{ has no associated methods (did you mean to provide an "is" argument?)});
 222     }
 223     return $attr;
 224 }
 225
 226 sub linearized_isa;
 227
 228 sub new_object;
 229 sub clone_object;
 230
 231 sub immutable_options {
 232     my ( $self, @args ) = @_;
 233
 234     return (
 235         inline_constructor => 1,
 236         inline_destructor  => 1,
 237         constructor_name   => 'new',
 238         @args,
 239     );
 240 }
 241
 242 sub make_immutable {
 243     my $self = shift;
 244     my %args = $self->immutable_options(@_);
 245
 246     $self->{is_immutable}++;
 247
 248     if ($args{inline_constructor}) {
 249         $self->add_method($args{constructor_name} =>
 250             Mouse::Util::load_class($self->constructor_class)
 251                 ->_generate_constructor($self, \%args));
 252     }
 253
 254     if ($args{inline_destructor}) {
 255         $self->add_method(DESTROY =>
 256             Mouse::Util::load_class($self->destructor_class)
 257                 ->_generate_destructor($self, \%args));
 258     }
 259
 260     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 261     # at the end of a source file.
 262     return 1;
 263 }
 264
 265 sub make_mutable {
 266     my($self) = @_;
 267     $self->{is_immutable} = 0;
 268     return;
 269 }
 270
 271 sub is_immutable;
 272 sub is_mutable   { !$_[0]->is_immutable }
 273
 274 sub _install_modifier {
 275     my( $self, $type, $name, $code ) = @_;
 276     my $into = $self->name;
 277
 278     my $original = $into->can($name)
 279         or $self->throw_error("The method '$name' was not found in the inheritance hierarchy for $into");
 280
 281     my $modifier_table = $self->{modifiers}{$name};
 282
 283     if(!$modifier_table){
 284         my(@before, @after, @around);
 285         my $cache = $original;
 286         my $modified = sub {
 287             if(@before) {
 288                 for my $c (@before) { $c->(@_) }
 289             }
 290             unless(@after) {
 291                 return $cache->(@_);
 292             }
 293
 294             if(wantarray){ # list context
 295                 my @rval = $cache->(@_);
 296
 297                 for my $c(@after){ $c->(@_) }
 298                 return @rval;
 299             }
 300             elsif(defined wantarray){ # scalar context
 301                 my $rval = $cache->(@_);
 302
 303                 for my $c(@after){ $c->(@_) }
 304                 return $rval;
 305             }
 306             else{ # void context
 307                 $cache->(@_);
 308
 309                 for my $c(@after){ $c->(@_) }
 310                 return;
 311             }
 312         };
 313
 314         $self->{modifiers}{$name} = $modifier_table = {
 315             original => $original,
 316
 317             before   => \@before,
 318             after    => \@after,
 319             around   => \@around,
 320
 321             cache    => \$cache, # cache for around modifiers
 322         };
 323
 324         $self->add_method($name => $modified);
 325     }
 326
 327     if($type eq 'before'){
 328         unshift @{$modifier_table->{before}}, $code;
 329     }
 330     elsif($type eq 'after'){
 331         push @{$modifier_table->{after}}, $code;
 332     }
 333     else{ # around
 334         push @{$modifier_table->{around}}, $code;
 335
 336         my $next = ${ $modifier_table->{cache} };
 337         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 338     }
 339
 340     return;
 341 }
 342
 343 sub add_before_method_modifier {
 344     my ( $self, $name, $code ) = @_;
 345     $self->_install_modifier( 'before', $name, $code );
 346 }
 347
 348 sub add_around_method_modifier {
 349     my ( $self, $name, $code ) = @_;
 350     $self->_install_modifier( 'around', $name, $code );
 351 }
 352
 353 sub add_after_method_modifier {
 354     my ( $self, $name, $code ) = @_;
 355     $self->_install_modifier( 'after', $name, $code );
 356 }
 357
 358 sub add_override_method_modifier {
 359     my ($self, $name, $code) = @_;
 360
 361     if($self->has_method($name)){
 362         $self->throw_error("Cannot add an override method if a local method is already present");
 363     }
 364
 365     my $package = $self->name;
 366
 367     my $super_body = $package->can($name)
 368         or $self->throw_error("You cannot override '$name' because it has no super method");
 369
 370     $self->add_method($name => sub {
 371         local $Mouse::SUPER_PACKAGE = $package;
 372         local $Mouse::SUPER_BODY    = $super_body;
 373         local @Mouse::SUPER_ARGS    = @_;
 374
 375         $code->(@_);
 376     });
 377     return;
 378 }
 379
 380 sub add_augment_method_modifier {
 381     my ($self, $name, $code) = @_;
 382     if($self->has_method($name)){
 383         $self->throw_error("Cannot add an augment method if a local method is already present");
 384     }
 385
 386     my $super = $self->find_method_by_name($name)
 387         or $self->throw_error("You cannot augment '$name' because it has no super method");
 388
 389     my $super_package = $super->package_name;
 390     my $super_body    = $super->body;
 391
 392     $self->add_method($name => sub{
 393         local $Mouse::INNER_BODY{$super_package} = $code;
 394         local $Mouse::INNER_ARGS{$super_package} = [@_];
 395         $super_body->(@_);
 396     });
 397     return;
 398 }
 399
 400 sub does_role {
 401     my ($self, $role_name) = @_;
 402
 403     (defined $role_name)
 404         || $self->throw_error("You must supply a role name to look for");
 405
 406     $role_name = $role_name->name if ref $role_name;
 407
 408     for my $class ($self->linearized_isa) {
 409         my $meta = Mouse::Util::get_metaclass_by_name($class)
 410             or next;
 411
 412         for my $role (@{ $meta->roles }) {
 413
 414             return 1 if $role->does_role($role_name);
 415         }
 416     }
 417
 418     return 0;
 419 }
 420
 421 1;
 422 __END__
 423
 424 =head1 NAME
 425
 426 Mouse::Meta::Class - The Mouse class metaclass
 427
 428 =head1 VERSION
 429
 430 This document describes Mouse version 0.68
 431
 432 =head1 DESCRIPTION
 433
 434 This class is a meta object protocol for Mouse classes,
 435 which is a subset of Moose::Meta:::Class.
 436
 437 =head1 METHODS
 438
 439 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 440
 441 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 442 one instance should exist for a given class.
 443
 444 =head2 C<< name -> ClassName >>
 445
 446 Returns the name of the owner class.
 447
 448 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 449
 450 Gets (or sets) the list of superclasses of the owner class.
 451
 452 =head2 C<< add_method(name => CodeRef) >>
 453
 454 Adds a method to the owner class.
 455
 456 =head2 C<< has_method(name) -> Bool >>
 457
 458 Returns whether we have a method with the given name.
 459
 460 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 461
 462 Returns a L<Mouse::Meta::Method> with the given name.
 463
 464 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 465
 466 =head2 C<< get_method_list -> Names >>
 467
 468 Returns a list of method names which are defined in the local class.
 469 If you want a list of all applicable methods for a class, use the
 470 C<get_all_methods> method.
 471
 472 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 473
 474 Return the list of all L<Mouse::Meta::Method> instances associated with
 475 the class and its superclasses.
 476
 477 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 478
 479 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 480 class.
 481
 482 =head2 C<< has_attribute(Name) -> Bool >>
 483
 484 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 485
 486 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 487
 488 Returns the L<Mouse::Meta::Attribute> with the given name.
 489
 490 =head2 C<< get_attribute_list -> Names >>
 491
 492 Returns a list of attribute names which are defined in the local
 493 class. If you want a list of all applicable attributes for a class,
 494 use the C<get_all_attributes> method.
 495
 496 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 497
 498 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 499 this class and its superclasses.
 500
 501 =head2 C<< linearized_isa -> [ClassNames] >>
 502
 503 Returns the list of classes in method dispatch order, with duplicates removed.
 504
 505 =head2 C<< new_object(Parameters) -> Instance >>
 506
 507 Creates a new instance.
 508
 509 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 510
 511 Clones the given instance which must be an instance governed by this
 512 metaclass.
 513
 514 =head2 C<< throw_error(Message, Parameters) >>
 515
 516 Throws an error with the given message.
 517
 518 =head1 SEE ALSO
 519
 520 L<Mouse::Meta::Module>
 521
 522 L<Moose::Meta::Class>
 523
 524 L<Class::MOP::Class>
 525
 526 =cut
 527