lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Method::Constructor;
   7 use Mouse::Meta::Method::Destructor;
   8 use Mouse::Meta::Module;
   9 our @ISA = qw(Mouse::Meta::Module);
  10
  11 sub method_metaclass()    { 'Mouse::Meta::Method'    }
  12 sub attribute_metaclass() { 'Mouse::Meta::Attribute' }
  13
  14 sub constructor_class()   { 'Mouse::Meta::Method::Constructor' }
  15 sub destructor_class()    { 'Mouse::Meta::Method::Destructor'  }
  16
  17 sub _construct_meta {
  18     my($class, %args) = @_;
  19
  20     $args{attributes} = {};
  21     $args{methods}    = {};
  22     $args{roles}      = [];
  23
  24     $args{superclasses} = do {
  25         no strict 'refs';
  26         \@{ $args{package} . '::ISA' };
  27     };
  28
  29     my $self = bless \%args, ref($class) || $class;
  30     if(ref($self) ne __PACKAGE__){
  31         $self->meta->_initialize_object($self, \%args);
  32     }
  33     return $self;
  34 }
  35
  36 sub create_anon_class{
  37     my $self = shift;
  38     return $self->create(undef, @_);
  39 }
  40
  41 sub is_anon_class;
  42
  43 sub roles;
  44
  45 sub calculate_all_roles {
  46     my $self = shift;
  47     my %seen;
  48     return grep { !$seen{ $_->name }++ }
  49            map  { $_->calculate_all_roles } @{ $self->roles };
  50 }
  51
  52 sub superclasses {
  53     my $self = shift;
  54
  55     if (@_) {
  56         foreach my $super(@_){
  57             Mouse::Util::load_class($super);
  58             my $meta = Mouse::Util::get_metaclass_by_name($super);
  59             if(Mouse::Util::is_a_metarole($meta)){
  60                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  61             }
  62         }
  63         @{ $self->{superclasses} } = @_;
  64     }
  65
  66     return @{ $self->{superclasses} };
  67 }
  68
  69 sub find_method_by_name{
  70     my($self, $method_name) = @_;
  71     defined($method_name)
  72         or $self->throw_error('You must define a method name to find');
  73
  74     foreach my $class( $self->linearized_isa ){
  75         my $method = $self->initialize($class)->get_method($method_name);
  76         return $method if defined $method;
  77     }
  78     return undef;
  79 }
  80
  81 sub get_all_methods {
  82     my($self) = @_;
  83     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
  84 }
  85
  86 sub get_all_method_names {
  87     my $self = shift;
  88     my %uniq;
  89     return grep { $uniq{$_}++ == 0 }
  90             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
  91             $self->linearized_isa;
  92 }
  93
  94 sub find_attribute_by_name{
  95     my($self, $name) = @_;
  96     my $attr;
  97     foreach my $class($self->linearized_isa){
  98         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
  99         $attr = $meta->get_attribute($name) and last;
 100     }
 101     return $attr;
 102 }
 103
 104 sub add_attribute {
 105     my $self = shift;
 106
 107     my($attr, $name);
 108
 109     if(blessed $_[0]){
 110         $attr = $_[0];
 111
 112         $attr->isa('Mouse::Meta::Attribute')
 113             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 114
 115         $name = $attr->name;
 116     }
 117     else{
 118         # _process_attribute
 119         $name = shift;
 120
 121         my %args = (@_ == 1) ? %{$_[0]} : @_;
 122
 123         defined($name)
 124             or $self->throw_error('You must provide a name for the attribute');
 125
 126         if ($name =~ s/^\+//) { # inherited attributes
 127             my $inherited_attr = $self->find_attribute_by_name($name)
 128                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 129
 130             $attr = $inherited_attr->clone_and_inherit_options(%args);
 131         }
 132         else{
 133             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 134             $args{traits} = \@traits if @traits;
 135
 136             $attr = $attribute_class->new($name, %args);
 137         }
 138     }
 139
 140     weaken( $attr->{associated_class} = $self );
 141
 142     $self->{attributes}{$attr->name} = $attr;
 143     $attr->install_accessors();
 144
 145     if(_MOUSE_VERBOSE && !$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 146         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 147     }
 148     return $attr;
 149 }
 150
 151 sub compute_all_applicable_attributes {
 152     Carp::cluck('compute_all_applicable_attributes() has been deprecated')
 153         if _MOUSE_VERBOSE;
 154     return shift->get_all_attributes(@_)
 155 }
 156
 157 sub linearized_isa;
 158
 159 sub new_object {
 160     my $self = shift;
 161     my %args = (@_ == 1 ? %{$_[0]} : @_);
 162
 163     my $object = bless {}, $self->name;
 164
 165     $self->_initialize_object($object, \%args);
 166     return $object;
 167 }
 168
 169 sub _initialize_object{
 170     my($self, $object, $args, $ignore_triggers) = @_;
 171
 172     my @triggers_queue;
 173
 174     foreach my $attribute ($self->get_all_attributes) {
 175         my $from = $attribute->init_arg;
 176         my $key  = $attribute->name;
 177
 178         if (defined($from) && exists($args->{$from})) {
 179             $object->{$key} = $attribute->_coerce_and_verify($args->{$from}, $object);
 180
 181             weaken($object->{$key})
 182                 if ref($object->{$key}) && $attribute->is_weak_ref;
 183
 184             if ($attribute->has_trigger) {
 185                 push @triggers_queue, [ $attribute->trigger, $object->{$key} ];
 186             }
 187         }
 188         else {
 189             if ($attribute->has_default || $attribute->has_builder) {
 190                 unless ($attribute->is_lazy) {
 191                     my $default = $attribute->default;
 192                     my $builder = $attribute->builder;
 193                     my $value =   $builder                ? $object->$builder()
 194                                 : ref($default) eq 'CODE' ? $object->$default()
 195                                 :                           $default;
 196
 197                     $object->{$key} = $attribute->_coerce_and_verify($value, $object);
 198
 199                     weaken($object->{$key})
 200                         if ref($object->{$key}) && $attribute->is_weak_ref;
 201                 }
 202             }
 203             else {
 204                 if ($attribute->is_required) {
 205                     $self->throw_error("Attribute (".$attribute->name.") is required");
 206                 }
 207             }
 208         }
 209     }
 210
 211     if(!$ignore_triggers){
 212         foreach my $trigger_and_value(@triggers_queue){
 213             my($trigger, $value) = @{$trigger_and_value};
 214             $trigger->($object, $value);
 215         }
 216     }
 217
 218     if($self->is_anon_class){
 219         $object->{__METACLASS__} = $self;
 220     }
 221
 222     return $object;
 223 }
 224
 225 sub clone_object {
 226     my $class  = shift;
 227     my $object = shift;
 228     my %params = (@_ == 1) ? %{$_[0]} : @_;
 229
 230     (blessed($object) && $object->isa($class->name))
 231         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 232
 233     my $cloned = bless { %$object }, ref $object;
 234     $class->_initialize_object($cloned, \%params);
 235
 236     return $cloned;
 237 }
 238
 239 sub clone_instance {
 240     my ($class, $instance, %params) = @_;
 241
 242     Carp::cluck('clone_instance has been deprecated. Use clone_object instead')
 243         if _MOUSE_VERBOSE;
 244     return $class->clone_object($instance, %params);
 245 }
 246
 247 sub make_immutable {
 248     my $self = shift;
 249     my %args = (
 250         inline_constructor => 1,
 251         inline_destructor  => 1,
 252         constructor_name   => 'new',
 253         @_,
 254     );
 255
 256     $self->{is_immutable}++;
 257
 258     if ($args{inline_constructor}) {
 259         $self->add_method($args{constructor_name} =>
 260             $self->constructor_class->_generate_constructor($self, \%args));
 261     }
 262
 263     if ($args{inline_destructor}) {
 264         $self->add_method(DESTROY =>
 265             $self->destructor_class->_generate_destructor($self, \%args));
 266     }
 267
 268     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 269     # at the end of a source file.
 270     return 1;
 271 }
 272
 273 sub make_mutable { not_supported }
 274
 275 sub is_immutable {  $_[0]->{is_immutable} }
 276 sub is_mutable   { !$_[0]->{is_immutable} }
 277
 278 sub _install_modifier_pp{
 279     my( $self, $type, $name, $code ) = @_;
 280     my $into = $self->name;
 281
 282     my $original = $into->can($name)
 283         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 284
 285     my $modifier_table = $self->{modifiers}{$name};
 286
 287     if(!$modifier_table){
 288         my(@before, @after, @around, $cache, $modified);
 289
 290         $cache = $original;
 291
 292         $modified = sub {
 293             for my $c (@before) { $c->(@_) }
 294
 295             if(wantarray){ # list context
 296                 my @rval = $cache->(@_);
 297
 298                 for my $c(@after){ $c->(@_) }
 299                 return @rval;
 300             }
 301             elsif(defined wantarray){ # scalar context
 302                 my $rval = $cache->(@_);
 303
 304                 for my $c(@after){ $c->(@_) }
 305                 return $rval;
 306             }
 307             else{ # void context
 308                 $cache->(@_);
 309
 310                 for my $c(@after){ $c->(@_) }
 311                 return;
 312             }
 313         };
 314
 315         $self->{modifiers}{$name} = $modifier_table = {
 316             original => $original,
 317
 318             before   => \@before,
 319             after    => \@after,
 320             around   => \@around,
 321
 322             cache    => \$cache, # cache for around modifiers
 323         };
 324
 325         $self->add_method($name => $modified);
 326     }
 327
 328     if($type eq 'before'){
 329         unshift @{$modifier_table->{before}}, $code;
 330     }
 331     elsif($type eq 'after'){
 332         push @{$modifier_table->{after}}, $code;
 333     }
 334     else{ # around
 335         push @{$modifier_table->{around}}, $code;
 336
 337         my $next = ${ $modifier_table->{cache} };
 338         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 339     }
 340
 341     return;
 342 }
 343
 344 sub _install_modifier {
 345     my ( $self, $type, $name, $code ) = @_;
 346
 347     # load Class::Method::Modifiers first
 348     my $no_cmm_fast = do{
 349         local $@;
 350         eval q{ require Class::Method::Modifiers::Fast };
 351         $@;
 352     };
 353
 354     my $impl;
 355     if($no_cmm_fast){
 356         $impl = \&_install_modifier_pp;
 357     }
 358     else{
 359         my $install_modifier = Class::Method::Modifiers::Fast->can('_install_modifier');
 360         $impl = sub {
 361             my ( $self, $type, $name, $code ) = @_;
 362             my $into = $self->name;
 363             $install_modifier->($into, $type, $name, $code);
 364
 365             $self->add_method($name => do{
 366                 no strict 'refs';
 367                 \&{ $into . '::' . $name };
 368             });
 369             return;
 370         };
 371     }
 372
 373     # replace this method itself :)
 374     {
 375         no warnings 'redefine';
 376         *_install_modifier = $impl;
 377     }
 378
 379     $self->$impl( $type, $name, $code );
 380 }
 381
 382 sub add_before_method_modifier {
 383     my ( $self, $name, $code ) = @_;
 384     $self->_install_modifier( 'before', $name, $code );
 385 }
 386
 387 sub add_around_method_modifier {
 388     my ( $self, $name, $code ) = @_;
 389     $self->_install_modifier( 'around', $name, $code );
 390 }
 391
 392 sub add_after_method_modifier {
 393     my ( $self, $name, $code ) = @_;
 394     $self->_install_modifier( 'after', $name, $code );
 395 }
 396
 397 sub add_override_method_modifier {
 398     my ($self, $name, $code) = @_;
 399
 400     if($self->has_method($name)){
 401         $self->throw_error("Cannot add an override method if a local method is already present");
 402     }
 403
 404     my $package = $self->name;
 405
 406     my $super_body = $package->can($name)
 407         or $self->throw_error("You cannot override '$name' because it has no super method");
 408
 409     $self->add_method($name => sub {
 410         local $Mouse::SUPER_PACKAGE = $package;
 411         local $Mouse::SUPER_BODY    = $super_body;
 412         local @Mouse::SUPER_ARGS    = @_;
 413
 414         $code->(@_);
 415     });
 416     return;
 417 }
 418
 419 sub add_augment_method_modifier {
 420     my ($self, $name, $code) = @_;
 421     if($self->has_method($name)){
 422         $self->throw_error("Cannot add an augment method if a local method is already present");
 423     }
 424
 425     my $super = $self->find_method_by_name($name)
 426         or $self->throw_error("You cannot augment '$name' because it has no super method");
 427
 428     my $super_package = $super->package_name;
 429     my $super_body    = $super->body;
 430
 431     $self->add_method($name => sub{
 432         local $Mouse::INNER_BODY{$super_package} = $code;
 433         local $Mouse::INNER_ARGS{$super_package} = [@_];
 434         $super_body->(@_);
 435     });
 436     return;
 437 }
 438
 439 sub does_role {
 440     my ($self, $role_name) = @_;
 441
 442     (defined $role_name)
 443         || $self->throw_error("You must supply a role name to look for");
 444
 445     for my $class ($self->linearized_isa) {
 446         my $meta = Mouse::Util::get_metaclass_by_name($class)
 447             or next;
 448
 449         for my $role (@{ $meta->roles }) {
 450
 451             return 1 if $role->does_role($role_name);
 452         }
 453     }
 454
 455     return 0;
 456 }
 457
 458 1;
 459 __END__
 460
 461 =head1 NAME
 462
 463 Mouse::Meta::Class - The Mouse class metaclass
 464
 465 =head1 VERSION
 466
 467 This document describes Mouse version 0.40_05
 468
 469 =head1 METHODS
 470
 471 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 472
 473 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 474 one instance should exist for a given class.
 475
 476 =head2 C<< name -> ClassName >>
 477
 478 Returns the name of the owner class.
 479
 480 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 481
 482 Gets (or sets) the list of superclasses of the owner class.
 483
 484 =head2 C<< add_method(name => CodeRef) >>
 485
 486 Adds a method to the owner class.
 487
 488 =head2 C<< has_method(name) -> Bool >>
 489
 490 Returns whether we have a method with the given name.
 491
 492 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 493
 494 Returns a L<Mouse::Meta::Method> with the given name.
 495
 496 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 497
 498 =head2 C<< get_method_list -> Names >>
 499
 500 Returns a list of method names which are defined in the local class.
 501 If you want a list of all applicable methods for a class, use the
 502 C<get_all_methods> method.
 503
 504 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 505
 506 Return the list of all L<Mouse::Meta::Method> instances associated with
 507 the class and its superclasses.
 508
 509 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 510
 511 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 512 class.
 513
 514 =head2 C<< has_attribute(Name) -> Bool >>
 515
 516 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 517
 518 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 519
 520 Returns the L<Mouse::Meta::Attribute> with the given name.
 521
 522 =head2 C<< get_attribute_list -> Names >>
 523
 524 Returns a list of attribute names which are defined in the local
 525 class. If you want a list of all applicable attributes for a class,
 526 use the C<get_all_attributes> method.
 527
 528 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 529
 530 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 531 this class and its superclasses.
 532
 533 =head2 C<< linearized_isa -> [ClassNames] >>
 534
 535 Returns the list of classes in method dispatch order, with duplicates removed.
 536
 537 =head2 C<< new_object(Parameters) -> Instance >>
 538
 539 Creates a new instance.
 540
 541 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 542
 543 Clones the given instance which must be an instance governed by this
 544 metaclass.
 545
 546 =head2 C<< throw_error(Message, Parameters) >>
 547
 548 Throws an error with the given message.
 549
 550 =head1 SEE ALSO
 551
 552 L<Moose::Meta::Class>
 553
 554 L<Class::MOP::Class>
 555
 556 =cut
 557