lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Module;
   7 our @ISA = qw(Mouse::Meta::Module);
   8
   9 sub attribute_metaclass;
  10 sub method_metaclass;
  11
  12 sub constructor_class;
  13 sub destructor_class;
  14
  15 my @MetaClassTypes = qw(
  16     attribute_metaclass
  17     method_metaclass
  18     constructor_class
  19     destructor_class
  20 );
  21
  22 sub _construct_meta {
  23     my($class, %args) = @_;
  24
  25     $args{attributes} = {};
  26     $args{methods}    = {};
  27     $args{roles}      = [];
  28
  29     $args{superclasses} = do {
  30         no strict 'refs';
  31         \@{ $args{package} . '::ISA' };
  32     };
  33
  34     my $self = bless \%args, ref($class) || $class;
  35     if(ref($self) ne __PACKAGE__){
  36         $self->meta->_initialize_object($self, \%args);
  37     }
  38     return $self;
  39 }
  40
  41 sub create_anon_class{
  42     my $self = shift;
  43     return $self->create(undef, @_);
  44 }
  45
  46 sub is_anon_class;
  47
  48 sub roles;
  49
  50 sub calculate_all_roles {
  51     my $self = shift;
  52     my %seen;
  53     return grep { !$seen{ $_->name }++ }
  54            map  { $_->calculate_all_roles } @{ $self->roles };
  55 }
  56
  57 sub superclasses {
  58     my $self = shift;
  59
  60     if (@_) {
  61         foreach my $super(@_){
  62             Mouse::Util::load_class($super);
  63             my $meta = Mouse::Util::get_metaclass_by_name($super);
  64
  65             next if not defined $meta;
  66
  67             if(Mouse::Util::is_a_metarole($meta)){
  68                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  69             }
  70
  71             next if $self->isa(ref $meta); # _superclass_meta_is_compatible
  72
  73             $self->_reconcile_with_superclass_meta($meta);
  74         }
  75         @{ $self->{superclasses} } = @_;
  76     }
  77
  78     return @{ $self->{superclasses} };
  79 }
  80
  81 sub _reconcile_with_superclass_meta {
  82     my($self, $super_meta) = @_;
  83
  84     my @incompatibles;
  85
  86     foreach my $metaclass_type(@MetaClassTypes){
  87         my $super_c = $super_meta->$metaclass_type();
  88         my $self_c  = $self->$metaclass_type();
  89
  90         if(!$super_c->isa($self_c)){
  91             push @incompatibles, ($metaclass_type => $super_c);
  92         }
  93     }
  94
  95     my @roles;
  96
  97     foreach my $role($self->meta->calculate_all_roles){
  98         if(!$super_meta->meta->does_role($role->name)){
  99             push @roles, $role->name;
 100         }
 101     }
 102
 103     #print "reconcile($self vs. $super_meta; @roles; @incompatibles)\n";
 104
 105     require Mouse::Util::MetaRole;
 106     Mouse::Util::MetaRole::apply_metaclass_roles(
 107         for_class       => $self,
 108         metaclass       => ref $super_meta,
 109         metaclass_roles => \@roles,
 110         @incompatibles,
 111     );
 112     return;
 113 }
 114
 115 sub find_method_by_name{
 116     my($self, $method_name) = @_;
 117     defined($method_name)
 118         or $self->throw_error('You must define a method name to find');
 119
 120     foreach my $class( $self->linearized_isa ){
 121         my $method = $self->initialize($class)->get_method($method_name);
 122         return $method if defined $method;
 123     }
 124     return undef;
 125 }
 126
 127 sub get_all_methods {
 128     my($self) = @_;
 129     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
 130 }
 131
 132 sub get_all_method_names {
 133     my $self = shift;
 134     my %uniq;
 135     return grep { $uniq{$_}++ == 0 }
 136             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
 137             $self->linearized_isa;
 138 }
 139
 140 sub find_attribute_by_name{
 141     my($self, $name) = @_;
 142     my $attr;
 143     foreach my $class($self->linearized_isa){
 144         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
 145         $attr = $meta->get_attribute($name) and last;
 146     }
 147     return $attr;
 148 }
 149
 150 sub add_attribute {
 151     my $self = shift;
 152
 153     my($attr, $name);
 154
 155     if(blessed $_[0]){
 156         $attr = $_[0];
 157
 158         $attr->isa('Mouse::Meta::Attribute')
 159             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 160
 161         $name = $attr->name;
 162     }
 163     else{
 164         # _process_attribute
 165         $name = shift;
 166
 167         my %args = (@_ == 1) ? %{$_[0]} : @_;
 168
 169         defined($name)
 170             or $self->throw_error('You must provide a name for the attribute');
 171
 172         if ($name =~ s/^\+//) { # inherited attributes
 173             my $inherited_attr = $self->find_attribute_by_name($name)
 174                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 175
 176             $attr = $inherited_attr->clone_and_inherit_options(%args);
 177         }
 178         else{
 179             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 180             $args{traits} = \@traits if @traits;
 181
 182             $attr = $attribute_class->new($name, %args);
 183         }
 184     }
 185
 186     weaken( $attr->{associated_class} = $self );
 187
 188     $self->{attributes}{$attr->name} = $attr;
 189     $attr->install_accessors();
 190
 191     if(Mouse::Util::_MOUSE_VERBOSE && !$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 192         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 193     }
 194     return $attr;
 195 }
 196
 197 sub compute_all_applicable_attributes {
 198     Carp::cluck('compute_all_applicable_attributes() has been deprecated')
 199         if Mouse::Util::_MOUSE_VERBOSE;
 200     return shift->get_all_attributes(@_)
 201 }
 202
 203 sub linearized_isa;
 204
 205 sub new_object;
 206
 207 sub clone_object {
 208     my $class  = shift;
 209     my $object = shift;
 210     my %params = (@_ == 1) ? %{$_[0]} : @_;
 211
 212     (blessed($object) && $object->isa($class->name))
 213         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 214
 215     my $cloned = bless { %$object }, ref $object;
 216     $class->_initialize_object($cloned, \%params);
 217
 218     return $cloned;
 219 }
 220
 221 sub clone_instance {
 222     my ($class, $instance, %params) = @_;
 223
 224     Carp::cluck('clone_instance has been deprecated. Use clone_object instead')
 225         if Mouse::Util::_MOUSE_VERBOSE;
 226     return $class->clone_object($instance, %params);
 227 }
 228
 229
 230 sub immutable_options {
 231     my ( $self, @args ) = @_;
 232
 233     return (
 234         inline_constructor => 1,
 235         inline_destructor  => 1,
 236         constructor_name   => 'new',
 237         @args,
 238     );
 239 }
 240
 241
 242 sub make_immutable {
 243     my $self = shift;
 244     my %args = $self->immutable_options(@_);
 245
 246     $self->{is_immutable}++;
 247
 248     if ($args{inline_constructor}) {
 249         my $c = $self->constructor_class;
 250         Mouse::Util::load_class($c);
 251         $self->add_method($args{constructor_name} =>
 252             $c->_generate_constructor($self, \%args));
 253     }
 254
 255     if ($args{inline_destructor}) {
 256         my $c = $self->destructor_class;
 257         Mouse::Util::load_class($c);
 258         $self->add_method(DESTROY =>
 259             $c->_generate_destructor($self, \%args));
 260     }
 261
 262     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 263     # at the end of a source file.
 264     return 1;
 265 }
 266
 267 sub make_mutable { not_supported }
 268
 269 sub is_immutable {  $_[0]->{is_immutable} }
 270 sub is_mutable   { !$_[0]->{is_immutable} }
 271
 272 sub _install_modifier_pp{
 273     my( $self, $type, $name, $code ) = @_;
 274     my $into = $self->name;
 275
 276     my $original = $into->can($name)
 277         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 278
 279     my $modifier_table = $self->{modifiers}{$name};
 280
 281     if(!$modifier_table){
 282         my(@before, @after, @around, $cache, $modified);
 283
 284         $cache = $original;
 285
 286         $modified = sub {
 287             for my $c (@before) { $c->(@_) }
 288
 289             if(wantarray){ # list context
 290                 my @rval = $cache->(@_);
 291
 292                 for my $c(@after){ $c->(@_) }
 293                 return @rval;
 294             }
 295             elsif(defined wantarray){ # scalar context
 296                 my $rval = $cache->(@_);
 297
 298                 for my $c(@after){ $c->(@_) }
 299                 return $rval;
 300             }
 301             else{ # void context
 302                 $cache->(@_);
 303
 304                 for my $c(@after){ $c->(@_) }
 305                 return;
 306             }
 307         };
 308
 309         $self->{modifiers}{$name} = $modifier_table = {
 310             original => $original,
 311
 312             before   => \@before,
 313             after    => \@after,
 314             around   => \@around,
 315
 316             cache    => \$cache, # cache for around modifiers
 317         };
 318
 319         $self->add_method($name => $modified);
 320     }
 321
 322     if($type eq 'before'){
 323         unshift @{$modifier_table->{before}}, $code;
 324     }
 325     elsif($type eq 'after'){
 326         push @{$modifier_table->{after}}, $code;
 327     }
 328     else{ # around
 329         push @{$modifier_table->{around}}, $code;
 330
 331         my $next = ${ $modifier_table->{cache} };
 332         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 333     }
 334
 335     return;
 336 }
 337
 338 sub _install_modifier {
 339     my ( $self, $type, $name, $code ) = @_;
 340
 341     # load Class::Method::Modifiers first
 342     my $no_cmm_fast = do{
 343         local $@;
 344         eval q{ require Class::Method::Modifiers::Fast };
 345         $@;
 346     };
 347
 348     my $impl;
 349     if($no_cmm_fast){
 350         $impl = \&_install_modifier_pp;
 351     }
 352     else{
 353         my $install_modifier = Class::Method::Modifiers::Fast->can('_install_modifier');
 354         $impl = sub {
 355             my ( $self, $type, $name, $code ) = @_;
 356             my $into = $self->name;
 357             $install_modifier->($into, $type, $name, $code);
 358
 359             $self->add_method($name => do{
 360                 no strict 'refs';
 361                 \&{ $into . '::' . $name };
 362             });
 363             return;
 364         };
 365     }
 366
 367     # replace this method itself :)
 368     {
 369         no warnings 'redefine';
 370         *_install_modifier = $impl;
 371     }
 372
 373     $self->$impl( $type, $name, $code );
 374 }
 375
 376 sub add_before_method_modifier {
 377     my ( $self, $name, $code ) = @_;
 378     $self->_install_modifier( 'before', $name, $code );
 379 }
 380
 381 sub add_around_method_modifier {
 382     my ( $self, $name, $code ) = @_;
 383     $self->_install_modifier( 'around', $name, $code );
 384 }
 385
 386 sub add_after_method_modifier {
 387     my ( $self, $name, $code ) = @_;
 388     $self->_install_modifier( 'after', $name, $code );
 389 }
 390
 391 sub add_override_method_modifier {
 392     my ($self, $name, $code) = @_;
 393
 394     if($self->has_method($name)){
 395         $self->throw_error("Cannot add an override method if a local method is already present");
 396     }
 397
 398     my $package = $self->name;
 399
 400     my $super_body = $package->can($name)
 401         or $self->throw_error("You cannot override '$name' because it has no super method");
 402
 403     $self->add_method($name => sub {
 404         local $Mouse::SUPER_PACKAGE = $package;
 405         local $Mouse::SUPER_BODY    = $super_body;
 406         local @Mouse::SUPER_ARGS    = @_;
 407
 408         $code->(@_);
 409     });
 410     return;
 411 }
 412
 413 sub add_augment_method_modifier {
 414     my ($self, $name, $code) = @_;
 415     if($self->has_method($name)){
 416         $self->throw_error("Cannot add an augment method if a local method is already present");
 417     }
 418
 419     my $super = $self->find_method_by_name($name)
 420         or $self->throw_error("You cannot augment '$name' because it has no super method");
 421
 422     my $super_package = $super->package_name;
 423     my $super_body    = $super->body;
 424
 425     $self->add_method($name => sub{
 426         local $Mouse::INNER_BODY{$super_package} = $code;
 427         local $Mouse::INNER_ARGS{$super_package} = [@_];
 428         $super_body->(@_);
 429     });
 430     return;
 431 }
 432
 433 sub does_role {
 434     my ($self, $role_name) = @_;
 435
 436     (defined $role_name)
 437         || $self->throw_error("You must supply a role name to look for");
 438
 439     for my $class ($self->linearized_isa) {
 440         my $meta = Mouse::Util::get_metaclass_by_name($class)
 441             or next;
 442
 443         for my $role (@{ $meta->roles }) {
 444
 445             return 1 if $role->does_role($role_name);
 446         }
 447     }
 448
 449     return 0;
 450 }
 451
 452 1;
 453 __END__
 454
 455 =head1 NAME
 456
 457 Mouse::Meta::Class - The Mouse class metaclass
 458
 459 =head1 VERSION
 460
 461 This document describes Mouse version 0.40_08
 462
 463 =head1 METHODS
 464
 465 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 466
 467 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 468 one instance should exist for a given class.
 469
 470 =head2 C<< name -> ClassName >>
 471
 472 Returns the name of the owner class.
 473
 474 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 475
 476 Gets (or sets) the list of superclasses of the owner class.
 477
 478 =head2 C<< add_method(name => CodeRef) >>
 479
 480 Adds a method to the owner class.
 481
 482 =head2 C<< has_method(name) -> Bool >>
 483
 484 Returns whether we have a method with the given name.
 485
 486 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 487
 488 Returns a L<Mouse::Meta::Method> with the given name.
 489
 490 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 491
 492 =head2 C<< get_method_list -> Names >>
 493
 494 Returns a list of method names which are defined in the local class.
 495 If you want a list of all applicable methods for a class, use the
 496 C<get_all_methods> method.
 497
 498 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 499
 500 Return the list of all L<Mouse::Meta::Method> instances associated with
 501 the class and its superclasses.
 502
 503 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 504
 505 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 506 class.
 507
 508 =head2 C<< has_attribute(Name) -> Bool >>
 509
 510 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 511
 512 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 513
 514 Returns the L<Mouse::Meta::Attribute> with the given name.
 515
 516 =head2 C<< get_attribute_list -> Names >>
 517
 518 Returns a list of attribute names which are defined in the local
 519 class. If you want a list of all applicable attributes for a class,
 520 use the C<get_all_attributes> method.
 521
 522 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 523
 524 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 525 this class and its superclasses.
 526
 527 =head2 C<< linearized_isa -> [ClassNames] >>
 528
 529 Returns the list of classes in method dispatch order, with duplicates removed.
 530
 531 =head2 C<< new_object(Parameters) -> Instance >>
 532
 533 Creates a new instance.
 534
 535 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 536
 537 Clones the given instance which must be an instance governed by this
 538 metaclass.
 539
 540 =head2 C<< throw_error(Message, Parameters) >>
 541
 542 Throws an error with the given message.
 543
 544 =head1 SEE ALSO
 545
 546 L<Mouse::Meta::Module>
 547
 548 L<Moose::Meta::Class>
 549
 550 L<Class::MOP::Class>
 551
 552 =cut
 553