lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use strict;
   3 use warnings;
   4
   5 use Mouse::Meta::Method::Constructor;
   6 use Mouse::Meta::Method::Destructor;
   7 use Scalar::Util qw/blessed/;
   8 use Mouse::Util qw/get_linear_isa version authority identifier/;
   9 use Carp 'confess';
  10
  11 do {
  12     my %METACLASS_CACHE;
  13
  14     # because Mouse doesn't introspect existing classes, we're forced to
  15     # only pay attention to other Mouse classes
  16     sub _metaclass_cache {
  17         my $class = shift;
  18         my $name  = shift;
  19         return $METACLASS_CACHE{$name};
  20     }
  21
  22     sub initialize {
  23         my $class = blessed($_[0]) || $_[0];
  24         my $name  = $_[1];
  25
  26         $METACLASS_CACHE{$name} = $class->new(name => $name)
  27             if !exists($METACLASS_CACHE{$name});
  28         return $METACLASS_CACHE{$name};
  29     }
  30 };
  31
  32 sub new {
  33     my $class = shift;
  34     my %args  = @_;
  35
  36     $args{attributes} = {};
  37     $args{superclasses} = do {
  38         no strict 'refs';
  39         \@{ $args{name} . '::ISA' };
  40     };
  41     $args{roles} ||= [];
  42
  43     bless \%args, $class;
  44 }
  45
  46 sub name { $_[0]->{name} }
  47
  48 sub superclasses {
  49     my $self = shift;
  50
  51     if (@_) {
  52         Mouse::load_class($_) for @_;
  53         @{ $self->{superclasses} } = @_;
  54     }
  55
  56     @{ $self->{superclasses} };
  57 }
  58
  59 sub add_method {
  60     my $self = shift;
  61     my $name = shift;
  62     my $code = shift;
  63
  64     my $pkg = $self->name;
  65
  66     no strict 'refs';
  67     no warnings 'redefine';
  68     $self->{'methods'}->{$name}++; # Moose stores meta object here.
  69     *{ $pkg . '::' . $name } = $code;
  70 }
  71
  72 sub has_method {
  73     my $self = shift;
  74     my $name = shift;
  75     $self->name->can($name);
  76 }
  77
  78 # copied from Class::Inspector
  79 my $get_methods_for_class = sub {
  80     my $self = shift;
  81     my $name = shift;
  82
  83     no strict 'refs';
  84     # Get all the CODE symbol table entries
  85     my @functions =
  86       grep !/^(?:has|with|around|before|after|augment|inner|blessed|extends|confess|override|super)$/,
  87       grep { defined &{"${name}::$_"} }
  88       keys %{"${name}::"};
  89     push @functions, keys %{$self->{'methods'}->{$name}} if $self;
  90     wantarray ? @functions : \@functions;
  91 };
  92
  93 sub get_method_list {
  94     my $self = shift;
  95     $get_methods_for_class->($self, $self->name);
  96 }
  97
  98 sub get_all_method_names {
  99     my $self = shift;
 100     my %uniq;
 101     return grep { $uniq{$_}++ == 0 }
 102             map { $get_methods_for_class->(undef, $_) }
 103             $self->linearized_isa;
 104 }
 105
 106 sub add_attribute {
 107     my $self = shift;
 108
 109     if (@_ == 1 && blessed($_[0])) {
 110         my $attr = shift @_;
 111         $self->{'attributes'}{$attr->name} = $attr;
 112     } else {
 113         my $names = shift @_;
 114         $names = [$names] if !ref($names);
 115         my $metaclass = 'Mouse::Meta::Attribute';
 116         my %options = @_;
 117
 118         if ( my $metaclass_name = delete $options{metaclass} ) {
 119             my $new_class = Mouse::Util::resolve_metaclass_alias(
 120                 'Attribute',
 121                 $metaclass_name
 122             );
 123             if ( $metaclass ne $new_class ) {
 124                 $metaclass = $new_class;
 125             }
 126         }
 127
 128         for my $name (@$names) {
 129             if ($name =~ s/^\+//) {
 130                 $metaclass->clone_parent($self, $name, @_);
 131             }
 132             else {
 133                 $metaclass->create($self, $name, @_);
 134             }
 135         }
 136     }
 137 }
 138
 139 sub compute_all_applicable_attributes {
 140     my $self = shift;
 141     my (@attr, %seen);
 142
 143     for my $class ($self->linearized_isa) {
 144         my $meta = $self->_metaclass_cache($class)
 145             or next;
 146
 147         for my $name (keys %{ $meta->get_attribute_map }) {
 148             next if $seen{$name}++;
 149             push @attr, $meta->get_attribute($name);
 150         }
 151     }
 152
 153     return @attr;
 154 }
 155
 156 sub get_attribute_map { $_[0]->{attributes} }
 157 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
 158 sub get_attribute     { $_[0]->{attributes}->{$_[1]} }
 159 sub get_attribute_list {
 160     my $self = shift;
 161     keys %{$self->get_attribute_map};
 162 }
 163
 164 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 165
 166 sub clone_object {
 167     my $class    = shift;
 168     my $instance = shift;
 169
 170     (blessed($instance) && $instance->isa($class->name))
 171         || confess "You must pass an instance of the metaclass (" . $class->name . "), not ($instance)";
 172
 173     $class->clone_instance($instance, @_);
 174 }
 175
 176 sub clone_instance {
 177     my ($class, $instance, %params) = @_;
 178
 179     (blessed($instance))
 180         || confess "You can only clone instances, ($instance) is not a blessed instance";
 181
 182     my $clone = bless { %$instance }, ref $instance;
 183
 184     foreach my $attr ($class->compute_all_applicable_attributes()) {
 185         if ( defined( my $init_arg = $attr->init_arg ) ) {
 186             if (exists $params{$init_arg}) {
 187                 $clone->{ $attr->name } = $params{$init_arg};
 188             }
 189         }
 190     }
 191
 192     return $clone;
 193
 194 }
 195
 196 sub make_immutable {
 197     my $self = shift;
 198     my %args = (
 199         inline_constructor => 1,
 200         @_,
 201     );
 202
 203     my $name = $self->name;
 204     $self->{is_immutable}++;
 205
 206     if ($args{inline_constructor}) {
 207         $self->add_method('new' => Mouse::Meta::Method::Constructor->generate_constructor_method_inline( $self ));
 208     }
 209
 210     if ($args{inline_destructor}) {
 211         $self->add_method('DESTROY' => Mouse::Meta::Method::Destructor->generate_destructor_method_inline( $self ));
 212     }
 213
 214     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 215     # at the end of a source file.
 216     return 1;
 217 }
 218
 219 sub make_mutable { confess "Mouse does not currently support 'make_mutable'" }
 220
 221 sub is_immutable { $_[0]->{is_immutable} }
 222
 223 sub attribute_metaclass { "Mouse::Meta::Class" }
 224
 225 sub _install_modifier {
 226     my ( $self, $into, $type, $name, $code ) = @_;
 227
 228     # which is modifer class available?
 229     my $modifier_class = do {
 230         if (eval "require Class::Method::Modifiers::Fast; 1") {
 231             'Class::Method::Modifiers::Fast';
 232         } elsif (eval "require Class::Method::Modifiers; 1") {
 233             'Class::Method::Modifiers';
 234         } else {
 235             Carp::croak("Method modifiers require the use of Class::Method::Modifiers or Class::Method::Modifiers::Fast. Please install it from CPAN and file a bug report with this application.");
 236         }
 237     };
 238     my $modifier = $modifier_class->can('_install_modifier');
 239
 240     # replace this method itself :)
 241     {
 242         no strict 'refs';
 243         no warnings 'redefine';
 244         *{__PACKAGE__ . '::_install_modifier'} = sub {
 245             my ( $self, $into, $type, $name, $code ) = @_;
 246             $modifier->(
 247                 $into,
 248                 $type,
 249                 $name,
 250                 $code
 251             );
 252         };
 253     }
 254
 255     # call me. for first time.
 256     $self->_install_modifier( $into, $type, $name, $code );
 257 }
 258
 259 sub add_before_method_modifier {
 260     my ( $self, $name, $code ) = @_;
 261     $self->_install_modifier( $self->name, 'before', $name, $code );
 262 }
 263
 264 sub add_around_method_modifier {
 265     my ( $self, $name, $code ) = @_;
 266     $self->_install_modifier( $self->name, 'around', $name, $code );
 267 }
 268
 269 sub add_after_method_modifier {
 270     my ( $self, $name, $code ) = @_;
 271     $self->_install_modifier( $self->name, 'after', $name, $code );
 272 }
 273
 274 sub add_override_method_modifier {
 275     my ($self, $name, $code) = @_;
 276
 277     my $pkg = $self->name;
 278     my $method = "${pkg}::${name}";
 279
 280     # Class::Method::Modifiers won't do this for us, so do it ourselves
 281
 282     my $body = $pkg->can($name)
 283         or confess "You cannot override '$method' because it has no super method";
 284
 285     no strict 'refs';
 286     *$method = sub { $code->($pkg, $body, @_) };
 287 }
 288
 289
 290 sub roles { $_[0]->{roles} }
 291
 292 sub does_role {
 293     my ($self, $role_name) = @_;
 294
 295     (defined $role_name)
 296         || confess "You must supply a role name to look for";
 297
 298     for my $role (@{ $self->{roles} }) {
 299         return 1 if $role->name eq $role_name;
 300     }
 301
 302     return 0;
 303 }
 304
 305 sub create {
 306     my ($self, $package_name, %options) = @_;
 307
 308     (ref $options{superclasses} eq 'ARRAY')
 309         || confess "You must pass an ARRAY ref of superclasses"
 310             if exists $options{superclasses};
 311
 312     (ref $options{attributes} eq 'ARRAY')
 313         || confess "You must pass an ARRAY ref of attributes"
 314             if exists $options{attributes};
 315
 316     (ref $options{methods} eq 'HASH')
 317         || confess "You must pass a HASH ref of methods"
 318             if exists $options{methods};
 319
 320     do {
 321         ( defined $package_name && $package_name )
 322           || confess "You must pass a package name";
 323
 324         my $code = "package $package_name;";
 325         $code .= "\$$package_name\:\:VERSION = '" . $options{version} . "';"
 326           if exists $options{version};
 327         $code .= "\$$package_name\:\:AUTHORITY = '" . $options{authority} . "';"
 328           if exists $options{authority};
 329
 330         eval $code;
 331         confess "creation of $package_name failed : $@" if $@;
 332     };
 333
 334     my %initialize_options = %options;
 335     delete @initialize_options{qw(
 336         package
 337         superclasses
 338         attributes
 339         methods
 340         version
 341         authority
 342     )};
 343     my $meta = $self->initialize( $package_name => %initialize_options );
 344
 345     # FIXME totally lame
 346     $meta->add_method('meta' => sub {
 347         $self->initialize(ref($_[0]) || $_[0]);
 348     });
 349
 350     $meta->superclasses(@{$options{superclasses}})
 351         if exists $options{superclasses};
 352     # NOTE:
 353     # process attributes first, so that they can
 354     # install accessors, but locally defined methods
 355     # can then overwrite them. It is maybe a little odd, but
 356     # I think this should be the order of things.
 357     if (exists $options{attributes}) {
 358         foreach my $attr (@{$options{attributes}}) {
 359             Mouse::Meta::Attribute->create($meta, $attr->{name}, %$attr);
 360         }
 361     }
 362     if (exists $options{methods}) {
 363         foreach my $method_name (keys %{$options{methods}}) {
 364             $meta->add_method($method_name, $options{methods}->{$method_name});
 365         }
 366     }
 367     return $meta;
 368 }
 369
 370 {
 371     my $ANON_CLASS_SERIAL = 0;
 372     my $ANON_CLASS_PREFIX = 'Mouse::Meta::Class::__ANON__::SERIAL::';
 373     sub create_anon_class {
 374         my ( $class, %options ) = @_;
 375         my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
 376         return $class->create( $package_name, %options );
 377     }
 378 }
 379
 380 1;
 381
 382 __END__
 383
 384 =head1 NAME
 385
 386 Mouse::Meta::Class - hook into the Mouse MOP
 387
 388 =head1 METHODS
 389
 390 =head2 initialize ClassName -> Mouse::Meta::Class
 391
 392 Finds or creates a Mouse::Meta::Class instance for the given ClassName. Only
 393 one instance should exist for a given class.
 394
 395 =head2 new %args -> Mouse::Meta::Class
 396
 397 Creates a new Mouse::Meta::Class. Don't call this directly.
 398
 399 =head2 name -> ClassName
 400
 401 Returns the name of the owner class.
 402
 403 =head2 superclasses -> [ClassName]
 404
 405 Gets (or sets) the list of superclasses of the owner class.
 406
 407 =head2 add_attribute (Mouse::Meta::Attribute| name => spec)
 408
 409 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 410 class.
 411
 412 =head2 compute_all_applicable_attributes -> (Mouse::Meta::Attribute)
 413
 414 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 415 this class and its superclasses.
 416
 417 =head2 get_attribute_map -> { name => Mouse::Meta::Attribute }
 418
 419 Returns a mapping of attribute names to their corresponding
 420 L<Mouse::Meta::Attribute> objects.
 421
 422 =head2 get_attribute_list -> { name => Mouse::Meta::Attribute }
 423
 424 This returns a list of attribute names which are defined in the local
 425 class. If you want a list of all applicable attributes for a class,
 426 use the C<compute_all_applicable_attributes> method.
 427
 428 =head2 has_attribute Name -> Bool
 429
 430 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 431
 432 =head2 get_attribute Name -> Mouse::Meta::Attribute | undef
 433
 434 Returns the L<Mouse::Meta::Attribute> with the given name.
 435
 436 =head2 linearized_isa -> [ClassNames]
 437
 438 Returns the list of classes in method dispatch order, with duplicates removed.
 439
 440 =head2 clone_object Instance -> Instance
 441
 442 Clones the given C<Instance> which must be an instance governed by this
 443 metaclass.
 444
 445 =head2 clone_instance Instance, Parameters -> Instance
 446
 447 Clones the given C<Instance> and sets any additional parameters.
 448
 449 =cut
 450