lib/Mouse/Meta/Class.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Class;
   3 use strict;
   4 use warnings;
   5
   6 use Mouse::Meta::Method::Constructor;
   7 use Mouse::Meta::Method::Destructor;
   8 use Mouse::Util qw/get_linear_isa blessed/;
   9 use Carp 'confess';
  10
  11 do {
  12     my %METACLASS_CACHE;
  13
  14     # because Mouse doesn't introspect existing classes, we're forced to
  15     # only pay attention to other Mouse classes
  16     sub _metaclass_cache {
  17         my $class = shift;
  18         my $name  = shift;
  19         return $METACLASS_CACHE{$name};
  20     }
  21
  22     sub initialize {
  23         my $class = shift;
  24         my $name  = shift;
  25         $METACLASS_CACHE{$name} = $class->new(name => $name)
  26             if !exists($METACLASS_CACHE{$name});
  27         return $METACLASS_CACHE{$name};
  28     }
  29 };
  30
  31 sub new {
  32     my $class = shift;
  33     my %args  = @_;
  34
  35     $args{attributes} = {};
  36     $args{superclasses} = do {
  37         no strict 'refs';
  38         \@{ $args{name} . '::ISA' };
  39     };
  40     $args{roles} ||= [];
  41
  42     bless \%args, $class;
  43 }
  44
  45 sub name { $_[0]->{name} }
  46
  47 sub superclasses {
  48     my $self = shift;
  49
  50     if (@_) {
  51         Mouse::load_class($_) for @_;
  52         @{ $self->{superclasses} } = @_;
  53     }
  54
  55     @{ $self->{superclasses} };
  56 }
  57
  58 sub add_method {
  59     my $self = shift;
  60     my $name = shift;
  61     my $code = shift;
  62
  63     my $pkg = $self->name;
  64
  65     no strict 'refs';
  66     *{ $pkg . '::' . $name } = $code;
  67 }
  68
  69 # copied from Class::Inspector
  70 sub get_method_list {
  71     my $self = shift;
  72     my $name = $self->name;
  73
  74     no strict 'refs';
  75     # Get all the CODE symbol table entries
  76     my @functions = grep !/^meta$/,
  77       grep { /\A[^\W\d]\w*\z/o }
  78       grep { defined &{"${name}::$_"} }
  79       keys %{"${name}::"};
  80     wantarray ? @functions : \@functions;
  81 }
  82
  83 sub add_attribute {
  84     my $self = shift;
  85     my $attr = shift;
  86
  87     $self->{'attributes'}{$attr->name} = $attr;
  88 }
  89
  90 sub compute_all_applicable_attributes {
  91     my $self = shift;
  92     my (@attr, %seen);
  93
  94     for my $class ($self->linearized_isa) {
  95         my $meta = $self->_metaclass_cache($class)
  96             or next;
  97
  98         for my $name (keys %{ $meta->get_attribute_map }) {
  99             next if $seen{$name}++;
 100             push @attr, $meta->get_attribute($name);
 101         }
 102     }
 103
 104     return @attr;
 105 }
 106
 107 sub get_attribute_map { $_[0]->{attributes} }
 108 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
 109 sub get_attribute     { $_[0]->{attributes}->{$_[1]} }
 110
 111 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 112
 113 sub clone_object {
 114     my $class    = shift;
 115     my $instance = shift;
 116
 117     (blessed($instance) && $instance->isa($class->name))
 118         || confess "You must pass an instance of the metaclass (" . $class->name . "), not ($instance)";
 119
 120     $class->clone_instance($instance, @_);
 121 }
 122
 123 sub clone_instance {
 124     my ($class, $instance, %params) = @_;
 125
 126     (blessed($instance))
 127         || confess "You can only clone instances, ($instance) is not a blessed instance";
 128
 129     my $clone = bless { %$instance }, ref $instance;
 130
 131     foreach my $attr ($class->compute_all_applicable_attributes()) {
 132         if ( defined( my $init_arg = $attr->init_arg ) ) {
 133             if (exists $params{$init_arg}) {
 134                 $clone->{ $attr->name } = $params{$init_arg};
 135             }
 136         }
 137     }
 138
 139     return $clone;
 140
 141 }
 142
 143 sub make_immutable {
 144     my $self = shift;
 145     my $name = $self->name;
 146     $self->{is_immutable}++;
 147     no strict 'refs';
 148     *{"$name\::new"}     = Mouse::Meta::Method::Constructor->generate_constructor_method_inline( $self );
 149     *{"$name\::DESTROY"} = Mouse::Meta::Method::Destructor->generate_destructor_method_inline( $self );
 150 }
 151 sub make_mutable {
 152     Carp::croak "Mouse::Meta::Class->make_mutable does not supported by Mouse";
 153 }
 154 sub is_immutable { $_[0]->{is_immutable} }
 155
 156 sub attribute_metaclass { "Mouse::Meta::Class" }
 157
 158 sub add_before_method_modifier {
 159     my ($self, $name, $code) = @_;
 160     require Class::Method::Modifiers;
 161     Class::Method::Modifiers::_install_modifier(
 162         $self->name,
 163         'before',
 164         $name,
 165         $code,
 166     );
 167 }
 168
 169 sub add_around_method_modifier {
 170     my ($self, $name, $code) = @_;
 171     require Class::Method::Modifiers;
 172     Class::Method::Modifiers::_install_modifier(
 173         $self->name,
 174         'around',
 175         $name,
 176         $code,
 177     );
 178 }
 179
 180 sub add_after_method_modifier {
 181     my ($self, $name, $code) = @_;
 182     require Class::Method::Modifiers;
 183     Class::Method::Modifiers::_install_modifier(
 184         $self->name,
 185         'after',
 186         $name,
 187         $code,
 188     );
 189 }
 190
 191 sub roles { $_[0]->{roles} }
 192
 193 sub does_role {
 194     my ($self, $role_name) = @_;
 195     (defined $role_name)
 196         || confess "You must supply a role name to look for";
 197     for my $role (@{ $self->{roles} }) {
 198         return 1 if $role->name eq $role_name;
 199     }
 200     return 0;
 201 }
 202
 203 sub create {
 204     my ( $class, @args ) = @_;
 205
 206     unshift @args, 'package' if @args % 2 == 1;
 207
 208     my (%options) = @args;
 209     my $package_name = $options{package};
 210
 211     (ref $options{superclasses} eq 'ARRAY')
 212         || confess "You must pass an ARRAY ref of superclasses"
 213             if exists $options{superclasses};
 214
 215     (ref $options{attributes} eq 'ARRAY')
 216         || confess "You must pass an ARRAY ref of attributes"
 217             if exists $options{attributes};
 218
 219     (ref $options{methods} eq 'HASH')
 220         || confess "You must pass a HASH ref of methods"
 221             if exists $options{methods};
 222
 223     do {
 224         # XXX should I implement Mouse::Meta::Module?
 225         my $package_name = $options{package};
 226
 227         ( defined $package_name && $package_name )
 228           || confess "You must pass a package name";
 229
 230         my $code = "package $package_name;";
 231         $code .= "\$$package_name\:\:VERSION = '" . $options{version} . "';"
 232           if exists $options{version};
 233         $code .= "\$$package_name\:\:AUTHORITY = '" . $options{authority} . "';"
 234           if exists $options{authority};
 235
 236         eval $code;
 237         confess "creation of $package_name failed : $@" if $@;
 238     };
 239
 240     my (%initialize_options) = @args;
 241     delete @initialize_options{qw(
 242         package
 243         superclasses
 244         attributes
 245         methods
 246         version
 247         authority
 248     )};
 249     my $meta = $class->initialize( $package_name => %initialize_options );
 250
 251     # FIXME totally lame
 252     $meta->add_method('meta' => sub {
 253         $class->initialize(ref($_[0]) || $_[0]);
 254     });
 255
 256     $meta->superclasses(@{$options{superclasses}})
 257         if exists $options{superclasses};
 258     # NOTE:
 259     # process attributes first, so that they can
 260     # install accessors, but locally defined methods
 261     # can then overwrite them. It is maybe a little odd, but
 262     # I think this should be the order of things.
 263     if (exists $options{attributes}) {
 264         foreach my $attr (@{$options{attributes}}) {
 265             Mouse::Meta::Attribute->create($meta, $attr->{name}, %$attr);
 266         }
 267     }
 268     if (exists $options{methods}) {
 269         foreach my $method_name (keys %{$options{methods}}) {
 270             $meta->add_method($method_name, $options{methods}->{$method_name});
 271         }
 272     }
 273     return $meta;
 274 }
 275
 276 {
 277     my $ANON_CLASS_SERIAL = 0;
 278     my $ANON_CLASS_PREFIX = 'Mouse::Meta::Class::__ANON__::SERIAL::';
 279     sub create_anon_class {
 280         my ( $class, %options ) = @_;
 281         my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
 282         return $class->create( $package_name, %options );
 283     }
 284 }
 285
 286 1;
 287
 288 __END__
 289
 290 =head1 NAME
 291
 292 Mouse::Meta::Class - hook into the Mouse MOP
 293
 294 =head1 METHODS
 295
 296 =head2 initialize ClassName -> Mouse::Meta::Class
 297
 298 Finds or creates a Mouse::Meta::Class instance for the given ClassName. Only
 299 one instance should exist for a given class.
 300
 301 =head2 new %args -> Mouse::Meta::Class
 302
 303 Creates a new Mouse::Meta::Class. Don't call this directly.
 304
 305 =head2 name -> ClassName
 306
 307 Returns the name of the owner class.
 308
 309 =head2 superclasses -> [ClassName]
 310
 311 Gets (or sets) the list of superclasses of the owner class.
 312
 313 =head2 add_attribute Mouse::Meta::Attribute
 314
 315 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 316 class.
 317
 318 =head2 compute_all_applicable_attributes -> (Mouse::Meta::Attribute)
 319
 320 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 321 this class and its superclasses.
 322
 323 =head2 get_attribute_map -> { name => Mouse::Meta::Attribute }
 324
 325 Returns a mapping of attribute names to their corresponding
 326 L<Mouse::Meta::Attribute> objects.
 327
 328 =head2 has_attribute Name -> Boool
 329
 330 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 331
 332 =head2 get_attribute Name -> Mouse::Meta::Attribute | undef
 333
 334 Returns the L<Mouse::Meta::Attribute> with the given name.
 335
 336 =head2 linearized_isa -> [ClassNames]
 337
 338 Returns the list of classes in method dispatch order, with duplicates removed.
 339
 340 =head2 clone_object Instance -> Instance
 341
 342 Clones the given C<Instance> which must be an instance governed by this
 343 metaclass.
 344
 345 =head2 clone_instance Instance, Parameters -> Instance
 346
 347 Clones the given C<Instance> and sets any additional parameters.
 348
 349 =cut
 350