lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use strict;
   3 use warnings;
   4
   5 use Mouse::Meta::Method::Constructor;
   6 use Mouse::Meta::Method::Destructor;
   7 use Scalar::Util qw/blessed/;
   8 use Mouse::Util qw/get_linear_isa/;
   9 use Carp 'confess';
  10
  11 do {
  12     my %METACLASS_CACHE;
  13
  14     # because Mouse doesn't introspect existing classes, we're forced to
  15     # only pay attention to other Mouse classes
  16     sub _metaclass_cache {
  17         my $class = shift;
  18         my $name  = shift;
  19         return $METACLASS_CACHE{$name};
  20     }
  21
  22     sub initialize {
  23         my $class = shift;
  24         my $name  = shift;
  25         $METACLASS_CACHE{$name} = $class->new(name => $name)
  26             if !exists($METACLASS_CACHE{$name});
  27         return $METACLASS_CACHE{$name};
  28     }
  29 };
  30
  31 sub new {
  32     my $class = shift;
  33     my %args  = @_;
  34
  35     $args{attributes} = {};
  36     $args{superclasses} = do {
  37         no strict 'refs';
  38         \@{ $args{name} . '::ISA' };
  39     };
  40     $args{roles} ||= [];
  41
  42     bless \%args, $class;
  43 }
  44
  45 sub name { $_[0]->{name} }
  46
  47 sub superclasses {
  48     my $self = shift;
  49
  50     if (@_) {
  51         Mouse::load_class($_) for @_;
  52         @{ $self->{superclasses} } = @_;
  53     }
  54
  55     @{ $self->{superclasses} };
  56 }
  57
  58 sub add_method {
  59     my $self = shift;
  60     my $name = shift;
  61     my $code = shift;
  62
  63     my $pkg = $self->name;
  64
  65     no strict 'refs';
  66     no warnings 'redefine';
  67     $self->{'methods'}->{$name}++; # Moose stores meta object here.
  68     *{ $pkg . '::' . $name } = $code;
  69 }
  70
  71 # copied from Class::Inspector
  72 my $get_methods_for_class = sub {
  73     my $self = shift;
  74     my $name = shift;
  75
  76     no strict 'refs';
  77     # Get all the CODE symbol table entries
  78     my @functions =
  79       grep !/^(?:has|with|around|before|after|blessed|extends|confess|override|super)$/,
  80       grep { defined &{"${name}::$_"} }
  81       keys %{"${name}::"};
  82     push @functions, keys %{$self->{'methods'}->{$name}} if $self;
  83     wantarray ? @functions : \@functions;
  84 };
  85
  86 sub get_method_list {
  87     my $self = shift;
  88     $get_methods_for_class->($self, $self->name);
  89 }
  90
  91 sub get_all_method_names {
  92     my $self = shift;
  93     my %uniq;
  94     return grep { $uniq{$_}++ == 0 }
  95             map { $get_methods_for_class->(undef, $_) }
  96             $self->linearized_isa;
  97 }
  98
  99 sub add_attribute {
 100     my $self = shift;
 101     my $attr = shift;
 102
 103     $self->{'attributes'}{$attr->name} = $attr;
 104 }
 105
 106 sub compute_all_applicable_attributes {
 107     my $self = shift;
 108     my (@attr, %seen);
 109
 110     for my $class ($self->linearized_isa) {
 111         my $meta = $self->_metaclass_cache($class)
 112             or next;
 113
 114         for my $name (keys %{ $meta->get_attribute_map }) {
 115             next if $seen{$name}++;
 116             push @attr, $meta->get_attribute($name);
 117         }
 118     }
 119
 120     return @attr;
 121 }
 122
 123 sub get_attribute_map { $_[0]->{attributes} }
 124 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
 125 sub get_attribute     { $_[0]->{attributes}->{$_[1]} }
 126
 127 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 128
 129 sub clone_object {
 130     my $class    = shift;
 131     my $instance = shift;
 132
 133     (blessed($instance) && $instance->isa($class->name))
 134         || confess "You must pass an instance of the metaclass (" . $class->name . "), not ($instance)";
 135
 136     $class->clone_instance($instance, @_);
 137 }
 138
 139 sub clone_instance {
 140     my ($class, $instance, %params) = @_;
 141
 142     (blessed($instance))
 143         || confess "You can only clone instances, ($instance) is not a blessed instance";
 144
 145     my $clone = bless { %$instance }, ref $instance;
 146
 147     foreach my $attr ($class->compute_all_applicable_attributes()) {
 148         if ( defined( my $init_arg = $attr->init_arg ) ) {
 149             if (exists $params{$init_arg}) {
 150                 $clone->{ $attr->name } = $params{$init_arg};
 151             }
 152         }
 153     }
 154
 155     return $clone;
 156
 157 }
 158
 159 sub make_immutable {
 160     my $self = shift;
 161     my %args = (
 162         inline_constructor => 1,
 163         @_,
 164     );
 165
 166     my $name = $self->name;
 167     $self->{is_immutable}++;
 168
 169     if ($args{inline_constructor}) {
 170         $self->add_method('new' => Mouse::Meta::Method::Constructor->generate_constructor_method_inline( $self ));
 171     }
 172
 173     if ($args{inline_destructor}) {
 174         $self->add_method('DESTROY' => Mouse::Meta::Method::Destructor->generate_destructor_method_inline( $self ));
 175     }
 176
 177     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 178     # at the end of a source file.
 179     return 1;
 180 }
 181
 182 sub make_mutable { confess "Mouse does not currently support 'make_mutable'" }
 183
 184 sub is_immutable { $_[0]->{is_immutable} }
 185
 186 sub attribute_metaclass { "Mouse::Meta::Class" }
 187
 188 sub _install_modifier {
 189     my ( $self, $into, $type, $name, $code ) = @_;
 190     if (eval "require Class::Method::Modifiers::Fast; 1") {
 191         Class::Method::Modifiers::Fast::_install_modifier(
 192             $into,
 193             $type,
 194             $name,
 195             $code
 196         );
 197     }
 198     elsif (eval "require Class::Method::Modifiers; 1") {
 199         Class::Method::Modifiers::_install_modifier(
 200             $into,
 201             $type,
 202             $name,
 203             $code
 204         );
 205     }
 206     else {
 207         Carp::croak("Method modifiers require the use of Class::Method::Modifiers. Please install it from CPAN and file a bug report with this application.");
 208     }
 209 }
 210
 211 sub add_before_method_modifier {
 212     my ( $self, $name, $code ) = @_;
 213     $self->_install_modifier( $self->name, 'before', $name, $code );
 214 }
 215
 216 sub add_around_method_modifier {
 217     my ( $self, $name, $code ) = @_;
 218     $self->_install_modifier( $self->name, 'around', $name, $code );
 219 }
 220
 221 sub add_after_method_modifier {
 222     my ( $self, $name, $code ) = @_;
 223     $self->_install_modifier( $self->name, 'after', $name, $code );
 224 }
 225
 226 sub roles { $_[0]->{roles} }
 227
 228 sub does_role {
 229     my ($self, $role_name) = @_;
 230
 231     (defined $role_name)
 232         || confess "You must supply a role name to look for";
 233
 234     for my $role (@{ $self->{roles} }) {
 235         return 1 if $role->name eq $role_name;
 236     }
 237
 238     return 0;
 239 }
 240
 241 sub create {
 242     my ($self, $package_name, %options) = @_;
 243
 244     (ref $options{superclasses} eq 'ARRAY')
 245         || confess "You must pass an ARRAY ref of superclasses"
 246             if exists $options{superclasses};
 247
 248     (ref $options{attributes} eq 'ARRAY')
 249         || confess "You must pass an ARRAY ref of attributes"
 250             if exists $options{attributes};
 251
 252     (ref $options{methods} eq 'HASH')
 253         || confess "You must pass a HASH ref of methods"
 254             if exists $options{methods};
 255
 256     do {
 257         ( defined $package_name && $package_name )
 258           || confess "You must pass a package name";
 259
 260         my $code = "package $package_name;";
 261         $code .= "\$$package_name\:\:VERSION = '" . $options{version} . "';"
 262           if exists $options{version};
 263         $code .= "\$$package_name\:\:AUTHORITY = '" . $options{authority} . "';"
 264           if exists $options{authority};
 265
 266         eval $code;
 267         confess "creation of $package_name failed : $@" if $@;
 268     };
 269
 270     my %initialize_options = %options;
 271     delete @initialize_options{qw(
 272         package
 273         superclasses
 274         attributes
 275         methods
 276         version
 277         authority
 278     )};
 279     my $meta = $self->initialize( $package_name => %initialize_options );
 280
 281     # FIXME totally lame
 282     $meta->add_method('meta' => sub {
 283         $self->initialize(ref($_[0]) || $_[0]);
 284     });
 285
 286     $meta->superclasses(@{$options{superclasses}})
 287         if exists $options{superclasses};
 288     # NOTE:
 289     # process attributes first, so that they can
 290     # install accessors, but locally defined methods
 291     # can then overwrite them. It is maybe a little odd, but
 292     # I think this should be the order of things.
 293     if (exists $options{attributes}) {
 294         foreach my $attr (@{$options{attributes}}) {
 295             Mouse::Meta::Attribute->create($meta, $attr->{name}, %$attr);
 296         }
 297     }
 298     if (exists $options{methods}) {
 299         foreach my $method_name (keys %{$options{methods}}) {
 300             $meta->add_method($method_name, $options{methods}->{$method_name});
 301         }
 302     }
 303     return $meta;
 304 }
 305
 306 {
 307     my $ANON_CLASS_SERIAL = 0;
 308     my $ANON_CLASS_PREFIX = 'Mouse::Meta::Class::__ANON__::SERIAL::';
 309     sub create_anon_class {
 310         my ( $class, %options ) = @_;
 311         my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
 312         return $class->create( $package_name, %options );
 313     }
 314 }
 315
 316 1;
 317
 318 __END__
 319
 320 =head1 NAME
 321
 322 Mouse::Meta::Class - hook into the Mouse MOP
 323
 324 =head1 METHODS
 325
 326 =head2 initialize ClassName -> Mouse::Meta::Class
 327
 328 Finds or creates a Mouse::Meta::Class instance for the given ClassName. Only
 329 one instance should exist for a given class.
 330
 331 =head2 new %args -> Mouse::Meta::Class
 332
 333 Creates a new Mouse::Meta::Class. Don't call this directly.
 334
 335 =head2 name -> ClassName
 336
 337 Returns the name of the owner class.
 338
 339 =head2 superclasses -> [ClassName]
 340
 341 Gets (or sets) the list of superclasses of the owner class.
 342
 343 =head2 add_attribute Mouse::Meta::Attribute
 344
 345 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 346 class.
 347
 348 =head2 compute_all_applicable_attributes -> (Mouse::Meta::Attribute)
 349
 350 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 351 this class and its superclasses.
 352
 353 =head2 get_attribute_map -> { name => Mouse::Meta::Attribute }
 354
 355 Returns a mapping of attribute names to their corresponding
 356 L<Mouse::Meta::Attribute> objects.
 357
 358 =head2 has_attribute Name -> Bool
 359
 360 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 361
 362 =head2 get_attribute Name -> Mouse::Meta::Attribute | undef
 363
 364 Returns the L<Mouse::Meta::Attribute> with the given name.
 365
 366 =head2 linearized_isa -> [ClassNames]
 367
 368 Returns the list of classes in method dispatch order, with duplicates removed.
 369
 370 =head2 clone_object Instance -> Instance
 371
 372 Clones the given C<Instance> which must be an instance governed by this
 373 metaclass.
 374
 375 =head2 clone_instance Instance, Parameters -> Instance
 376
 377 Clones the given C<Instance> and sets any additional parameters.
 378
 379 =cut
 380