lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Module;
   7 our @ISA = qw(Mouse::Meta::Module);
   8
   9 our @CARP_NOT = qw(Mouse); # trust Mouse
  10
  11 sub attribute_metaclass;
  12 sub method_metaclass;
  13
  14 sub constructor_class;
  15 sub destructor_class;
  16
  17
  18 sub _construct_meta {
  19     my($class, %args) = @_;
  20
  21     $args{attributes} = {};
  22     $args{methods}    = {};
  23     $args{roles}      = [];
  24
  25     $args{superclasses} = do {
  26         no strict 'refs';
  27         \@{ $args{package} . '::ISA' };
  28     };
  29
  30     my $self = bless \%args, ref($class) || $class;
  31     if(ref($self) ne __PACKAGE__){
  32         $self->meta->_initialize_object($self, \%args);
  33     }
  34     return $self;
  35 }
  36
  37 sub create_anon_class{
  38     my $self = shift;
  39     return $self->create(undef, @_);
  40 }
  41
  42 sub is_anon_class;
  43
  44 sub roles;
  45
  46 sub calculate_all_roles {
  47     my $self = shift;
  48     my %seen;
  49     return grep { !$seen{ $_->name }++ }
  50            map  { $_->calculate_all_roles } @{ $self->roles };
  51 }
  52
  53 sub superclasses {
  54     my $self = shift;
  55
  56     if (@_) {
  57         foreach my $super(@_){
  58             Mouse::Util::load_class($super);
  59             my $meta = Mouse::Util::get_metaclass_by_name($super);
  60
  61             next if not defined $meta;
  62
  63             if(Mouse::Util::is_a_metarole($meta)){
  64                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  65             }
  66
  67             next if $self->isa(ref $meta); # _superclass_meta_is_compatible
  68
  69             $self->_reconcile_with_superclass_meta($meta);
  70         }
  71         @{ $self->{superclasses} } = @_;
  72     }
  73
  74     return @{ $self->{superclasses} };
  75 }
  76 my @MetaClassTypes = (
  77     'attribute',   # Mouse::Meta::Attribute
  78     'method',      # Mouse::Meta::Method
  79     'constructor', # Mouse::Meta::Method::Constructor
  80     'destructor',  # Mouse::Meta::Method::Destructor
  81 );
  82
  83 sub _reconcile_with_superclass_meta {
  84     my($self, $other) = @_;
  85
  86     # find incompatible traits
  87     my %metaroles;
  88     foreach my $metaclass_type(@MetaClassTypes){
  89         my $accessor = $self->can($metaclass_type . '_metaclass')
  90             || $self->can($metaclass_type . '_class');
  91
  92         my $other_c = $other->$accessor();
  93         my $self_c  = $self->$accessor();
  94
  95         if(!$self_c->isa($other_c)){
  96             $metaroles{$metaclass_type}
  97                 = [ $self_c->meta->_collect_roles($other_c->meta) ];
  98         }
  99     }
 100
 101     $metaroles{class} = [$self->meta->_collect_roles($other->meta)];
 102
 103     #use Data::Dumper; print Data::Dumper->new([\%metaroles], ['*metaroles'])->Indent(1)->Dump;
 104
 105     require Mouse::Util::MetaRole;
 106     $_[0] = Mouse::Util::MetaRole::apply_metaroles(
 107         for             => $self,
 108         class_metaroles => \%metaroles,
 109     );
 110     return;
 111 }
 112
 113 sub _collect_roles {
 114     my ($self, $other) = @_;
 115
 116     # find common ancestor
 117     my @self_lin_isa  = $self->linearized_isa;
 118     my @other_lin_isa = $other->linearized_isa;
 119
 120     my(@self_anon_supers, @other_anon_supers);
 121     push @self_anon_supers,  shift @self_lin_isa  while $self_lin_isa[0]->meta->is_anon_class;
 122     push @other_anon_supers, shift @other_lin_isa while $other_lin_isa[0]->meta->is_anon_class;
 123
 124     my $common_ancestor = $self_lin_isa[0] eq $other_lin_isa[0] && $self_lin_isa[0];
 125
 126     if(!$common_ancestor){
 127         $self->throw_error(sprintf '%s cannot have %s as a super class because of their metaclass incompatibility',
 128             $self->name, $other->name);
 129     }
 130
 131     my %seen;
 132     return sort grep { !$seen{$_}++ } ## no critic
 133         (map{ $_->name } map{ $_->meta->calculate_all_roles } @self_anon_supers),
 134         (map{ $_->name } map{ $_->meta->calculate_all_roles } @other_anon_supers),
 135     ;
 136 }
 137
 138
 139 sub find_method_by_name{
 140     my($self, $method_name) = @_;
 141     defined($method_name)
 142         or $self->throw_error('You must define a method name to find');
 143
 144     foreach my $class( $self->linearized_isa ){
 145         my $method = $self->initialize($class)->get_method($method_name);
 146         return $method if defined $method;
 147     }
 148     return undef;
 149 }
 150
 151 sub get_all_methods {
 152     my($self) = @_;
 153     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
 154 }
 155
 156 sub get_all_method_names {
 157     my $self = shift;
 158     my %uniq;
 159     return grep { $uniq{$_}++ == 0 }
 160             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
 161             $self->linearized_isa;
 162 }
 163
 164 sub find_attribute_by_name{
 165     my($self, $name) = @_;
 166     my $attr;
 167     foreach my $class($self->linearized_isa){
 168         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
 169         $attr = $meta->get_attribute($name) and last;
 170     }
 171     return $attr;
 172 }
 173
 174 sub add_attribute {
 175     my $self = shift;
 176
 177     my($attr, $name);
 178
 179     if(blessed $_[0]){
 180         $attr = $_[0];
 181
 182         $attr->isa('Mouse::Meta::Attribute')
 183             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 184
 185         $name = $attr->name;
 186     }
 187     else{
 188         # _process_attribute
 189         $name = shift;
 190
 191         my %args = (@_ == 1) ? %{$_[0]} : @_;
 192
 193         defined($name)
 194             or $self->throw_error('You must provide a name for the attribute');
 195
 196         if ($name =~ s/^\+//) { # inherited attributes
 197             my $inherited_attr = $self->find_attribute_by_name($name)
 198                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 199
 200             $attr = $inherited_attr->clone_and_inherit_options(%args);
 201         }
 202         else{
 203             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 204             $args{traits} = \@traits if @traits;
 205
 206             $attr = $attribute_class->new($name, %args);
 207         }
 208     }
 209
 210     weaken( $attr->{associated_class} = $self );
 211
 212     # install accessors first
 213     $attr->install_accessors();
 214
 215     # then register the attribute to the metaclass
 216     $attr->{insertion_order} = keys %{ $self->{attributes} };
 217     $self->{attributes}{$attr->name} = $attr;
 218
 219     if(!$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 220         Carp::carp(qq{Attribute ($name) of class }.$self->name
 221             .qq{ has no associated methods (did you mean to provide an "is" argument?)});
 222     }
 223     return $attr;
 224 }
 225
 226 sub linearized_isa;
 227
 228 sub new_object;
 229 sub clone_object;
 230
 231 sub immutable_options {
 232     my ( $self, @args ) = @_;
 233
 234     return (
 235         inline_constructor => 1,
 236         inline_destructor  => 1,
 237         constructor_name   => 'new',
 238         @args,
 239     );
 240 }
 241
 242 sub make_immutable {
 243     my $self = shift;
 244     my %args = $self->immutable_options(@_);
 245
 246     $self->{is_immutable}++;
 247
 248     if ($args{inline_constructor}) {
 249         $self->add_method($args{constructor_name} =>
 250             Mouse::Util::load_class($self->constructor_class)
 251                 ->_generate_constructor($self, \%args));
 252     }
 253
 254     if ($args{inline_destructor}) {
 255         $self->add_method(DESTROY =>
 256             Mouse::Util::load_class($self->destructor_class)
 257                 ->_generate_destructor($self, \%args));
 258     }
 259
 260     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 261     # at the end of a source file.
 262     return 1;
 263 }
 264
 265 sub make_mutable {
 266     my($self) = @_;
 267     $self->{is_immutable} = 0;
 268     return;
 269 }
 270
 271 sub is_immutable;
 272 sub is_mutable   { !$_[0]->is_immutable }
 273
 274 sub _install_modifier_pp{
 275     my( $self, $type, $name, $code ) = @_;
 276     my $into = $self->name;
 277
 278     my $original = $into->can($name)
 279         or $self->throw_error("The method '$name' was not found in the inheritance hierarchy for $into");
 280
 281     my $modifier_table = $self->{modifiers}{$name};
 282
 283     if(!$modifier_table){
 284         my(@before, @after, @around, $cache, $modified);
 285
 286         $cache = $original;
 287
 288         $modified = sub {
 289             for my $c (@before) { $c->(@_) }
 290
 291             if(wantarray){ # list context
 292                 my @rval = $cache->(@_);
 293
 294                 for my $c(@after){ $c->(@_) }
 295                 return @rval;
 296             }
 297             elsif(defined wantarray){ # scalar context
 298                 my $rval = $cache->(@_);
 299
 300                 for my $c(@after){ $c->(@_) }
 301                 return $rval;
 302             }
 303             else{ # void context
 304                 $cache->(@_);
 305
 306                 for my $c(@after){ $c->(@_) }
 307                 return;
 308             }
 309         };
 310
 311         $self->{modifiers}{$name} = $modifier_table = {
 312             original => $original,
 313
 314             before   => \@before,
 315             after    => \@after,
 316             around   => \@around,
 317
 318             cache    => \$cache, # cache for around modifiers
 319         };
 320
 321         $self->add_method($name => $modified);
 322     }
 323
 324     if($type eq 'before'){
 325         unshift @{$modifier_table->{before}}, $code;
 326     }
 327     elsif($type eq 'after'){
 328         push @{$modifier_table->{after}}, $code;
 329     }
 330     else{ # around
 331         push @{$modifier_table->{around}}, $code;
 332
 333         my $next = ${ $modifier_table->{cache} };
 334         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 335     }
 336
 337     return;
 338 }
 339
 340 sub _install_modifier {
 341     my ( $self, $type, $name, $code ) = @_;
 342
 343     # load Data::Util first
 344     my $no_cmm_fast = do{
 345         local $@;
 346         eval q{ use Data::Util 0.55 () };
 347         $@;
 348     };
 349
 350     my $impl;
 351     if($no_cmm_fast){
 352         $impl = \&_install_modifier_pp;
 353     }
 354     else{
 355         $impl = sub {
 356             my ( $self, $type, $name, $code ) = @_;
 357             my $into = $self->name;
 358
 359             my $method = Mouse::Util::get_code_ref( $into, $name );
 360
 361             if ( !$method || !Data::Util::subroutine_modifier($method) ) {
 362                 unless ($method) {
 363                     $method = $into->can($name)
 364                         or $self->throw_error("The method '$name' was not found in the inheritance hierarchy for $into");
 365                 }
 366                 $method = Data::Util::modify_subroutine( $method,
 367                     $type => [$code] );
 368
 369                 $self->add_method($name => $method);
 370             }
 371             else {
 372                 Data::Util::subroutine_modifier( $method, $type => $code );
 373                 $self->add_method($name => Mouse::Util::get_code_ref($into, $name));
 374             }
 375
 376             return;
 377         };
 378     }
 379
 380     # workaround older Perl's bug that caused segv :(
 381     {
 382         no warnings 'once';
 383         our $__not_used = \&_install_modifier; # keep the CV not to be released
 384     }
 385
 386     # replace this method itself :)
 387     {
 388         no warnings 'redefine';
 389         *_install_modifier = $impl;
 390     }
 391
 392     $self->$impl( $type, $name, $code );
 393 }
 394
 395 sub add_before_method_modifier {
 396     my ( $self, $name, $code ) = @_;
 397     $self->_install_modifier( 'before', $name, $code );
 398 }
 399
 400 sub add_around_method_modifier {
 401     my ( $self, $name, $code ) = @_;
 402     $self->_install_modifier( 'around', $name, $code );
 403 }
 404
 405 sub add_after_method_modifier {
 406     my ( $self, $name, $code ) = @_;
 407     $self->_install_modifier( 'after', $name, $code );
 408 }
 409
 410 sub add_override_method_modifier {
 411     my ($self, $name, $code) = @_;
 412
 413     if($self->has_method($name)){
 414         $self->throw_error("Cannot add an override method if a local method is already present");
 415     }
 416
 417     my $package = $self->name;
 418
 419     my $super_body = $package->can($name)
 420         or $self->throw_error("You cannot override '$name' because it has no super method");
 421
 422     $self->add_method($name => sub {
 423         local $Mouse::SUPER_PACKAGE = $package;
 424         local $Mouse::SUPER_BODY    = $super_body;
 425         local @Mouse::SUPER_ARGS    = @_;
 426
 427         $code->(@_);
 428     });
 429     return;
 430 }
 431
 432 sub add_augment_method_modifier {
 433     my ($self, $name, $code) = @_;
 434     if($self->has_method($name)){
 435         $self->throw_error("Cannot add an augment method if a local method is already present");
 436     }
 437
 438     my $super = $self->find_method_by_name($name)
 439         or $self->throw_error("You cannot augment '$name' because it has no super method");
 440
 441     my $super_package = $super->package_name;
 442     my $super_body    = $super->body;
 443
 444     $self->add_method($name => sub{
 445         local $Mouse::INNER_BODY{$super_package} = $code;
 446         local $Mouse::INNER_ARGS{$super_package} = [@_];
 447         $super_body->(@_);
 448     });
 449     return;
 450 }
 451
 452 sub does_role {
 453     my ($self, $role_name) = @_;
 454
 455     (defined $role_name)
 456         || $self->throw_error("You must supply a role name to look for");
 457
 458     $role_name = $role_name->name if ref $role_name;
 459
 460     for my $class ($self->linearized_isa) {
 461         my $meta = Mouse::Util::get_metaclass_by_name($class)
 462             or next;
 463
 464         for my $role (@{ $meta->roles }) {
 465
 466             return 1 if $role->does_role($role_name);
 467         }
 468     }
 469
 470     return 0;
 471 }
 472
 473 1;
 474 __END__
 475
 476 =head1 NAME
 477
 478 Mouse::Meta::Class - The Mouse class metaclass
 479
 480 =head1 VERSION
 481
 482 This document describes Mouse version 0.65
 483
 484 =head1 METHODS
 485
 486 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 487
 488 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 489 one instance should exist for a given class.
 490
 491 =head2 C<< name -> ClassName >>
 492
 493 Returns the name of the owner class.
 494
 495 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 496
 497 Gets (or sets) the list of superclasses of the owner class.
 498
 499 =head2 C<< add_method(name => CodeRef) >>
 500
 501 Adds a method to the owner class.
 502
 503 =head2 C<< has_method(name) -> Bool >>
 504
 505 Returns whether we have a method with the given name.
 506
 507 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 508
 509 Returns a L<Mouse::Meta::Method> with the given name.
 510
 511 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 512
 513 =head2 C<< get_method_list -> Names >>
 514
 515 Returns a list of method names which are defined in the local class.
 516 If you want a list of all applicable methods for a class, use the
 517 C<get_all_methods> method.
 518
 519 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 520
 521 Return the list of all L<Mouse::Meta::Method> instances associated with
 522 the class and its superclasses.
 523
 524 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 525
 526 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 527 class.
 528
 529 =head2 C<< has_attribute(Name) -> Bool >>
 530
 531 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 532
 533 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 534
 535 Returns the L<Mouse::Meta::Attribute> with the given name.
 536
 537 =head2 C<< get_attribute_list -> Names >>
 538
 539 Returns a list of attribute names which are defined in the local
 540 class. If you want a list of all applicable attributes for a class,
 541 use the C<get_all_attributes> method.
 542
 543 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 544
 545 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 546 this class and its superclasses.
 547
 548 =head2 C<< linearized_isa -> [ClassNames] >>
 549
 550 Returns the list of classes in method dispatch order, with duplicates removed.
 551
 552 =head2 C<< new_object(Parameters) -> Instance >>
 553
 554 Creates a new instance.
 555
 556 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 557
 558 Clones the given instance which must be an instance governed by this
 559 metaclass.
 560
 561 =head2 C<< throw_error(Message, Parameters) >>
 562
 563 Throws an error with the given message.
 564
 565 =head1 SEE ALSO
 566
 567 L<Mouse::Meta::Module>
 568
 569 L<Moose::Meta::Class>
 570
 571 L<Class::MOP::Class>
 572
 573 =cut
 574