lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Method::Constructor;
   7 use Mouse::Meta::Method::Destructor;
   8 use Mouse::Meta::Module;
   9 our @ISA = qw(Mouse::Meta::Module);
  10
  11 sub method_metaclass()    { 'Mouse::Meta::Method'    }
  12 sub attribute_metaclass() { 'Mouse::Meta::Attribute' }
  13
  14 sub constructor_class()   { 'Mouse::Meta::Method::Constructor' }
  15 sub destructor_class()    { 'Mouse::Meta::Method::Destructor'  }
  16
  17 sub _construct_meta {
  18     my($class, %args) = @_;
  19
  20     $args{attributes} ||= {};
  21     $args{methods}    ||= {};
  22     $args{roles}      ||= [];
  23
  24     $args{superclasses} = do {
  25         no strict 'refs';
  26         \@{ $args{package} . '::ISA' };
  27     };
  28
  29     my $self = bless \%args, ref($class) || $class;
  30     if(ref($self) ne __PACKAGE__){
  31         $self->meta->_initialize_object($self, \%args);
  32     }
  33     return $self;
  34 }
  35
  36 sub create_anon_class{
  37     my $self = shift;
  38     return $self->create(undef, @_);
  39 }
  40
  41 sub is_anon_class{
  42     return exists $_[0]->{anon_serial_id};
  43 }
  44
  45 sub roles { $_[0]->{roles} }
  46
  47 sub superclasses {
  48     my $self = shift;
  49
  50     if (@_) {
  51         foreach my $super(@_){
  52             Mouse::Util::load_class($super);
  53             my $meta = Mouse::Util::get_metaclass_by_name($super);
  54             if($meta && $meta->isa('Mouse::Meta::Role')){
  55                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  56             }
  57         }
  58         @{ $self->{superclasses} } = @_;
  59     }
  60
  61     return @{ $self->{superclasses} };
  62 }
  63
  64 sub find_method_by_name{
  65     my($self, $method_name) = @_;
  66     defined($method_name)
  67         or $self->throw_error('You must define a method name to find');
  68     foreach my $class( $self->linearized_isa ){
  69         my $method = $self->initialize($class)->get_method($method_name);
  70         return $method if defined $method;
  71     }
  72     return undef;
  73 }
  74
  75 sub get_all_methods {
  76     my($self) = @_;
  77     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
  78 }
  79
  80 sub get_all_method_names {
  81     my $self = shift;
  82     my %uniq;
  83     return grep { $uniq{$_}++ == 0 }
  84             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
  85             $self->linearized_isa;
  86 }
  87
  88 sub find_attribute_by_name{
  89     my($self, $name) = @_;
  90     my $attr;
  91     foreach my $class($self->linearized_isa){
  92         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
  93         $attr = $meta->get_attribute($name) and last;
  94     }
  95     return $attr;
  96 }
  97
  98 sub add_attribute {
  99     my $self = shift;
 100
 101     my($attr, $name);
 102
 103     if(blessed $_[0]){
 104         $attr = $_[0];
 105
 106         $attr->isa('Mouse::Meta::Attribute')
 107             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 108
 109         $name = $attr->name;
 110     }
 111     else{
 112         # _process_attribute
 113         $name = shift;
 114
 115         my %args = (@_ == 1) ? %{$_[0]} : @_;
 116
 117         defined($name)
 118             or $self->throw_error('You must provide a name for the attribute');
 119
 120         if ($name =~ s/^\+//) { # inherited attributes
 121             my $inherited_attr = $self->find_attribute_by_name($name)
 122                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 123
 124             $attr = $inherited_attr->clone_and_inherit_options(%args);
 125         }
 126         else{
 127             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 128             $args{traits} = \@traits if @traits;
 129
 130             $attr = $attribute_class->new($name, %args);
 131         }
 132     }
 133
 134     weaken( $attr->{associated_class} = $self );
 135
 136     $self->{attributes}{$attr->name} = $attr;
 137     $attr->install_accessors();
 138
 139     if(_MOUSE_VERBOSE && !$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 140         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 141     }
 142     return $attr;
 143 }
 144
 145 sub compute_all_applicable_attributes {
 146     Carp::cluck('compute_all_applicable_attributes() has been deprecated');
 147     return shift->get_all_attributes(@_)
 148 }
 149
 150 sub get_all_attributes {
 151     my $self = shift;
 152     my (@attr, %seen);
 153
 154     for my $class ($self->linearized_isa) {
 155         my $meta = Mouse::Util::get_metaclass_by_name($class)
 156             or next;
 157
 158         for my $name ($meta->get_attribute_list) {
 159             next if $seen{$name}++;
 160             push @attr, $meta->get_attribute($name);
 161         }
 162     }
 163
 164     return @attr;
 165 }
 166
 167 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 168
 169 sub new_object {
 170     my $self = shift;
 171     my %args = (@_ == 1 ? %{$_[0]} : @_);
 172
 173     my $object = bless {}, $self->name;
 174
 175     $self->_initialize_object($object, \%args);
 176     return $object;
 177 }
 178
 179 sub _initialize_object{
 180     my($self, $object, $args) = @_;
 181
 182     my @triggers_queue;
 183
 184     foreach my $attribute ($self->get_all_attributes) {
 185         my $from = $attribute->init_arg;
 186         my $key  = $attribute->name;
 187
 188         if (defined($from) && exists($args->{$from})) {
 189             $object->{$key} = $attribute->_coerce_and_verify($args->{$from});
 190
 191             weaken($object->{$key})
 192                 if ref($object->{$key}) && $attribute->is_weak_ref;
 193
 194             if ($attribute->has_trigger) {
 195                 push @triggers_queue, [ $attribute->trigger, $object->{$key} ];
 196             }
 197         }
 198         else {
 199             if ($attribute->has_default || $attribute->has_builder) {
 200                 unless ($attribute->is_lazy) {
 201                     my $default = $attribute->default;
 202                     my $builder = $attribute->builder;
 203                     my $value =   $builder                ? $object->$builder()
 204                                 : ref($default) eq 'CODE' ? $object->$default()
 205                                 :                           $default;
 206
 207                     # XXX: we cannot use $attribute->set_value() because it invokes triggers.
 208                     $object->{$key} = $attribute->_coerce_and_verify($value, $object);;
 209
 210                     weaken($object->{$key})
 211                         if ref($object->{$key}) && $attribute->is_weak_ref;
 212                 }
 213             }
 214             else {
 215                 if ($attribute->is_required) {
 216                     $self->throw_error("Attribute (".$attribute->name.") is required");
 217                 }
 218             }
 219         }
 220     }
 221
 222     foreach my $trigger_and_value(@triggers_queue){
 223         my($trigger, $value) = @{$trigger_and_value};
 224         $trigger->($object, $value);
 225     }
 226
 227     if($self->is_anon_class){
 228         $object->{__METACLASS__} = $self;
 229     }
 230
 231     return $object;
 232 }
 233
 234 sub clone_object {
 235     my $class  = shift;
 236     my $object = shift;
 237     my %params = (@_ == 1) ? %{$_[0]} : @_;
 238
 239     (blessed($object) && $object->isa($class->name))
 240         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 241
 242     my $cloned = bless { %$object }, ref $object;
 243     $class->_initialize_object($cloned, \%params);
 244
 245     return $cloned;
 246 }
 247
 248 sub clone_instance {
 249     my ($class, $instance, %params) = @_;
 250
 251     Carp::cluck('clone_instance has been deprecated. Use clone_object instead')
 252         if _MOUSE_VERBOSE;
 253     return $class->clone_object($instance, %params);
 254 }
 255
 256 sub make_immutable {
 257     my $self = shift;
 258     my %args = (
 259         inline_constructor => 1,
 260         inline_destructor  => 1,
 261         constructor_name   => 'new',
 262         @_,
 263     );
 264
 265     $self->{is_immutable}++;
 266
 267     if ($args{inline_constructor}) {
 268         $self->add_method($args{constructor_name} =>
 269             $self->constructor_class->_generate_constructor($self, \%args));
 270     }
 271
 272     if ($args{inline_destructor}) {
 273         $self->add_method(DESTROY =>
 274             $self->destructor_class->_generate_destructor($self, \%args));
 275     }
 276
 277     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 278     # at the end of a source file.
 279     return 1;
 280 }
 281
 282 sub make_mutable { not_supported }
 283
 284 sub is_immutable {  $_[0]->{is_immutable} }
 285 sub is_mutable   { !$_[0]->{is_immutable} }
 286
 287 sub _install_modifier_pp{
 288     my( $self, $type, $name, $code ) = @_;
 289     my $into = $self->name;
 290
 291     my $original = $into->can($name)
 292         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 293
 294     my $modifier_table = $self->{modifiers}{$name};
 295
 296     if(!$modifier_table){
 297         my(@before, @after, @around, $cache, $modified);
 298
 299         $cache = $original;
 300
 301         $modified = sub {
 302             for my $c (@before) { $c->(@_) }
 303
 304             if(wantarray){ # list context
 305                 my @rval = $cache->(@_);
 306
 307                 for my $c(@after){ $c->(@_) }
 308                 return @rval;
 309             }
 310             elsif(defined wantarray){ # scalar context
 311                 my $rval = $cache->(@_);
 312
 313                 for my $c(@after){ $c->(@_) }
 314                 return $rval;
 315             }
 316             else{ # void context
 317                 $cache->(@_);
 318
 319                 for my $c(@after){ $c->(@_) }
 320                 return;
 321             }
 322         };
 323
 324         $self->{modifiers}{$name} = $modifier_table = {
 325             original => $original,
 326
 327             before   => \@before,
 328             after    => \@after,
 329             around   => \@around,
 330
 331             cache    => \$cache, # cache for around modifiers
 332         };
 333
 334         $self->add_method($name => $modified);
 335     }
 336
 337     if($type eq 'before'){
 338         unshift @{$modifier_table->{before}}, $code;
 339     }
 340     elsif($type eq 'after'){
 341         push @{$modifier_table->{after}}, $code;
 342     }
 343     else{ # around
 344         push @{$modifier_table->{around}}, $code;
 345
 346         my $next = ${ $modifier_table->{cache} };
 347         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 348     }
 349
 350     return;
 351 }
 352
 353 sub _install_modifier {
 354     my ( $self, $type, $name, $code ) = @_;
 355
 356     # load Class::Method::Modifiers first
 357     my $no_cmm_fast = do{
 358         local $@;
 359         eval q{ require Class::Method::Modifiers::Fast };
 360         $@;
 361     };
 362
 363     my $impl;
 364     if($no_cmm_fast){
 365         $impl = \&_install_modifier_pp;
 366     }
 367     else{
 368         my $install_modifier = Class::Method::Modifiers::Fast->can('_install_modifier');
 369         $impl = sub {
 370             my ( $self, $type, $name, $code ) = @_;
 371             my $into = $self->name;
 372             $install_modifier->($into, $type, $name, $code);
 373
 374             $self->add_method($name => do{
 375                 no strict 'refs';
 376                 \&{ $into . '::' . $name };
 377             });
 378             return;
 379         };
 380     }
 381
 382     # replace this method itself :)
 383     {
 384         no warnings 'redefine';
 385         *_install_modifier = $impl;
 386     }
 387
 388     $self->$impl( $type, $name, $code );
 389 }
 390
 391 sub add_before_method_modifier {
 392     my ( $self, $name, $code ) = @_;
 393     $self->_install_modifier( 'before', $name, $code );
 394 }
 395
 396 sub add_around_method_modifier {
 397     my ( $self, $name, $code ) = @_;
 398     $self->_install_modifier( 'around', $name, $code );
 399 }
 400
 401 sub add_after_method_modifier {
 402     my ( $self, $name, $code ) = @_;
 403     $self->_install_modifier( 'after', $name, $code );
 404 }
 405
 406 sub add_override_method_modifier {
 407     my ($self, $name, $code) = @_;
 408
 409     if($self->has_method($name)){
 410         $self->throw_error("Cannot add an override method if a local method is already present");
 411     }
 412
 413     my $package = $self->name;
 414
 415     my $super_body = $package->can($name)
 416         or $self->throw_error("You cannot override '$name' because it has no super method");
 417
 418     $self->add_method($name => sub {
 419         local $Mouse::SUPER_PACKAGE = $package;
 420         local $Mouse::SUPER_BODY    = $super_body;
 421         local @Mouse::SUPER_ARGS    = @_;
 422
 423         $code->(@_);
 424     });
 425     return;
 426 }
 427
 428 sub add_augment_method_modifier {
 429     my ($self, $name, $code) = @_;
 430     if($self->has_method($name)){
 431         $self->throw_error("Cannot add an augment method if a local method is already present");
 432     }
 433
 434     my $super = $self->find_method_by_name($name)
 435         or $self->throw_error("You cannot augment '$name' because it has no super method");
 436
 437     my $super_package = $super->package_name;
 438     my $super_body    = $super->body;
 439
 440     $self->add_method($name => sub{
 441         local $Mouse::INNER_BODY{$super_package} = $code;
 442         local $Mouse::INNER_ARGS{$super_package} = [@_];
 443         $super_body->(@_);
 444     });
 445     return;
 446 }
 447
 448 sub does_role {
 449     my ($self, $role_name) = @_;
 450
 451     (defined $role_name)
 452         || $self->throw_error("You must supply a role name to look for");
 453
 454     for my $class ($self->linearized_isa) {
 455         my $meta = Mouse::Util::get_metaclass_by_name($class)
 456             or next;
 457
 458         for my $role (@{ $meta->roles }) {
 459
 460             return 1 if $role->does_role($role_name);
 461         }
 462     }
 463
 464     return 0;
 465 }
 466
 467 1;
 468 __END__
 469
 470 =head1 NAME
 471
 472 Mouse::Meta::Class - The Mouse class metaclass
 473
 474 =head1 METHODS
 475
 476 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 477
 478 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 479 one instance should exist for a given class.
 480
 481 =head2 C<< name -> ClassName >>
 482
 483 Returns the name of the owner class.
 484
 485 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 486
 487 Gets (or sets) the list of superclasses of the owner class.
 488
 489 =head2 C<< add_method(name => CodeRef) >>
 490
 491 Adds a method to the owner class.
 492
 493 =head2 C<< has_method(name) -> Bool >>
 494
 495 Returns whether we have a method with the given name.
 496
 497 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 498
 499 Returns a L<Mouse::Meta::Method> with the given name.
 500
 501 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 502
 503 =head2 C<< get_method_list -> Names >>
 504
 505 Returns a list of method names which are defined in the local class.
 506 If you want a list of all applicable methods for a class, use the
 507 C<get_all_methods> method.
 508
 509 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 510
 511 Return the list of all L<Mouse::Meta::Method> instances associated with
 512 the class and its superclasses.
 513
 514 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 515
 516 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 517 class.
 518
 519 =head2 C<< has_attribute(Name) -> Bool >>
 520
 521 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 522
 523 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 524
 525 Returns the L<Mouse::Meta::Attribute> with the given name.
 526
 527 =head2 C<< get_attribute_list -> Names >>
 528
 529 Returns a list of attribute names which are defined in the local
 530 class. If you want a list of all applicable attributes for a class,
 531 use the C<get_all_attributes> method.
 532
 533 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 534
 535 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 536 this class and its superclasses.
 537
 538 =head2 C<< linearized_isa -> [ClassNames] >>
 539
 540 Returns the list of classes in method dispatch order, with duplicates removed.
 541
 542 =head2 C<< new_object(Parameters) -> Instance >>
 543
 544 Creates a new instance.
 545
 546 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 547
 548 Clones the given instance which must be an instance governed by this
 549 metaclass.
 550
 551 =head2 C<< throw_error(Message, Parameters) >>
 552
 553 Throws an error with the given message.
 554
 555 =head1 SEE ALSO
 556
 557 L<Moose::Meta::Class>
 558
 559 L<Class::MOP::Class>
 560
 561 =cut
 562