lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Method::Constructor;
   7 use Mouse::Meta::Method::Destructor;
   8 use Mouse::Meta::Module;
   9 our @ISA = qw(Mouse::Meta::Module);
  10
  11 sub method_metaclass()    { 'Mouse::Meta::Method'    }
  12 sub attribute_metaclass() { 'Mouse::Meta::Attribute' }
  13
  14 sub constructor_class()   { 'Mouse::Meta::Method::Constructor' }
  15 sub destructor_class()    { 'Mouse::Meta::Method::Destructor'  }
  16
  17 sub _construct_meta {
  18     my($class, %args) = @_;
  19
  20     $args{attributes} ||= {};
  21     $args{methods}    ||= {};
  22     $args{roles}      ||= [];
  23
  24     $args{superclasses} = do {
  25         no strict 'refs';
  26         \@{ $args{package} . '::ISA' };
  27     };
  28
  29     my $self = bless \%args, ref($class) || $class;
  30     if(ref($self) ne __PACKAGE__){
  31         $self->meta->_initialize_object($self, \%args);
  32     }
  33     return $self;
  34 }
  35
  36 sub create_anon_class{
  37     my $self = shift;
  38     return $self->create(undef, @_);
  39 }
  40
  41 sub is_anon_class{
  42     return exists $_[0]->{anon_serial_id};
  43 }
  44
  45 sub roles { $_[0]->{roles} }
  46
  47 sub superclasses {
  48     my $self = shift;
  49
  50     if (@_) {
  51         foreach my $super(@_){
  52             Mouse::Util::load_class($super);
  53             my $meta = Mouse::Util::get_metaclass_by_name($super);
  54             if($meta && $meta->isa('Mouse::Meta::Role')){
  55                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  56             }
  57         }
  58         @{ $self->{superclasses} } = @_;
  59     }
  60
  61     return @{ $self->{superclasses} };
  62 }
  63
  64 sub find_method_by_name{
  65     my($self, $method_name) = @_;
  66     defined($method_name)
  67         or $self->throw_error('You must define a method name to find');
  68     foreach my $class( $self->linearized_isa ){
  69         my $method = $self->initialize($class)->get_method($method_name);
  70         return $method if defined $method;
  71     }
  72     return undef;
  73 }
  74
  75 sub get_all_methods {
  76     my($self) = @_;
  77     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
  78 }
  79
  80 sub get_all_method_names {
  81     my $self = shift;
  82     my %uniq;
  83     return grep { $uniq{$_}++ == 0 }
  84             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
  85             $self->linearized_isa;
  86 }
  87
  88 sub find_attribute_by_name{
  89     my($self, $name) = @_;
  90     my $attr;
  91     foreach my $class($self->linearized_isa){
  92         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
  93         $attr = $meta->get_attribute($name) and last;
  94     }
  95     return $attr;
  96 }
  97
  98 sub add_attribute {
  99     my $self = shift;
 100
 101     my($attr, $name);
 102
 103     if(blessed $_[0]){
 104         $attr = $_[0];
 105
 106         $attr->isa('Mouse::Meta::Attribute')
 107             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 108
 109         $name = $attr->name;
 110     }
 111     else{
 112         # _process_attribute
 113         $name = shift;
 114
 115         my %args = (@_ == 1) ? %{$_[0]} : @_;
 116
 117         defined($name)
 118             or $self->throw_error('You must provide a name for the attribute');
 119
 120         if ($name =~ s/^\+//) { # inherited attributes
 121             my $inherited_attr = $self->find_attribute_by_name($name)
 122                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 123
 124             $attr = $inherited_attr->clone_and_inherit_options(%args);
 125         }
 126         else{
 127             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 128             $args{traits} = \@traits if @traits;
 129
 130             $attr = $attribute_class->new($name, %args);
 131         }
 132     }
 133
 134     weaken( $attr->{associated_class} = $self );
 135
 136     $self->{attributes}{$attr->name} = $attr;
 137     $attr->install_accessors();
 138
 139     if(_MOUSE_VERBOSE && !$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 140         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 141     }
 142     return $attr;
 143 }
 144
 145 sub compute_all_applicable_attributes {
 146     Carp::cluck('compute_all_applicable_attributes() has been deprecated');
 147     return shift->get_all_attributes(@_)
 148 }
 149
 150 sub get_all_attributes {
 151     my $self = shift;
 152     my (@attr, %seen);
 153
 154     for my $class ($self->linearized_isa) {
 155         my $meta = Mouse::Util::get_metaclass_by_name($class)
 156             or next;
 157
 158         for my $name ($meta->get_attribute_list) {
 159             next if $seen{$name}++;
 160             push @attr, $meta->get_attribute($name);
 161         }
 162     }
 163
 164     return @attr;
 165 }
 166
 167 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 168
 169 sub new_object {
 170     my $self = shift;
 171     my %args = (@_ == 1 ? %{$_[0]} : @_);
 172
 173     my $object = bless {}, $self->name;
 174
 175     $self->_initialize_object($object, \%args);
 176     return $object;
 177 }
 178
 179 sub _initialize_object{
 180     my($self, $object, $args) = @_;
 181
 182     my @triggers_queue;
 183
 184     foreach my $attribute ($self->get_all_attributes) {
 185         my $from = $attribute->init_arg;
 186         my $key  = $attribute->name;
 187
 188         if (defined($from) && exists($args->{$from})) {
 189             $object->{$key} = $attribute->_coerce_and_verify($args->{$from});
 190
 191             weaken($object->{$key})
 192                 if ref($object->{$key}) && $attribute->is_weak_ref;
 193
 194             if ($attribute->has_trigger) {
 195                 push @triggers_queue, [ $attribute->trigger, $object->{$key} ];
 196             }
 197         }
 198         else {
 199             if ($attribute->has_default || $attribute->has_builder) {
 200                 unless ($attribute->is_lazy) {
 201                     my $default = $attribute->default;
 202                     my $builder = $attribute->builder;
 203                     my $value =   $builder                ? $object->$builder()
 204                                 : ref($default) eq 'CODE' ? $object->$default()
 205                                 :                           $default;
 206
 207                     $object->{$key} = $attribute->_coerce_and_verify($value, $object);;
 208
 209                     weaken($object->{$key})
 210                         if ref($object->{$key}) && $attribute->is_weak_ref;
 211                 }
 212             }
 213             else {
 214                 if ($attribute->is_required) {
 215                     $self->throw_error("Attribute (".$attribute->name.") is required");
 216                 }
 217             }
 218         }
 219     }
 220
 221     foreach my $trigger_and_value(@triggers_queue){
 222         my($trigger, $value) = @{$trigger_and_value};
 223         $trigger->($object, $value);
 224     }
 225
 226     if($self->is_anon_class){
 227         $object->{__METACLASS__} = $self;
 228     }
 229
 230     return $object;
 231 }
 232
 233 sub clone_object {
 234     my $class  = shift;
 235     my $object = shift;
 236     my %params = (@_ == 1) ? %{$_[0]} : @_;
 237
 238     (blessed($object) && $object->isa($class->name))
 239         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 240
 241     my $cloned = bless { %$object }, ref $object;
 242     $class->_initialize_object($cloned, \%params);
 243
 244     return $cloned;
 245 }
 246
 247 sub clone_instance {
 248     my ($class, $instance, %params) = @_;
 249
 250     Carp::cluck('clone_instance has been deprecated. Use clone_object instead')
 251         if _MOUSE_VERBOSE;
 252     return $class->clone_object($instance, %params);
 253 }
 254
 255 sub make_immutable {
 256     my $self = shift;
 257     my %args = (
 258         inline_constructor => 1,
 259         inline_destructor  => 1,
 260         constructor_name   => 'new',
 261         @_,
 262     );
 263
 264     $self->{is_immutable}++;
 265
 266     if ($args{inline_constructor}) {
 267         $self->add_method($args{constructor_name} =>
 268             $self->constructor_class->_generate_constructor($self, \%args));
 269     }
 270
 271     if ($args{inline_destructor}) {
 272         $self->add_method(DESTROY =>
 273             $self->destructor_class->_generate_destructor($self, \%args));
 274     }
 275
 276     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 277     # at the end of a source file.
 278     return 1;
 279 }
 280
 281 sub make_mutable { not_supported }
 282
 283 sub is_immutable {  $_[0]->{is_immutable} }
 284 sub is_mutable   { !$_[0]->{is_immutable} }
 285
 286 sub _install_modifier_pp{
 287     my( $self, $type, $name, $code ) = @_;
 288     my $into = $self->name;
 289
 290     my $original = $into->can($name)
 291         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 292
 293     my $modifier_table = $self->{modifiers}{$name};
 294
 295     if(!$modifier_table){
 296         my(@before, @after, @around, $cache, $modified);
 297
 298         $cache = $original;
 299
 300         $modified = sub {
 301             for my $c (@before) { $c->(@_) }
 302
 303             if(wantarray){ # list context
 304                 my @rval = $cache->(@_);
 305
 306                 for my $c(@after){ $c->(@_) }
 307                 return @rval;
 308             }
 309             elsif(defined wantarray){ # scalar context
 310                 my $rval = $cache->(@_);
 311
 312                 for my $c(@after){ $c->(@_) }
 313                 return $rval;
 314             }
 315             else{ # void context
 316                 $cache->(@_);
 317
 318                 for my $c(@after){ $c->(@_) }
 319                 return;
 320             }
 321         };
 322
 323         $self->{modifiers}{$name} = $modifier_table = {
 324             original => $original,
 325
 326             before   => \@before,
 327             after    => \@after,
 328             around   => \@around,
 329
 330             cache    => \$cache, # cache for around modifiers
 331         };
 332
 333         $self->add_method($name => $modified);
 334     }
 335
 336     if($type eq 'before'){
 337         unshift @{$modifier_table->{before}}, $code;
 338     }
 339     elsif($type eq 'after'){
 340         push @{$modifier_table->{after}}, $code;
 341     }
 342     else{ # around
 343         push @{$modifier_table->{around}}, $code;
 344
 345         my $next = ${ $modifier_table->{cache} };
 346         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 347     }
 348
 349     return;
 350 }
 351
 352 sub _install_modifier {
 353     my ( $self, $type, $name, $code ) = @_;
 354
 355     # load Class::Method::Modifiers first
 356     my $no_cmm_fast = do{
 357         local $@;
 358         eval q{ require Class::Method::Modifiers::Fast };
 359         $@;
 360     };
 361
 362     my $impl;
 363     if($no_cmm_fast){
 364         $impl = \&_install_modifier_pp;
 365     }
 366     else{
 367         my $install_modifier = Class::Method::Modifiers::Fast->can('_install_modifier');
 368         $impl = sub {
 369             my ( $self, $type, $name, $code ) = @_;
 370             my $into = $self->name;
 371             $install_modifier->($into, $type, $name, $code);
 372
 373             $self->add_method($name => do{
 374                 no strict 'refs';
 375                 \&{ $into . '::' . $name };
 376             });
 377             return;
 378         };
 379     }
 380
 381     # replace this method itself :)
 382     {
 383         no warnings 'redefine';
 384         *_install_modifier = $impl;
 385     }
 386
 387     $self->$impl( $type, $name, $code );
 388 }
 389
 390 sub add_before_method_modifier {
 391     my ( $self, $name, $code ) = @_;
 392     $self->_install_modifier( 'before', $name, $code );
 393 }
 394
 395 sub add_around_method_modifier {
 396     my ( $self, $name, $code ) = @_;
 397     $self->_install_modifier( 'around', $name, $code );
 398 }
 399
 400 sub add_after_method_modifier {
 401     my ( $self, $name, $code ) = @_;
 402     $self->_install_modifier( 'after', $name, $code );
 403 }
 404
 405 sub add_override_method_modifier {
 406     my ($self, $name, $code) = @_;
 407
 408     if($self->has_method($name)){
 409         $self->throw_error("Cannot add an override method if a local method is already present");
 410     }
 411
 412     my $package = $self->name;
 413
 414     my $super_body = $package->can($name)
 415         or $self->throw_error("You cannot override '$name' because it has no super method");
 416
 417     $self->add_method($name => sub {
 418         local $Mouse::SUPER_PACKAGE = $package;
 419         local $Mouse::SUPER_BODY    = $super_body;
 420         local @Mouse::SUPER_ARGS    = @_;
 421
 422         $code->(@_);
 423     });
 424     return;
 425 }
 426
 427 sub add_augment_method_modifier {
 428     my ($self, $name, $code) = @_;
 429     if($self->has_method($name)){
 430         $self->throw_error("Cannot add an augment method if a local method is already present");
 431     }
 432
 433     my $super = $self->find_method_by_name($name)
 434         or $self->throw_error("You cannot augment '$name' because it has no super method");
 435
 436     my $super_package = $super->package_name;
 437     my $super_body    = $super->body;
 438
 439     $self->add_method($name => sub{
 440         local $Mouse::INNER_BODY{$super_package} = $code;
 441         local $Mouse::INNER_ARGS{$super_package} = [@_];
 442         $super_body->(@_);
 443     });
 444     return;
 445 }
 446
 447 sub does_role {
 448     my ($self, $role_name) = @_;
 449
 450     (defined $role_name)
 451         || $self->throw_error("You must supply a role name to look for");
 452
 453     for my $class ($self->linearized_isa) {
 454         my $meta = Mouse::Util::get_metaclass_by_name($class)
 455             or next;
 456
 457         for my $role (@{ $meta->roles }) {
 458
 459             return 1 if $role->does_role($role_name);
 460         }
 461     }
 462
 463     return 0;
 464 }
 465
 466 1;
 467 __END__
 468
 469 =head1 NAME
 470
 471 Mouse::Meta::Class - The Mouse class metaclass
 472
 473 =head1 METHODS
 474
 475 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 476
 477 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 478 one instance should exist for a given class.
 479
 480 =head2 C<< name -> ClassName >>
 481
 482 Returns the name of the owner class.
 483
 484 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 485
 486 Gets (or sets) the list of superclasses of the owner class.
 487
 488 =head2 C<< add_method(name => CodeRef) >>
 489
 490 Adds a method to the owner class.
 491
 492 =head2 C<< has_method(name) -> Bool >>
 493
 494 Returns whether we have a method with the given name.
 495
 496 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 497
 498 Returns a L<Mouse::Meta::Method> with the given name.
 499
 500 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 501
 502 =head2 C<< get_method_list -> Names >>
 503
 504 Returns a list of method names which are defined in the local class.
 505 If you want a list of all applicable methods for a class, use the
 506 C<get_all_methods> method.
 507
 508 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 509
 510 Return the list of all L<Mouse::Meta::Method> instances associated with
 511 the class and its superclasses.
 512
 513 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 514
 515 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 516 class.
 517
 518 =head2 C<< has_attribute(Name) -> Bool >>
 519
 520 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 521
 522 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 523
 524 Returns the L<Mouse::Meta::Attribute> with the given name.
 525
 526 =head2 C<< get_attribute_list -> Names >>
 527
 528 Returns a list of attribute names which are defined in the local
 529 class. If you want a list of all applicable attributes for a class,
 530 use the C<get_all_attributes> method.
 531
 532 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 533
 534 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 535 this class and its superclasses.
 536
 537 =head2 C<< linearized_isa -> [ClassNames] >>
 538
 539 Returns the list of classes in method dispatch order, with duplicates removed.
 540
 541 =head2 C<< new_object(Parameters) -> Instance >>
 542
 543 Creates a new instance.
 544
 545 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 546
 547 Clones the given instance which must be an instance governed by this
 548 metaclass.
 549
 550 =head2 C<< throw_error(Message, Parameters) >>
 551
 552 Throws an error with the given message.
 553
 554 =head1 SEE ALSO
 555
 556 L<Moose::Meta::Class>
 557
 558 L<Class::MOP::Class>
 559
 560 =cut
 561