lib/Mouse/Meta/Class.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Class;
   3 use strict;
   4 use warnings;
   5
   6 use Mouse::Meta::Method::Constructor;
   7 use Mouse::Meta::Method::Destructor;
   8 use Scalar::Util qw/blessed/;
   9 use Mouse::Util qw/get_linear_isa/;
  10 use Carp 'confess';
  11
  12 do {
  13     my %METACLASS_CACHE;
  14
  15     # because Mouse doesn't introspect existing classes, we're forced to
  16     # only pay attention to other Mouse classes
  17     sub _metaclass_cache {
  18         my $class = shift;
  19         my $name  = shift;
  20         return $METACLASS_CACHE{$name};
  21     }
  22
  23     sub initialize {
  24         my $class = shift;
  25         my $name  = shift;
  26         $METACLASS_CACHE{$name} = $class->new(name => $name)
  27             if !exists($METACLASS_CACHE{$name});
  28         return $METACLASS_CACHE{$name};
  29     }
  30 };
  31
  32 sub new {
  33     my $class = shift;
  34     my %args  = @_;
  35
  36     $args{attributes} = {};
  37     $args{superclasses} = do {
  38         no strict 'refs';
  39         \@{ $args{name} . '::ISA' };
  40     };
  41     $args{roles} ||= [];
  42
  43     bless \%args, $class;
  44 }
  45
  46 sub name { $_[0]->{name} }
  47
  48 sub superclasses {
  49     my $self = shift;
  50
  51     if (@_) {
  52         Mouse::load_class($_) for @_;
  53         @{ $self->{superclasses} } = @_;
  54     }
  55
  56     @{ $self->{superclasses} };
  57 }
  58
  59 sub add_method {
  60     my $self = shift;
  61     my $name = shift;
  62     my $code = shift;
  63
  64     my $pkg = $self->name;
  65
  66     no strict 'refs';
  67     $self->{'methods'}->{$name}++; # Moose stores meta object here.
  68     *{ $pkg . '::' . $name } = $code;
  69 }
  70
  71 # copied from Class::Inspector
  72 sub get_method_list {
  73     my $self = shift;
  74     my $name = $self->name;
  75
  76     no strict 'refs';
  77     # Get all the CODE symbol table entries
  78     my @functions =
  79       grep !/(?:has|with|around|before|after|blessed|extends|confess)/,
  80       grep { defined &{"${name}::$_"} }
  81       keys %{"${name}::"};
  82     push @functions, keys %{$self->{'methods'}->{$name}};
  83     wantarray ? @functions : \@functions;
  84 }
  85
  86 sub add_attribute {
  87     my $self = shift;
  88     my $attr = shift;
  89
  90     $self->{'attributes'}{$attr->name} = $attr;
  91 }
  92
  93 sub compute_all_applicable_attributes {
  94     my $self = shift;
  95     my (@attr, %seen);
  96
  97     for my $class ($self->linearized_isa) {
  98         my $meta = $self->_metaclass_cache($class)
  99             or next;
 100
 101         for my $name (keys %{ $meta->get_attribute_map }) {
 102             next if $seen{$name}++;
 103             push @attr, $meta->get_attribute($name);
 104         }
 105     }
 106
 107     return @attr;
 108 }
 109
 110 sub get_attribute_map { $_[0]->{attributes} }
 111 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
 112 sub get_attribute     { $_[0]->{attributes}->{$_[1]} }
 113
 114 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 115
 116 sub clone_object {
 117     my $class    = shift;
 118     my $instance = shift;
 119
 120     (blessed($instance) && $instance->isa($class->name))
 121         || confess "You must pass an instance of the metaclass (" . $class->name . "), not ($instance)";
 122
 123     $class->clone_instance($instance, @_);
 124 }
 125
 126 sub clone_instance {
 127     my ($class, $instance, %params) = @_;
 128
 129     (blessed($instance))
 130         || confess "You can only clone instances, ($instance) is not a blessed instance";
 131
 132     my $clone = bless { %$instance }, ref $instance;
 133
 134     foreach my $attr ($class->compute_all_applicable_attributes()) {
 135         if ( defined( my $init_arg = $attr->init_arg ) ) {
 136             if (exists $params{$init_arg}) {
 137                 $clone->{ $attr->name } = $params{$init_arg};
 138             }
 139         }
 140     }
 141
 142     return $clone;
 143
 144 }
 145
 146 sub make_immutable {
 147     my $self = shift;
 148     my %args = @_;
 149     my $name = $self->name;
 150     $self->{is_immutable}++;
 151     $self->add_method('new' => Mouse::Meta::Method::Constructor->generate_constructor_method_inline( $self ));
 152     if ($args{inline_destructor}) {
 153         $self->add_method('DESTROY' => Mouse::Meta::Method::Destructor->generate_destructor_method_inline( $self ));
 154     }
 155 }
 156 sub make_mutable {
 157     Carp::croak "Mouse::Meta::Class->make_mutable does not supported by Mouse";
 158 }
 159 sub is_immutable { $_[0]->{is_immutable} }
 160
 161 sub attribute_metaclass { "Mouse::Meta::Class" }
 162
 163 sub add_before_method_modifier {
 164     my ($self, $name, $code) = @_;
 165     require Class::Method::Modifiers;
 166     Class::Method::Modifiers::_install_modifier(
 167         $self->name,
 168         'before',
 169         $name,
 170         $code,
 171     );
 172 }
 173
 174 sub add_around_method_modifier {
 175     my ($self, $name, $code) = @_;
 176     require Class::Method::Modifiers;
 177     Class::Method::Modifiers::_install_modifier(
 178         $self->name,
 179         'around',
 180         $name,
 181         $code,
 182     );
 183 }
 184
 185 sub add_after_method_modifier {
 186     my ($self, $name, $code) = @_;
 187     require Class::Method::Modifiers;
 188     Class::Method::Modifiers::_install_modifier(
 189         $self->name,
 190         'after',
 191         $name,
 192         $code,
 193     );
 194 }
 195
 196 sub roles { $_[0]->{roles} }
 197
 198 sub does_role {
 199     my ($self, $role_name) = @_;
 200     (defined $role_name)
 201         || confess "You must supply a role name to look for";
 202     for my $role (@{ $self->{roles} }) {
 203         return 1 if $role->name eq $role_name;
 204     }
 205     return 0;
 206 }
 207
 208 sub create {
 209     my ( $class, @args ) = @_;
 210
 211     unshift @args, 'package' if @args % 2 == 1;
 212
 213     my (%options) = @args;
 214     my $package_name = $options{package};
 215
 216     (ref $options{superclasses} eq 'ARRAY')
 217         || confess "You must pass an ARRAY ref of superclasses"
 218             if exists $options{superclasses};
 219
 220     (ref $options{attributes} eq 'ARRAY')
 221         || confess "You must pass an ARRAY ref of attributes"
 222             if exists $options{attributes};
 223
 224     (ref $options{methods} eq 'HASH')
 225         || confess "You must pass a HASH ref of methods"
 226             if exists $options{methods};
 227
 228     do {
 229         # XXX should I implement Mouse::Meta::Module?
 230         my $package_name = $options{package};
 231
 232         ( defined $package_name && $package_name )
 233           || confess "You must pass a package name";
 234
 235         my $code = "package $package_name;";
 236         $code .= "\$$package_name\:\:VERSION = '" . $options{version} . "';"
 237           if exists $options{version};
 238         $code .= "\$$package_name\:\:AUTHORITY = '" . $options{authority} . "';"
 239           if exists $options{authority};
 240
 241         eval $code;
 242         confess "creation of $package_name failed : $@" if $@;
 243     };
 244
 245     my (%initialize_options) = @args;
 246     delete @initialize_options{qw(
 247         package
 248         superclasses
 249         attributes
 250         methods
 251         version
 252         authority
 253     )};
 254     my $meta = $class->initialize( $package_name => %initialize_options );
 255
 256     # FIXME totally lame
 257     $meta->add_method('meta' => sub {
 258         $class->initialize(ref($_[0]) || $_[0]);
 259     });
 260
 261     $meta->superclasses(@{$options{superclasses}})
 262         if exists $options{superclasses};
 263     # NOTE:
 264     # process attributes first, so that they can
 265     # install accessors, but locally defined methods
 266     # can then overwrite them. It is maybe a little odd, but
 267     # I think this should be the order of things.
 268     if (exists $options{attributes}) {
 269         foreach my $attr (@{$options{attributes}}) {
 270             Mouse::Meta::Attribute->create($meta, $attr->{name}, %$attr);
 271         }
 272     }
 273     if (exists $options{methods}) {
 274         foreach my $method_name (keys %{$options{methods}}) {
 275             $meta->add_method($method_name, $options{methods}->{$method_name});
 276         }
 277     }
 278     return $meta;
 279 }
 280
 281 {
 282     my $ANON_CLASS_SERIAL = 0;
 283     my $ANON_CLASS_PREFIX = 'Mouse::Meta::Class::__ANON__::SERIAL::';
 284     sub create_anon_class {
 285         my ( $class, %options ) = @_;
 286         my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
 287         return $class->create( $package_name, %options );
 288     }
 289 }
 290
 291 1;
 292
 293 __END__
 294
 295 =head1 NAME
 296
 297 Mouse::Meta::Class - hook into the Mouse MOP
 298
 299 =head1 METHODS
 300
 301 =head2 initialize ClassName -> Mouse::Meta::Class
 302
 303 Finds or creates a Mouse::Meta::Class instance for the given ClassName. Only
 304 one instance should exist for a given class.
 305
 306 =head2 new %args -> Mouse::Meta::Class
 307
 308 Creates a new Mouse::Meta::Class. Don't call this directly.
 309
 310 =head2 name -> ClassName
 311
 312 Returns the name of the owner class.
 313
 314 =head2 superclasses -> [ClassName]
 315
 316 Gets (or sets) the list of superclasses of the owner class.
 317
 318 =head2 add_attribute Mouse::Meta::Attribute
 319
 320 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 321 class.
 322
 323 =head2 compute_all_applicable_attributes -> (Mouse::Meta::Attribute)
 324
 325 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 326 this class and its superclasses.
 327
 328 =head2 get_attribute_map -> { name => Mouse::Meta::Attribute }
 329
 330 Returns a mapping of attribute names to their corresponding
 331 L<Mouse::Meta::Attribute> objects.
 332
 333 =head2 has_attribute Name -> Boool
 334
 335 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 336
 337 =head2 get_attribute Name -> Mouse::Meta::Attribute | undef
 338
 339 Returns the L<Mouse::Meta::Attribute> with the given name.
 340
 341 =head2 linearized_isa -> [ClassNames]
 342
 343 Returns the list of classes in method dispatch order, with duplicates removed.
 344
 345 =head2 clone_object Instance -> Instance
 346
 347 Clones the given C<Instance> which must be an instance governed by this
 348 metaclass.
 349
 350 =head2 clone_instance Instance, Parameters -> Instance
 351
 352 Clones the given C<Instance> and sets any additional parameters.
 353
 354 =cut
 355