lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use strict;
   3 use warnings;
   4
   5 use Mouse::Meta::Method::Constructor;
   6 use Mouse::Meta::Method::Destructor;
   7 use Scalar::Util qw/blessed/;
   8 use Mouse::Util qw/get_linear_isa version authority identifier/;
   9 use Carp 'confess';
  10
  11 do {
  12     my %METACLASS_CACHE;
  13
  14     # because Mouse doesn't introspect existing classes, we're forced to
  15     # only pay attention to other Mouse classes
  16     sub _metaclass_cache {
  17         my $class = shift;
  18         my $name  = shift;
  19         return $METACLASS_CACHE{$name};
  20     }
  21
  22     sub initialize {
  23         my $class = blessed($_[0]) || $_[0];
  24         my $name  = $_[1];
  25
  26         $METACLASS_CACHE{$name} = $class->new(name => $name)
  27             if !exists($METACLASS_CACHE{$name});
  28         return $METACLASS_CACHE{$name};
  29     }
  30 };
  31
  32 sub new {
  33     my $class = shift;
  34     my %args  = @_;
  35
  36     $args{attributes} = {};
  37     $args{superclasses} = do {
  38         no strict 'refs';
  39         \@{ $args{name} . '::ISA' };
  40     };
  41     $args{roles} ||= [];
  42
  43     bless \%args, $class;
  44 }
  45
  46 sub name { $_[0]->{name} }
  47
  48 sub superclasses {
  49     my $self = shift;
  50
  51     if (@_) {
  52         Mouse::load_class($_) for @_;
  53         @{ $self->{superclasses} } = @_;
  54     }
  55
  56     @{ $self->{superclasses} };
  57 }
  58
  59 sub add_method {
  60     my $self = shift;
  61     my $name = shift;
  62     my $code = shift;
  63
  64     my $pkg = $self->name;
  65
  66     no strict 'refs';
  67     no warnings 'redefine';
  68     $self->{'methods'}->{$name}++; # Moose stores meta object here.
  69     *{ $pkg . '::' . $name } = $code;
  70 }
  71
  72 # copied from Class::Inspector
  73 my $get_methods_for_class = sub {
  74     my $self = shift;
  75     my $name = shift;
  76
  77     no strict 'refs';
  78     # Get all the CODE symbol table entries
  79     my @functions =
  80       grep !/^(?:has|with|around|before|after|augment|inner|blessed|extends|confess|override|super)$/,
  81       grep { defined &{"${name}::$_"} }
  82       keys %{"${name}::"};
  83     push @functions, keys %{$self->{'methods'}->{$name}} if $self;
  84     wantarray ? @functions : \@functions;
  85 };
  86
  87 sub get_method_list {
  88     my $self = shift;
  89     $get_methods_for_class->($self, $self->name);
  90 }
  91
  92 sub get_all_method_names {
  93     my $self = shift;
  94     my %uniq;
  95     return grep { $uniq{$_}++ == 0 }
  96             map { $get_methods_for_class->(undef, $_) }
  97             $self->linearized_isa;
  98 }
  99
 100 sub add_attribute {
 101     my $self = shift;
 102
 103     if (@_ == 1 && blessed($_[0])) {
 104         my $attr = shift @_;
 105         $self->{'attributes'}{$attr->name} = $attr;
 106     } else {
 107         my $names = shift @_;
 108         $names = [$names] if !ref($names);
 109         my $metaclass = 'Mouse::Meta::Attribute';
 110         my %options = @_;
 111
 112         if ( my $metaclass_name = delete $options{metaclass} ) {
 113             my $new_class = Mouse::Util::resolve_metaclass_alias(
 114                 'Attribute',
 115                 $metaclass_name
 116             );
 117             if ( $metaclass ne $new_class ) {
 118                 $metaclass = $new_class;
 119             }
 120         }
 121
 122         for my $name (@$names) {
 123             if ($name =~ s/^\+//) {
 124                 $metaclass->clone_parent($self, $name, @_);
 125             }
 126             else {
 127                 $metaclass->create($self, $name, @_);
 128             }
 129         }
 130     }
 131 }
 132
 133 sub compute_all_applicable_attributes {
 134     my $self = shift;
 135     my (@attr, %seen);
 136
 137     for my $class ($self->linearized_isa) {
 138         my $meta = $self->_metaclass_cache($class)
 139             or next;
 140
 141         for my $name (keys %{ $meta->get_attribute_map }) {
 142             next if $seen{$name}++;
 143             push @attr, $meta->get_attribute($name);
 144         }
 145     }
 146
 147     return @attr;
 148 }
 149
 150 sub get_attribute_map { $_[0]->{attributes} }
 151 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
 152 sub get_attribute     { $_[0]->{attributes}->{$_[1]} }
 153
 154 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 155
 156 sub clone_object {
 157     my $class    = shift;
 158     my $instance = shift;
 159
 160     (blessed($instance) && $instance->isa($class->name))
 161         || confess "You must pass an instance of the metaclass (" . $class->name . "), not ($instance)";
 162
 163     $class->clone_instance($instance, @_);
 164 }
 165
 166 sub clone_instance {
 167     my ($class, $instance, %params) = @_;
 168
 169     (blessed($instance))
 170         || confess "You can only clone instances, ($instance) is not a blessed instance";
 171
 172     my $clone = bless { %$instance }, ref $instance;
 173
 174     foreach my $attr ($class->compute_all_applicable_attributes()) {
 175         if ( defined( my $init_arg = $attr->init_arg ) ) {
 176             if (exists $params{$init_arg}) {
 177                 $clone->{ $attr->name } = $params{$init_arg};
 178             }
 179         }
 180     }
 181
 182     return $clone;
 183
 184 }
 185
 186 sub make_immutable {
 187     my $self = shift;
 188     my %args = (
 189         inline_constructor => 1,
 190         @_,
 191     );
 192
 193     my $name = $self->name;
 194     $self->{is_immutable}++;
 195
 196     if ($args{inline_constructor}) {
 197         $self->add_method('new' => Mouse::Meta::Method::Constructor->generate_constructor_method_inline( $self ));
 198     }
 199
 200     if ($args{inline_destructor}) {
 201         $self->add_method('DESTROY' => Mouse::Meta::Method::Destructor->generate_destructor_method_inline( $self ));
 202     }
 203
 204     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 205     # at the end of a source file.
 206     return 1;
 207 }
 208
 209 sub make_mutable { confess "Mouse does not currently support 'make_mutable'" }
 210
 211 sub is_immutable { $_[0]->{is_immutable} }
 212
 213 sub attribute_metaclass { "Mouse::Meta::Class" }
 214
 215 sub _install_modifier {
 216     my ( $self, $into, $type, $name, $code ) = @_;
 217
 218     # which is modifer class available?
 219     my $modifier_class = do {
 220         if (eval "require Class::Method::Modifiers::Fast; 1") {
 221             'Class::Method::Modifiers::Fast';
 222         } elsif (eval "require Class::Method::Modifiers; 1") {
 223             'Class::Method::Modifiers';
 224         } else {
 225             Carp::croak("Method modifiers require the use of Class::Method::Modifiers or Class::Method::Modifiers::Fast. Please install it from CPAN and file a bug report with this application.");
 226         }
 227     };
 228     my $modifier = $modifier_class->can('_install_modifier');
 229
 230     # replace this method itself :)
 231     {
 232         no strict 'refs';
 233         no warnings 'redefine';
 234         *{__PACKAGE__ . '::_install_modifier'} = sub {
 235             my ( $self, $into, $type, $name, $code ) = @_;
 236             $modifier->(
 237                 $into,
 238                 $type,
 239                 $name,
 240                 $code
 241             );
 242         };
 243     }
 244
 245     # call me. for first time.
 246     $self->_install_modifier( $into, $type, $name, $code );
 247 }
 248
 249 sub add_before_method_modifier {
 250     my ( $self, $name, $code ) = @_;
 251     $self->_install_modifier( $self->name, 'before', $name, $code );
 252 }
 253
 254 sub add_around_method_modifier {
 255     my ( $self, $name, $code ) = @_;
 256     $self->_install_modifier( $self->name, 'around', $name, $code );
 257 }
 258
 259 sub add_after_method_modifier {
 260     my ( $self, $name, $code ) = @_;
 261     $self->_install_modifier( $self->name, 'after', $name, $code );
 262 }
 263
 264 sub add_override_method_modifier {
 265     my ($self, $name, $code) = @_;
 266
 267     my $pkg = $self->name;
 268     my $method = "${pkg}::${name}";
 269
 270     # Class::Method::Modifiers won't do this for us, so do it ourselves
 271
 272     my $body = $pkg->can($name)
 273         or confess "You cannot override '$method' because it has no super method";
 274
 275     no strict 'refs';
 276     *$method = sub { $code->($pkg, $body, @_) };
 277 }
 278
 279
 280 sub roles { $_[0]->{roles} }
 281
 282 sub does_role {
 283     my ($self, $role_name) = @_;
 284
 285     (defined $role_name)
 286         || confess "You must supply a role name to look for";
 287
 288     for my $role (@{ $self->{roles} }) {
 289         return 1 if $role->name eq $role_name;
 290     }
 291
 292     return 0;
 293 }
 294
 295 sub create {
 296     my ($self, $package_name, %options) = @_;
 297
 298     (ref $options{superclasses} eq 'ARRAY')
 299         || confess "You must pass an ARRAY ref of superclasses"
 300             if exists $options{superclasses};
 301
 302     (ref $options{attributes} eq 'ARRAY')
 303         || confess "You must pass an ARRAY ref of attributes"
 304             if exists $options{attributes};
 305
 306     (ref $options{methods} eq 'HASH')
 307         || confess "You must pass a HASH ref of methods"
 308             if exists $options{methods};
 309
 310     do {
 311         ( defined $package_name && $package_name )
 312           || confess "You must pass a package name";
 313
 314         my $code = "package $package_name;";
 315         $code .= "\$$package_name\:\:VERSION = '" . $options{version} . "';"
 316           if exists $options{version};
 317         $code .= "\$$package_name\:\:AUTHORITY = '" . $options{authority} . "';"
 318           if exists $options{authority};
 319
 320         eval $code;
 321         confess "creation of $package_name failed : $@" if $@;
 322     };
 323
 324     my %initialize_options = %options;
 325     delete @initialize_options{qw(
 326         package
 327         superclasses
 328         attributes
 329         methods
 330         version
 331         authority
 332     )};
 333     my $meta = $self->initialize( $package_name => %initialize_options );
 334
 335     # FIXME totally lame
 336     $meta->add_method('meta' => sub {
 337         $self->initialize(ref($_[0]) || $_[0]);
 338     });
 339
 340     $meta->superclasses(@{$options{superclasses}})
 341         if exists $options{superclasses};
 342     # NOTE:
 343     # process attributes first, so that they can
 344     # install accessors, but locally defined methods
 345     # can then overwrite them. It is maybe a little odd, but
 346     # I think this should be the order of things.
 347     if (exists $options{attributes}) {
 348         foreach my $attr (@{$options{attributes}}) {
 349             Mouse::Meta::Attribute->create($meta, $attr->{name}, %$attr);
 350         }
 351     }
 352     if (exists $options{methods}) {
 353         foreach my $method_name (keys %{$options{methods}}) {
 354             $meta->add_method($method_name, $options{methods}->{$method_name});
 355         }
 356     }
 357     return $meta;
 358 }
 359
 360 {
 361     my $ANON_CLASS_SERIAL = 0;
 362     my $ANON_CLASS_PREFIX = 'Mouse::Meta::Class::__ANON__::SERIAL::';
 363     sub create_anon_class {
 364         my ( $class, %options ) = @_;
 365         my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
 366         return $class->create( $package_name, %options );
 367     }
 368 }
 369
 370 1;
 371
 372 __END__
 373
 374 =head1 NAME
 375
 376 Mouse::Meta::Class - hook into the Mouse MOP
 377
 378 =head1 METHODS
 379
 380 =head2 initialize ClassName -> Mouse::Meta::Class
 381
 382 Finds or creates a Mouse::Meta::Class instance for the given ClassName. Only
 383 one instance should exist for a given class.
 384
 385 =head2 new %args -> Mouse::Meta::Class
 386
 387 Creates a new Mouse::Meta::Class. Don't call this directly.
 388
 389 =head2 name -> ClassName
 390
 391 Returns the name of the owner class.
 392
 393 =head2 superclasses -> [ClassName]
 394
 395 Gets (or sets) the list of superclasses of the owner class.
 396
 397 =head2 add_attribute (Mouse::Meta::Attribute| name => spec)
 398
 399 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 400 class.
 401
 402 =head2 compute_all_applicable_attributes -> (Mouse::Meta::Attribute)
 403
 404 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 405 this class and its superclasses.
 406
 407 =head2 get_attribute_map -> { name => Mouse::Meta::Attribute }
 408
 409 Returns a mapping of attribute names to their corresponding
 410 L<Mouse::Meta::Attribute> objects.
 411
 412 =head2 has_attribute Name -> Bool
 413
 414 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 415
 416 =head2 get_attribute Name -> Mouse::Meta::Attribute | undef
 417
 418 Returns the L<Mouse::Meta::Attribute> with the given name.
 419
 420 =head2 linearized_isa -> [ClassNames]
 421
 422 Returns the list of classes in method dispatch order, with duplicates removed.
 423
 424 =head2 clone_object Instance -> Instance
 425
 426 Clones the given C<Instance> which must be an instance governed by this
 427 metaclass.
 428
 429 =head2 clone_instance Instance, Parameters -> Instance
 430
 431 Clones the given C<Instance> and sets any additional parameters.
 432
 433 =cut
 434